WOLFRAM

Wolfram 语言与系统参考资料中心

Composition[f1,f2,f3,…]

表示函数 f1、f2、f3、…. 的复合.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

Composition

Composition[f1,f2,f3,…]

表示函数 f1、f2、f3、…. 的复合.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

将复合函数应用于参数：

Wolfram Language code: Composition[f, g, h][x, y]

使用中缀表示法应用复合：

Wolfram Language code: f @* g @* h@x

范围  (4)

在 Composition 内用纯函数：

Wolfram Language code: Composition[1 + # ^ #&, a #&, # / (# + 1)&][x]

将 Composition 与 Apply 联用：

Wolfram Language code: Composition[f, g, h]@@{x, y, z}

在可能的情况下，Composition 对象会自动简化：

Wolfram Language code: Composition[f, Identity, g]
Wolfram Language code: Composition[RotationTransform[θ], RotationTransform[ϕ]]

将 Composition 对象赋值给变量：

Wolfram Language code: f = 2#& @* Cases[_Symbol]

该变量可以像其他函数一样使用：

Wolfram Language code: f[{a, "b", c, d, "e", 5}]

应用  (2)

创建一个函数序列的复合：

Wolfram Language code: Apply[Composition, Array[Subscript[f, #]&, 10]][x]

创建数字的一个和式，按不计算的形式显示：

Wolfram Language code: Composition[HoldForm, Plus]@@Range[20]

属性和关系  (10)

Composition[f] 给出 f：

Wolfram Language code: Composition[f]

Composition[] 给出 Identity：

Wolfram Language code: Composition[]

复合中的 Identity 会被自动删除：

Wolfram Language code: Composition[f, Identity, g]

合并连续的 TransformationFunction 对象：

Wolfram Language code: Composition[TranslationTransform[{2, 2}], f, RotationTransform[θ], RotationTransform[-θ]]//Simplify

复合的 InverseFunction 会产生逆向的反函数复合：

Wolfram Language code: InverseFunction[Composition[f, g, h]]

Composition 在左侧复合：

Wolfram Language code: Composition[f, g][x]

RightComposition 在右侧复合：

Wolfram Language code: RightComposition[f, g][x]

纯函数让您建立类似 Composition 的对象：

Wolfram Language code: Composition[f, g, h][x]
Wolfram Language code: f[g[h[#]]]&[x]

进入同一复合的不同方式：

Wolfram Language code: Composition[f, g, h][x]
Wolfram Language code: f @* g @* h@x

使用前缀表示法，以相同的顺序输入函数，Composition 就很自然了：

Wolfram Language code: f@g@h@x

使用后缀表示法时，相对于纯粹的后缀应用，函数是逆向的：

Wolfram Language code: x//h//g//f
Wolfram Language code: x//f @* g @* h

用 Nest 将函数和它本身复合 次：

Wolfram Language code: Nest[f, x, 3]
Wolfram Language code: Composition[f, f, f][x]

用 RSolve 将函数和它本身复合 次：

Wolfram Language code: f[x_] := (2x + 3/x + 4)
Wolfram Language code: fn = a /. First@RSolve[{a[n + 1] == f[a[n]], a[0] == 0}, a, n]
Wolfram Language code: fn[10]
Wolfram Language code: (Composition@@Table[f, {10}])[0]

用 ComposeSeries 进行级数展开的复合：

Wolfram Language code: Series[Composition[Sin, Cos][x], {x, 0, 3}]
Wolfram Language code: ComposeSeries[Series[Sin[x], {x, Cos[0], 3}], Series[Cos[x], {x, 0, 3}]]

可能存在的问题  (1)

Composition[…] 对象不保留其参数：

Wolfram Language code: Composition[Hold, Times][2 + 3, 4 + 5]

使用普通函数应用允许函数保存参数：

Wolfram Language code: Hold[Times[2 + 3, 4 + 5]]

巧妙范例  (1)

用表格形式显示值的平方根，不需要辅助变量：

Wolfram Language code: TableForm[Composition[Through, {Identity, Sqrt}] /@ {0, 1.0, 2.0, 3.0, 4.0}]
Wolfram Research (1991)，Composition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Composition.html （更新于 2014 年）.

文本

Wolfram Research (1991)，Composition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Composition.html （更新于 2014 年）.

CMS

Wolfram 语言. 1991. "Composition." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Composition.html.

APA

Wolfram 语言. (1991). Composition. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Composition.html 年

BibTeX

@misc{reference.wolfram_2026_composition, author="Wolfram Research", title="{Composition}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Composition.html}", note=[Accessed: 05-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_composition, organization={Wolfram Research}, title={Composition}, year={2014}, url={https://reference.wolfram.com/language/ref/Composition.html}, note=[Accessed: 05-September-2026]}