Wolfram言語＆システムドキュメントセンター

FactorialMoment

FactorialMoment[data,r]

data の r 次階乗モーメントを与える．

FactorialMoment[data,{r₁,…,r_m}]

data の多変量{r₁,…,r_m}次階乗モーメントを与える．

FactorialMoment[dist,…]

分布 dist の階乗モーメントを与える．

FactorialMoment[r]

r 次の形式的階乗モーメントを表す．

詳細

階乗モーメントは，によって与えられるFactorialPower[x,r]を使って定義される．
次数 r のスカラーで data が配列のとき：
r 次階乗ベキの和 »

列ごとの r 次階乗ベキの和 »

$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$ 列ごとの r 次階乗ベキの和 »
FactorialMoment[x,r]はArrayReduce[FactorialMoment[#,r]&,x,1]に等しい．
次数{r₁,…,r_m}のベクトルで data が配列のとき：
第 j 列の r_j次階乗ベキの和

$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$ 第 j 列の r_j次階乗ベキの和 »
FactorialMoment[x,{r₁,…,r_m}]はArrayReduce[FactorialMoment[#,{r₁,…,r_m}]&,x,{{1},{2}}]に等しい．
FactorialMomentは数値データと記号データの両方を扱うことができる．
data は次の追加的な形式と解釈を持つことができる．

	Association	値（キーは無視される） »
	WeightedData	もとになっているEmpiricalDistributionに基づく加重平均 »
	EventData	もとになっているSurvivalDistributionに基づく »
	TimeSeries, TemporalData, …	値のベクトルまたは配列（タイムスタンプは無視される） »
	Image,Image3D	RGBチャンネル値またはグレースケール強度値 »
	Audio	すべてのチャンネルの振幅値 »

分布 dist についての r 次階乗モーメントは Expectation[x^(r),xdist]で与えられる． »
多変量分布 dist についての{r₁,…,r_m}次階乗モーメントはExpectation[x₁^(r₁)⋯ x_m^(r_m),{x₁,…,x_m}dist]で与えられる． »
ランダム過程 proc については，階乗モーメント関数は時点 t におけるスライス分布SliceDistribution[proc,t]について，[t]=FactorialMoment[SliceDistribution[proc,t],r]として計算できる． »
FactorialMoment[r]はMomentConvertやMomentEvaluate等の関数で使うことができる． »

例題

すべて開くすべて閉じる

例 (2)

データから階乗モーメントを計算する：

Wolfram Language code: data = RandomVariate[PoissonDistribution[4], 10 ^ 4];

Wolfram Language code: FactorialMoment[data, 3]

記号データを使う：

Wolfram Language code: FactorialMoment[{Subscript[k, 1], Subscript[k, 2], Subscript[k, 3]}, 3]

一変量離散分布の二次階乗モーメントを計算する：

Wolfram Language code: FactorialMoment[BinomialDistribution[n, p], 2]

多変量分布の階乗モーメント：

Wolfram Language code: FactorialMoment[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {2, 2, 2}]

スコープ (20)

基本的な用法 (5)

厳密な入力は厳密な出力を与える：

Wolfram Language code: FactorialMoment[{1, 2, 3, 4}, 1]

Wolfram Language code: FactorialMoment[{π, E, 2}, 2]//Together

近似入力は近似出力を与える：

Wolfram Language code: FactorialMoment[{1., 2., 3., 4.}, 2]

Wolfram Language code: FactorialMoment[N[{1, 2, 3, 4}, 30], 2]

WeightedDataの階乗モーメントを求める：

Wolfram Language code: FactorialMoment[WeightedData[{1, 2, 3}, {Subscript[w, 1], Subscript[w, 2], Subscript[w, 3]}], 1]

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: FactorialMoment[WeightedData[data, weights], 2]

EventDataの階乗モーメントを求める：

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: FactorialMoment[EventData[e, ci], 2]

TimeSeriesの階乗モーメントを求める：

Wolfram Language code:

FactorialMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.], 2]

階乗モーメントは値のみに依存する：

Wolfram Language code:

FactorialMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]["Values"], 2]

