WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DistanceMatrix[{u1,u2,…}]

要素 ui, ujの各ペア間の距離の行列を与える．

DistanceMatrix[{u1,u2,…},{v1,v2,…}]

要素 ui, vjの各ペア間の距離の行列を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
DistanceFunction  
FeatureExtractor  
FeatureNames  
Show More Show More
FeatureTypes  
PerformanceGoal  
RandomSeeding  
WorkingPrecision  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

DistanceMatrix

DistanceMatrix[{u1,u2,…}]

要素 ui, ujの各ペア間の距離の行列を与える．

DistanceMatrix[{u1,u2,…},{v1,v2,…}]

要素 ui, vjの各ペア間の距離の行列を与える．

詳細とオプション

例題

すべて開く すべて閉じる

例  (3)

整数のリストから距離行列を計算する：

Wolfram Language code: dm = DistanceMatrix[{1, 2, 3, 4}]
Wolfram Language code: dm // MatrixForm

整数のリスト2つから距離行列を計算する：

Wolfram Language code: dm = DistanceMatrix[{1, 2, 3, 4}, {5, 6, 7}]
Wolfram Language code: dm // MatrixForm

実数値の数値ベクトルから距離行列を計算する：

Wolfram Language code: dm = DistanceMatrix[{{1.5, 4.3}, {2.1, 5.6}, {6.2, 4.5}}, {{1.6, 4.2}, {2.3, 5.4}}]
Wolfram Language code: dm // MatrixForm

スコープ  (10)

画像から距離行列を計算する：

Wolfram Language code: DistanceMatrix[{[image], [image], [image]}] // MatrixForm

文字列から距離行列を計算する：

Wolfram Language code: DistanceMatrix[{"abcd", "bcde", "xyz"}] // MatrixForm

ブールベクトルから距離行列を計算する：

Wolfram Language code: DistanceMatrix[{{True, False, True}, {True, True, True}, {True, False, False}}] // MatrixForm

日付オブジェクトのリストから距離行列を計算する：

Wolfram Language code: DistanceMatrix[{DateObject[{1985, 10, 3}], DateObject[{1989, 5, 30}], DateObject[]}] // MatrixForm

測地位置から距離行列を計算する：

Wolfram Language code: DistanceMatrix[{GeoPosition[Entity["City", {"Paris", "IleDeFrance", "France"}]], GeoPosition[Entity["City", {"Sydney", "NewSouthWales", "Australia"}]], GeoPosition[Entity["City", {"Boston", "Massachusetts", "UnitedStates"}]], GeoPosition[Entity["City", {"SanFrancisco", "California", "UnitedStates"}]]}] // MatrixForm

名目列から距離行列を計算する：

Wolfram Language code: DistanceMatrix[{{"a", "b", "c", "d"}, {"b", "c", "d", "e"}, {"x", "y", "z"}}] // MatrixForm

数列から距離行列を計算する：

Wolfram Language code: DistanceMatrix[{{1.1, 1.2, 1.3, 1.4, 1.5}, {1.2, 1.3}, {1.4, 1.5, 1.6}}] // MatrixForm

名目ベクトルについて距離行列を計算する：

Wolfram Language code: DistanceMatrix[{{"A", "Sugar"}, {"A", "Salt"}, {"B", "Sugar"}, {"B", "Salt"}}]//MatrixForm

混合タイプのベクトルから距離行列を計算する：

Wolfram Language code: DistanceMatrix[{{1.2, "A"}, {3.1, "A"}, {1.1, "B"}, {3.3, "B"}}] // MatrixForm

連想のリストとしてフォーマットされたデータ集合から距離行列を計算する：

Wolfram Language code: data = {<|"age" -> 32, "height" -> 160, "gender" -> "female"|>, <|"height" -> 183, "age" -> 41, "gender" -> "female"|>, <|"height" -> 123, "age" -> 30, "gender" -> "female"|>, <|"height" -> 175, "age" -> 21, "gender" -> "male"|>, <|"height" -> 150, "age" -> 11, "gender" -> "male"|>, <|"age" -> 52, "height" -> 164, "gender" -> "female"|>};
Wolfram Language code: DistanceMatrix[data]//MatrixForm

列指向のデータ集合について同じ距離行列を計算する：

Wolfram Language code: DistanceMatrix[<|"age" -> {32, 41, 30, 21, 11, 52}, "height" -> {160, 183, 123, 175, 150, 164}, "gender" -> {"female", "female", "female", "male", "male", "female"}|>]//MatrixForm

データはDatasetオブジェクトとして与えることもできる：

Wolfram Language code: dataset = Dataset[data]
Wolfram Language code: DistanceMatrix[dataset]//MatrixForm

オプション  (9)

DistanceFunction  (3)

SquaredEuclideanDistanceを距離関数として使って整数ベクトルから距離行列を計算する：

Wolfram Language code: DistanceMatrix[{{1, 5}, {2, 3}, {3, 1}, {4, 7}}, DistanceFunction -> SquaredEuclideanDistance] // MatrixForm

ManhattanDistanceを使って距離行列を計算する：

Wolfram Language code: DistanceMatrix[{{1.3, 5.2}, {1.2, 7.3}, {3.6, 1.1}, {4.6, 7.4}}, DistanceFunction -> ManhattanDistance] // MatrixForm

デフォルト距離とは異なる色距離を使う：

Wolfram Language code: DistanceMatrix[{RGBColor[0.8153963685313876, 0.8780324414500478, 0.8878969785400366], RGBColor[0.7000498357974252, 0.12659377056191357, 0.2441846342253282], RGBColor[0.22075683601648843, 0.11406627268342273, 0.5155520370226843], RGBColor[0.7106648135050211, 0.42410292720247544, 0.14462936430464635], RGBColor[0.46490866303974765, 0.16254211516915973, 0.6466382153254229]}, DistanceFunction -> "CIE2000"]

