WOLFRAM

Wolfram 语言与系统参考资料中心

CreateArchive[source]

从 source 的当前目录中创建一个压缩档案.

CreateArchive[source,path]

在由 path 指定的目录或者文件中创建一个压缩档案.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
源  
路径  
格式  
选项  
CompressionLevel  
CreateIntermediateDirectories  
OverwriteTarget  
应用  
用电子邮件发送一个压缩过的目录  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

CreateArchive

CreateArchive[source]

从 source 的当前目录中创建一个压缩档案.

CreateArchive[source,path]

在由 path 指定的目录或者文件中创建一个压缩档案.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

从 ExampleData 目录创建一个 ZIP 归档文件：

Wolfram Language code: archive = CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}]]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

从 ExampleData 目录的文件列表中创建一个 ZIP 文件：

Wolfram Language code: archive = CreateArchive[FileNames["*.jpg", FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}]]]

导入 ZIP 文件中包含的文件名列表：

Wolfram Language code: Import[archive]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

指定一个明确的目标路径：

Wolfram Language code: archive = CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}]]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

范围  (12)

源  (6)

从文件创建一个 ZIP 归档文件：

Wolfram Language code: file = FindFile["ExampleData/coneflower.jpg"];
Wolfram Language code: archive = CreateArchive[file]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

从目录创建一个 ZIP 归档文件：

Wolfram Language code: archive = CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}]]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

用远程和本地文件创建 ZIP 存档文件：

Wolfram Language code: archive = CreateArchive[{FindFile["ExampleData/coneflower.jpg"], URL["http://exampledata.wolfram.com/sample.pdf"]}]

导入 ZIP 文件中包含的文件名列表：

Wolfram Language code: Import[archive]

删除所得的存档文件：

Wolfram Language code: DeleteFile[archive]

收集要归档的文件列表：

Wolfram Language code: files = FileNames["*.jpg", FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}]]

根据所选文件创建一个 ZIP 存档：

Wolfram Language code: archive = CreateArchive[files]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

为档案中的每个文件或目录指定名称：

Wolfram Language code: files = FileNames["*.jpg", FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}]];
Wolfram Language code: archive = CreateArchive[Association@MapIndexed[ToString@#2[[1]] <> ".jpg" -> #1&, files]]

导入 ZIP 文件中包含的文件名列表：

Wolfram Language code: Import[archive]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

用包含图像文件的 CloudObject 创建 ZIP 压缩包：

Wolfram Language code: co = CloudObject["https://www.wolframcloud.com/obj/documentation/flower2"]; Import[co] CreateArchive[co]

导入 ZIP 文件中包含的文件名列表：

Wolfram Language code: Import[%]

删除生成的存档：

Wolfram Language code: DeleteFile[%%]

路径  (3)

如果未指定目的地，则将存档放置在 Directory[] 指定的路径中：

Wolfram Language code: archive = CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}]]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

指定一个明确的目标目录：

Wolfram Language code: archive = CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}], $UserBaseDirectory]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

指定一个明确的档案名称：

Wolfram Language code: archive = CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}], FileNameJoin[{$UserBaseDirectory, "file.zip"}]]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

格式  (3)

默认情况下，将创建一个ZIP文件：

Wolfram Language code: archive = CreateArchive[FindFile["ExampleData/coneflower.jpg"]]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

如果指定了目的地，则从目的地的扩展名推断出存档格式.

创建一个 .gz 文件：

Wolfram Language code: archive = CreateArchive[FindFile["ExampleData/coneflower.jpg"], "coneflower.jpg.gz"]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

在特定目录中创建一个显式命名的 .tar.bz2 存档：

Wolfram Language code: archive = CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}] , FileNameJoin[{$UserBaseDirectory, "archive.tar.bz2"}]]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

选项  (4)

CompressionLevel  (1)

压缩前检查文件大小：

Wolfram Language code: FileByteCount[file = FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData", "coneflower.jpg"}]]

默认情况下执行一些压缩：

Wolfram Language code: FileByteCount[archive = CreateArchive[file]]

删除生成的档案：

Wolfram Language code: DeleteFile[archive]

指定不使用压缩：

Wolfram Language code: FileByteCount[archive = CreateArchive[file, "CompressionLevel" -> 0]]

删除生成的档案：

Wolfram Language code: DeleteFile[archive]

指定应使用最大压缩率：

Wolfram Language code: FileByteCount[archive = CreateArchive[file, "CompressionLevel" -> 1]]

删除生成的存档：

Wolfram Language code: DeleteFile[archive]

CreateIntermediateDirectories  (2)

不创建到目标路径的中间目录：

Wolfram Language code: CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}], FileNameJoin[{$HomeDirectory, CreateUUID[], "non", "existent", "directory"}], CreateIntermediateDirectories -> False]

默认情况下，中间目录在目标路径上创建：

Wolfram Language code: CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}], FileNameJoin[{$HomeDirectory, uniqueDir = CreateUUID[], "non", "existent", "directory"}]]

删除创建的目录：

Wolfram Language code: DeleteDirectory[FileNameJoin[{$HomeDirectory, uniqueDir}], DeleteContents -> True]

OverwriteTarget  (1)

创建一个 GZIP 压缩文件：

Wolfram Language code: file = CreateArchive[FindFile["ExampleData/turtle.jpg"], "file.gz"]

默认情况下不会覆盖文件：

Wolfram Language code: CreateArchive[FindFile["ExampleData/turtle.jpg"], "file.gz"]

用 OverwriteTargetTrue 覆盖现有文件：

Wolfram Language code: CreateArchive[FindFile["ExampleData/turtle.jpg"], "file.gz", OverwriteTarget -> True]

删除生成的存档文件：

Wolfram Language code: DeleteFile[file]

应用  (1)

用电子邮件发送一个压缩过的目录  (1)

用 SendMail 发送具有最大文件压缩率的目录：

Wolfram Language code: file = CreateArchive[FileNameJoin[{$InstallationDirectory, "Documentation", "English", "System", "ExampleData"}], CompressionLevel -> 1, OverwriteTarget -> True];
Wolfram Language code: SendMail[<|"Subject" -> "Wolfram Guide Pages", "Body" -> "Here's a zip archive of the Wolfram guide pages.", "AttachedFiles" -> file|>]

删除生成的存档：

Wolfram Language code: DeleteFile[file]

属性和关系  (1)

CreateArchive 从文件系统上已有的文件和目录构造一个归档文件：

Wolfram Language code: archive1 = CreateArchive[FindFile["ExampleData/turtle.jpg"]]

Export 可用于根据 Wolfram 语言中的表达式创建档案：

Wolfram Language code: archive2 = Export["test.zip", <|"a.gif" -> \!\(\*GraphicsBox[«4»]\), "b.txt" -> "earth seen from space"|>, "Rules" ]

删除生成的档案：

Wolfram Language code: DeleteFile[{archive1, archive2}]

可能存在的问题  (1)

GZIP 和 BZIP2 仅支持压缩单个文件：

Wolfram Language code: CreateArchive[{FindFile["ExampleData/turtle.jpg"], FindFile["ExampleData/coneflower.jpg"]}, "test.gz"]
Wolfram Research (2010)，CreateArchive，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CreateArchive.html （更新于 2026 年）.

文本

Wolfram Research (2010)，CreateArchive，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CreateArchive.html （更新于 2026 年）.

CMS

Wolfram 语言. 2010. "CreateArchive." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2026. https://reference.wolfram.com/language/ref/CreateArchive.html.

APA

Wolfram 语言. (2010). CreateArchive. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CreateArchive.html 年

BibTeX

@misc{reference.wolfram_2026_createarchive, author="Wolfram Research", title="{CreateArchive}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/CreateArchive.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_createarchive, organization={Wolfram Research}, title={CreateArchive}, year={2026}, url={https://reference.wolfram.com/language/ref/CreateArchive.html}, note=[Accessed: 16-September-2026]}