WOLFRAM

Wolfram 语言与系统参考资料中心

ExpIntegralE[n,z]

给出指数积分函数 TemplateBox[{n, z}, ExpIntegralE].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
积分变换  
函数恒等式和化简  
函数表示  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ExpIntegralE

ExpIntegralE[n,z]

给出指数积分函数 TemplateBox[{n, z}, ExpIntegralE].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值计算：

Wolfram Language code: ExpIntegralE[3, 5.5]

在实数子集绘制参数 为整数的函数：

Wolfram Language code: Plot[Table[ExpIntegralE[n, x], {n, 6}]//Evaluate, {x, 0, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ExpIntegralE[2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

一般情形和对数情况下在原点处的级数：

Wolfram Language code: Series[ExpIntegralE[n, x], {x, 0, 4}]
Wolfram Language code: Series[ExpIntegralE[1, x], {x, 0, 4}]

在 Infinity 的级数展开：

Wolfram Language code: Series[ExpIntegralE[n, x], {x, ∞, 4}]//Normal

范围  (42)

数值计算  (5)

高精度数值计算：

Wolfram Language code: N[ExpIntegralE[3, 22 / 10], 50]

输出精度与输入精度相一致：

Wolfram Language code: ExpIntegralE[3, 2.20000000000000000000000]

计算复数参数：

Wolfram Language code: N[ExpIntegralE[1 + I, 2 + 3I]]

在高精度条件下高效计算 ExpIntegralE：

Wolfram Language code: ExpIntegralE[3, 2.2`500]//Timing
Wolfram Language code: ExpIntegralE[3, 2.2`10000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ExpIntegralE[2, Interval[{0.1, 0.2}]]
Wolfram Language code: ExpIntegralE[2, CenteredInterval[1, 1 / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: ExpIntegralE[2, Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: ExpIntegralE[2, {{I π, I π / 2}, {0, -I }}]//FunctionExpand

或用 MatrixFunction 计算矩阵形式的 ExpIntegralE 函数：

Wolfram Language code: MatrixFunction[ExpIntegralE[2, #]&, {{I π, I π / 2}, {0, I}}]//FunctionExpand

特殊值  (3)

固定点上的值：

Wolfram Language code: Table[ExpIntegralE[n, 0], {n, 1, 5}]
Wolfram Language code: ExpIntegralE[0, z]

无穷处的极限：

Wolfram Language code: Limit[ExpIntegralE[n, x], x -> Infinity]

求方程 TemplateBox[{0, x}, ExpIntegralE]=0.5 的实根：

Wolfram Language code: f[x_] := ExpIntegralE[0, x] - 0.5;
Wolfram Language code: xzero = Solve[f[x] == 0 && 0 < x < 2, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[f[x], {x, 0, 6}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制 ExpIntegralE 函数：

Wolfram Language code: Plot[{ExpIntegralE[-2, x], ExpIntegralE[-3 / 2, x], ExpIntegralE[-1, x], ExpIntegralE[-1 / 2, x], ExpIntegralE[0, x], ExpIntegralE[1 / 2, x], ExpIntegralE[1, x], ExpIntegralE[3 / 2, x], ExpIntegralE[2, x]}, {x, -2, 2}]

绘制 TemplateBox[{1, z}, ExpIntegralE] 的实部：

Wolfram Language code: ComplexContourPlot[Re[ExpIntegralE[1, z]], {z, -4 - 5I, 4 + 5 I}, Contours -> 20]

绘制 TemplateBox[{1, z}, ExpIntegralE] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ExpIntegralE[1, z]], {z, -4 - 5I, 4 + 5 I}, Contours -> 20]

绘制 TemplateBox[{{-, {7, /, 2}}, {x, +, {ⅈ, , y}}}, ExpIntegralE] 的实部：

Wolfram Language code: ComplexContourPlot[Re[ExpIntegralE[-7 / 2, z]], {z, -4 - 5I, 4 + 5 I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{{-, {7, /, 2}}, {x, +, {ⅈ, , y}}}, ExpIntegralE] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ExpIntegralE[-7 / 2, z]], {z, -4 - 5I, 4 + 5 I}, IconizedObject[«PlotOptions»]]

函数属性  (9)

ExpIntegralE 的实定义域：

Wolfram Language code: FunctionDomain[ExpIntegralE[n, x], x]

ExpIntegralE 的复定义域：

Wolfram Language code: FunctionDomain[ExpIntegralE[n, z], z, Complexes]

时，TemplateBox[{n, x}, ExpIntegralE] 的值域是所有实数：

Wolfram Language code: Table[Reduce[FunctionRange[ExpIntegralE[n, x], x, y], y, Reals], {n, 4}]

取较小值时，ExpIntegralE 的值域可能会也可能不会更有限：

Wolfram Language code: FunctionRange[ExpIntegralE[0, x], x, y]
Wolfram Language code: FunctionRange[ExpIntegralE[-3, x], x, y]

ExpIntegralE 具有镜像属性 TemplateBox[{0, TemplateBox[{z}, Conjugate, SyntaxForm -> SuperscriptBox]}, ExpIntegralE]=TemplateBox[{TemplateBox[{0, z}, ExpIntegralE]}, Conjugate]：

Wolfram Language code: FullSimplify[ExpIntegralE[0, Conjugate[z]] == Conjugate[ExpIntegralE[0, z]]]

ExpIntegralE 不是解析函数：

Wolfram Language code: FunctionAnalytic[ExpIntegralE[n, x], {n, x}]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ExpIntegralE[n, x], x]//Reduce

时，TemplateBox[{n, x}, ExpIntegralE] 总是非递增：

Wolfram Language code: FunctionMonotonicity[{ExpIntegralE[n, x], x > 0}, x, Assumptions -> n > 0]

时，TemplateBox[{n, x}, ExpIntegralE] 是单射函数：

Wolfram Language code: FunctionInjective[ExpIntegralE[n, x], x, Assumptions -> n ≥ 2]

取较小值时，可能是也可能不是单射函数：

Wolfram Language code: FunctionInjective[ExpIntegralE[1 / 2, x], x]
Wolfram Language code: FunctionInjective[ExpIntegralE[-1, x], x]

可视化三个例子：

Wolfram Language code: Plot[{ExpIntegralE[2, x], ExpIntegralE[1 / 2, x], ExpIntegralE[-1, x], 1 / 2}, {x, -2, 2}]

时，TemplateBox[{n, x}, ExpIntegralE] 为正：

Wolfram Language code: FunctionSign[{ExpIntegralE[n, x], x > 0}, x, Assumptions -> n∈Reals, StrictInequalities -> True]

x≤0 时，ExpIntegralE 有奇点和断点：

Wolfram Language code: FunctionSingularities[ExpIntegralE[2, x], x]
Wolfram Language code: FunctionDiscontinuities[ExpIntegralE[2, x], x]

时，TemplateBox[{n, x}, ExpIntegralE] 是凸函数：

Wolfram Language code: FunctionConvexity[{ExpIntegralE[n, x], x > 0}, x, Assumptions -> n∈Reals]

微分  (3)

一阶导数：

Wolfram Language code: D[ExpIntegralE[n, x], x]

高阶导数：

Wolfram Language code: derivs = Table[D[ExpIntegralE[n, x], {x, k}], {k, 1, 4}]

绘制 时的高阶导数：

Wolfram Language code: Plot[Evaluate[derivs /. n -> 0], {x, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

绘制 时的高阶导数：

Wolfram Language code: Plot[Evaluate[derivs /. n -> 3], {x, -5, 5}]

阶导数的公式：

Wolfram Language code: D[ExpIntegralE[n, x], {x, k}]

积分  (3)

ExpIntegralE 的不定积分：

Wolfram Language code: Integrate[ExpIntegralE[n, x], x]

ExpIntegralE 的定积分：

Wolfram Language code: Integrate[ExpIntegralE[n, x], {x, 0, Infinity}]

更多积分：

Wolfram Language code: Integrate[x ExpIntegralE[n, x], x]
Wolfram Language code: Integrate[ExpIntegralE[n, x]ExpIntegralE[n + 1, x], x]

级数展开式  (4)

ExpIntegralE 的级数展开式：

Wolfram Language code: Series[ExpIntegralE[n, x], {x, 0, 7}]

绘制 TemplateBox[{1, x}, ExpIntegralE] 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[ExpIntegralE[1, x], {x, 0, m}], {m, 0, 2}]; Plot[{ExpIntegralE[1, x], terms}, {x, 0, 2}]

TemplateBox[{0, x}, ExpIntegralE] 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[ExpIntegralE[0, x], {x, 0, n}]

在无穷处的级数展开式：

Wolfram Language code: Series[ExpIntegralE[n, z], {z, Infinity, 5}]//Normal

给出在任意符号方向上的结果：

Wolfram Language code: Series[ExpIntegralE[n, z], {z, DirectedInfinity[w], 2}]//Normal

ExpIntegralE 可用于幂级数：

Wolfram Language code: ExpIntegralE[2, 1 + x + (x^2/2) + O[x]^4]

积分变换  (3)

用 FourierSinTransform 计算 TemplateBox[{0, t}, ExpIntegralE] 的傅立叶正弦变换：

Wolfram Language code: FourierSinTransform[ExpIntegralE[0, t], t, ω]

TemplateBox[{1, t}, ExpIntegralE] 的LaplaceTransform：

Wolfram Language code: LaplaceTransform[ExpIntegralE[1, t], t, s]

MellinTransform：

Wolfram Language code: MellinTransform[ExpIntegralE[n, x], x, s ]

函数恒等式和化简  (4)

用 FullSimplify 化简指数积分：

Wolfram Language code: FullSimplify[ExpIntegralE[3, z] + z / 2ExpIntegralE[2, z]]

通过 FunctionExpand 用更简单的函数来表示特例：

Wolfram Language code: FunctionExpand[{ExpIntegralE[5 / 2, z], ExpIntegralE[4, z], ExpIntegralE[-4, z]}]//Simplify

递归关系式：

Wolfram Language code: ExpIntegralE[n, z] == (1/n - 1)(E^-z - z ExpIntegralE[n - 1, z])//FullSimplify

时，TemplateBox[{1, x}, ExpIntegralE]=-TemplateBox[{{-, x}}, ExpIntegralEi]：

Wolfram Language code: FullSimplify[ExpIntegralE[1, x] == -ExpIntegralEi[-x], x > 0]

函数表示  (5)

指数积分函数的主定义：

Wolfram Language code: Integrate[Exp[-z t]t ^ -n, {t, 1, Infinity}, Assumptions -> z > 0 && n < 1]

与不完全伽玛函数 Gamma 的关系：

Wolfram Language code: ExpIntegralE[n, z]//FunctionExpand

ExpIntegralE 可以被表示为 MeijerG 的形式：

Wolfram Language code: MeijerGReduce[ExpIntegralE[n, x], x]
Wolfram Language code: Activate[%]//FullSimplify

ExpIntegralE 可以被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[ExpIntegralE[n, x], x]

TraditionalForm 格式：

Wolfram Language code: ExpIntegralE[n, z]//TraditionalForm

推广和延伸  (2)

无穷参数给出精确的结果：

Wolfram Language code: ExpIntegralE[0, Infinity]

ExpIntegralE 按元素线性作用于列表和数组：

Wolfram Language code: ExpIntegralE[0, {2., 3., 5., 7., 11.}]

应用  (5)

在复平面上绘制图形：

Wolfram Language code: Plot3D[Im[ExpIntegralE[-3, x + I y]], {x, -1, 1}, {y, -1, 1}]

求解分段初始条件的热方程：

Wolfram Language code: T[x_, t_] := (1/4Sqrt[π]Sqrt[α t])T0((x - x1)ExpIntegralE[(1/2), ((x - x1)^2/4α t)] + (-x + x2)ExpIntegralE[(1/2), ((x - x2)^2/4α t)])

检查结果是否满足热方程：

Wolfram Language code: D[T[x, t], t] == α D[T[x, t], x, x]//FullSimplify

绘制不同时刻的解：

Wolfram Language code: Plot[Evaluate[{T[x, 10 ^ -3], T[x, 0.5], T[x, 1], T[x, 2]} /. {x1 -> -1, x2 -> 1, T0 -> 1, α -> 1}], {x, -4, 4}]//Quiet

计算带有阶乘系数的经典渐近级数：

Wolfram Language code: Series[Exp[1 / z]ExpIntegralE[1, 1 / z], {z, 0, 12}, Assumptions -> z > 0]

绘制被截断的级数与指数积分和的差异：

Wolfram Language code: δ[z_, o_] := -Sum[(-1) ^ n(n - 1)!(z) ^ n, {n, 1, o}] + Exp[1 / z]ExpIntegralEi[-1 / z]
Wolfram Language code: Plot[Evaluate[Table[Log[Abs[δ[z, o]]], {o, 6}]], {z, 0.1, 2}]

利用 ExpIntegralE 的级数展开，求水文学和电子结构计算中出现的“渗漏含水层”函数的近似（也称为 Hantush–Jacob 函数或不完全贝塞尔函数）：

Wolfram Language code: LeakyAquiferApprox[u_, ϵ_, n_Integer : 10] := ExpIntegralE[1, u] + Sum[(-ϵ / u) ^ k / k! ExpIntegralE[k + 1, u], {k, 1, n}]

与定义积分的求积比较：

Wolfram Language code: LeakyAquiferQuadrature[u_, ϵ_] := NIntegrate[Exp[- - ϵ / ] / , {, u, Infinity}]
Wolfram Language code: {LeakyAquiferApprox[0.001, 0.001], LeakyAquiferQuadrature[0.001, 0.001]}
Wolfram Language code: Plot[{LeakyAquiferApprox[u, 0.001], LeakyAquiferApprox[u, 0.5, 20], LeakyAquiferApprox[u, 1, 100]}, {u, 0.1, 2}]

计算在时间 支付 1 美元的死亡保险金的预期时间值，其中 从姜氏-梅约翰分布中提取：

Wolfram Language code: tv = TimeValue[Cashflow[{{t, 1}}], EffectiveInterest[r, 0], 0]
Wolfram Language code: nsp = Expectation[tv, tGompertzMakehamDistribution[a, b]]

求通常在保单年度开始时支付的年保险费，该保险费使得支付现金流在共 期期间的预期时间值（其中 来自姜氏-梅约翰分布）等于净单次保险费：

Wolfram Language code: nap = TimeValue[AnnuityDue[premium, t], EffectiveInterest[r, 0], 0]
Wolfram Language code: etv = Expectation[nap, tGompertzMakehamDistribution[a, b]]

由此产生的年净保费：

Wolfram Language code: Solve[etv == nsp, premium]//FullSimplify

属性和关系  (8)

用 FullSimplify 来化简指数积分：

Wolfram Language code: FullSimplify[ExpIntegralE[3, z] + z / 2ExpIntegralE[2, z]]

用 FunctionExpand 来表示简单函数中的特殊条件：

Wolfram Language code: FunctionExpand[{ExpIntegralE[5 / 2, z], ExpIntegralE[4, z], ExpIntegralE[-4, z]}]//Simplify

求超越方程的数值根：

Wolfram Language code: FindRoot[ExpIntegralE[1, z] - 2ExpIntegralE[2, z + 2] + z == 2, {z, 1}]

从积分、求和和微分方程中产生：

Wolfram Language code: Integrate[Exp[-z t]t ^ -n, {t, 1, Infinity}, Assumptions -> z > 0 && n < 1]
Wolfram Language code: FullSimplify[n!z ^ (-n - 1)Exp[-z]Sum[z ^ k / k!, {k, 0, n}]]
Wolfram Language code: DSolve[x y''[x] + (ν + 1 - x)y'[x] == 0, y[x], x]//FullSimplify

ExpIntegralE 显示为超几何和 Meijer G 函数的一个特例：

Wolfram Language code: {Hypergeometric1F1[1 - ν, 2 - ν, -z], MeijerG[{{ν}, {}}, {{0}, {ν - 1}}, z]}//FunctionExpand//FullSimplify

积分：

Wolfram Language code: Integrate[ExpIntegralE[ν, z], z]

ExpIntegralE 是一个数值函数：

Wolfram Language code: Attributes[ExpIntegralE]
Wolfram Language code: NumericQ[ExpIntegralE[2, 2 + E]]

ExpIntegralE 可以被表示为 DifferenceRoot：

Wolfram Language code: DifferenceRootReduce[DifferenceRootReduce[ExpIntegralE[k, z], k], k]

可能存在的问题  (3)

过大参数给出的结果太大以致无法直接计算：

Wolfram Language code: ExpIntegralE[2, -10. ^ 16]

机器数输入可以给出高精度结果：

Wolfram Language code: ExpIntegralE[2, -10. ^ 3]
Wolfram Language code: MachineNumberQ[%]

在 TraditionalForm 中，E_n(z) 不能自动解释为指数积分：

Wolfram Language code: Subscript[E, n](z)

巧妙范例  (1)

绘制 的黎曼面：

Wolfram Language code: With[{p = 1 / 2, ε = 10 ^ -8}, ParametricPlot3D[Table[{r Cos[ϕ], r Sin[ϕ], Re[ExpIntegralE[p, r Exp[I ϕ]] + 2π I((r Exp[I ϕ])^p - 1/Gamma[p])Exp[k p π I]ChebyshevU[k - 1, Cos[p π]]]}, {k, 0, 1}], {r, ε, 2}, {ϕ, -π, π}, PlotRange -> {All, All, {-5, 3}}]]
Wolfram Research (1988)，ExpIntegralE，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExpIntegralE.html （更新于 2022 年）.

文本

Wolfram Research (1988)，ExpIntegralE，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExpIntegralE.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "ExpIntegralE." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/ExpIntegralE.html.

APA

Wolfram 语言. (1988). ExpIntegralE. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ExpIntegralE.html 年

BibTeX

@misc{reference.wolfram_2026_expintegrale, author="Wolfram Research", title="{ExpIntegralE}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ExpIntegralE.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_expintegrale, organization={Wolfram Research}, title={ExpIntegralE}, year={2022}, url={https://reference.wolfram.com/language/ref/ExpIntegralE.html}, note=[Accessed: 11-September-2026]}