配列データ (4)

FactorialMomentは，行列については列ごとの平均を与える：

Wolfram Language code:

FactorialMoment[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), 2]

FactorialMomentは，配列については第1レベルの列ごとの平均を与える：

Wolfram Language code: FactorialMoment[Array[Subscript[a, ##]&, {2, 2, 2}], 2]//Simplify//MatrixForm

配列についての多変量FactorialMoment：

Wolfram Language code: FactorialMoment[Array[Subscript[a, ##]&, {2, 2, 2}], {2, 2}]//Simplify//TraditionalForm

Wolfram Language code: %//FunctionExpand//Simplify

大きい配列に使う：

Wolfram Language code: FactorialMoment[RandomReal[1, 10 ^ 7], 2]

Wolfram Language code: FactorialMoment[RandomReal[1, {10 ^ 6, 5}], 1]

入力がAssociationのとき，FactorialMomentはその値に作用する：

Wolfram Language code:

mat = RandomReal[1, {2, 2}];
assoc = AssociationThread[Range[2], mat]

Wolfram Language code: FactorialMoment[assoc, 3]

SparseArrayデータは密は配列のように使うことができる：

Wolfram Language code: FactorialMoment[SparseArray[{{1} -> 1, {100} -> 1}], 1]

Wolfram Language code: FactorialMoment[SparseArray[{{1, 1} -> 1, {2, 2} -> 2, {3, 3} -> 3, {1, 3} -> 4}], 2]

画像データと音声データ (2)

RGB画像のチャンネルごとの階乗モーメント：

Wolfram Language code: FactorialMoment[[image], 5]

Wolfram Language code: RGBColor[%]

グレースケール画像の階乗モーメント強度値：

Wolfram Language code: FactorialMoment[[image], 4]

FactorialMomentは，音声オブジェクトについてはチャンネルごとに作用する：

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]

Wolfram Language code: AudioMeasurements[a, "Channels"]

Wolfram Language code: FactorialMoment[a, 3]

分布のモーメントと過程のモーメント (5)

一変量分布のスカラー階乗モーメント：

Wolfram Language code: FactorialMoment[BinomialDistribution[n, p], 1]//Together

Wolfram Language code: FactorialMoment[NormalDistribution[μ, σ], 2]

多変量分布の結合階乗モーメント：

Wolfram Language code: FactorialMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], 2]

Wolfram Language code: FactorialMoment[DirichletDistribution[{a, b, c}], 2]//Simplify

多変量分布の場合：

Wolfram Language code: FactorialMoment[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {1, 1, 1}]

Wolfram Language code:

FactorialMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], {2, 2}]

記号次数 r についての階乗モーメントを計算する：

Wolfram Language code: FactorialMoment[PoissonDistribution[μ], r]

階乗モーメントは特定の次数についてしか評価されないことがある：

Wolfram Language code: FactorialMoment[BorelTannerDistribution[𝒶, n], r]

Wolfram Language code: % /. {r -> 2}

階乗モーメントは数値的にしか評価されないことがある：

Wolfram Language code: FactorialMoment[VonMisesDistribution[Pi / 2, 2], 4]

Wolfram Language code: N[%]

派生分布についての階乗モーメント：

Wolfram Language code: FactorialMoment[TransformedDistribution[x^2, xNormalDistribution[μ, σ]], 1]

Wolfram Language code: FactorialMoment[ProbabilityDistribution[(Sqrt[2] / π)(1 / (1 + (x - 2)^4)), {x, -∞, ∞}], 2]

データ分布について：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];

Wolfram Language code: FactorialMoment[HistogramDistribution[data], 4]

ランダム過程についての階乗モーメント関数：

Wolfram Language code: FactorialMoment[BrownianBridgeProcess[μ, σ][t], 2]

Wolfram Language code: Plot[Evaluate[% /. {μ -> 3, σ -> 1}], {t, 0, 1}, PlotRange -> All]

