Wolfram 语言与系统参考资料中心

Cos

Cos[z]

给出 z 的余弦值.

背景

Cos 是余弦函数，三角学中的基本函数之一. 对于实数变量它的定义如下：设是一个点从轴出发，沿着单位圆的圆周逆时针走过的弧度值，则 Cos[x] 给出了圆弧上这个点的横坐标. 直角三角形中一个锐角的余弦值在教科书上的等价定义是角的邻边边长与弦长的比值.
当变量是的简单有理数倍时，Cos 会自动计算出精确值. 对一些更复杂的有理倍数，FunctionExpand 有时可用于算得显式的精确值. 若要使用角度值的变量，则可用符号 Degree 作为乘数（例如 Cos[30 Degree]）. 当给出精确数值表达式作为变量时，Cos 可以算出任意精度的数值结果. 对包含 Cos 的符号表达式，其他适用的操作运算有 TrigToExp、TrigExpand、Simplify 和 FullSimplify.
Cos 自动逐项作用于列表和矩阵. 相比之下，MatrixFunction 则可用于给出整个方阵的余弦值（即用矩阵幂次代替普通幂次的余弦函数的幂级数）而不是单个矩阵元素的余弦值.
Cos 是周期函数，周期为，可由 FunctionPeriod 算出. Cos 满足恒等式，这其实与勾股定理等价. 余弦函数的定义可由等式扩展到复数变量上，其中是自然对数的底数. 余弦函数是整函数，也就是说它在复平面的每个有限点处都是复可微的. Cos[z] 在原点处的级数展开为 .
Cos 的反函数是 ArcCos. 双曲余弦函数是 Cosh. 其他相关的数学函数有 Sec 和 Sin.

范例

打开所有单元关闭所有单元

基本范例 (5)

自变量以弧度单位给出：

Wolfram Language code: Cos[Pi / 6]

用 Degree 以度为单位来指定一个自变量：

Wolfram Language code: Cos[30Degree]

在实数的子集上绘图：

Wolfram Language code: Plot[Cos[x], {x, 0, 2Pi}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Cos[z], {z, -2 π - 2 I, 2 π + 2 I}, PlotLegends -> Automatic]

在 0 级数展开：

Wolfram Language code: Series[Cos[x], {x, 0, 10}]

范围 (51)

数值计算 (6)

数值运算：

Wolfram Language code: Cos[1.2]

高精度求值：

Wolfram Language code: N[Cos[12 / 10], 50]

输出精度与输入精度一致：

Wolfram Language code: Cos[1.20000000000000000000000]

Cos 可以处理复数输入：

Wolfram Language code: Cos[2.5 + I]

在高精度条件下高效计算 Cos：

Wolfram Language code: Cos[1.2`500]//Timing

Wolfram Language code: Cos[1.2`100000];//Timing

自动逐项计算数组中每个元素的值：

Wolfram Language code: Cos[ {{5π / 6, 0}, {3π / 2, -π / 2}}]

或用 MatrixFunction 计算矩阵形式的 Cos 函数：

Wolfram Language code: MatrixFunction[Cos[#]&, {{5π / 6, 0}, {3π / 2, -π / 2}}]

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Cos[Interval[{π / 2, π / 3}]]

Wolfram Language code: Cos[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Cos[CenteredInterval[2 + 3I, (1 + I) / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Cos[Around[2, 0.01]]

特殊值 (5)

Cos 在固定点上的值：

Wolfram Language code: Table[Cos[n (π/6)], {n, 0, 6}]

无穷处的值：

Wolfram Language code: Cos[Infinity]

Wolfram Language code: Cos[ComplexInfinity]

Cos 的零点：

Wolfram Language code: Assuming[m∈Integers, Refine[Cos[π ((1/2) + m)]]]

Cos 的极值：

Wolfram Language code: Assuming[m∈Integers, FullSimplify[Refine[Cos[π m]]]]

在最小值的邻域中求 Cos 的最小值，以作为的根：

Wolfram Language code: sol = Solve[D[Cos[x], x] == 0 && 0 < x < 2π, x]

代入结果：

Wolfram Language code: xmin = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[Cos[x], {x, 0, 2π}, Epilog -> Style[Point[{xmin, Cos[xmin]}], PointSize[Large], Red]]

自动生成简单精确值：

Wolfram Language code: Cos[Pi / 5]

更复杂的情况则需使用 FunctionExpand:

Wolfram Language code: Cos[Pi / 24]

Wolfram Language code: FunctionExpand[%]

可视化 (3)

绘制 Cos 函数：

Wolfram Language code: Plot[Cos[x], {x, -2π, 2π}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[Cos[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[Cos[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[Cos[k ϕ], {ϕ, 0, 2π}, Sequence[Frame -> True, FrameTicks -> {{{-1, -0.5, 0, 0.5, 1}, None}, {{-1, -0.5, 0, 0.5, 1}, None}}, PlotLabel -> "k=" <> ToString[k]]], {k, 1, 8}]

函数属性 (13)

Cos 是针对所有实数和复数定义的：

Wolfram Language code: FunctionDomain[Cos[x], x]

Wolfram Language code: FunctionDomain[Cos[z], z, Complexes]

Cos 的值域是 -1 和 1 之间的所有实数：

Wolfram Language code: FunctionRange[Cos[x], x, y]

复数的值域是整个平面：

Wolfram Language code: FunctionRange[Cos[z], z, y, Complexes]

Cos 是周期为的周期函数：

Wolfram Language code: FunctionPeriod[Cos[x], x]

Cos 是一个偶函数：

Wolfram Language code: Cos[-x]

Cos 具有镜像属性：

Wolfram Language code: FullSimplify[Cos[Conjugate[z]] == Conjugate[Cos[z]]]

Cos 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[Cos[x], x]

Cos 在特定范围内是单调的：

Wolfram Language code: FunctionMonotonicity[Cos[x], x]

Wolfram Language code: FunctionMonotonicity[{Cos[x], -π / 2 < x < 0}, x]

Cos 不是单射函数：

Wolfram Language code: FunctionInjective[Cos[x], x]

Wolfram Language code: Plot[{Cos[x], 1 / 2}, {x, -2π, 2π}]

Cos 不是满射函数：

Wolfram Language code: FunctionSurjective[Cos[x], x]

Wolfram Language code: Plot[{Cos[x], 1.5}, {x, -2π, 2π}]

Cos 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[Cos[x], x]

Cos 没有奇点或断点：

Wolfram Language code: FunctionSingularities[Cos[x], x]

Wolfram Language code: FunctionDiscontinuities[Cos[x], x]

Cos 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[Cos[x], x]

x 位于 [0,π] 时是凹函数：

Wolfram Language code: FunctionConvexity[{Cos[x], -π / 2 < x < π / 2}, x]

Wolfram Language code: Plot[Cos[x], {x, -π / 2, π / 2}]

TraditionalForm 格式：

Wolfram Language code: Cos[α]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[Cos[x], x]

高阶导数：

Wolfram Language code: Table[D[Cos[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -π, π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[Cos[x], {x, n}]

积分 (3)

Cos 的不定积分：

Wolfram Language code: Integrate[Cos[x], x]

Cos 在一个周期上的定积分为 0：

Wolfram Language code: Integrate[Cos[x], {x, 0, 2 π}]

更多积分：

Wolfram Language code: Integrate[Sin[x]Cos[x], x]

Wolfram Language code: Integrate[Cos[x] ^ a, x]

级数展开式 (4)

使用 Series 求泰勒展开式：

Wolfram Language code: Series[Cos[x], {x, 0, 8}]

绘制 Cos 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[Cos[x], {x, 0, m}], {m, 2, 6, 2}];
Plot[{Cos[x], terms}, {x, -2π, 2π}, PlotRange -> {-1.5, 1.5}]

Cos 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[Cos[x], {x, 0, n}]

傅立叶级数：

Wolfram Language code: FourierSeries[Cos[z], z, 1]

Cos 可被应用于幂级数：

Wolfram Language code: Cos[(π/2) + x + (x^2/2) + (x^3/3) + O[x]^4]

积分变换 (3)

用 FourierTransform 计算傅立叶变换：

Wolfram Language code: FourierTransform[Cos[t], t, ω ]

LaplaceTransform:

Wolfram Language code: LaplaceTransform[Cos[t], t, s ]

MellinTransform:

Wolfram Language code: MellinTransform[Cos[x], x, s ]

函数属性和化简 (6)

倍角的 Cos：

Wolfram Language code: Expand[Cos[2x] , Trig -> True]

和的 Cos：

Wolfram Language code: Expand[Cos[x + y] , Trig -> True]

转换多倍角表达式：

Wolfram Language code: TrigExpand[Cos[4x]]

Wolfram Language code: TrigReduce[%]

把三角函数的和转换为积：

Wolfram Language code: TrigFactor[Cos[x] + Cos[y]]

假定实数变量和的情况下进行展开：

Wolfram Language code: ComplexExpand[Cos[x + I y]]

转换为复指数：

Wolfram Language code: TrigToExp[Cos[z]]

函数表示 (5)

用 Sin 来表示：

Wolfram Language code: Simplify[Sin[(Pi/2) - x]]

用贝塞尔函数来表示：

Wolfram Language code: Simplify[Sqrt[( π x/2)]BesselJ[-(1/2), x]]

Wolfram Language code: Simplify[Sqrt[( π I x/2)]BesselI[-(1/2), I x]]

用 SphericalHarmonicY 来表示：

Wolfram Language code: Simplify[Sqrt[4 π / 3]SphericalHarmonicY[1, 0, θ, 0]]

用 MeijerG 来表示：

Wolfram Language code: MeijerGReduce[Cos[x], x]

Wolfram Language code: Activate[%]

Cos 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[Cos[x], x]

应用 (14)

绘制一个圆：

Wolfram Language code: ParametricPlot[{Cos[t], Sin[t]}, {t, 0, 2Pi}]

Lissajous 图形：

Wolfram Language code: ParametricPlot[{Cos[2t], Cos[5t]}, {t, 0, 2Pi}]

等角 (对数) 螺旋：

Wolfram Language code: ParametricPlot[Exp[t / 10]{Cos[t], Sin[t]}, {t, 0, 10Pi}, PlotRange -> All]

圆周运动：

Wolfram Language code: Animate[Graphics[Line[{{0, 0}, {Cos[t], Sin[t]}}], PlotRange -> 1.2], {t, 0, 10Pi}]

求解谐振动方程：

Wolfram Language code: DSolve[x''[t] + ω^2x[t] == 0, x[t], t]

旋转矩阵：

Wolfram Language code: RotationMatrix[θ]

作用于水平向量：

Wolfram Language code: %.{1, 0}

绘制一个球体：

Wolfram Language code: ParametricPlot3D[{Cos[ϕ] Sin[θ], Sin[θ] Sin[ϕ], Cos[θ]}, {ϕ, -π, π}, {θ, 0, π}]

绘制一个 torus：

Wolfram Language code:

ParametricPlot3D[{Cos[ϕ] + 1 / 2 Cos[θ] Cos[ϕ], Sin[ϕ] + 1 / 2 Cos[θ] Sin[ϕ], Sin[θ] / 2}, {ϕ, -π, π}, {θ, 0, 2 π}]

二维波：

Wolfram Language code: Plot3D[Cos[x]Cos[y], {x, 0, 10Pi}, {y, 0, 10Pi}]

三元周期曲面：

Wolfram Language code:

ContourPlot3D[Cos[x] + Cos[y] + Cos[z], {x, -2Pi, 2Pi}, {y, -2Pi, 2Pi}, {z, -2Pi, 2Pi}, Contours -> {0}, Mesh -> False, BoundaryStyle -> None, 
	ContourStyle -> {Opacity[0.8]}]

在黎曼–Weierstras 函数的任何可微处的近似：

Wolfram Language code: Plot[Sum[N[Cos[j ^ 2 x] / j ^ 2], {j, 12}], {x, 0, 2Pi}]

具有两个相等角的三角形是等腰三角形：

Wolfram Language code: IsoscelesTriangle[α_, s_] := AASTriangle[α, α, s]

Wolfram Language code: t = IsoscelesTriangle[5π / 13, 1]

对其进行可视化：

Wolfram Language code: Graphics[t]

求解面积：

Wolfram Language code: FullSimplify[Area@IsoscelesTriangle[α, s], s > 0 && 0 < α < π]

检查艾里函数组合的索末菲 (Sommerfeld) 辐射条件：

Wolfram Language code: Series[AiryBi[z] - I AiryAi[z], {z, -∞, 2}]

只有一个出射平面波：

Wolfram Language code: Simplify[Normal[%]//TrigToExp]

使用 Cos 和 Sin 函数求得圆上一点：

Wolfram Language code:

ContourPlot[x ^ 2 + y ^ 2 == 1, {x, -1.5, 1.5}, {y, -1.5, 1.5}, Epilog -> Style[Point[{Cos[π / 4], Sin[π / 4]}], PointSize[Large], Red], Axes -> True, Frame -> False, AxesLabel -> {x, y}]

属性和关系 (12)

自动应用余弦函数的周期性和奇偶性：

Wolfram Language code: Cos[x + 2Pi]

Wolfram Language code: {Cos[-x], Cos[I x]}

Wolfram Language code: 1 / Cos[x]

包含三角函数的复杂表达式不能自动化简：

Wolfram Language code: Cos[3z]^2 - (Cos[z]^3 - 3 Cos[z] Sin[z]^2)^2

Wolfram Language code: Simplify[%]

Wolfram Language code: Cos[(x + y/2)]Cos[(x - y/2)] + ((1/2) Cos[(x/2)]^2 + (1/2) Cos[(y/2)]^2 - (1/2) Sin[(x/2)]^2 - (1/2) Sin[(y/2)]^2)

Wolfram Language code: Simplify[%]

与逆函数的组合：

Wolfram Language code: {Cos[ArcCos[z]], Cos[2ArcCos[z]], Cos[3ArcCos[z]]}

Wolfram Language code: FunctionExpand[%]

1 弧度是度：

Wolfram Language code: Cos[1] == CosDegrees[180 / π]//Simplify

求解一个三角方程：

Wolfram Language code: Reduce[Cos[z]^2 + 3 Cos[z + Pi / 6] == 4, z]

求出一个超越方程的数值解：

Wolfram Language code: FindRoot[Cos[z]^2 + 3 Cos[z + Pi / 6] + z == 4, {z, 4}]

化简一个三角方程：

Wolfram Language code: Reduce[Cos[α x + β] == 0, x]

积分：

Wolfram Language code: ∫Cos[z]^aⅆz

Cos 出现在多个数学函数的特例中：

Wolfram Language code:

{BesselJ[-(1/2), z], MathieuC[1, 0, z], JacobiCD[z, 0], Hypergeometric0F1[(1/2), -z], MeijerG[{{}, {}}, {{0}, {(1/2)}}, z]}

Cos 是一个数值函数：

Wolfram Language code: Attributes[Cos]

Wolfram Language code: NumericQ[Cos[2 + E]]

Cos 的母函数：

Wolfram Language code: GeneratingFunction[Cos[n], n, x]

Wolfram Language code: Series[%, {x, 0, 5}]//FullSimplify

Cos 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[Cos[n], n, x]

可能存在的问题 (5)

机器精度输入不足以获得正确结果：

Wolfram Language code: Cos[10. ^ 45]

精确的输入得到正确的结果：

Wolfram Language code: N[Cos[10 ^ 45], 20]

需要增大 $MaxExtraPrecision 的值：

Wolfram Language code: N[Cos[10 ^ 100], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Cos[10 ^ 100], 20]]

机器精度输入可以给出高精度结果：

Wolfram Language code: Cos[10. ^ 3I]

Wolfram Language code: MachineNumberQ[%]

涉及 Cos[x] 的连续函数可以给出不连续的不定积分：

Wolfram Language code: Integrate[(1/2 + Cos[x]), x]

Wolfram Language code: Plot[%, {x, 0, 2Pi}]

在 TraditionalForm 中，需要在自变量外加圆括号：

Wolfram Language code: cos x

Wolfram Language code: cos(x)

巧妙范例 (5)

非相称波（准周期函数）：

Wolfram Language code: Plot[Cos[x] + Cos[Sqrt[2]x], {x, 0, 40Pi}]

有些参数可以表示为嵌套的有限序列的根式：

Wolfram Language code: Cos[(π/2^12)]//FunctionExpand

的不定积分：

Wolfram Language code: Table[Integrate[Cos[x ^ n], x], {n, 3}]

Chladni 图形：

Wolfram Language code: DensityPlot[Cos[4x]Cos[3y] + 1 / 2Cos[3x]Cos[4y], {x, 0, 2Pi}, {y, 0, 2Pi}]

绘制积分点的 Cos：

Wolfram Language code: ArrayPlot[Table[Cos[x y], {x, -20, 20}, {y, -20, 20}]]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Cos

更多信息

背景

范例

基本范例 (5)

范围 (51)

数值计算 (6)

特殊值 (5)

可视化 (3)

函数属性 (13)

微分 (3)

积分 (3)

级数展开式 (4)

积分变换 (3)

函数属性和化简 (6)

函数表示 (5)

应用 (14)

属性和关系 (12)

可能存在的问题 (5)

巧妙范例 (5)

文本

CMS

APA

BibTeX

BibLaTeX

Cos

更多信息

背景

范例

基本范例 (5)

范围 (51)

数值计算 (6)

特殊值 (5)

可视化 (3)

函数属性 (13)

微分 (3)

积分 (3)

级数展开式 (4)

积分变换 (3)

函数属性和化简 (6)

函数表示 (5)

应用 (14)

属性和关系 (12)

可能存在的问题 (5)

巧妙范例 (5)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX