WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BoundedRegionQ[reg]

reg が有界の領域の場合はTrueを，それ以外の場合はFalseを与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特別な領域  
数式定義領域  
メッシュ領域  
Show More Show More
派生領域  
地理的領域  
CSG領域  
細分割領域  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BoundedRegionQ

BoundedRegionQ[reg]

reg が有界の領域の場合はTrueを，それ以外の場合はFalseを与える．

詳細

  • 有限な範囲のボックスに含まれるなら，その領域は有界である．

例題

すべて開く すべて閉じる

例  (2)

有界領域：

Wolfram Language code: BoundedRegionQ[Disk[]]
Wolfram Language code: Region[Disk[]]

非有界領域：

Wolfram Language code: BoundedRegionQ[HalfPlane[{{0, 0, 0}, {-1, 1, 1}}, {1, 1, 1}]]
Wolfram Language code: Region[HalfPlane[{{0, 0, 0}, {-1, 1, 1}}, {1, 1, 1}], Boxed -> True]

スコープ  (20)

特別な領域  (4)

Pointを含む内の領域：

Wolfram Language code: BoundedRegionQ[Point[{1}]]

Interval：

Wolfram Language code: ℛ = Interval[{1, 2}]; NumberLinePlot[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

HalfLineは非有界である：

Wolfram Language code: BoundedRegionQ[HalfLine[{{1}, {2}}]]

Pointを含む内の領域：

Wolfram Language code: ℛ = Point[Tuples[Range[5], 2]]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Line：

Wolfram Language code: ℛ = Line[{{1, 2}, {4, 3}}]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Polygon：

Wolfram Language code: ℛ = Polygon[{{0, 0}, {2, -1}, {1, 0}, {2, 1}}]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Circle：

Wolfram Language code: ℛ = Circle[{1, 2}, 3]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Disk：

Wolfram Language code: ℛ = Disk[{1, 2}, {4, 3}]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

InfiniteLineは非有界領域である：

Wolfram Language code: ℛ = InfiniteLine[{0, 0}, {3, 1}]; Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

Pointを含む内の領域：

Wolfram Language code: ℛ = Point[Tuples[Range[5], 3]]; Region[ℛ, Boxed -> True]
Wolfram Language code: BoundedRegionQ[ℛ]

Line：

Wolfram Language code: ℛ = Line[{{1, 2, 3}, {6, 5, 4}}]; Region[ℛ, Boxed -> True]
Wolfram Language code: BoundedRegionQ[ℛ]

Cylinder：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2]; Region[ℛ, Boxed -> True]
Wolfram Language code: BoundedRegionQ[ℛ]

HalfPlaneは非有界である：

Wolfram Language code: ℛ = HalfPlane[{{0, 0, 0}, {1, 0, 0}}, {0, 1, 1}]; Region[ℛ, Boxed -> True]
Wolfram Language code: BoundedRegionQ[ℛ]

内のSimplexを含む内の領域：

Wolfram Language code: BoundedRegionQ[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}]]

内のCuboid：

Wolfram Language code: BoundedRegionQ[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}]]

内のBall：

Wolfram Language code: BoundedRegionQ[Ball[{1, 2, 3, 4, 5, 6, 7}, 8]]

数式定義領域  (3)

ImplicitRegionとしての放物線領域：

Wolfram Language code: ℛ = ImplicitRegion[x^2 - y^2 ≤ 1, {x, y}];
Wolfram Language code: DiscretizeRegion[ℛ, {{-2, 2}, {-2, 2}}]
Wolfram Language code: BoundedRegionQ[ℛ]

円柱：

Wolfram Language code: BoundedRegionQ[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}]]

ParametricRegionとして表された放物線：

Wolfram Language code: ℛ = ParametricRegion[{t, t^2}, {t}];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

円板の有理パラメータ化を使う：

Wolfram Language code: ℛ = ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}];

この領域は有界だが，パラメータ は非有界である：

Wolfram Language code: BoundedRegionQ[ℛ]

ImplicitRegionは，次元が異なる複数の成分を持つことができる：

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1∨(x + 1)^2 + y^2 == 1, {x, y}];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

メッシュ領域  (4)

1DにおけるMeshRegion：

Wolfram Language code: DelaunayMesh[RandomReal[1, {10, 1}]]
Wolfram Language code: BoundedRegionQ[%]