ある時点 t=0.5におけるTemporalDataの階乗モーメントを求める：

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 500]

Wolfram Language code: FactorialMoment[td[0.5], 1]

対応する階乗モーメント関数をすべてのシミュレーションとともに求める：

Wolfram Language code:

Show[ListLinePlot[td, PlotStyle -> Directive[Opacity[0.2], Thin]], Plot[FactorialMoment[td[t], 1], {t, 0, 10}, PlotStyle -> Thick]]

形式的なモーメント (4)

形式的なモーメントのTraditionalFormによる表示：

Wolfram Language code: FactorialMoment[r]//TraditionalForm

Wolfram Language code: FactorialMoment[{p, q, r}]//TraditionalForm

形式的なモーメントの組合せを，FactorialMomentを含む式に変換する：

Wolfram Language code: MomentConvert[Moment[2], FactorialMoment]//TraditionalForm

Wolfram Language code: MomentConvert[CentralMoment[2]Cumulant[2], FactorialMoment]//TraditionalForm

形式的なモーメントを含む式を分布について評価する：

Wolfram Language code: MomentEvaluate[FactorialMoment[2] + FactorialMoment[3], PoissonDistribution[λ]]

データについて評価する：

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[FactorialMoment[2] + FactorialMoment[3], data]

FactorialMomentを含む式についてのサンプル推定量を求める：

Wolfram Language code: estimator = MomentConvert[FactorialMoment[2], "UnbiasedSampleEstimator"]

結果の推定量をデータについて評価する：

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[estimator, data]

アプリケーション (4)

階乗モーメント法を使って分布母数を推定する：

Wolfram Language code: data = RandomVariate[SkellamDistribution[2, 5], 10 ^ 4];

Wolfram Language code: NSolve[Table[FactorialMoment[data, k] == FactorialMoment[SkellamDistribution[m1, m2], k], {k, 1, 2}], {m1, m2}]

データと推定パラメトリック分布を比較する：

Wolfram Language code:

Show[Histogram[data, Automatic, "ProbabilityDensity"], DiscretePlot[Evaluate[PDF[SkellamDistribution[m1, m2], x] /. %], {x, -10, 10}, PlotStyle -> PointSize[Medium]]]

一連の階乗モーメントから確率質量関数を再構築する：

Wolfram Language code: fm[r_] = (7 / 3)^-r(3 + (-1)^r) / 4;

階乗モーメント母関数(FMGF)を求める：

Wolfram Language code: fmgf = Sum[fm[r](t - 1) ^ r / r!, {r, 0, Infinity}]

FMGFと確率母関数の等価性を使う：

Wolfram Language code:

dist = ProbabilityDistribution[
	SeriesCoefficient[fmgf, {t, 0, k}], {k, 0, Infinity, 1}]

求まった分布の階乗モーメントがもとの階乗モーメントと一致することを確認する：

Wolfram Language code: Table[FactorialMoment[dist, r], {r, 0, 6}]

Wolfram Language code: Table[fm[r], {r, 0, 6}]

あるデータについての移動階乗モーメントを計算する：

Wolfram Language code:

data = TemporalData[TimeSeries, {{{0., -0.1658757846470872, -0.2728638398721067, -0.20572896599603147, 
    -0.10538217461042272, -0.05347321047935807, -0.09210914812542037, -0.19681903814874602, 
    -0.2868001703261339, -0.39654025546507443, -0.42843667 ... 4643, -0.020432977410382067, 0.061353433083862305, 
    -0.05763556841195196}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

長さ.1の窓を使う：

Wolfram Language code: md = MovingMap[FactorialMoment[#, 2]&, data, .1];

Wolfram Language code: ListLinePlot[md, PlotRange -> All]

ランダム過程の経路集合のスライスについて，階乗モーメントを計算する：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

いくつかのスライス時間を選ぶ：

Wolfram Language code: times = Range[0, 1, .1];

Wolfram Language code: fm = Map[{#, FactorialMoment[data[#], 2]}&, times];

これらの経路上に階乗モーメントをプロットする：

Wolfram Language code: Show[ListPlot[data], ListLinePlot[fm, PlotStyle -> StandardRed]]

特性と関係 (5)

階乗モーメントはFactorialPowerの期待値と等しい：

Wolfram Language code: FactorialMoment[PoissonDistribution[μ], 2]

Wolfram Language code: Expectation[FactorialPower[x, 2], xPoissonDistribution[μ]]

一次階乗モーメントはMeanと等しい：

Wolfram Language code: FactorialMoment[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}, 1]

Wolfram Language code: Mean[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]

FactorialMomentは $mu^__r=sum_(k=1)^rTemplateBox[{r, k}, StirlingS1]mu_k$ を使ってMomentから計算することができる：

Wolfram Language code: With[{r = 5, 𝒟 = BinomialDistribution[n, p]}, Subsuperscript[∑, k = 1, r]StirlingS1[r, k]Moment[𝒟, k]]

Wolfram Language code: With[{r = 5, 𝒟 = BinomialDistribution[n, p]}, FactorialMoment[𝒟, r]]

Wolfram Language code: Simplify[%% - %]

MomentConvertも同じ結果を生む：

Wolfram Language code: MomentConvert[FactorialMoment[5], Moment]

Wolfram Language code: Subsuperscript[∑, k = 1, r]StirlingS1[r, k]Moment[k] /. r -> 5

Momentは $mu_r=sum_(k=0)^rmu^__k TemplateBox[{r, k}, StirlingS2]$ を使ってFactorialMomentから計算することができる：

Wolfram Language code:

With[{r = 5, 𝒟 = ExponentialDistribution[λ]}, Underoverscript[∑, k = 0, r]StirlingS2[r, k]FactorialMoment[𝒟, k]]

Wolfram Language code: With[{r = 5, 𝒟 = ExponentialDistribution[λ]}, Moment[𝒟, r]]

Wolfram Language code: Simplify[%% - %]

MomentConvertも同じ結果を生む：

Wolfram Language code: MomentConvert[Moment[5], FactorialMoment]

Wolfram Language code: Subsuperscript[∑, k = 1, r]StirlingS2[r, k]FactorialMoment[k] /. r -> 5

深さの配列の多変量階乗モーメントの深さはである：

Wolfram Language code:

arr = Array[Subscript[a, Row@{##}]&, {n = 4, m = 3, 2, 3}];
rs = {2, 2, 2};
Length[rs] == m

Wolfram Language code:

FactorialMoment[arr, rs] == 
	 ArrayReduce[Mean, 
	ArrayReduce[Times@@FactorialPower[#, rs]&, arr, 2], 
	1]//Simplify

おもしろい例題 (1)

30個，100個，300個のサンプルについてFactorialMomentの分布を推定する：

Wolfram Language code: FactorialMoment[ExponentialDistribution[0.9], 2]

Wolfram Language code:

SmoothHistogram[Table[FactorialMoment[RandomVariate[ExponentialDistribution[0.9], {s, 1000}], 2], {s, {30, 100, 300}}], Filling -> Axis, PlotLegends -> {30, 100, 300}, PlotRange -> {{0, 4}, Automatic}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

FactorialMoment

詳細

例題

例 (2)

スコープ (20)

基本的な用法 (5)

配列データ (4)

画像データと音声データ (2)

分布のモーメントと過程のモーメント (5)

形式的なモーメント (4)

アプリケーション (4)

特性と関係 (5)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

			r 次階乗ベキの和 »
			列ごとの r 次階乗ベキの和 »
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		列ごとの r 次階乗ベキの和 »

			第 j 列の r_j次階乗ベキの和
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		第 j 列の r_j次階乗ベキの和 »

FactorialMoment

詳細

例題

例 (2)

スコープ (20)

基本的な用法 (5)

配列データ (4)

画像データと音声データ (2)

分布のモーメントと過程のモーメント (5)

形式的なモーメント (4)

アプリケーション (4)

特性と関係 (5)

おもしろい例題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX