WOLFRAM

Wolfram 语言与系统参考资料中心

Convolve[f,g,x,y]

给出表达式 f 和 g 的关于 x 的卷积.

Convolve[f,g,{x1,x2,…},{y1,y2,…}]

给出多维卷积.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
一元卷积  
多元卷积  
推广和延伸  
选项  
Assumptions  
GenerateConditions  
应用  
属性和关系  
互动范例  
参见
相关指南
相关链接
历史
按以下格式引用：

Convolve

Convolve[f,g,x,y]

给出表达式 f 和 g 的关于 x 的卷积.

Convolve[f,g,{x1,x2,…},{y1,y2,…}]

给出多维卷积.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

将函数与 DiracDelta 卷积：

Wolfram Language code: Convolve[DiracDelta[x], f[x], x, y]

对两个单位脉冲进行卷积：

Wolfram Language code: Convolve[UnitBox[x], UnitBox[x], x, y]

对两个指数函数进行卷积，并绘制结果的图形：

Wolfram Language code: Convolve[Exp[-x]UnitStep[x], Exp[-x]UnitStep[x], x, y]
Wolfram Language code: Plot[%, {y, 0, 10}, PlotRange -> All]

范围  (5)

一元卷积  (3)

卷积给出平移的乘积积分：

Wolfram Language code: f[x_] := UnitBox[x]
Wolfram Language code: g[x_] := E ^ (-x ^ 2)
Wolfram Language code: GraphicsRow@Table[Plot[{f[x], g[x - i]}, {x, -3, 4}, Ticks -> None, Exclusions -> None, PlotRange -> All], {i, -1, 2}]
Wolfram Language code: Convolve[f[x], g[x], x, y]

初等函数：

Wolfram Language code: Convolve[x, 1 / (x ^ 2 + 1), x, y]
Wolfram Language code: Convolve[E ^ (-a x ^ 2), 1, x, y]

卷积通常可以使函数变得更平滑：

Wolfram Language code: f0 = UnitBox[x];
Wolfram Language code: f1 = Convolve[f0, f0, x, y] /. y -> x
Wolfram Language code: f2 = Convolve[f1, f1, x, y] /. y -> x//Simplify
Wolfram Language code: f3 = Convolve[f2, f2, x, y] /. y -> x//Simplify;
Wolfram Language code: Plot[Evaluate[{f0, f1, f2, f3}], {x, -3, 3}, Exclusions -> None]

对这个系列，它们均有单位面积：

Wolfram Language code: Integrate[{f0, f1, f2, f3}, {x, -∞, ∞}]

多元卷积  (2)

卷积给出平移的乘积积分：

Wolfram Language code: f[x_, y_] := E ^ (-x ^ 2 - y ^ 2)
Wolfram Language code: GraphicsGrid@Table[Plot3D[{f[x, y], f[x - i, y - j]}, {x, -3, 3}, {y, -3, 3}, Mesh -> 5, ImageSize -> 400, Ticks -> None, PlotRange -> All, PlotStyle -> {LightRed, LightOrange}], {i, -1, 1}, {j, -1, 1}]

多元 δ 函数的卷积起到一个点运算符的作用：

Wolfram Language code: Convolve[f[x, y], DiracDelta[x, y], {x, y}, {r, s}]

有界函数的卷积起滤波作用：

Wolfram Language code: Convolve[E ^ (-x ^ 2 - y ^ 2), UnitBox[x, y], {x, y}, {r, s}]

推广和延伸  (1)

UnitStep 的乘法实际上给出有限区间上的卷积：

Wolfram Language code: Convolve[x ^ 5 UnitStep[x], Sin[x] UnitStep[x], x, y, Assumptions -> y > 0]
Wolfram Language code: Integrate[x ^ 5 Sin[y - x], {x, 0, y}, Assumptions -> y > 0]

选项  (2)

Assumptions  (1)

指定关于一个变量或参数的假设：

Wolfram Language code: Convolve[a ^ x UnitStep[x], UnitStep[x], x, y]
Wolfram Language code: Convolve[a ^ x UnitStep[x], UnitStep[x], x, y, Assumptions -> y > 0]

GenerateConditions  (1)

生成关于参数范围的条件：

Wolfram Language code: Convolve[E ^ (-a x ^ 2), x ^ 3, x, y, GenerateConditions -> True]

应用  (5)

用卷积得到一个线性常微分方程的特解:

Wolfram Language code: First@Simplify[y[x] /. DSolve[{y'[x] + y[x] == x ^ 2, y[0] == 0}, y, x]]
Wolfram Language code: Expand[Simplify[Convolve[E ^ (-t)UnitStep[t], t ^ 2 UnitStep[t], t, x], x > 0]]

给定脉冲响应 h，获得线性时不变系统的阶跃响应：

Wolfram Language code: h = Exp[-x]UnitStep[x];
Wolfram Language code: Plot[h, {x, 0, 10}, PlotRange -> All]

系统的阶跃响应：

Wolfram Language code: Convolve[h, UnitStep[x], x, y]
Wolfram Language code: Plot[%, {y, 0, 10}, PlotRange -> All]

UniformDistribution 的 PDF 与自身的卷积得到一个 TriangularDistribution:

Wolfram Language code: Convolve[PDF[UniformDistribution[{0, 1}], x], PDF[UniformDistribution[{0, 1}], x], x, y]
Wolfram Language code: PDF[TriangularDistribution[{0, 2}], y]
Wolfram Language code: FullSimplify[%% - %]

UniformSumDistribution[n] 是 n 个 UniformDistribution[] 的概率密度函数的卷积：

Wolfram Language code: Table[Convolve[PDF[UniformSumDistribution[k], x], PDF[UniformDistribution[{0, 1}], x], x, y] - PDF[UniformSumDistribution[k + 1], y], {k, 2, 5}]//FullSimplify
Wolfram Language code: Table[Plot[PDF[UniformSumDistribution[k], x], {x, 0, 4}, Filling -> Axis, Exclusions -> None, PlotRange -> {0, 1}, PlotLabel -> k], {k, 1, 4}]

ErlangDistribution[k,λ] 是 k 个 ExponentialDistribution[λ] 的概率密度函数的卷积：

Wolfram Language code: Convolve[PDF[ErlangDistribution[k, λ], x], PDF[ExponentialDistribution[λ], x], x, y]
Wolfram Language code: PDF[ErlangDistribution[k + 1, λ], y]
Wolfram Language code: FullSimplify[%% - %]
Wolfram Language code: Table[Plot[PDF[ErlangDistribution[k, 1], x], {x, 0, 8}, Filling -> Axis, Exclusions -> None, PlotRange -> {0, 1}, PlotLabel -> k], {k, 1, 4}]

属性和关系  (7)

Convolve 在实数线上计算一个积分:

Wolfram Language code: Convolve[x ^ 2, E ^ (-x ^ 2), x, y]
Wolfram Language code: Integrate[x ^ 2 E ^ (-(y - x) ^ 2), {x, -Infinity, Infinity}, Assumptions -> Im[y] == 0]

与 DiracDelta 的卷积给出函数本身：

Wolfram Language code: Convolve[Sin[x], DiracDelta[x], x, y]

伸缩性：

Wolfram Language code: Convolve[a r[x], s[x], x, y]
Wolfram Language code: Convolve[r[x], a s[x], x, y]

交换律：

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: g[x_] := E ^ (-Abs[x])
Wolfram Language code: Convolve[f[x], g[x], x, y]
Wolfram Language code: Convolve[g[x], f[x], x, y]

分配律：

Wolfram Language code: Convolve[h[x], i[x] + j[x], x, y]
Wolfram Language code: Convolve[h[x] + i[x], j[x], x, y]

一个因果卷积的 Laplace 变换是单个变换的乘积：

Wolfram Language code: f[x_] := Sin[x]UnitStep[x]
Wolfram Language code: g[x_] := x UnitStep[x]
Wolfram Language code: Together[LaplaceTransform[Convolve[f[x], g[x], x, y], y, s]]
Wolfram Language code: LaplaceTransform[f[x], x, s]LaplaceTransform[g[x], x, s]

一个卷积的傅立叶变换与单个变换的乘积相关：

Wolfram Language code: f[x_] := UnitBox[x / 2];
Wolfram Language code: g[x_] := 2UnitBox[(x + 1) / 3];
Wolfram Language code: Plot[{f[x], g[x]}, {x, -3, 3}, Exclusions -> None, Filling -> Axis]
Wolfram Language code: FourierTransform[f[x], x, ω, FourierParameters -> {1, 1}] FourierTransform[g[x], x, ω, FourierParameters -> {1, 1}]
Wolfram Language code: FourierTransform[Convolve[f[y], g[y], y, x], x, ω, FourierParameters -> {1, 1}]//FullSimplify
Wolfram Language code: FullSimplify[% / %%]

互动范例  (1)

这里对卷积运算 进行说明：

Wolfram Language code: DynamicModule[{f, g, h}, f[x_] := UnitBox[x / 2]; g[x_] := UnitBox[x]; h[y_] = Convolve[f[x], g[x], x, y]; Manipulate[ GraphicsRow[{ Plot[{f[x], g[y - x]}, {x, -5 / 2, 5 / 2}, ...], Plot[f[x] g[y - x], {x, -5 / 2, 5 / 2}, ...], Plot[h[x], {x, -5 / 2, y}, ...]}, ImageSize -> 480], {{y, -0.8, Style["y", Italic]}, -2, 2}]]
Wolfram Research (2008)，Convolve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Convolve.html.

文本

Wolfram Research (2008)，Convolve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Convolve.html.

CMS

Wolfram 语言. 2008. "Convolve." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Convolve.html.

APA

Wolfram 语言. (2008). Convolve. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Convolve.html 年

BibTeX

@misc{reference.wolfram_2026_convolve, author="Wolfram Research", title="{Convolve}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Convolve.html}", note=[Accessed: 12-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_convolve, organization={Wolfram Research}, title={Convolve}, year={2008}, url={https://reference.wolfram.com/language/ref/Convolve.html}, note=[Accessed: 12-October-2026]}