2D：

Wolfram Language code: DelaunayMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: BoundedRegionQ[%]

3D：

Wolfram Language code: DelaunayMesh[RandomReal[1, {100, 3}]]
Wolfram Language code: BoundedRegionQ[%]

1DにおけるBoundaryMeshRegion：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {10, 1}]]
Wolfram Language code: RegionQ[%]

2D：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: BoundedRegionQ[%]

3D：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {100, 3}]]
Wolfram Language code: BoundedRegionQ[%]

2Dにおける曲線を表すMeshRegion：

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2, 3, 4, 2}}]}]
Wolfram Language code: BoundedRegionQ[ℛ]

MeshRegionは次元が異なる成分を持つことができる：

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2}}], Polygon[{{2, 3, 4}}]}]
Wolfram Language code: BoundedRegionQ[ℛ]

派生領域  (4)

2つの領域のRegionIntersection：

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

混合次元領域のRegionUnion：

Wolfram Language code: ℛ = RegionUnion[Circle[{1, 0}, 1], Disk[{0, 0}, 1]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

TransformedRegion：

Wolfram Language code: ℛ = TransformedRegion[Disk[{0, 0}, 1], ScalingTransform[{3, 2}]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: BoundedRegionQ[ℛ]

RegionBoundary：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = RegionBoundary[Subscript[ℛ, 1]]
Wolfram Language code: {Region[Subscript[ℛ, 1]], Region[Subscript[ℛ, 2]]}
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 1]], BoundedRegionQ[Subscript[ℛ, 2]]}

地理的領域  (3)

GeoPositionを使った多角形：

Wolfram Language code: ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149}, {40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558}, {40.083686, -88.271512}, {40.083659999999995, -88.267046}, ... 33323}, {40.098112, -88.228687}, {40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546}, {40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477}, {40.090741, -88.235745}}}]];
Wolfram Language code: BoundedRegionQ[ℛ]

GeoPositionXYZを使った多角形：

Wolfram Language code: ℛ = Polygon[GeoPositionXYZ[{{{150451.6968462432, -4.884430486484052*^6, 4.085078564164219*^6}, {148595.27532671497, -4.884475441490381*^6, 4.085092666620835*^6}, {148626.35829777512, -4.884546311005128*^6, 4.0850073717259285*^6}, {148618.5908634042 ... 7*^6, 4.0860187668081024*^6}, {150697.56410771207, -4.8836599487428395*^6, 4.085984535480795*^6}, {150711.88303095422, -4.883905546449982*^6, 4.0856924143435075*^6}, {150433.15479548014, -4.883908845676418*^6, 4.0856987003255524*^6}}}]];
Wolfram Language code: BoundedRegionQ[ℛ]

GeoPositionENUを使った多角形：

Wolfram Language code: ℛ = Polygon[GeoPositionENU[{{{3378.2547059731055, -3369.2234780923936, -0.7440009205072329}, {1521.3211635380246, -3351.391253626573, -0.022340134218666208}, {1550.2571145363192, -3462.8657556618973, -0.08899812728964207}, {1528.5672303494055, -418 ... 63383291193, -0.37494203351275246}, {3654.121991908476, -2566.7472331234085, -0.5214977847472255}, {3375.420726854886, -2558.6597093173914, -0.3648706331350695}}}, GeoPosition[{40.11379115639895, -88.2753251202516, -1.0415787873318691}]]];
Wolfram Language code: BoundedRegionQ[ℛ]

GeoGridPositionを使った多角形：

Wolfram Language code: ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015}, {-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167}, {-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449}, {-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654}, {-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825}, {-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];
Wolfram Language code: BoundedRegionQ[ℛ]

BoundedRegionQは，地理実体の多角形に使うことができる：

Wolfram Language code: ℛ = Polygon[["france"]];
Wolfram Language code: BoundedRegionQ[ℛ]

CSG領域  (1)

2DCSGRegion：

Wolfram Language code: CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}]
Wolfram Language code: BoundedRegionQ[%]

3Dの場合：

Wolfram Language code: CSGRegion["Difference", {Cube[2], Cylinder[{{1, 1, 1}, {1, -1, 1}}]}]
Wolfram Language code: BoundedRegionQ[%]

細分割領域  (1)

2DのSubdivisionRegion：

Wolfram Language code: SubdivisionRegion[Rectangle[]]
Wolfram Language code: BoundedRegionQ[%]

3Dの場合：

Wolfram Language code: SubdivisionRegion[Tetrahedron[]]
Wolfram Language code: BoundedRegionQ[%]

アプリケーション  (2)

有界領域のみに適用される定義を作る：

Wolfram Language code: f[br_ ? BoundedRegionQ] := RegionBounds[br]
Wolfram Language code: f /@ {Disk[], InfiniteLine[{0, 0}, {1, 1}]}

領域を囲み込んでいるSphereを求める：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {0, 0, 3}}, 1];

境界を計算する：

Wolfram Language code: bounds = RegionBounds[ℛ];
Wolfram Language code: {min, max} = Transpose[bounds];
Wolfram Language code: c = Mean /@ bounds;
Wolfram Language code: r = EuclideanDistance[min, max] / 2;

囲み込んでいる球面を計算する：

Wolfram Language code: enclosingSphere = Sphere[c, r];

これを可視化する：

Wolfram Language code: Show[Graphics3D[{ℛ, Opacity[0.2, Yellow], enclosingSphere}], Boxed -> False]

特性と関係  (5)

RegionIntersectionは，少なくとも1領域がBoundedRegionQであれば有界である：

Wolfram Language code: r1 = HalfPlane[{{0, 0}, {1, 0}}, {0, 1}]; r2 = Circle[{0, 0}, 1]; ℛ = RegionIntersection[r1, r2];
Wolfram Language code: {Graphics[{LightBlue, r1, Orange, r2}], DiscretizeRegion[ℛ]}

有界の領域が1つあるので，この共通集合は有界である：

Wolfram Language code: BoundedRegionQ /@ {r1, r2, ℛ}

TransformedRegionは，領域と変換が有界であれば有界である：

Wolfram Language code: ℛ = Rectangle[]; 𝒯 = TransformedRegion[ℛ, RotationTransform[-π / 3]];

変換が有界なので結果の領域は有界である：

Wolfram Language code: {BoundedRegionQ[ℛ], BoundedRegionQ[𝒯]}
Wolfram Language code: {Region[ℛ], Region[𝒯]}

RegionBoundsは領域を含む境界ボックスを求める：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1]; Subscript[ℛ, 2] = InfiniteLine[{{0, 0}, {1, 1}}];
Wolfram Language code: {Region[Subscript[ℛ, 1]], Region[Subscript[ℛ, 2]]}

境界は有界の領域については有限である：

Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 1]], RegionBounds[Subscript[ℛ, 1]]}

非有界領域については，境界は無限である：

Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 2]], RegionBounds[Subscript[ℛ, 2]]}

有界領域のRegionMeasureは有限である：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 1];
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 1]], RegionMeasure[Subscript[ℛ, 1]]}

非有界領域のRegionMeasureは無限である：

Wolfram Language code: Subscript[ℛ, 2] = HalfPlane[{{0, 0}, {1, 0}}, {0, 1}];
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 2]], RegionMeasure[Subscript[ℛ, 2]]}

有界領域のRegionCentroidは有限である：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{0, 0}, {1, 1}}];
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 1]], RegionCentroid[Subscript[ℛ, 1]]}

非有界領域のRegionCentroidはIndeterminateである：

Wolfram Language code: Subscript[ℛ, 2] = InfiniteLine[{{0, 0}, {1, 1}}];
Wolfram Language code: {BoundedRegionQ[Subscript[ℛ, 2]], RegionCentroid[Subscript[ℛ, 2]]}
Wolfram Research (2014), BoundedRegionQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/BoundedRegionQ.html.

テキスト

Wolfram Research (2014), BoundedRegionQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/BoundedRegionQ.html.

CMS

Wolfram Language. 2014. "BoundedRegionQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BoundedRegionQ.html.

APA

Wolfram Language. (2014). BoundedRegionQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BoundedRegionQ.html

BibTeX

@misc{reference.wolfram_2026_boundedregionq, author="Wolfram Research", title="{BoundedRegionQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/BoundedRegionQ.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_boundedregionq, organization={Wolfram Research}, title={BoundedRegionQ}, year={2014}, url={https://reference.wolfram.com/language/ref/BoundedRegionQ.html}, note=[Accessed: 19-August-2026]}