ChannelListen[…]はChannelListenerオブジェクトを与える．
ChannelListen[channel,…]では，channel はチャネルオブジェクトとして，あるいはChannelObject内で使われている任意の形で指定することができる．
ChannelListen[channel]はChannelListen[channel,Automatic]に等しい．
func は，ChannelListen[channel,func]内で指定された場合は channel の"MessageReceived"ハンドラを無効にする．channel は次の要素を含む連想によって呼ばれる．

	"Message"	メッセージのコンテンツ
	"MessageID"	一意のメッセージID
	"Timestamp"	メッセージについてのサーバタイムスタンプ
	"RequesterWolframID"	送信者のWolfram ID
	"RequesterWolframUUID"	送信者のWolfram UUID
	"ListenerID"	現行リスナのID

メッセージのコンテンツは，メッセージが文字列，Real，Integer，ByteArray，True，False，Null，Image，Image3D，あるいはそのようなオブジェクトのリストまたは連想の場合は，文字通りに与えられる．その他のメッセージはすべてHoldComplete[DisableFormatting[expr]]形式か"name"DisableFormatting[val]の形の遅延規則のリストか連想としてで与えられる．
セキュリティのために，ホールドされた式の一部や遅延規則の右辺，あるいは文字列メッセージにToExpressionを適用する等の未評価のメッセージの内容には注意してアクセスすべきである．
ChannelListenには次のオプションが使える．

AutoRemove	False	メッセージを1つ受信した後でリスナを削除するかどうか
ChannelBase	$ChannelBase	仮定するデフォルトのチャネルベース
ChannelHistoryLength	100	リスナのキャッシュにいくつのメッセージを保存するか
NotificationFunction	Inherited	メッセージが届いた際に与える通知

ChannelListenが設定したチャネルリスナはRemoveChannelListenerで削除することができる．
チャネルリスナを削除するとリスナがキャッシュしたメッセージも破棄される．
Wolfram言語セッションを終了するとアクティブなチャネルリスナが削除される．

例題

すべて開くすべて閉じる

例 (2)

チャネルを作成し，聞き始める：

Wolfram Language code: channel = CreateChannel["example"]

Wolfram Language code: listener = ChannelListen[channel]

チャネルにメッセージを送り，リスナからメッセージのコンテンツを取り出す：

Wolfram Language code: ChannelSend[channel, "hello"]

Wolfram Language code: listener["Message"]

リスナを取り除いてチャネルを削除する：

Wolfram Language code: RemoveChannelListener[listener]

Wolfram Language code: DeleteChannel[channel]

メッセージが到着すると実行されるカスタムハンドラ関数を定義する：

Wolfram Language code:

CreateChannel["speak"];
listener = ChannelListen["speak", Speak[#Message]&]

チャネルにメッセージを送るとこの関数が呼ばれる：

Wolfram Language code: ChannelSend["speak", "hello"]

メッセージはChannelListenerオブジェクトにも記録される：

Wolfram Language code: listener["Message"]

リスナを取り除いてチャネルを削除する：

Wolfram Language code: RemoveChannelListener[listener]

Wolfram Language code: DeleteChannel["speak"]

スコープ (4)

チャネル指定 (2)

ChannelObjectで定義されたチャネルを聞く：

Wolfram Language code:

CreateChannel["x"];
ChannelObject["x"]

Wolfram Language code: ChannelListen[%]

チャネルブローカサーバー上のホームエリアのチャネルを，名前を指定して聞く：

Wolfram Language code: ChannelListen["x"]

完全修飾名で指定されたチャネルを聞く：

Wolfram Language code: $WolframID <> ":x"

Wolfram Language code: ChannelListen[%]

完全URLで指定されたチャネルを聞く：

Wolfram Language code: URLBuild[{$ChannelBase, "users", $WolframID, "x"}]

Wolfram Language code: ChannelListen[%]

チャネルを削除する．こうするとリスナも削除される：

Wolfram Language code: DeleteChannel["x"]

サーバ上の共通エリアのURLで指定されたチャネルを聞く：

Wolfram Language code:

channel = CreateChannel[];
url = URLBuild[Information[channel, {"ChannelBase", "Path"}]]

Wolfram Language code: ChannelListen[url]

チャネルを削除する．こうするとリスナも削除される：

Wolfram Language code: DeleteChannel[channel]

ハンドラ (2)

ハンドラ関数が受信した引数を調べる：

Wolfram Language code:

CreateChannel["x"];
listener = ChannelListen["x", Print]

チャネルにメッセージを送信するとハンドラが受信した連想が出力される：

Wolfram Language code: ChannelSend["x", "message"]

チャネルを削除する．こうするとリスナも削除される：

Wolfram Language code: DeleteChannel["x"]

メッセージが受信されたときはハンドラ関数を実行しない：

Wolfram Language code:

CreateChannel["x"];
listener = ChannelListen["x"]

Wolfram Language code: listener["HandlerFunction"]

それでも，チャネルに送信されたメッセージを取り出すことはできる：

Wolfram Language code: ChannelSend["x", "hello"]

Wolfram Language code: listener["Message"]

チャネルを削除する．こうするとリスナも削除される：

Wolfram Language code: DeleteChannel["x"]

オプション (3)

AutoRemove (1)

最初のメッセージの受信後に自らを削除するリスナを起動する：

Wolfram Language code: CreateChannel["x"];listener = ChannelListen["x", AutoRemove -> True]

リスナはアクティブである：

Wolfram Language code: ChannelListeners[]

メッセージが送信され処理された後でこのリスナは削除される：

Wolfram Language code: ChannelSend["x", "message"]

Wolfram Language code: ChannelListeners[]

チャネルを削除する：

Wolfram Language code: DeleteChannel["x"]

ChannelHistoryLength (1)

ChannelHistoryLengthを10に設定してチャネルリスナを作成する：

Wolfram Language code:

channel = CreateChannel[];
listener = ChannelListen[channel, ChannelHistoryLength -> 10]

チャネルに20のメッセージを送信する：

Wolfram Language code: Do[ChannelSend[channel, i], {i, 1, 20}]

最も最近受信された10のメッセージだけが保存されている：

Wolfram Language code: listener["Message", All]

チャネルを削除する．こうするとリスナも削除される：

Wolfram Language code: DeleteChannel[channel];

NotificationFunction (1)

リスナ内にカスタムの通知関数を定義する：

Wolfram Language code:

CreateChannel["x"];
listener = ChannelListen["x", NotificationFunction -> (EmitSound[Sound[SoundNote[]]]&)]

メッセージが送信され処理されるとこの関数が実行される：

Wolfram Language code: ChannelSend["x", "message"]

チャネルを削除する．こうするとリスナも削除される：

Wolfram Language code: DeleteChannel["x"];

アプリケーション (4)

電子メール (1)

デスクトップセッションで受信したメッセージの件名を読み上げるリスナを設定する：

Wolfram Language code:

CreateChannel["mailSpeak"];
listener = ChannelListen[
	"mailSpeak", 
	Speak[StringTemplate["From `from`, message: `msg`"][#Message]]&, 
	Permissions -> <|"Owner" -> {"Read", "Execute"}, "All" -> "Write"|>
	]

受信したメールを自分のリスナに転送するMailReceiverFunctionを作る：

Wolfram Language code:

cloudObj = CloudDeploy@With[{user = $WolframID}, 
	MailReceiverFunction[ChannelSend[
	user <> ":" <> "mailSpeak", 
	<|"msg" -> #Subject, "from" -> #From|>
	]&]
	]

受信器関数に電子メールを送り，リスナが読み上げるのを聞く：

Wolfram Language code: address = "EmailAddress" /. (MetaInformation /. Options[cloudObj, MetaInformation])

Wolfram Language code: SendMail[<|"To" -> address, "Subject" -> "Hello There"|>];

チャネルを削除する．こうするとリスナも削除される：

Wolfram Language code: DeleteChannel["mailSpeak"];

リモート評価 (1)

自分のWolfram Cloudアカウント，あるいは他のリモートのWolframシステムで，受信したメッセージを評価し，指定のチャネルに結果を送り返すリスナを設定する：

Wolfram Language code:

CreateChannel["remote"];
ChannelListen["remote", ChannelSend[#Message["ReplyTo"], #Message["Evaluate"]]&]

ローカルシステム上に受信チャネルを設定する：

Wolfram Language code:

CreateChannel["local"];
listener = ChannelListen["local"]

コマンドをリモートの評価器に送る：

Wolfram Language code:

ChannelSend["remote", <|"Evaluate" :> {$OperatingSystem, $MachineID}, "ReplyTo" -> Information[listener["ChannelObject"], "Path"]|>]

受信した応答にアクセスする：

Wolfram Language code: listener["Message"]

結果が別のマシンから来ていることを確かめる：

Wolfram Language code: {$OperatingSystem, $MachineID}

きれいにする：

Wolfram Language code: DeleteChannel[{"remote", "local"}]

Wolfram Cloud (1)

ChannelListenを使うと現行のセッションでAPIFunction，FormFunction，あるいはその他の関数がWolfram Cloudで実行された際に，アップデートが受信できる：

Wolfram Language code:

CreateChannel["api"];
listener = ChannelListen["api"]

Wolfram Language code: Dynamic[listener["Dataset"]]

単純な操作を行って結果をメタデータと一緒にリスナに送信するWebページを配備する：

Wolfram Language code:

CloudDeploy[FormPage[{"x" -> "Integer"}, With[{user = $WolframID}, Module[{result = #x + 1}, ChannelSend[user <> ":" <> "api", <|"input" -> #x, "result" -> result, "from" -> $RequesterAddress|>];result]&]]]

リスナはWebフォームが送信されると動的に更新される：

チャネルを削除する：

Wolfram Language code: DeleteChannel["api"];

ソーシャルメディア (1)

HTTPリクエストのコンテンツをチャネルに転送するAPIFunctionを作る：

Wolfram Language code:

channel = CreateChannel["TwitterMathematicaMentions"];
api = CloudDeploy[APIFunction[
	{"from" -> "String", "text" -> "String"}, 
	ChannelSend["TwitterMathematicaMentions", <|##|>]&
	], Permissions -> "Public"]

Twitter上の「Mathematica」という単語への言及を追跡して，これをHTTPを介してAPIFunctionに送信するIFTTTアプレットを作る：

このチャネル上にリスナを作る：

Wolfram Language code: listener = ChannelListen[channel]

Twitterへのサービスを接続し，キーワードを含むツイートを送信する：

Wolfram Language code: twitter = ServiceConnect["Twitter", "New"]

Wolfram Language code: twitter["Tweet", "Message" -> "I am sending this tweet from Mathematica!"]

リスナが受信したメッセージをリストにする：

Wolfram Language code: listener["Message", All]

チャネルを削除する：

Wolfram Language code: DeleteChannel[channel];

特性と関係 (3)

ChannelListenはChannelListenerオブジェクトを返す：

Wolfram Language code:

CreateChannel["x"];
listener = ChannelListen["x"]

リスナについてクエリを行い，特性を取り出すことができる：

Wolfram Language code: listener["URL"]

チャネルを削除する．こうするとリスナも削除される：

Wolfram Language code: DeleteChannel["x"];

RemoveChannelListenerを使ってChannelListenerオブジェクトを取り除く：

Wolfram Language code:

CreateChannel["x"];
listener = ChannelListen["x"]

Wolfram Language code: RemoveChannelListener[listener]

チャネルを削除する：

Wolfram Language code: DeleteChannel["x"];

デスクトップのWolframシステムでは，メッセージハンドラ関数内で実行されたPrintの出力は，メッセージウィンドウに表示される：

Wolfram Language code:

CreateChannel["x"];
ChannelListen["x", Print[#Message]&]

Wolfram Language code: ChannelSend["x", "here we are"]

チャネルを削除する．こうするとリスナも削除される：

Wolfram Language code: DeleteChannel["x"];

考えられる問題 (1)

セキュリティ上の理由から，デフォルトで，他のユーザのチャネルを聞くことはできない：

Wolfram Language code: $WolframID

Wolfram Language code: ChannelListen["another@example.com:listen"]

自分のコンピュータ上でメッセージハンドラ関数を実行されてもよいほどチャネルの作者を信頼しているのなら，セキュリティの設定を一時的に無効にすることができる：

Wolfram Language code:

Unprotect[$AllowExternalChannelFunctions];
$AllowExternalChannelFunctions = True;

Wolfram Language code: ChannelListen["another@example.com:listen"]

デフォルトに戻す：

Wolfram Language code:

$AllowExternalChannelFunctions = False;
Protect[$AllowExternalChannelFunctions];

おもしろい例題 (1)

チャネルを聞き，受信すると同時に動的に点をプロットするようにする：

Wolfram Language code:

CreateChannel["p"];
listener = ChannelListen["p"]

Wolfram Language code: Dynamic[ListLinePlot[If[AssociationQ[#], Lookup[#, "points"], {}]&@listener["Message"]]]

現行セッションから，あるいはインターネットに接続している他の任意のWolframセッションから，チャネルにデータを送る：

Wolfram Language code: ChannelSend["p", <|"points" -> RandomReal[{0, 1}, 100]|>]

チャネルURLに定期的に点を送るタスクを設定する：

Wolfram Language code: task = SessionSubmit[ScheduledTask[ChannelSend["p", <|"points" -> RandomReal[{0, 1}, 100]|>], 1]]

データの送信を中止し，チャネルを削除する：

Wolfram Language code: TaskRemove[task]

Wolfram Language code: DeleteChannel["p"];

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ChannelListen

詳細とオプション

例題

例 (2)

スコープ (4)

チャネル指定 (2)

ハンドラ (2)

オプション (3)

AutoRemove (1)

ChannelHistoryLength (1)

NotificationFunction (1)

アプリケーション (4)

電子メール (1)

リモート評価 (1)

Wolfram Cloud (1)

ソーシャルメディア (1)

特性と関係 (3)

考えられる問題 (1)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

ChannelListen

詳細とオプション

例題

例 (2)

スコープ (4)

チャネル指定 (2)

ハンドラ (2)

オプション (3)

AutoRemove (1)

ChannelHistoryLength (1)

NotificationFunction (1)

アプリケーション (4)

電子メール (1)

リモート評価 (1)

Wolfram Cloud (1)

ソーシャルメディア (1)

特性と関係 (3)

考えられる問題 (1)

おもしろい例題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX