Wolfram 语言与系统参考资料中心

Cumulant

Cumulant[data,r]

给出 data 的第 r 个累积量 .

Cumulant[data,{r₁,…,r_m} ]

给出 data 的阶次为 {r₁,…,r_m}的多元累积量 .

Cumulant[dist,r]

给出分布 dist 的 r 阶累积量.

Cumulant[r]

表示 r 阶形式累积量.

范例

打开所有单元关闭所有单元

基本范例 (3)

从数据计算累积量：

Wolfram Language code: data = RandomVariate[LogisticDistribution[0, 1], 10 ^ 5];

Wolfram Language code: Cumulant[data, 2]

对于符号数据：

Wolfram Language code: Cumulant[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, 2]

日期列表的累积量：

Wolfram Language code: Cumulant[{Yesterday, Today, Tomorrow}, 4]

计算一个连续单变量分布的二阶累积量：

Wolfram Language code: Cumulant[GammaDistribution[α, β], 2]

一个多变量分布的累积量：

Wolfram Language code: Cumulant[DirichletDistribution[{α, β, γ}], {1, 2}]

范围 (26)

基础用法 (6)

精确输入产生精确输出：

Wolfram Language code: Cumulant[{1, 2, 3, 4}, 2]

Wolfram Language code: Cumulant[{π, E, 2}, 1]

近似输入产生近似输出：

Wolfram Language code: Cumulant[{1., 2., 3., 4.}, 2]

Wolfram Language code: Cumulant[N[{1, 2, 3, 4}, 30], 2]

求 WeightedData 的累积量：

Wolfram Language code: Cumulant[WeightedData[{1, 2, 3}, {Subscript[w, 1], Subscript[w, 2], Subscript[w, 3]}], 1]

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: Cumulant[WeightedData[data, weights], 2]

求 EventData 的累积量：

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: Cumulant[EventData[e, ci], 1]

求 TimeSeries 的累积量：

Wolfram Language code:

Cumulant[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.], 2]

累积量仅与数值有关：

Wolfram Language code:

Cumulant[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]["Values"], 2]

求带单位数据的累积量：

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]

Wolfram Language code: Cumulant[data, 2]

数组数据 (5)

对于矩阵而言，Cumulant 给出列向累计量：

Wolfram Language code:

Cumulant[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), 4]//Simplify

对于数组而言，Cumulant 给出第一层的列向累积量：