FeatureExtractor  (1)

特徴抽出器メソッドの"NumericVector"を使って前処理された画像から，距離行列を計算する：

Wolfram Language code: DistanceMatrix[{[image], [image], [image], [image], [image], [image]}, FeatureExtractor -> "NumericVector"] // MatrixPlot

FeatureNames  (1)

FeatureNamesを使って特徴に命名し，さらなる指定でこの名前を参照する：

Wolfram Language code: DistanceMatrix[{{2.3, "male"}, {4.8, Missing[]}, {Missing[], "female"}, {5.2, "female"}}, FeatureNames -> {"gender", "age"}, FeatureTypes -> <|"gender" -> "Numerical", "age" -> "Nominal"|>]

FeatureTypes  (1)

FeatureTypesを使って最初の特徴を名目的であるとする解釈を強制する：

Wolfram Language code: DistanceMatrix[{{1, "A"}, {2, "A"}, {2, "B"}, {1, "B"}}, FeatureTypes -> <|1 -> "Nominal"|>]// MatrixForm

PerformanceGoal  (1)

長さ1000のランダムな数値ベクトルを2000個生成する：

Wolfram Language code: vectors = RandomReal[{10, 11}, {2000, 1000}];

このベクトルの距離行列を計算し，その操作を基準に従って評価する：

Wolfram Language code: AbsoluteTiming[result = DistanceMatrix[vectors];]

PerformanceGoalを"Speed"に設定して同じ操作を行う：

Wolfram Language code: AbsoluteTiming[resultspeed = DistanceMatrix[vectors, PerformanceGoal -> "Speed"];]

上記結果の時間と確度を基準値と比較する：

Wolfram Language code: AbsoluteTiming[reference = Outer[EuclideanDistance, vectors, vectors, 1];]
Wolfram Language code: StandardDeviation[Flatten[result - reference]]
Wolfram Language code: StandardDeviation[Flatten[resultspeed - reference]]

PerformanceGoal"Speed"のときは，データの中心化の精度が上がる：

Wolfram Language code: mean = Mean[vectors]; centered = # - mean & /@ vectors;
Wolfram Language code: AbsoluteTiming[resultspeedcentered = DistanceMatrix[centered, PerformanceGoal -> "Speed"];]
Wolfram Language code: StandardDeviation[Flatten[resultspeedcentered - reference]]

RandomSeeding  (1)

DistanceMatrixは，たとえランダム性が含まれていても，何回計算されても同じ結果を与える．

20次元ベクトルのペアを生成する：

Wolfram Language code: data = RandomReal[1, {2, 20}];

ランダム性を含む特徴検出器を使って距離行列を数回計算する：

Wolfram Language code: table = Table[DistanceMatrix[data, FeatureExtractor -> (RandomChoice[#, 10]&)], 5];

結果を比較する：

Wolfram Language code: Counts[table]

RandomSeedingオプションの与えを変えて距離行列を計算する：

Wolfram Language code: randomtable = Table[DistanceMatrix[data, FeatureExtractor -> (RandomChoice[#, 10]&), RandomSeeding -> RandomInteger[10]], 5];

結果を比較する：

Wolfram Language code: Counts[randomtable]

WorkingPrecision  (1)

長さ100の500個のランダムな数値ベクトルについて，精度が30で距離行列を計算する：

Wolfram Language code: r = RandomReal[1, {500, 100}, WorkingPrecision -> 30];
Wolfram Language code: AbsoluteTiming[dm = DistanceMatrix[r];]

DistanceMatrixは任意精度計算を使う：

Wolfram Language code: Precision[dm]

WorkingPrecisionMachinePrecisionを使うと計算速度が上がる：

Wolfram Language code: AbsoluteTiming[dmmachine = DistanceMatrix[r, WorkingPrecision -> MachinePrecision];]

しかし，結果の精度は前の計算ほどよくない：

Wolfram Language code: Precision[dmmachine]

ベクトルが類似している場合は，WorkingPrecisionの値を変えることで結果が著しく変わることがある：

Wolfram Language code: r = RandomReal[{10 ^ 20, 10 ^ 20 + 1}, {3, 2}, WorkingPrecision -> 30]
Wolfram Language code: DistanceMatrix[r] // MatrixForm
Wolfram Language code: DistanceMatrix[r, WorkingPrecision -> MachinePrecision] // MatrixForm

アプリケーション  (1)

2つの点集合間の最短距離を求める：

Wolfram Language code: p1 = RandomPoint[Sphere[], 20]; p2 = RandomPoint[Sphere[{3, 2, 5}], 20]; ListPointPlot3D[{p1, p2}, AspectRatio -> 1]
Wolfram Language code: Min[DistanceMatrix[p1, p2]]
Wolfram Research (2015), DistanceMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/DistanceMatrix.html （2017年に更新）.

テキスト

Wolfram Research (2015), DistanceMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/DistanceMatrix.html （2017年に更新）.

CMS

Wolfram Language. 2015. "DistanceMatrix." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/DistanceMatrix.html.

APA

Wolfram Language. (2015). DistanceMatrix. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DistanceMatrix.html

BibTeX

@misc{reference.wolfram_2026_distancematrix, author="Wolfram Research", title="{DistanceMatrix}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/DistanceMatrix.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_distancematrix, organization={Wolfram Research}, title={DistanceMatrix}, year={2017}, url={https://reference.wolfram.com/language/ref/DistanceMatrix.html}, note=[Accessed: 14-September-2026]}