WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Composition[f1,f2,f3,…]

関数 f1, f2, f3, …の合成関数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Composition

Composition[f1,f2,f3,…]

関数 f1, f2, f3, …の合成関数を表す．

詳細

例題

すべて開く すべて閉じる

例  (2)

引数に関数合成を適用する：

Wolfram Language code: Composition[f, g, h][x, y]

接中辞表記を使って合成関数を適用する：

Wolfram Language code: f @* g @* h@x

スコープ  (4)

Composition内で純関数を使う：

Wolfram Language code: Composition[1 + # ^ #&, a #&, # / (# + 1)&][x]

Compositionと共にApplyを使う：

Wolfram Language code: Composition[f, g, h]@@{x, y, z}

Compositionオブジェクトは，可能な場合は自動的に簡約される：

Wolfram Language code: Composition[f, Identity, g]
Wolfram Language code: Composition[RotationTransform[θ], RotationTransform[ϕ]]

Compositionオブジェクトを変数に割り当てる：

Wolfram Language code: f = 2#& @* Cases[_Symbol]

変数は他の任意の関数と同じように使うことができる：

Wolfram Language code: f[{a, "b", c, d, "e", 5}]

アプリケーション  (2)

一連の関数の合成関数を作成する：

Wolfram Language code: Apply[Composition, Array[Subscript[f, #]&, 10]][x]

数の合計を未評価の状態で表示されるようにする：

Wolfram Language code: Composition[HoldForm, Plus]@@Range[20]

特性と関係  (10)

Composition[f]は f を与える：

Wolfram Language code: Composition[f]

Composition[]はIdentityを与える：

Wolfram Language code: Composition[]

合成関数内のIdentityは自動的に削除される：

Wolfram Language code: Composition[f, Identity, g]

連続するTransformationFunctionオブジェクトは組み合される：

Wolfram Language code: Composition[TranslationTransform[{2, 2}], f, RotationTransform[θ], RotationTransform[-θ]]//Simplify

合成関数のInverseFunctionは逆関数の逆合成関数を生成する：

Wolfram Language code: InverseFunction[Composition[f, g, h]]

Compositionは左側に構成する：

Wolfram Language code: Composition[f, g][x]

RightCompositionは右側に構成する：

Wolfram Language code: RightComposition[f, g][x]

純関数を使ってCompositionのような動作をするオブジェクトを設定することができる：

Wolfram Language code: Composition[f, g, h][x]
Wolfram Language code: f[g[h[#]]]&[x]

同じ関数合成を入力するいろいろな方法：

Wolfram Language code: Composition[f, g, h][x]
Wolfram Language code: f @* g @* h@x

接頭辞表記を使用すると，同じ順序で関数を入力するため，Compositionが自然になる：

Wolfram Language code: f@g@h@x

後置記法では，関数は純粋な後置アプリケーションに対して反転される：

Wolfram Language code: x//h//g//f
Wolfram Language code: x//f @* g @* h

Nestを使って関数をそれ自身と 回合成する：

Wolfram Language code: Nest[f, x, 3]
Wolfram Language code: Composition[f, f, f][x]

RSolveを使って関数をそれ自身と 回合成する：

Wolfram Language code: f[x_] := (2x + 3/x + 4)
Wolfram Language code: fn = a /. First@RSolve[{a[n + 1] == f[a[n]], a[0] == 0}, a, n]
Wolfram Language code: fn[10]
Wolfram Language code: (Composition@@Table[f, {10}])[0]

ComposeSeriesを使って級数展開を合成する：

Wolfram Language code: Series[Composition[Sin, Cos][x], {x, 0, 3}]
Wolfram Language code: ComposeSeries[Series[Sin[x], {x, Cos[0], 3}], Series[Cos[x], {x, 0, 3}]]

考えられる問題  (1)

Composition[…]オブジェクトは引数をホールドしない：

Wolfram Language code: Composition[Hold, Times][2 + 3, 4 + 5]

通常の関数適用によって引数がホールドできるようにする：

Wolfram Language code: Hold[Times[2 + 3, 4 + 5]]

おもしろい例題  (1)

補助変数を使わずに値の平方根を表にする：

Wolfram Language code: TableForm[Composition[Through, {Identity, Sqrt}] /@ {0, 1.0, 2.0, 3.0, 4.0}]
Wolfram Research (1991), Composition, Wolfram言語関数， https://reference.wolfram.com/language/ref/Composition.html （2014年に更新）.

テキスト

Wolfram Research (1991), Composition, Wolfram言語関数， https://reference.wolfram.com/language/ref/Composition.html （2014年に更新）.

CMS

Wolfram Language. 1991. "Composition." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Composition.html.

APA

Wolfram Language. (1991). Composition. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Composition.html

BibTeX

@misc{reference.wolfram_2026_composition, author="Wolfram Research", title="{Composition}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Composition.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_composition, organization={Wolfram Research}, title={Composition}, year={2014}, url={https://reference.wolfram.com/language/ref/Composition.html}, note=[Accessed: 07-October-2026]}