WOLFRAM

Wolfram 语言与系统参考资料中心

DistanceMatrix[{u1,u2,…}]

给出每对元素 ui, uj 之间距离的矩阵.

DistanceMatrix[{u1,u2,…},{v1,v2,…}]

给出每对元素 ui, vj 之间距离的矩阵.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
DistanceFunction  
FeatureExtractor  
FeatureNames  
Show More Show More
FeatureTypes  
PerformanceGoal  
RandomSeeding  
WorkingPrecision  
应用  
参见
相关指南
历史
按以下格式引用：

DistanceMatrix

DistanceMatrix[{u1,u2,…}]

给出每对元素 ui, uj 之间距离的矩阵.

DistanceMatrix[{u1,u2,…},{v1,v2,…}]

给出每对元素 ui, vj 之间距离的矩阵.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

计算一个整数列表的距离矩阵：

Wolfram Language code: dm = DistanceMatrix[{1, 2, 3, 4}]
Wolfram Language code: dm // MatrixForm

计算两个整数列表的距离矩阵：

Wolfram Language code: dm = DistanceMatrix[{1, 2, 3, 4}, {5, 6, 7}]
Wolfram Language code: dm // MatrixForm

计算实数数值向量的距离矩阵：

Wolfram Language code: dm = DistanceMatrix[{{1.5, 4.3}, {2.1, 5.6}, {6.2, 4.5}}, {{1.6, 4.2}, {2.3, 5.4}}]
Wolfram Language code: dm // MatrixForm

范围  (10)

计算图像间的距离矩阵：

Wolfram Language code: DistanceMatrix[{[image], [image], [image]}] // MatrixForm

计算字符串间的距离矩阵：

Wolfram Language code: DistanceMatrix[{"abcd", "bcde", "xyz"}] // MatrixForm

计算布尔向量间的距离矩阵：

Wolfram Language code: DistanceMatrix[{{True, False, True}, {True, True, True}, {True, False, False}}] // MatrixForm

计算一列日期对象的距离矩阵：

Wolfram Language code: DistanceMatrix[{DateObject[{1985, 10, 3}], DateObject[{1989, 5, 30}], DateObject[]}] // MatrixForm

计算测地位置间的距离矩阵：

Wolfram Language code: DistanceMatrix[{GeoPosition[Entity["City", {"Paris", "IleDeFrance", "France"}]], GeoPosition[Entity["City", {"Sydney", "NewSouthWales", "Australia"}]], GeoPosition[Entity["City", {"Boston", "Massachusetts", "UnitedStates"}]], GeoPosition[Entity["City", {"SanFrancisco", "California", "UnitedStates"}]]}] // MatrixForm

计算标称序列的距离矩阵：

Wolfram Language code: DistanceMatrix[{{"a", "b", "c", "d"}, {"b", "c", "d", "e"}, {"x", "y", "z"}}] // MatrixForm

计算数值序列的距离矩阵：

Wolfram Language code: DistanceMatrix[{{1.1, 1.2, 1.3, 1.4, 1.5}, {1.2, 1.3}, {1.4, 1.5, 1.6}}] // MatrixForm

计算标称向量的距离矩阵：

Wolfram Language code: DistanceMatrix[{{"A", "Sugar"}, {"A", "Salt"}, {"B", "Sugar"}, {"B", "Salt"}}]//MatrixForm

计算混合型向量的距离矩阵：

Wolfram Language code: DistanceMatrix[{{1.2, "A"}, {3.1, "A"}, {1.1, "B"}, {3.3, "B"}}] // MatrixForm

计算格式化为关联列表的数据集的距离矩阵：

Wolfram Language code: data = {<|"age" -> 32, "height" -> 160, "gender" -> "female"|>, <|"height" -> 183, "age" -> 41, "gender" -> "female"|>, <|"height" -> 123, "age" -> 30, "gender" -> "female"|>, <|"height" -> 175, "age" -> 21, "gender" -> "male"|>, <|"height" -> 150, "age" -> 11, "gender" -> "male"|>, <|"age" -> 52, "height" -> 164, "gender" -> "female"|>};
Wolfram Language code: DistanceMatrix[data]//MatrixForm

用按列排列的数据集计算同一个距离矩阵：

Wolfram Language code: DistanceMatrix[<|"age" -> {32, 41, 30, 21, 11, 52}, "height" -> {160, 183, 123, 175, 150, 164}, "gender" -> {"female", "female", "female", "male", "male", "female"}|>]//MatrixForm

还可以用 Dataset 对象给出数据：

Wolfram Language code: dataset = Dataset[data]
Wolfram Language code: DistanceMatrix[dataset]//MatrixForm

选项  (9)

DistanceFunction  (3)

用 SquaredEuclideanDistance 作为距离函数计算整数向量间的距离矩阵：

Wolfram Language code: DistanceMatrix[{{1, 5}, {2, 3}, {3, 1}, {4, 7}}, DistanceFunction -> SquaredEuclideanDistance] // MatrixForm

用 ManhattanDistance 计算距离矩阵：

Wolfram Language code: DistanceMatrix[{{1.3, 5.2}, {1.2, 7.3}, {3.6, 1.1}, {4.6, 7.4}}, DistanceFunction -> ManhattanDistance] // MatrixForm

使用一个不同于默认距离的颜色距离：

Wolfram Language code: DistanceMatrix[{RGBColor[0.8153963685313876, 0.8780324414500478, 0.8878969785400366], RGBColor[0.7000498357974252, 0.12659377056191357, 0.2441846342253282], RGBColor[0.22075683601648843, 0.11406627268342273, 0.5155520370226843], RGBColor[0.7106648135050211, 0.42410292720247544, 0.14462936430464635], RGBColor[0.46490866303974765, 0.16254211516915973, 0.6466382153254229]}, DistanceFunction -> "CIE2000"]

FeatureExtractor  (1)

计算用特征提取方法 "NumericVector" 预处理过的图像的距离矩阵：

Wolfram Language code: DistanceMatrix[{[image], [image], [image], [image], [image], [image]}, FeatureExtractor -> "NumericVector"] // MatrixPlot

FeatureNames  (1)

用 FeatureNames 命名特征，在以后的规范中用该名称来指代：

Wolfram Language code: DistanceMatrix[{{2.3, "male"}, {4.8, Missing[]}, {Missing[], "female"}, {5.2, "female"}}, FeatureNames -> {"gender", "age"}, FeatureTypes -> <|"gender" -> "Numerical", "age" -> "Nominal"|>]

FeatureTypes  (1)

用 FeatureTypes 把第一个特征强制解释为标称特征：

Wolfram Language code: DistanceMatrix[{{1, "A"}, {2, "A"}, {2, "B"}, {1, "B"}}, FeatureTypes -> <|1 -> "Nominal"|>]// MatrixForm

PerformanceGoal  (1)

生成 500 个长度为 1000 的随机数值向量：

Wolfram Language code: vectors = RandomReal[{10, 11}, {2000, 1000}];

计算它们的距离矩阵并将运算作为比较的基准：

Wolfram Language code: AbsoluteTiming[result = DistanceMatrix[vectors];]

将 PerformanceGoal 设为 "Speed"，进行同样的计算：

Wolfram Language code: AbsoluteTiming[resultspeed = DistanceMatrix[vectors, PerformanceGoal -> "Speed"];]

将之前结果的用时和准确度与参考值进行比较：

Wolfram Language code: AbsoluteTiming[reference = Outer[EuclideanDistance, vectors, vectors, 1];]
Wolfram Language code: StandardDeviation[Flatten[result - reference]]
Wolfram Language code: StandardDeviation[Flatten[resultspeed - reference]]

当 PerformanceGoal"Speed" 时，将数据中心化会提高精度：

Wolfram Language code: mean = Mean[vectors]; centered = # - mean & /@ vectors;
Wolfram Language code: AbsoluteTiming[resultspeedcentered = DistanceMatrix[centered, PerformanceGoal -> "Speed"];]
Wolfram Language code: StandardDeviation[Flatten[resultspeedcentered - reference]]

RandomSeeding  (1)

多次对 DistanceMatrix 进行计算给出同样的结果，即便是用到了随机数字.

生成一对 20-维的向量：

Wolfram Language code: data = RandomReal[1, {2, 20}];

使用涉及随机性的特征提取器多次计算其距离矩阵：

Wolfram Language code: table = Table[DistanceMatrix[data, FeatureExtractor -> (RandomChoice[#, 10]&)], 5];

比较结果：

Wolfram Language code: Counts[table]

对 RandomSeeding 选项给出不同的值，计算距离矩阵：

Wolfram Language code: randomtable = Table[DistanceMatrix[data, FeatureExtractor -> (RandomChoice[#, 10]&), RandomSeeding -> RandomInteger[10]], 5];

比较结果：

Wolfram Language code: Counts[randomtable]

WorkingPrecision  (1)

计算500个长度为100、精度为30位的随机数值向量的距离矩阵：

Wolfram Language code: r = RandomReal[1, {500, 100}, WorkingPrecision -> 30];
Wolfram Language code: AbsoluteTiming[dm = DistanceMatrix[r];]

DistanceMatrix 使用任意精度的计算：

Wolfram Language code: Precision[dm]

设置 WorkingPrecisionMachinePrecision 可以加快计算速度：

Wolfram Language code: AbsoluteTiming[dmmachine = DistanceMatrix[r, WorkingPrecision -> MachinePrecision];]

但结果的精确度下降：

Wolfram Language code: Precision[dmmachine]

当向量彼此比较相似时，改变 WorkingPrecision 的值会得到相差甚远的不同结果.

Wolfram Language code: r = RandomReal[{10 ^ 20, 10 ^ 20 + 1}, {3, 2}, WorkingPrecision -> 30]
Wolfram Language code: DistanceMatrix[r] // MatrixForm
Wolfram Language code: DistanceMatrix[r, WorkingPrecision -> MachinePrecision] // MatrixForm

应用  (1)

计算两组数据点之间的最小距离：

Wolfram Language code: p1 = RandomPoint[Sphere[], 20]; p2 = RandomPoint[Sphere[{3, 2, 5}], 20]; ListPointPlot3D[{p1, p2}, AspectRatio -> 1]
Wolfram Language code: Min[DistanceMatrix[p1, p2]]
Wolfram Research (2015)，DistanceMatrix，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DistanceMatrix.html （更新于 2017 年）.

文本

Wolfram Research (2015)，DistanceMatrix，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DistanceMatrix.html （更新于 2017 年）.

CMS

Wolfram 语言. 2015. "DistanceMatrix." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2017. https://reference.wolfram.com/language/ref/DistanceMatrix.html.

APA

Wolfram 语言. (2015). DistanceMatrix. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DistanceMatrix.html 年

BibTeX

@misc{reference.wolfram_2026_distancematrix, author="Wolfram Research", title="{DistanceMatrix}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/DistanceMatrix.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_distancematrix, organization={Wolfram Research}, title={DistanceMatrix}, year={2017}, url={https://reference.wolfram.com/language/ref/DistanceMatrix.html}, note=[Accessed: 04-September-2026]}