WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ExpIntegralE[n,z]

指数積分関数 TemplateBox[{n, z}, ExpIntegralE]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開：  
積分変換  
関数の恒等式と簡約  
関数表現  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ExpIntegralE

ExpIntegralE[n,z]

指数積分関数 TemplateBox[{n, z}, ExpIntegralE]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 積分が収束するところで TemplateBox[{n, z}, ExpIntegralE]=int_1^inftye^(-z t)/t^ndt．
  • ExpIntegralE[n,z]は，複素 z 平面上，〜0の範囲で不連続な分枝切断線を持つ．
  • 特別な引数の場合，ExpIntegralEは，自動的に厳密値を計算する．
  • ExpIntegralE は任意の数値精度で評価できる．
  • ExpIntegralE は，自動的にリストに縫い込まれる．
  • ExpIntegralEはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (5)

数値的に評価する：

Wolfram Language code: ExpIntegralE[3, 5.5]

実数の部分集合上でパラメータ の整数値についてプロットする：

Wolfram Language code: Plot[Table[ExpIntegralE[n, x], {n, 6}]//Evaluate, {x, 0, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ExpIntegralE[2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における一般的および対数的な場合の級数：

Wolfram Language code: Series[ExpIntegralE[n, x], {x, 0, 4}]
Wolfram Language code: Series[ExpIntegralE[1, x], {x, 0, 4}]

Infinityにおける級数展開：

Wolfram Language code: Series[ExpIntegralE[n, x], {x, ∞, 4}]//Normal

スコープ  (42)

数値評価  (5)

高精度で数値的に評価する：

Wolfram Language code: N[ExpIntegralE[3, 22 / 10], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: ExpIntegralE[3, 2.20000000000000000000000]

複素引数：

Wolfram Language code: N[ExpIntegralE[1 + I, 2 + 3I]]

ExpIntegralEを高精度で効率よく評価する：

Wolfram Language code: ExpIntegralE[3, 2.2`500]//Timing
Wolfram Language code: ExpIntegralE[3, 2.2`10000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ExpIntegralE[2, Interval[{0.1, 0.2}]]
Wolfram Language code: ExpIntegralE[2, CenteredInterval[1, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ExpIntegralE[2, Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: ExpIntegralE[2, {{I π, I π / 2}, {0, -I }}]//FunctionExpand

MatrixFunctionを使って行列のExpIntegralE関数を計算することもできる：

Wolfram Language code: MatrixFunction[ExpIntegralE[2, #]&, {{I π, I π / 2}, {0, I}}]//FunctionExpand

特定の値  (3)

固定点における値：

Wolfram Language code: Table[ExpIntegralE[n, 0], {n, 1, 5}]
Wolfram Language code: ExpIntegralE[0, z]

無限大における極限値：

Wolfram Language code: Limit[ExpIntegralE[n, x], x -> Infinity]

方程式 TemplateBox[{0, x}, ExpIntegralE]=0.5の実根を求める：

Wolfram Language code: f[x_] := ExpIntegralE[0, x] - 0.5;
Wolfram Language code: xzero = Solve[f[x] == 0 && 0 < x < 2, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[f[x], {x, 0, 6}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化  (3)

ExpIntegralE関数をプロットする：

Wolfram Language code: Plot[{ExpIntegralE[-2, x], ExpIntegralE[-3 / 2, x], ExpIntegralE[-1, x], ExpIntegralE[-1 / 2, x], ExpIntegralE[0, x], ExpIntegralE[1 / 2, x], ExpIntegralE[1, x], ExpIntegralE[3 / 2, x], ExpIntegralE[2, x]}, {x, -2, 2}]

TemplateBox[{1, z}, ExpIntegralE]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ExpIntegralE[1, z]], {z, -4 - 5I, 4 + 5 I}, Contours -> 20]

TemplateBox[{1, z}, ExpIntegralE]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ExpIntegralE[1, z]], {z, -4 - 5I, 4 + 5 I}, Contours -> 20]

TemplateBox[{{-, {7, /, 2}}, z}, ExpIntegralE]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ExpIntegralE[-7 / 2, z]], {z, -4 - 5I, 4 + 5 I}, IconizedObject[«PlotOptions»]]

TemplateBox[{{-, {7, /, 2}}, z}, ExpIntegralE]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ExpIntegralE[-7 / 2, z]], {z, -4 - 5I, 4 + 5 I}, IconizedObject[«PlotOptions»]]

関数の特性  (9)

ExpIntegralEの実領域：

Wolfram Language code: FunctionDomain[ExpIntegralE[n, x], x]

ExpIntegralEの複素領域：

Wolfram Language code: FunctionDomain[ExpIntegralE[n, z], z, Complexes]

TemplateBox[{n, x}, ExpIntegralE]は のときすべての実数値に達する：

Wolfram Language code: Table[Reduce[FunctionRange[ExpIntegralE[n, x], x, y], y, Reals], {n, 4}]

の小さい値についてのExpIntegralEの値域は，より制限されていることもいないこともある：

Wolfram Language code: FunctionRange[ExpIntegralE[0, x], x, y]
Wolfram Language code: FunctionRange[ExpIntegralE[-3, x], x, y]

ExpIntegralEは鏡特性 TemplateBox[{0, TemplateBox[{z}, Conjugate, SyntaxForm -> SuperscriptBox]}, ExpIntegralE]=TemplateBox[{TemplateBox[{0, z}, ExpIntegralE]}, Conjugate]を持つ：

Wolfram Language code: FullSimplify[ExpIntegralE[0, Conjugate[z]] == Conjugate[ExpIntegralE[0, z]]]

ExpIntegralEは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ExpIntegralE[n, x], {n, x}]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ExpIntegralE[n, x], x]//Reduce

