WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Convolve[f,g,x,y]

式 fと g の x についてのたたみ込みを返す．

Convolve[f,g,{x1,x2,…},{y1,y2,…}]

多次元たたみ込みを返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一変数のたたみ込み  
多変数のたたみ込み  
一般化と拡張  
オプション  
Assumptions  
GenerateConditions  
アプリケーション  
特性と関係  
インタラクティブな例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

Convolve

Convolve[f,g,x,y]

式 fと g の x についてのたたみ込みを返す．

Convolve[f,g,{x1,x2,…},{y1,y2,…}]

多次元たたみ込みを返す．

詳細とオプション

  • Convolveは，フーリエ(Fourier)たたみ込み，非因果的たたみ込み，両側たたみ込みとしても知られている．
  • 2つの関数 と のたたみ込みは で与えられる．
  • 多次元たたみ込みはで与えられる．
  • 使用可能なオプション
  • Assumptions $Assumptionsパラメータに関する仮定
    GenerateConditions Falseパラメータについての条件を生成するかどうか
    MethodAutomatic使用するメソッド
    PrincipalValueFalse初期値積分を使うかどうか

例題

すべて開く すべて閉じる

例  (3)

DiracDeltaで関数をたたみ込む：

Wolfram Language code: Convolve[DiracDelta[x], f[x], x, y]

2つの単位パルスをたたみ込む：

Wolfram Language code: Convolve[UnitBox[x], UnitBox[x], x, y]

2つの指数関数をたたみ込んで結果をプロットする：

Wolfram Language code: Convolve[Exp[-x]UnitStep[x], Exp[-x]UnitStep[x], x, y]
Wolfram Language code: Plot[%, {y, 0, 10}, PlotRange -> All]

スコープ  (5)

一変数のたたみ込み  (3)

このたたみ込みは平行移動の積積分を与える：

Wolfram Language code: f[x_] := UnitBox[x]
Wolfram Language code: g[x_] := E ^ (-x ^ 2)
Wolfram Language code: GraphicsRow@Table[Plot[{f[x], g[x - i]}, {x, -3, 4}, Ticks -> None, Exclusions -> None, PlotRange -> All], {i, -1, 2}]
Wolfram Language code: Convolve[f[x], g[x], x, y]

初等関数：

Wolfram Language code: Convolve[x, 1 / (x ^ 2 + 1), x, y]
Wolfram Language code: Convolve[E ^ (-a x ^ 2), 1, x, y]

たたみ込みは一般に関数を滑らかにする：

Wolfram Language code: f0 = UnitBox[x];
Wolfram Language code: f1 = Convolve[f0, f0, x, y] /. y -> x
Wolfram Language code: f2 = Convolve[f1, f1, x, y] /. y -> x//Simplify
Wolfram Language code: f3 = Convolve[f2, f2, x, y] /. y -> x//Simplify;
Wolfram Language code: Plot[Evaluate[{f0, f1, f2, f3}], {x, -3, 3}, Exclusions -> None]

この族に関しては，すべてが単位面積を持つ：

Wolfram Language code: Integrate[{f0, f1, f2, f3}, {x, -∞, ∞}]

多変数のたたみ込み  (2)

このたたみ込みは平行移動の積積分を与える：

Wolfram Language code: f[x_, y_] := E ^ (-x ^ 2 - y ^ 2)
Wolfram Language code: GraphicsGrid@Table[Plot3D[{f[x, y], f[x - i, y - j]}, {x, -3, 3}, {y, -3, 3}, Mesh -> 5, ImageSize -> 400, Ticks -> None, PlotRange -> All, PlotStyle -> {LightRed, LightOrange}], {i, -1, 1}, {j, -1, 1}]

多変数デルタ関数のたたみ込みは点演算子として動作する：

Wolfram Language code: Convolve[f[x, y], DiracDelta[x, y], {x, y}, {r, s}]

有界サポートを持つ関数のたたみ込みはフィルタとして動作する：

Wolfram Language code: Convolve[E ^ (-x ^ 2 - y ^ 2), UnitBox[x, y], {x, y}, {r, s}]

一般化と拡張  (1)

UnitStepによる乗算は，事実上有限区間におけるたたみ込みを返す：

Wolfram Language code: Convolve[x ^ 5 UnitStep[x], Sin[x] UnitStep[x], x, y, Assumptions -> y > 0]
Wolfram Language code: Integrate[x ^ 5 Sin[y - x], {x, 0, y}, Assumptions -> y > 0]

オプション  (2)

Assumptions  (1)

変数すなわちパラメータについての仮定を指定する：

Wolfram Language code: Convolve[a ^ x UnitStep[x], UnitStep[x], x, y]
Wolfram Language code: Convolve[a ^ x UnitStep[x], UnitStep[x], x, y, Assumptions -> y > 0]

GenerateConditions  (1)

パラメータの範囲についての条件を生成する：

Wolfram Language code: Convolve[E ^ (-a x ^ 2), x ^ 3, x, y, GenerateConditions -> True]

アプリケーション  (5)

たたみ込みを使って線形常微分方程式の特殊解を得る：

Wolfram Language code: First@Simplify[y[x] /. DSolve[{y'[x] + y[x] == x ^ 2, y[0] == 0}, y, x]]
Wolfram Language code: Expand[Simplify[Convolve[E ^ (-t)UnitStep[t], t ^ 2 UnitStep[t], t, x], x > 0]]

インパルス応答が h のときの線形で時不変系のステップ応答を得る：

Wolfram Language code: h = Exp[-x]UnitStep[x];
Wolfram Language code: Plot[h, {x, 0, 10}, PlotRange -> All]

系のステップ応答：

Wolfram Language code: Convolve[h, UnitStep[x], x, y]
Wolfram Language code: Plot[%, {y, 0, 10}, PlotRange -> All]

UniformDistributionのPDFのそれ自身でのたたみ込みはTriangularDistributionを与える：

Wolfram Language code: Convolve[PDF[UniformDistribution[{0, 1}], x], PDF[UniformDistribution[{0, 1}], x], x, y]
Wolfram Language code: PDF[TriangularDistribution[{0, 2}], y]
Wolfram Language code: FullSimplify[%% - %]

UniformSumDistribution[n]は n 個のUniformDistribution[]の確率密度関数のたたみ込みである：

Wolfram Language code: Table[Convolve[PDF[UniformSumDistribution[k], x], PDF[UniformDistribution[{0, 1}], x], x, y] - PDF[UniformSumDistribution[k + 1], y], {k, 2, 5}]//FullSimplify
Wolfram Language code: Table[Plot[PDF[UniformSumDistribution[k], x], {x, 0, 4}, Filling -> Axis, Exclusions -> None, PlotRange -> {0, 1}, PlotLabel -> k], {k, 1, 4}]

ErlangDistribution[k,λ]は k 個のExponentialDistribution[λ]の確率密度関数のたたみ込みである：

Wolfram Language code: Convolve[PDF[ErlangDistribution[k, λ], x], PDF[ExponentialDistribution[λ], x], x, y]
Wolfram Language code: PDF[ErlangDistribution[k + 1, λ], y]
Wolfram Language code: FullSimplify[%% - %]
Wolfram Language code: Table[Plot[PDF[ErlangDistribution[k, 1], x], {x, 0, 8}, Filling -> Axis, Exclusions -> None, PlotRange -> {0, 1}, PlotLabel -> k], {k, 1, 4}]

特性と関係  (7)

Convolveは数直線上で積分を計算する：

Wolfram Language code: Convolve[x ^ 2, E ^ (-x ^ 2), x, y]
Wolfram Language code: Integrate[x ^ 2 E ^ (-(y - x) ^ 2), {x, -Infinity, Infinity}, Assumptions -> Im[y] == 0]

DiracDeltaを伴うたたみ込みは関数自身を与える：

Wolfram Language code: Convolve[Sin[x], DiracDelta[x], x, y]

スケーリング：

Wolfram Language code: Convolve[a r[x], s[x], x, y]
Wolfram Language code: Convolve[r[x], a s[x], x, y]

交換性：

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: g[x_] := E ^ (-Abs[x])
Wolfram Language code: Convolve[f[x], g[x], x, y]
Wolfram Language code: Convolve[g[x], f[x], x, y]

分配性：

Wolfram Language code: Convolve[h[x], i[x] + j[x], x, y]
Wolfram Language code: Convolve[h[x] + i[x], j[x], x, y]

因果的たたみ込みのラプラス(Laplace)変換は個々の変換の積である：

Wolfram Language code: f[x_] := Sin[x]UnitStep[x]
Wolfram Language code: g[x_] := x UnitStep[x]
Wolfram Language code: Together[LaplaceTransform[Convolve[f[x], g[x], x, y], y, s]]
Wolfram Language code: LaplaceTransform[f[x], x, s]LaplaceTransform[g[x], x, s]

たたみ込みのフーリエ(Fourier)変換は個々の変換の積に関連している：

Wolfram Language code: f[x_] := UnitBox[x / 2];
Wolfram Language code: g[x_] := 2UnitBox[(x + 1) / 3];
Wolfram Language code: Plot[{f[x], g[x]}, {x, -3, 3}, Exclusions -> None, Filling -> Axis]
Wolfram Language code: FourierTransform[f[x], x, ω, FourierParameters -> {1, 1}] FourierTransform[g[x], x, ω, FourierParameters -> {1, 1}]
Wolfram Language code: FourierTransform[Convolve[f[y], g[y], y, x], x, ω, FourierParameters -> {1, 1}]//FullSimplify
Wolfram Language code: FullSimplify[% / %%]

インタラクティブな例題  (1)

以下はたたみ込み演算を示す：

Wolfram Language code: DynamicModule[{f, g, h}, f[x_] := UnitBox[x / 2]; g[x_] := UnitBox[x]; h[y_] = Convolve[f[x], g[x], x, y]; Manipulate[ GraphicsRow[{ Plot[{f[x], g[y - x]}, {x, -5 / 2, 5 / 2}, ...], Plot[f[x] g[y - x], {x, -5 / 2, 5 / 2}, ...], Plot[h[x], {x, -5 / 2, y}, ...]}, ImageSize -> 480], {{y, -0.8, Style["y", Italic]}, -2, 2}]]
Wolfram Research (2008), Convolve, Wolfram言語関数， https://reference.wolfram.com/language/ref/Convolve.html.

テキスト

Wolfram Research (2008), Convolve, Wolfram言語関数， https://reference.wolfram.com/language/ref/Convolve.html.

CMS

Wolfram Language. 2008. "Convolve." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Convolve.html.

APA

Wolfram Language. (2008). Convolve. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Convolve.html

BibTeX

@misc{reference.wolfram_2026_convolve, author="Wolfram Research", title="{Convolve}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Convolve.html}", note=[Accessed: 14-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_convolve, organization={Wolfram Research}, title={Convolve}, year={2008}, url={https://reference.wolfram.com/language/ref/Convolve.html}, note=[Accessed: 14-July-2026]}