WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ClusteringComponents[array]

array の最低レベルにある各要素をその要素が含まれるクラスタを表す整数指標で置き換えた配列を与える．

ClusteringComponents[array,n]

n 個のクラスタを求める．

ClusteringComponents[array,n,level]

array の指定レベルのクラスタを求める．

ClusteringComponents[image]

image の値が同じような画素のクラスタを求める．

ClusteringComponents[image,n]

image 中のクラスタを n 個求める．

ClusteringComponents[video,…]

すべての動画フレームをクラスタ化した結果の時系列を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
CriterionFunction  
DistanceFunction  
FeatureExtractor  
Show More Show More
FeatureNames  
FeatureTypes  
Method  
PerformanceGoal  
RandomSeeding  
Weights  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ClusteringComponents

ClusteringComponents[array]

array の最低レベルにある各要素をその要素が含まれるクラスタを表す整数指標で置き換えた配列を与える．

ClusteringComponents[array,n]

n 個のクラスタを求める．

ClusteringComponents[array,n,level]

array の指定レベルのクラスタを求める．

ClusteringComponents[image]

image の値が同じような画素のクラスタを求める．

ClusteringComponents[image,n]

image 中のクラスタを n 個求める．

ClusteringComponents[video,…]

すべての動画フレームをクラスタ化した結果の時系列を返す．

詳細とオプション

  • ClusteringComponentsは，数値，テキスト，画像，動画，日付と時刻等を含むさまざまなデータ型に使うことができる．
  • クラスタの数は以下の形で指定できる．
  • Automaticクラスタ数を自動的に求める
    n厳密に n 個のクラスタを求める
    UpTo[n]最大で n 個のクラスタを求める
  • 使用可能なオプション
  • CriterionFunction Automaticメソッド選択の基準
    DistanceFunction Automatic使用する距離関数
    FeatureExtractor Identityそこから学ぶ特徴をどのように抽出するか
    FeatureNames Automatic入力データに割り当てる特徴名
    FeatureTypes Automatic入力データに仮定する特徴タイプ
    Method Automatic使用するメソッド
    MissingValueSynthesisAutomatic欠落値の合成方法
    PerformanceGoal Automaticパフォーマンスのどの面について最適化するか
    RandomSeeding 1234どのような擬似乱数生成器のシードを内部的に使うべきか
    Weights Automatic各例に与える重み
  • デフォルトでDistanceFunctionが指定されていなければ，ClusteringComponentsは自動的にデータを前処理する．
  • DistanceFunctionの設定は，任意の距離関数，非類似度関数，または2つの値間の距離を定義する関数 f でよい．
  • PerformanceGoalの可能な設定
  • Automatic速度，確度，メモリ間の自動トレードオフ
    "Quality"分類器の確度を最大にする
    "Speed"分類器の速度を最大にする
  • Methodの可能な設定
  • Automaticメソッドを自動選択する
    "Agglomerate"単一の結合クラスタ化アルゴリズム
    "DBSCAN"ノイズがあるアプリケーションの密度に基づいた空間クラスタ化
    "GaussianMixture"ガウス混合アルゴリズムのバリエーション
    "JarvisPatrick"Jarvis–Patrickクラスタ化アルゴリズム
    "KMeans"k 平均クラスタ化アルゴリズム
    "KMedoids"メドイドの周りで分割する
    "MeanShift"平均シフトクラスタ化アルゴリズム
    "NeighborhoodContraction"データ点を高密度領域にシフトする
    "SpanningTree"最小全域木に基づいたクラスタ化アルゴリズム
    "Spectral"スペクトルクラスタ化アルゴリズム
  • "KMeans"法と"KMedoids"法はクラスタ数が指定されているときにしか使用できない．
  • "DBSCAN"，"GaussianMixture"，"JarvisPatrick"，"MeanShift"，"NeighborhoodContraction"の各メソッドは，クラスタ数がAutomaticのときにしか使用できない．
  • 次のプロットは一般的なメソッドをトイデータ集合に適用した結果を示している．
    • Wolfram Language code: [image]
  • CriterionFunctionの可能な設定
  • "StandardDeviation"二乗平均平方根標準偏差
    "RSquared"R平方
    "Dunn"Dunn指標
    "CalinskiHarabasz"Calinski–Harabasz指標
    "DaviesBouldin"Davies–Bouldin指標
    Automatic内部指標
  • RandomSeedingの可能な設定
  • Automatic関数が呼び出されるたびに自動的にシードを変える
    Inherited外部シードの乱数を使う
    seed明示的な整数または文字列をシードとして使う

例題

すべて開く すべて閉じる

例  (3)

リスト中の2つの値のクラスタにラベルを付ける：

Wolfram Language code: ClusteringComponents[{1, 2, 3, 7, 8}, 2]

文字列のベクトルにラベルを付ける：

Wolfram Language code: ClusteringComponents[{"a", "aa", "aab", "aabb", "abbc", "abcc", "abccd"}]

MR画像のクラスタ分析：

Wolfram Language code: ClusteringComponents[[image], 7]//Colorize

スコープ  (10)

行列中の値のクラスタ：

Wolfram Language code: ClusteringComponents[(⁠| | | | | | | - | - | - | - | - | | 1 | 2 | 2 | 2 | 1 | | 1 | 1 | 3 | 5 | 5 | | 1 | 1 | 5 | 5 | 5 | | 1 | 1 | 2 | 5 | 6 | | 1 | 1 | 4 | 5 | 6 |⁠)] // MatrixForm

画像中の色のクラスタを求める：

Wolfram Language code: ClusteringComponents[[image], 5] // Colorize

3D画像中のクラスタを求める：

Wolfram Language code: i = ExampleData[{"TestImage3D", "MRknee"}]
Wolfram Language code: seg = ClusteringComponents[i, 3]; Image3D[Colorize[seg], ClipPlanes -> {{-1, 1, 0, 12}}]

ネストしたリストのクラスタ化変換：

Wolfram Language code: ClusteringComponents[{{1, 2}, 3, {10, 11}, {12, {13}}, 14}, 2]

リストのレベル2でクラスタを見付ける：

Wolfram Language code: ClusteringComponents[{{1, 2}, {3, 4}, {10, 11}, {12, 13}}, 2, 2]

リストのレベル1でクラスタを見付ける：

Wolfram Language code: ClusteringComponents[{{1, 2}, {3, 4}, {10, 11}, {12, 13}}, 2, 1]

大きい数の潜在的クラスタを指定することで重複を見付ける：

Wolfram Language code: ClusteringComponents[{1, 2, 2, 7, 7, 8}, UpTo[100]]

行列中のクラスタにラベルを付ける：

Wolfram Language code: ClusteringComponents[(⁠| | | | | | - | - | - | - | | 1 | 1 | 7 | 7 | | 1 | 2 | 6 | 6 | | 1 | 6 | 5 | 5 | | 0 | 7 | 5 | 5 |⁠), 2]//Colorize

ブール値のリストをクラスタ化する：

Wolfram Language code: ClusteringComponents[{{True, False, True}, {False, False, True}, {False, True, False}}, 2, 1]

ブールベクトルのリストをクラスタ化する：

Wolfram Language code: SeedRandom[1234]; tfdata = RandomChoice[{True, False}, {30, 3}]
Wolfram Language code: c = ClusteringComponents[tfdata, Automatic, 1]

オプション  (13)

CriterionFunction  (1)

分割されたデータを生成し，可視化する：

Wolfram Language code: circle[r_, theta_] := {r Sin[theta], r Cos[theta]}; points = RandomVariate[MixtureDistribution[{1, 1}, {UniformDistribution[{{3 / 2, 2}, {0, 2 Pi}}], UniformDistribution[{{0, 1 / 2}, {0, 2 Pi}}]}], 1000]; data = circle@@@points; ListPlot[data, PlotRange -> All]

CriterionFunctionの異なる設定を使って厳密に2つのクラスタによるクラスタ割当てを求める：

Wolfram Language code: assignment1 = ClusteringComponents[data, 2, 1];
Wolfram Language code: assignment2 = ClusteringComponents[data, 2, 1, CriterionFunction -> "CalinskiHarabasz"];

データの2種類のクラスタ化を比較する：

Wolfram Language code: cCluster1 = Pick[data, assignment1, 1]; cCluster2 = Pick[data, assignment1, 2]; ListPlot[{cCluster1, cCluster2}]
Wolfram Language code: dCluster1 = Pick[data, assignment2, 1]; dCluster2 = Pick[data, assignment2, 2]; ListPlot[{dCluster1, dCluster2}]

DistanceFunction  (1)

デフォルトで，文字列リストのクラスタ化にはEditDistanceが使われる：

Wolfram Language code: sdata = {"GCTAT", "TAGGA", "GAATT", "CATCT", "TCAGG", "GGGGA", "TTACG", "GTCAG", "TGGAG", "GAAAA", "ATAGG", "TCCGA", "TAACT", "GTGAT", "AAGAA", "CCGTA", "GCTAA", "GCTGG", "GAGGG", "CTCAT"};
Wolfram Language code: ClusteringComponents[sdata, 2]

HammingDistanceを使って，一致しない文字の数に基づいてクラスタ化する：

Wolfram Language code: ClusteringComponents[sdata, 2, DistanceFunction -> HammingDistance]

FeatureExtractor  (1)

画像のリストのクラスタ化要素を求める：

Wolfram Language code: flowers = {[image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image]};
Wolfram Language code: ClusteringComponents[flowers, 3, 1]

カスタムのFeatureExtractorを作って特徴を抽出する：

Wolfram Language code: fe = FeatureExtraction[flowers, (DominantColors[#, 2]&)]

結果の特徴を見る：

Wolfram Language code: extractedfeatures = fe[flowers]

FeatureExtractorを使って新たなクラスタ化要素を見る：

Wolfram Language code: cnew = ClusteringComponents[flowers, 3, 1, FeatureExtractor -> fe]

新たなクラスタ化を見る：

Wolfram Language code: GroupBy[Transpose[{extractedfeatures, flowers, cnew}], Last -> Most]

FeatureNames  (1)

FeatureNamesを使って特徴に名前を付け，以降の指定でこの名前を参照する：

Wolfram Language code: c = ClusteringComponents[{{2.3, "male"}, {4.8, "male"}, {9, "female"}, {5.2, "female"}, {1, "male"}, {10, "male"}, {5, "female"}}, Automatic, 1, FeatureNames -> {"age", "gender"}, FeatureTypes -> <|"age" -> "Numerical", "gender" -> "Nominal"|>]

FeatureTypes  (1)

FeatureTypesを使って特徴の解釈を強制する：

Wolfram Language code: ClusteringComponents[{{2.3, "male"}, {4.8, "male"}, {9, "female"}, {5.2, "female"}, {1, "male"}, {10, "male"}, {5, "female"}}, Automatic, 1, FeatureTypes -> {"Numerical", "Nominal"}]

名義的特徴を仮定して得られた結果と上記を比較する：

Wolfram Language code: ClusteringComponents[{{2.3, "male"}, {4.8, "male"}, {9, "female"}, {5.2, "female"}, {1, "male"}, {10, "male"}, {5, "female"}}, Automatic, 1, FeatureTypes -> {"Nominal", "Nominal"}]

Method  (5)

正規分布に従うデータを生成し，そのヒストグラムを可視化する：

Wolfram Language code: Dis = MixtureDistribution[{1, 1, 1, 1}, { NormalDistribution[1, 1], NormalDistribution[-5, 1], NormalDistribution[10, 1], NormalDistribution[20, 1]}]; data = RandomVariate[Dis, 500]; Histogram[data, {-7, 25, 0.3}]

"GaussianMixture"法を使ってこのデータについてのクラスタ割当てを求める：

Wolfram Language code: assignment = ClusteringComponents[data, Method -> "GaussianMixture"];

対応するクラタ化を可視化する：

Wolfram Language code: clustering = Pick[data, assignment, #]& /@ DeleteDuplicates[assignment]; Histogram[clustering, {-7, 25, 0.3}]

kメドイド法を使って文字列リストへのクラスタ割当てを求める：

Wolfram Language code: strings = DictionaryLookup["gi" ~~ __];
Wolfram Language code: assignment = ClusteringComponents[strings, 4, Method -> "KMedoids"];

結果のクラスタ化を見る：

Wolfram Language code: GatherBy[Transpose[{strings, assignment}], Last][[All, All, 1]]

さまざまなメソッドを使って画像中の色クラスタを求める：

Wolfram Language code: animals = [image];
Wolfram Language code: Table[Colorize[ClusteringComponents[animals, Method -> method]], {method, {"GaussianMixture", "NeighborhoodContraction", "MeanShift", "Spectral", "JarvisPatrick"}}]

"NeighborhoodContraction"法とそのサブオプションを使って画像中の色クラスタを求める：

Wolfram Language code: house = [image];
Wolfram Language code: Table[Colorize[ClusteringComponents[house, Method -> {"NeighborhoodContraction", "NeighborhoodRadius" -> t}]], {t, {0.3, 0.1, 0.05}}]

"Spectral"法とそのサブオプションを使って画像中の色クラスタを求める：

Wolfram Language code: flower = [image];
Wolfram Language code: ClusteringComponents[flower, Method -> "Spectral"]//Colorize
Wolfram Language code: Multicolumn[Table[Colorize[ClusteringComponents[flower, Method -> {"Spectral", "NeighborhoodRadius" -> t}]], {t, {0.3, 0.2, 0.1, 0.08}}], 2, Frame -> All]

PerformanceGoal  (1)

長さ1000のランダムな数値ベクトルを500個生成する：

Wolfram Language code: vectors = RandomReal[{10, 11}, {5000, 5}];

上で生成したベクトルのクラスタ化を計算し，基準に従って操作を評価する：

Wolfram Language code: AbsoluteTiming[ ClusteringComponents[vectors, Automatic, 1];]

PerformanceGoalを"Quality"に設定して同じ操作を行う：

Wolfram Language code: AbsoluteTiming[ClusteringComponents[vectors, Automatic, 1, PerformanceGoal -> "Quality"];]

RandomSeeding  (1)

500個のランダムな二次元数値ベクトルを生成する：

Wolfram Language code: vectors = RandomReal[{10, 11}, {500, 2}];

そのクラスタ化を数回計算し，結果を比較する：

Wolfram Language code: clusterings = Table[ ClusteringComponents[vectors, Automatic, 1], 5];
Wolfram Language code: SameQ@@clusterings

RandomSeedingオプションを変えてクラスタ化を数回計算し，結果を比較する：

Wolfram Language code: randomclusterings = Table[ ClusteringComponents[vectors, Automatic, 1, RandomSeeding -> RandomInteger[10]], 5];
Wolfram Language code: SameQ@@randomclusterings

Weights  (1)

数値データについてのクラスタ割当てを得る：

Wolfram Language code: data = {1, 1.1, 1.3, 5.6, 5.7, 5.65, 6.5};
Wolfram Language code: ClusteringComponents[data]

各数に与えられた重みを変えた場合のクラスタ割当てを見る：

Wolfram Language code: ClusteringComponents[data, Weights -> {1, 1, 1, 1, 1, 1, 0.2}]

アプリケーション  (2)

Perona–Malikフィルタで平滑化した後の顕微鏡画像のカラー分割：

Wolfram Language code: ClusteringComponents[PeronaMalikFilter[[image], 5, 0.05], 6] // Colorize

画像の二値分割：

Wolfram Language code: (segs = ClusteringComponents[[image], 2])//Colorize
Wolfram Language code: Image[segs - 1, "Bit"]

特性と関係  (3)

ClusteringComponentsはクラスタ指標の配列を与えるのに対し，FindClustersはクラスタのリストを返す：

Wolfram Language code: ClusteringComponents[{10, 4, 5, 6, 11}, 2]
Wolfram Language code: FindClusters[{10, 4, 5, 6, 11}, 2]

ClusteringComponentsの結果を類似要素の分割に変換する：

Wolfram Language code: list = {10, 4, 5, 6, 11}; components = ClusteringComponents[list]
Wolfram Language code: Map[First, GatherBy[Transpose[{list, components}], Last], {2}]

FindClustersも同じ結果を返す：

Wolfram Language code: FindClusters[list]

FindClustersの結果をクラスタ指標のリストに変換する：

Wolfram Language code: list = {10, 4, 5, 6, 11}; f = FindClusters[list, 2]
Wolfram Language code: list /. Flatten[MapIndexed[(#1 -> #2[[1]])&, f, {2}]]

ClusteringComponentsも同じ結果を返す：

Wolfram Language code: ClusteringComponents[list]

考えられる問題  (1)

"KMeans"法は入力のサブセットの平均が入力空間に属さない場合には使えない：

Wolfram Language code: ClusteringComponents[{{False, False, False}, {True, True, False}, {False, False, False}, {True, True, False}, {True, False, False}, {True, False, False}, {True, False, False}}, 2, 1, DistanceFunction -> (Abs[Length[#1] - Length[#2]]&), Method -> "KMeans"]
Wolfram Research (2010), ClusteringComponents, Wolfram言語関数， https://reference.wolfram.com/language/ref/ClusteringComponents.html （2025年に更新）.

テキスト

Wolfram Research (2010), ClusteringComponents, Wolfram言語関数， https://reference.wolfram.com/language/ref/ClusteringComponents.html （2025年に更新）.

CMS

Wolfram Language. 2010. "ClusteringComponents." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/ClusteringComponents.html.

APA

Wolfram Language. (2010). ClusteringComponents. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ClusteringComponents.html

BibTeX

@misc{reference.wolfram_2026_clusteringcomponents, author="Wolfram Research", title="{ClusteringComponents}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/ClusteringComponents.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_clusteringcomponents, organization={Wolfram Research}, title={ClusteringComponents}, year={2025}, url={https://reference.wolfram.com/language/ref/ClusteringComponents.html}, note=[Accessed: 10-September-2026]}