TemplateBox[{n, x}, ExpIntegralE]は のときは常に非増加である：

Wolfram Language code: FunctionMonotonicity[{ExpIntegralE[n, x], x > 0}, x, Assumptions -> n > 0]

のとき TemplateBox[{n, x}, ExpIntegralE]は単射である：

Wolfram Language code: FunctionInjective[ExpIntegralE[n, x], x, Assumptions -> n ≥ 2]

のより小さい値については，単射であることもそうではないこともある：

Wolfram Language code: FunctionInjective[ExpIntegralE[1 / 2, x], x]
Wolfram Language code: FunctionInjective[ExpIntegralE[-1, x], x]

3つの例を可視化する：

Wolfram Language code: Plot[{ExpIntegralE[2, x], ExpIntegralE[1 / 2, x], ExpIntegralE[-1, x], 1 / 2}, {x, -2, 2}]

のとき TemplateBox[{n, x}, ExpIntegralE]は正である：

Wolfram Language code: FunctionSign[{ExpIntegralE[n, x], x > 0}, x, Assumptions -> n∈Reals, StrictInequalities -> True]

ExpIntegralEは x≤0のとき特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ExpIntegralE[2, x], x]
Wolfram Language code: FunctionDiscontinuities[ExpIntegralE[2, x], x]

TemplateBox[{n, x}, ExpIntegralE]は のとき凸である：

Wolfram Language code: FunctionConvexity[{ExpIntegralE[n, x], x > 0}, x, Assumptions -> n∈Reals]

微分  (3)

一次導関数：

Wolfram Language code: D[ExpIntegralE[n, x], x]

高次導関数：

Wolfram Language code: derivs = Table[D[ExpIntegralE[n, x], {x, k}], {k, 1, 4}]

について高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[derivs /. n -> 0], {x, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

について高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[derivs /. n -> 3], {x, -5, 5}]

次導関数の式：

Wolfram Language code: D[ExpIntegralE[n, x], {x, k}]

積分  (3)

ExpIntegralEの不定積分：

Wolfram Language code: Integrate[ExpIntegralE[n, x], x]

ExpIntegralEの定積分：

Wolfram Language code: Integrate[ExpIntegralE[n, x], {x, 0, Infinity}]

その他の積分例：

Wolfram Language code: Integrate[x ExpIntegralE[n, x], x]
Wolfram Language code: Integrate[ExpIntegralE[n, x]ExpIntegralE[n + 1, x], x]

級数展開：  (4)

ExpIntegralEの級数展開：

Wolfram Language code: Series[ExpIntegralE[n, x], {x, 0, 7}]

周りの TemplateBox[{1, x}, ExpIntegralE]の最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ExpIntegralE[1, x], {x, 0, m}], {m, 0, 2}]; Plot[{ExpIntegralE[1, x], terms}, {x, 0, 2}]

TemplateBox[{0, x}, ExpIntegralE]の級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ExpIntegralE[0, x], {x, 0, n}]

無限大における級数展開：

Wolfram Language code: Series[ExpIntegralE[n, z], {z, Infinity, 5}]//Normal

任意の記号方向についての結果を与える：

Wolfram Language code: Series[ExpIntegralE[n, z], {z, DirectedInfinity[w], 2}]//Normal

ExpIntegralEはベキ級数に適用できる：

Wolfram Language code: ExpIntegralE[2, 1 + x + (x^2/2) + O[x]^4]

積分変換  (3)

FourierSinTransformを使って TemplateBox[{0, t}, ExpIntegralE]についてのフーリエ(Fourier)正弦変換を計算する：

Wolfram Language code: FourierSinTransform[ExpIntegralE[0, t], t, ω]

