WOLFRAM

Wolfram 语言与系统参考资料中心

ChannelListen[channel]

开始监听指定信道.

ChannelListen[channel,func]

对和信道收到的消息相对应的关联应用 funcl.

ChannelListen[channel,None]

保存信道收到的每条消息，不对其应用任何函数.

ChannelListen[url]

在指定的 URL 上监听，存储收到的消息，而无需在信道代理上存在显式信道.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
信道规范  
处理函数  
选项  
AutoRemove  
ChannelHistoryLength  
提醒函数  
应用  
Email  
远程评估  
Wolfram Cloud  
社交媒体  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ChannelListen

ChannelListen[channel]

开始监听指定信道.

ChannelListen[channel,func]

对和信道收到的消息相对应的关联应用 funcl.

ChannelListen[channel,None]

保存信道收到的每条消息，不对其应用任何函数.

ChannelListen[url]

在指定的 URL 上监听，存储收到的消息，而无需在信道代理上存在显式信道.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

生成一个信道并开始监听：

Wolfram Language code: channel = CreateChannel["example"]
Wolfram Language code: listener = ChannelListen[channel]

向信道发送消息，从监听器取回消息的内容：

Wolfram Language code: ChannelSend[channel, "hello"]
Wolfram Language code: listener["Message"]

清除监听器，删除信道：

Wolfram Language code: RemoveChannelListener[listener]
Wolfram Language code: DeleteChannel[channel]

定义一个在消息到达时执行的处理函数：

Wolfram Language code: CreateChannel["speak"]; listener = ChannelListen["speak", Speak[#Message]&]

向信道发送消息使该函数被调用：

Wolfram Language code: ChannelSend["speak", "hello"]

消息同时被记录在 ChannelListener 对象中：

Wolfram Language code: listener["Message"]

清除监听器，删除信道：

Wolfram Language code: RemoveChannelListener[listener]
Wolfram Language code: DeleteChannel["speak"]

范围  (4)

信道规范  (2)

监听由 ChannelObject 定义的信道：

Wolfram Language code: CreateChannel["x"]; ChannelObject["x"]
Wolfram Language code: ChannelListen[%]

在信道代理服务器上您家区域中的信道上监听，并指定其名称：

Wolfram Language code: ChannelListen["x"]

监听由其完全限定名称指定的信道：

Wolfram Language code: $WolframID <> ":x"
Wolfram Language code: ChannelListen[%]

监听由其完整 URL 指定的信道：

Wolfram Language code: URLBuild[{$ChannelBase, "users", $WolframID, "x"}]
Wolfram Language code: ChannelListen[%]

删除信道，这将删除监听器：

Wolfram Language code: DeleteChannel["x"]

监听服务器公共区域中由 URL 指定的信道：

Wolfram Language code: channel = CreateChannel[]; url = URLBuild[Information[channel, {"ChannelBase", "Path"}]]
Wolfram Language code: ChannelListen[url]

删除信道，这将删除监听器：

Wolfram Language code: DeleteChannel[channel]

处理函数  (2)

检查处理函数收到的参数：

Wolfram Language code: CreateChannel["x"]; listener = ChannelListen["x", Print]

向信道发送消息，输出处理函数收到的关联：

Wolfram Language code: ChannelSend["x", "message"]

删除信道，这将删除监听器：

Wolfram Language code: DeleteChannel["x"]

收到消息时不要执行任何处理程序函数：

Wolfram Language code: CreateChannel["x"]; listener = ChannelListen["x"]
Wolfram Language code: listener["HandlerFunction"]

仍然可以检索发送到该信道的消息：

Wolfram Language code: ChannelSend["x", "hello"]
Wolfram Language code: listener["Message"]

删除信道，这将删除监听器：

Wolfram Language code: DeleteChannel["x"]

选项  (3)

AutoRemove  (1)

启动在收到第一条消息后将自身清除掉的监听器：

Wolfram Language code: CreateChannel["x"];listener = ChannelListen["x", AutoRemove -> True]

监听器处于活动状态：

Wolfram Language code: ChannelListeners[]

在发送和处理消息后自动清除监听器：

Wolfram Language code: ChannelSend["x", "message"]
Wolfram Language code: ChannelListeners[]

删除信道：

Wolfram Language code: DeleteChannel["x"]

ChannelHistoryLength  (1)

创建信道监听器，其中 ChannelHistoryLength 设定为 10：

Wolfram Language code: channel = CreateChannel[]; listener = ChannelListen[channel, ChannelHistoryLength -> 10]

向该信道发送 20 条消息：

Wolfram Language code: Do[ChannelSend[channel, i], {i, 1, 20}]

仅存储最近收到的 10 条消息：

Wolfram Language code: listener["Message", All]

删除信道，这将删除监听器：

Wolfram Language code: DeleteChannel[channel];

提醒函数  (1)

在监听器中定义一个提醒函数：

Wolfram Language code: CreateChannel["x"]; listener = ChannelListen["x", NotificationFunction -> (EmitSound[Sound[SoundNote[]]]&)]

当消息被发送和处理后执行该函数：

Wolfram Language code: ChannelSend["x", "message"]

删除信道，这将删除监听器：

Wolfram Language code: DeleteChannel["x"];

应用  (4)

Email  (1)

在一个桌面进程中，设置一个监听器，读出收到的消息的主题：

Wolfram Language code: CreateChannel["mailSpeak"]; listener = ChannelListen[ "mailSpeak", Speak[StringTemplate["From `from`, message: `msg`"][#Message]]&, Permissions -> <|"Owner" -> {"Read", "Execute"}, "All" -> "Write"|> ]

生成一个 MailReceiverFunction，将收到的信件转发到你的监听器：

Wolfram Language code: cloudObj = CloudDeploy@With[{user = $WolframID}, MailReceiverFunction[ChannelSend[ user <> ":" <> "mailSpeak", <|"msg" -> #Subject, "from" -> #From|> ]&] ]

把 email 发送到接收函数，收听监听器的播报：

Wolfram Language code: address = "EmailAddress" /. (MetaInformation /. Options[cloudObj, MetaInformation])
Wolfram Language code: SendMail[<|"To" -> address, "Subject" -> "Hello There"|>];

删除信道，这将删除监听器：

Wolfram Language code: DeleteChannel["mailSpeak"];

远程评估  (1)

在你的 Wolfram 云账户，或其他远程 Wolfram 系统，设置一个对收到的消息进行评估的监听器，并将结果发送到指定信道：

Wolfram Language code: CreateChannel["remote"]; ChannelListen["remote", ChannelSend[#Message["ReplyTo"], #Message["Evaluate"]]&]

在本地系统上设置接收信道：

Wolfram Language code: CreateChannel["local"]; listener = ChannelListen["local"]

对远程评估器发送一条命令：

Wolfram Language code: ChannelSend["remote", <|"Evaluate" :> {$OperatingSystem, $MachineID}, "ReplyTo" -> Information[listener["ChannelObject"], "Path"]|>]

访问收到的响应：

Wolfram Language code: listener["Message"]

验证结果来自不同的机器：

Wolfram Language code: {$OperatingSystem, $MachineID}

清理：

Wolfram Language code: DeleteChannel[{"remote", "local"}]

Wolfram Cloud  (1)

ChannelListen 允许您当前的会话从 Wolfram Cloud 中执行的 APIFunction、FormFunction 和其他函数接收更新：

Wolfram Language code: CreateChannel["api"]; listener = ChannelListen["api"]
Wolfram Language code: Dynamic[listener["Dataset"]]

部署一个网页，执行简单操作，并将结果以及一些元数据发送到监听器：

Wolfram Language code: CloudDeploy[FormPage[{"x" -> "Integer"}, With[{user = $WolframID}, Module[{result = #x + 1}, ChannelSend[user <> ":" <> "api", <|"input" -> #x, "result" -> result, "from" -> $RequesterAddress|>];result]&]]]

提交 Web 表单后，监听器将动态更新：

删除信道：

Wolfram Language code: DeleteChannel["api"];

社交媒体  (1)

创建一个 APIFunction，将 HTTP 请求的内容转发到信道：

Wolfram Language code: channel = CreateChannel["TwitterMathematicaMentions"]; api = CloudDeploy[APIFunction[ {"from" -> "String", "text" -> "String"}, ChannelSend["TwitterMathematicaMentions", <|##|>]& ], Permissions -> "Public"]

创建一个 IFTTT 小程序，该程序跟踪 Twitter上对 "Mathematica" 一词的提及，并通过 HTTP 将其发送给 APIFunction：

在信道上创建一个监听器：

Wolfram Language code: listener = ChannelListen[channel]

创建与 Twitter 的服务连接，并发送包含关键字的推文：

Wolfram Language code: twitter = ServiceConnect["Twitter", "New"]
Wolfram Language code: twitter["Tweet", "Message" -> "I am sending this tweet from Mathematica!"]

列出监听器收到的消息：

Wolfram Language code: listener["Message", All]

删除信道：

Wolfram Language code: DeleteChannel[channel];

属性和关系  (3)

ChannelListen 返回 ChannelListener 对象：

Wolfram Language code: CreateChannel["x"]; listener = ChannelListen["x"]

可以对监听器进行查询并获取它的属性：

Wolfram Language code: listener["URL"]

删除信道，这将删除监听器：

Wolfram Language code: DeleteChannel["x"];

用 RemoveChannelListener 清除 ChannelListener 对象：

Wolfram Language code: CreateChannel["x"]; listener = ChannelListen["x"]
Wolfram Language code: RemoveChannelListener[listener]

删除信道：

Wolfram Language code: DeleteChannel["x"];

在桌面 Wolfram 系统上，在消息处理程序函数中执行的 Print 的输出定向到 Messages 窗口：

Wolfram Language code: CreateChannel["x"]; ChannelListen["x", Print[#Message]&]
Wolfram Language code: ChannelSend["x", "here we are"]

删除信道，这将删除监听器：

Wolfram Language code: DeleteChannel["x"];

可能存在的问题  (1)

为安全起见，缺省情况下你不能监听其他用户的信道：

Wolfram Language code: $WolframID
Wolfram Language code: ChannelListen["another@example.com:listen"]

如果你信得过信道拥有者在你的计算机上执行消息处理函数，那你可以暂时去掉安全设置：

Wolfram Language code: Unprotect[$AllowExternalChannelFunctions]; $AllowExternalChannelFunctions = True;
Wolfram Language code: ChannelListen["another@example.com:listen"]

恢复缺省设置：

Wolfram Language code: $AllowExternalChannelFunctions = False; Protect[$AllowExternalChannelFunctions];

巧妙范例  (1)

开始监听一个信道，并设置在数据点到达的时候，将他们即时绘制出来：

Wolfram Language code: CreateChannel["p"]; listener = ChannelListen["p"]
Wolfram Language code: Dynamic[ListLinePlot[If[AssociationQ[#], Lookup[#, "points"], {}]&@listener["Message"]]]

从当前会话或连接到互联网的任何其他 Wolfram 语言会话发送数据到信道的网址：

Wolfram Language code: ChannelSend["p", <|"points" -> RandomReal[{0, 1}, 100]|>]

设置定期向频道网址发送点的任务：

Wolfram Language code: task = SessionSubmit[ScheduledTask[ChannelSend["p", <|"points" -> RandomReal[{0, 1}, 100]|>], 1]]

停止发送数据并删除信道：

Wolfram Language code: TaskRemove[task]
Wolfram Language code: DeleteChannel["p"];
Wolfram Research (2016)，ChannelListen，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChannelListen.html （更新于 2020 年）.

文本

Wolfram Research (2016)，ChannelListen，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChannelListen.html （更新于 2020 年）.

CMS

Wolfram 语言. 2016. "ChannelListen." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/ChannelListen.html.

APA

Wolfram 语言. (2016). ChannelListen. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ChannelListen.html 年

BibTeX

@misc{reference.wolfram_2026_channellisten, author="Wolfram Research", title="{ChannelListen}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/ChannelListen.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_channellisten, organization={Wolfram Research}, title={ChannelListen}, year={2020}, url={https://reference.wolfram.com/language/ref/ChannelListen.html}, note=[Accessed: 12-August-2026]}