Wolfram 语言与系统参考资料中心

Cell

Cell[contents]

是一个单元在 Wolfram 语言笔记本内部的低层表示法.

Cell[contents,"style"]

表示一个指定样式的单元.

Cell[contents,"style₁","style₂",…]

表示应用了多种样式的单元.

更多信息

Wolfram 语言笔记本由 Cell 对象的列表组成.
可以把单元的形式看作一个表达式，该表达式通过在标准 Wolfram 语言前端使用显示表达式菜单命令得到.
可以用前端直接访问笔记本中的单元. 也可以用 NotebookRead 和 NotebookWrite，或用NotebookSelection[obj] 中的 Options 和 SetOptions 从内核访问单元.
单元可以有以下内容：

	"text"	纯文本
	TextData[exprs]	一般文本对象
	BoxData[boxes]	格式化的 Wolfram 语言表达式
	OutputFormData["itext","otext"]	由 OutputForm 生成的文本
	RawData[data]	未格式化的表达式
	GraphicsData["type",data]	无表达式图像或声音数据
	CellGroupData[{cell₁,cell₂,…},status]	单元组
	StyleData["style"]	一个特殊样式的样本单元

在任何给定的笔记本中，定义了所有可能的单元样式，典型的名称有 "Title"、"Section"、"Input" 和"Output".
单元可以有多个选项，包括：

	Background	单元的背景颜色
	CellFrame	是否在单元周围绘制框架
	CellTags	单元标签
	Editable	是否允许单元内容被编辑
	FontSize	单元中文本的缺省大小
	TextAlignment	如何对齐单元中的文本

范例

打开所有单元关闭所有单元

基本范例 (2)

从一个低层的描述生成一个单元文本：

Wolfram Language code: CellPrint[Cell["abc", "Text"]]

从一个低层的描述生成一个表达式单元：

Wolfram Language code: CellPrint[Cell[BoxData[SuperscriptBox["x", "2"]], "Print"]]

范围 (5)

单元可以包含复杂的排版格式：

Wolfram Language code: CellPrint[Cell[BoxData[ToBoxes[Integrate[Abs[1 + Abs[x]], x, Assumptions -> x∈Reals]]], "Print"]]

单元可以包含图形：

Wolfram Language code: CellPrint[Cell[BoxData[ToBoxes[Plot[Sin[x], {x, -2, 2}]]], "Print"]]

单元可以包含交互式控件：

Wolfram Language code: CellPrint[Cell[BoxData[ToBoxes[Slider[]]], "Print"]]

单元可以包含其它单元：

Wolfram Language code: CellPrint[Cell[TextData[{"the ", Cell[BoxData["x"]], " factor"}], "Text"]]

合并单元中的多个样式：

Wolfram Language code:

CellPrint[Cell["I'm a TB cell", "TB"]];CellPrint[Cell["I'm a Small cell", "Small"]];CellPrint[Cell["I'm both", "TB", "Small"]];

I'm a TB cell

I'm a Small cell

I'm both

选项 (10)

CellFrame (1)

在一个单元周围绘制一个框架：

Wolfram Language code: CellPrint[Cell["abc", "Text", CellFrame -> True]]

指定这个框架的宽度：

Wolfram Language code: CellPrint[Cell["abc", "Text", CellFrame -> 5]]

CellFrameColor (1)

Wolfram Language code: Do[CellPrint[Cell["abc", "Text", CellFrame -> 5, CellFrameColor -> c]], {c, {Red, Green, Blue}}]

CellFrameLabels (2)

Wolfram Language code: CellPrint[Cell["abc", "Text", CellFrame -> True, CellFrameLabels -> {{"L", "R"}, {"B", "T"}}]]

单元框架标签可以被显示成没有框架：

Wolfram Language code: CellPrint[Cell["abc", "Text", CellFrame -> False, CellFrameLabels -> {{"L", "R"}, {"B", "T"}}]]

CellTags (1)

根据标签用单元标签定位一个特定的单元：

Wolfram Language code: CellPrint[Cell["text", CellTags -> {"C1"}]]

text

Wolfram Language code: NotebookLocate["C1"]

也可使用 NotebookFind：

Wolfram Language code: NotebookFind[InputNotebook[], "C1", Next, CellTags];

Editable (1)

缺省时单元是可编辑的；设置 Editable 为 False 以取消这一行为：

Wolfram Language code: CellPrint[Cell["not editable", "Text", Editable -> False]]

FontColor (1)

Wolfram Language code: Do[CellPrint[Cell["text text", "Text", FontColor -> c]], {c, {Red, Green, Blue}}]

FontSize (1)

Wolfram Language code: Do[CellPrint[Cell["text", "Text", FontSize -> s]], {s, {12, 24, 36}}]

Hyphenation (1)

定义某一文本：

Wolfram Language code:

text = "Advanced experimentation with counterintuitively organized automatic aeronautically optimized mechanical anisotropic intermediaries";

带和不带连字符的同一文本：

Wolfram Language code: Do[CellPrint[Cell[text, "Text", CellMargins -> {{200, 250}, Inherited}, Hyphenation -> h]], {h, {True, False}}]

ShowCellBracket (1)

带和不带单元方框的单元，以及只在鼠标滑过时才显示单元方框的情况：

Wolfram Language code: Do[CellPrint[Cell["text text text", "Text", ShowCellBracket -> cb]], {cb, {False, True, Automatic}}]

属性和关系 (1)

NotebookPut 从低层的 Notebook 和 Cell 表达式生成笔记本窗口：

Wolfram Language code: nb = NotebookPut[Notebook[{Cell["first"], Cell["last"]}]];

Wolfram Language code: SelectionMove[nb, Next, Cell]

NotebookRead 为一个选定的单元恢复一个 Cell 表达式：

Wolfram Language code: NotebookRead[nb]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Cell

更多信息

范例

基本范例 (2)

范围 (5)