TemplateBox[{1, t}, ExpIntegralE]についてのLaplaceTransform：

Wolfram Language code: LaplaceTransform[ExpIntegralE[1, t], t, s]

MellinTransform：

Wolfram Language code: MellinTransform[ExpIntegralE[n, x], x, s ]

関数の恒等式と簡約  (4)

FullSimplifyを使って指数積分を簡約する：

Wolfram Language code: FullSimplify[ExpIntegralE[3, z] + z / 2ExpIntegralE[2, z]]

FunctionExpandを使って特殊ケースをより簡単な関数で表す：

Wolfram Language code: FunctionExpand[{ExpIntegralE[5 / 2, z], ExpIntegralE[4, z], ExpIntegralE[-4, z]}]//Simplify

再帰関係：

Wolfram Language code: ExpIntegralE[n, z] == (1/n - 1)(E^-z - z ExpIntegralE[n - 1, z])//FullSimplify

のとき TemplateBox[{1, x}, ExpIntegralE]=-TemplateBox[{{-, x}}, ExpIntegralEi]：

Wolfram Language code: FullSimplify[ExpIntegralE[1, x] == -ExpIntegralEi[-x], x > 0]

関数表現  (5)

指数積分関数の主定義：

Wolfram Language code: Integrate[Exp[-z t]t ^ -n, {t, 1, Infinity}, Assumptions -> z > 0 && n < 1]

不完全ガンマ関数Gammaとの関係：

Wolfram Language code: ExpIntegralE[n, z]//FunctionExpand

ExpIntegralEはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[ExpIntegralE[n, x], x]
Wolfram Language code: Activate[%]//FullSimplify

ExpIntegralEはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ExpIntegralE[n, x], x]

TraditionalFormによる表示：

Wolfram Language code: ExpIntegralE[n, z]//TraditionalForm

一般化と拡張  (2)

無限引数は厳密な結果を与える：

Wolfram Language code: ExpIntegralE[0, Infinity]

ExpIntegralEは要素単位でリストや配列に縫い込まれる：

Wolfram Language code: ExpIntegralE[0, {2., 3., 5., 7., 11.}]

アプリケーション  (5)

複素平面上でプロットする：

Wolfram Language code: Plot3D[Im[ExpIntegralE[-3, x + I y]], {x, -1, 1}, {y, -1, 1}]

区分定数の初期条件での熱伝導方程式の解：

Wolfram Language code: T[x_, t_] := (1/4Sqrt[π]Sqrt[α t])T0((x - x1)ExpIntegralE[(1/2), ((x - x1)^2/4α t)] + (-x + x2)ExpIntegralE[(1/2), ((x - x2)^2/4α t)])

解が熱伝導方程式を満足するかどうか確かめる：

Wolfram Language code: D[T[x, t], t] == α D[T[x, t], x, x]//FullSimplify

異なる時間で解をプロットする：

Wolfram Language code: Plot[Evaluate[{T[x, 10 ^ -3], T[x, 0.5], T[x, 1], T[x, 2]} /. {x1 -> -1, x2 -> 1, T0 -> 1, α -> 1}], {x, -4, 4}]//Quiet

階乗係数を持つ古典的な漸近級数を計算する：

Wolfram Language code: Series[Exp[1 / z]ExpIntegralE[1, 1 / z], {z, 0, 12}, Assumptions -> z > 0]

打ち切られた級数と指数積分和の差分をプロットする：

Wolfram Language code: δ[z_, o_] := -Sum[(-1) ^ n(n - 1)!(z) ^ n, {n, 1, o}] + Exp[1 / z]ExpIntegralEi[-1 / z]
Wolfram Language code: Plot[Evaluate[Table[Log[Abs[δ[z, o]]], {o, 6}]], {z, 0.1, 2}]

水文学および電子構造計算で生じる「漏出滞水層」関数（Hantush–Jacob関数または不完全ベッセル(Bessel)関数としても知られている）をExpIntegralEで級数展開を使って近似する：

Wolfram Language code: LeakyAquiferApprox[u_, ϵ_, n_Integer : 10] := ExpIntegralE[1, u] + Sum[(-ϵ / u) ^ k / k! ExpIntegralE[k + 1, u], {k, 1, n}]

定義積分の求積法と比較する：

Wolfram Language code: LeakyAquiferQuadrature[u_, ϵ_] := NIntegrate[Exp[- - ϵ / ] / , {, u, Infinity}]
Wolfram Language code: {LeakyAquiferApprox[0.001, 0.001], LeakyAquiferQuadrature[0.001, 0.001]}
Wolfram Language code: Plot[{LeakyAquiferApprox[u, 0.001], LeakyAquiferApprox[u, 0.5, 20], LeakyAquiferApprox[u, 1, 100]}, {u, 0.1, 2}]