Wolfram Language code: Cumulant[Array[Subscript[a, ##]&, {2, 2, 2}], 4]//Simplify//MatrixForm

Wolfram Language code: Cumulant[Array[Subscript[a, ##]&, {2, 2, 2}], {4, 4}]//Simplify

适用于大型数组：

Wolfram Language code: Cumulant[RandomReal[1, 10 ^ 7], 2]

Wolfram Language code: Cumulant[RandomReal[1, {10 ^ 6, 5}], 2]

当输入为 Association 时，Cumulant 作用于其值：

Wolfram Language code:

mat = RandomReal[1, {3, 2}];
assoc = AssociationThread[Range[3], mat]

Wolfram Language code: Cumulant[assoc, 3]

SparseArray 数据可以像稠密数组一样使用：

Wolfram Language code: Cumulant[SparseArray[{{1} -> 1, {100} -> 1}], 4]

Wolfram Language code: Cumulant[SparseArray[{{1, 1} -> 1, {2, 2} -> 2, {3, 3} -> 3, {1, 3} -> 4}], 2]

根据原始矩计算数组的多元累积量：

Wolfram Language code: (f = MomentConvert[Cumulant[{3, 3}], Moment])//Simplify//TraditionalForm//Short

Wolfram Language code: arr = RandomReal[1, {2, 2, 2}, WorkingPrecision -> 50];

Wolfram Language code: c1 = Cumulant[arr, {3, 3}]

Wolfram Language code: c2 = (f /. Moment[l_] :> Moment[arr, l])

Wolfram Language code: c1 == c2

图像和音频数据 (2)

RGB 图像的通道累积量：

Wolfram Language code: Cumulant[[image], 5]

Wolfram Language code: RGBColor[%]

灰度图像的累积量强度值：

Wolfram Language code: Cumulant[[image], 4]

对于音频对象，Cumulant 按通道工作：

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]

Wolfram Language code: AudioMeasurements[a, "Channels"]

Wolfram Language code: Cumulant[a, 3]

日期和时间 (4)

计算日期的累积量：

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];

Wolfram Language code: DateHistogram[dates]

Wolfram Language code: Cumulant[dates, 4]

Wolfram Language code: UnitConvert[%, "Decades" ^ 4]

计算日期的加权累积量：

Wolfram Language code: dates = RandomDate[4]

Wolfram Language code: weights = {1, 1, 1, 3};

Wolfram Language code: Cumulant[WeightedData[dates, weights], 3]

Wolfram Language code: UnitConvert[%, "Months" ^ 3]

与简单累积量比较：

Wolfram Language code: Cumulant[dates, 3]

Wolfram Language code: UnitConvert[%, "Months" ^ 3]

计算不同历法日期的累积量：

Wolfram Language code:

dates = {DateObject[{2024, 2, 29}, CalendarType -> "Julian"], DateObject[{1524, 1, 1}, CalendarType -> "Islamic"], DateObject[{6024, 1, 15}, CalendarType -> "Jewish"]}

Wolfram Language code: Cumulant[dates, 3]

Wolfram Language code: UnitConvert[%, "Centuries" ^ 3]

计算时间的累积量：

Wolfram Language code: RandomTime[3]

Wolfram Language code: Cumulant[%, 4]

不同时区规范的时间列表：

Wolfram Language code: {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}

Wolfram Language code: Cumulant[%, 3]

分布与过程累积量 (5)

Scalar单变量分布的累积量：

Wolfram Language code: Cumulant[BinomialDistribution[n, p], 1]

Wolfram Language code: Cumulant[NormalDistribution[μ, σ], 2]

多元分布的标量积：

Wolfram Language code: Cumulant[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {σ1, σ2}, ρ], 2]

Wolfram Language code: Cumulant[DirichletDistribution[{a, b, c}], 2]//Simplify

多元分布的联合累积量：

Wolfram Language code: Cumulant[MultivariateHypergeometricDistribution[n, {Subscript[m, 1], Subscript[m, 2]}], {1, 1}]

Wolfram Language code: Cumulant[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {σ1, σ2}, ρ], {1, 1}]

计算符号式阶 r 的累积量：

Wolfram Language code: Cumulant[PoissonDistribution[μ], r]

累积量仅对具体阶数计算：

Wolfram Language code: Cumulant[BetaDistribution[α, β], r]

Wolfram Language code: % /. r -> 2

累积量仅能数值式计算：

Wolfram Language code: Cumulant[VonMisesDistribution[Pi / 2, 2], 4]

Wolfram Language code: N[%]

导出分布的累积量：

Wolfram Language code: Cumulant[TransformedDistribution[x^2, xNormalDistribution[μ, σ]], 2]

Wolfram Language code: Cumulant[ProbabilityDistribution[(Exp[1 - x] x (1 - x)/3 - E), {x, 0, 1}], 3]

数据分布：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];

Wolfram Language code: Cumulant[HistogramDistribution[data], 1]

随机过程的累积量函数：

Wolfram Language code: Cumulant[QueueingProcess[λ, μ, ∞][t], 2]

Wolfram Language code: Plot[Evaluate[% /. {λ -> 1, μ -> 3}], {t, 0, 1}, PlotRange -> All]

求 TemporalData 在时刻 t=0.5 的累积量：

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 100]

Wolfram Language code: Cumulant[td[0.5], 1]

求相应的累积量函数和所有的模拟：

Wolfram Language code:

Show[ListLinePlot[td, PlotStyle -> Directive[Opacity[0.7], Thin]], Plot[Cumulant[td[t], 1], {t, 0, 10}, PlotStyle -> Thick]]

正式累积量 (4)

正式累积量的 TraditionalForm 格式：

Wolfram Language code: Cumulant[r]//TraditionalForm

Wolfram Language code: Cumulant[{p, q, r}]//TraditionalForm

将正式矩的组合转换为含 Cumulant 的表达式：

Wolfram Language code: MomentConvert[Moment[4], Cumulant]//TraditionalForm

Wolfram Language code: MomentConvert[CentralMoment[2]Moment[2], Cumulant]//TraditionalForm

计算包含正式累积量的一个分布的表达式：

Wolfram Language code: MomentEvaluate[Cumulant[1] + Cumulant[2], BetaDistribution[α, β]]

对数据计算：

Wolfram Language code: data = RandomVariate[BetaDistribution[2, 3], 10^4];

Wolfram Language code: MomentEvaluate[Cumulant[1] + Cumulant[2], data]

求包含 Cumulant 的一个表达式的样本估计量：

Wolfram Language code: estimator = MomentConvert[Cumulant[1], "UnbiasedSampleEstimator"]

计算数据所产生的估计量：

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[estimator, data]

应用 (5)

利用累积量法估计分布的参数：

Wolfram Language code: data = RandomVariate[BetaDistribution[3, 6], 10 ^ 4];

Wolfram Language code: NSolve[Table[Cumulant[data, k] == Cumulant[BetaDistribution[a, b], k], {k, 1, 2}], {a, b}]

根据大数定理，随着样本量的增加，样本矩逐渐趋向于总体矩. 使用 Histogram 说明不同样本量时，标准正态随机变量的样本累积量的概率分布：

Wolfram Language code:

Histogram[Table[Cumulant[RandomReal[NormalDistribution[], {n, 10 ^ 3}], 3], {n, {10, 10^2, 10^4}}], 50, "ProbabilityDensity", ChartLegends -> {10, 10^2, 10^4}]

阶数为的 Edgeworth 展开：

Wolfram Language code:

EdgeworthSeries[p_ /; p ≥ 2, y_] := With[{z = (y - Cumulant[1]), σ = Sqrt[Cumulant[2]]}, PDF[NormalDistribution[0, σ], z](1 + Sum[(σ^s/2^(s/2) + rs!)HermiteH[s + 2r, (z/Sqrt[2]σ)]BellY[s, r, Table[(Cumulant[k]/(k - 1)k σ^2k - 2), {k, 3, p}]], {s, p - 2}, {r, s}])]

趋向于 SechDistribution：

Wolfram Language code: dist = SechDistribution[1, 2];

Wolfram Language code: pdf = MomentEvaluate[EdgeworthSeries[4, y], dist]

Wolfram Language code: Plot[{pdf, PDF[dist, y]}, {y, -5, 5}, PlotRange -> All]

计算一些数据的移动累积量：

Wolfram Language code:

data = TemporalData[TimeSeries, {{{0., 0.06114665305643561, 0.23896662440972682, 0.30268800326923, 
    0.35534116766660545, 0.42472631677502126, 0.3966448861155263, 0.41578142003045876, 
    0.3468861633239847, 0.3381046650827597, 0.38002782955469216, 0. ... 208767424126402, 2.118103218029293, 2.18195782653722, 
    2.087973123089836}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

使用长度为.1的窗：

Wolfram Language code: mc = MovingMap[Cumulant[#, 2]&, data, .1];

Wolfram Language code: ListLinePlot[mc, PlotRange -> All]

计算随机过程一组路径的切片的累积量：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

选择几个切片时间：

Wolfram Language code: times = Range[0, 1, .1];

Wolfram Language code: cm = Map[{#, Cumulant[data[#], 2]}&, times];

绘制这些路径上的累积量：

Wolfram Language code: Show[ListPlot[data], ListLinePlot[cm, PlotStyle -> Green]]

属性和关系 (5)

一阶累积量与一阶矩等价：

Wolfram Language code: MomentConvert[Cumulant[1], Moment]

二阶累积量与二阶中心矩等价：

Wolfram Language code: MomentConvert[Cumulant[2], CentralMoment]

三阶累积量与三阶中心矩等价：

Wolfram Language code: MomentConvert[Cumulant[3], CentralMoment]

累积量等于累积量母函数在零点的阶导数：

Wolfram Language code: cgf = CumulantGeneratingFunction[ExponentialDistribution[λ], t]

Wolfram Language code: SeriesCoefficient[cgf r!, {t, 0, r}]

直接使用 Cumulant：

Wolfram Language code: Cumulant[ExponentialDistribution[λ], r]

利用 GeneratingFunction 求累积量母函数：

Wolfram Language code: Cumulant[PoissonDistribution[μ], r]

Wolfram Language code: cgf = GeneratingFunction[% / r!, r, t]

利用 CumulantGeneratingFunction 进行检验：

Wolfram Language code: CumulantGeneratingFunction[PoissonDistribution[μ], t]

形式上，可利用 CumulantGeneratingFunction[dist,t] 由 Log[MomentGeneratingFunction[dist,t]] 给出的事实来计算累积量：

Wolfram Language code:

Clear[mgf];
Series[Log@mgf[x], {x, 0, 3}]
coeff = SeriesCoefficient[%, 3]3!

根据生成函数输入矩的定义：

Wolfram Language code: rep = {mgf[0] -> 1, Derivative[n_][mgf][0] :> Moment[n]};

Wolfram Language code: (coeff /. rep) == MomentConvert[Cumulant[3], Moment]

对数据的 Cumulant 的样本估计值是有偏的：

Wolfram Language code: (se = MomentConvert[Cumulant[4], "SampleEstimator"])//TraditionalForm

假设大小为，求采样总体期望：

Wolfram Language code: see = MomentConvert[se, {Cumulant, n}]

使用 PowerSymmetricPolynomial 构建一个无偏样本估计量：

Wolfram Language code: (ue = MomentConvert[Cumulant[4], "UnbiasedSampleEstimator", PowerSymmetricPolynomial])//TraditionalForm

验证小样本上的无偏性：

Wolfram Language code:

Expand[MomentEvaluate[ue, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]] /. Subscript[x, i_]^r_. :> Moment[r]

Wolfram Language code: MomentConvert[%, Cumulant]

样本估计值是有偏的：

Wolfram Language code:

MomentConvert[Expand[Cumulant[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}, 4]] /. Subscript[x, i_]^r_. :> Moment[r], Cumulant]

与样本估计量的采样总体期望进行比较：

Wolfram Language code: see /. n -> 5

可能存在的问题 (1)

对于某些长尾分布，定义了某些低阶累积量：

Wolfram Language code: Table[Cumulant[ParetoDistribution[k, 5], r], {r, 5}]

巧妙范例 (2)

求累积量的积的无偏估计：

Wolfram Language code:

MomentConvert[Cumulant[1]Cumulant[2]Cumulant[3], {"UnbiasedEstimator", n}, "PowerSymmetricPolynomial"]//FullSimplify//TraditionalForm

检查采样总体期望：

Wolfram Language code: MomentConvert[%, {Cumulant, n}]

对 20、100和 300 个样本 Cumulant 的分布估计：

Wolfram Language code: Cumulant[ExponentialDistribution[0.9], 2]

Wolfram Language code:

SmoothHistogram[Table[Cumulant[RandomVariate[ExponentialDistribution[0.9], {s, 1000}], 2], {s, {20, 100, 300}}], Filling -> Axis, PlotLegends -> {20, 100, 300}, PlotRange -> {{0, 4}, Automatic}]

Top

	Association	值（键值被忽略） »
	WeightedData	加权平均值，基于底层的 EmpiricalDistribution »
	EventData	基于底层的 SurvivalDistribution »
	TimeSeries, TemporalData, …	值的向量或数组（时间戳忽略不计） »
	Image,Image3D	RGB 通道值或灰度强度值 »
	Audio	所有通道的振幅值 »
	DateObject, TimeObject	日期或时间列表 »

	Cumulant[,r]	»
	Cumulant[dist,{r₁,…,r_m}]	»

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Cumulant

更多信息

范例

基本范例 (3)

范围 (26)

基础用法 (6)

数组数据 (5)

图像和音频数据 (2)

日期和时间 (4)

分布与过程累积量 (5)

正式累积量 (4)

应用 (5)

属性和关系 (5)

可能存在的问题 (1)

巧妙范例 (2)

文本

CMS

APA

BibTeX

BibLaTeX

Cumulant

更多信息

范例

基本范例 (3)

范围 (26)

基础用法 (6)

数组数据 (5)

图像和音频数据 (2)

日期和时间 (4)

分布与过程累积量 (5)

正式累积量 (4)

应用 (5)

属性和关系 (5)

可能存在的问题 (1)

巧妙范例 (2)

参见

相关指南

相关的工作流程

历史

文本

CMS

APA

BibTeX

BibLaTeX