時間 に支払われる1ドルの死亡保険金の期待時間価値を計算する．ここで， はGompertz–Makeham分布から取られる：

Wolfram Language code: tv = TimeValue[Cashflow[{{t, 1}}], EffectiveInterest[r, 0], 0]
Wolfram Language code: nsp = Expectation[tv, tGompertzMakehamDistribution[a, b]]

通常は保険年度の初めに支払われる年間保険料を求めるが，これは 期間 ( はGompertz–Makeham分布から取られる) の支払ストリームの期待時間価値を正味単一保険料と等しくするために必要である：

Wolfram Language code: nap = TimeValue[AnnuityDue[premium, t], EffectiveInterest[r, 0], 0]
Wolfram Language code: etv = Expectation[nap, tGompertzMakehamDistribution[a, b]]

結果の正味変換保険料：

Wolfram Language code: Solve[etv == nsp, premium]//FullSimplify

特性と関係  (8)

FullSimplifyを使って指数積分を簡約する：

Wolfram Language code: FullSimplify[ExpIntegralE[3, z] + z / 2ExpIntegralE[2, z]]

FunctionExpandを使って，より簡単な関数の特殊形を表す：

Wolfram Language code: FunctionExpand[{ExpIntegralE[5 / 2, z], ExpIntegralE[4, z], ExpIntegralE[-4, z]}]//Simplify

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[ExpIntegralE[1, z] - 2ExpIntegralE[2, z + 2] + z == 2, {z, 1}]

積分，和，微分方程式から生成する：

Wolfram Language code: Integrate[Exp[-z t]t ^ -n, {t, 1, Infinity}, Assumptions -> z > 0 && n < 1]
Wolfram Language code: FullSimplify[n!z ^ (-n - 1)Exp[-z]Sum[z ^ k / k!, {k, 0, n}]]
Wolfram Language code: DSolve[x y''[x] + (ν + 1 - x)y'[x] == 0, y[x], x]//FullSimplify

ExpIntegralEは，超幾何関数およびマイヤー(Meijer)のG関数の特殊形の様に見える：

Wolfram Language code: {Hypergeometric1F1[1 - ν, 2 - ν, -z], MeijerG[{{ν}, {}}, {{0}, {ν - 1}}, z]}//FunctionExpand//FullSimplify

積分：

Wolfram Language code: Integrate[ExpIntegralE[ν, z], z]

ExpIntegralEは数値関数である：

Wolfram Language code: Attributes[ExpIntegralE]
Wolfram Language code: NumericQ[ExpIntegralE[2, 2 + E]]

ExpIntegralEはDifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[DifferenceRootReduce[ExpIntegralE[k, z], k], k]

考えられる問題  (3)

引数が大きいと，解が大きすぎて明示的に計算できないことがある：

Wolfram Language code: ExpIntegralE[2, -10. ^ 16]

機械数による入力だと，高精度の結果が得られることがある：

Wolfram Language code: ExpIntegralE[2, -10. ^ 3]
Wolfram Language code: MachineNumberQ[%]

TraditionalFormでは，E_n(z)は，自動的には指数積分だとは解釈されない：

Wolfram Language code: Subscript[E, n](z)

おもしろい例題  (1)

のリーマン(Riemann)面をプロットする：

Wolfram Language code: With[{p = 1 / 2, ε = 10 ^ -8}, ParametricPlot3D[Table[{r Cos[ϕ], r Sin[ϕ], Re[ExpIntegralE[p, r Exp[I ϕ]] + 2π I((r Exp[I ϕ])^p - 1/Gamma[p])Exp[k p π I]ChebyshevU[k - 1, Cos[p π]]]}, {k, 0, 1}], {r, ε, 2}, {ϕ, -π, π}, PlotRange -> {All, All, {-5, 3}}]]
Wolfram Research (1988), ExpIntegralE, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExpIntegralE.html （2022年に更新）.

テキスト

Wolfram Research (1988), ExpIntegralE, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExpIntegralE.html （2022年に更新）.

CMS

Wolfram Language. 1988. "ExpIntegralE." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/ExpIntegralE.html.

APA

Wolfram Language. (1988). ExpIntegralE. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ExpIntegralE.html

BibTeX

@misc{reference.wolfram_2026_expintegrale, author="Wolfram Research", title="{ExpIntegralE}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ExpIntegralE.html}", note=[Accessed: 19-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_expintegrale, organization={Wolfram Research}, title={ExpIntegralE}, year={2022}, url={https://reference.wolfram.com/language/ref/ExpIntegralE.html}, note=[Accessed: 19-July-2026]}