Wolfram 语言与系统参考资料中心

FactorialMoment

FactorialMoment[data,r]

给出 data 的阶 r 阶乘矩 .

FactorialMoment[data,{r₁,…,r_m}]

给出 data 的阶 {r₁,…,r_m} 多元阶乘矩 .

FactorialMoment[dist,…]

给出了分布 dist 的阶乘矩.

FactorialMoment[r]

代表阶 r 形式阶乘矩.

范例

打开所有单元关闭所有单元

基本范例 (2)

从数据计算阶乘矩：

Wolfram Language code: data = RandomVariate[PoissonDistribution[4], 10 ^ 4];

Wolfram Language code: FactorialMoment[data, 3]

使用符号数据：

Wolfram Language code: FactorialMoment[{Subscript[k, 1], Subscript[k, 2], Subscript[k, 3]}, 3]

计算一个离散单变量分布的二阶阶乘矩：

Wolfram Language code: FactorialMoment[BinomialDistribution[n, p], 2]

一个多变量分布的阶乘矩：

Wolfram Language code: FactorialMoment[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {2, 2, 2}]

范围 (20)

基础用法 (5)

精确输入产生精确输出：

Wolfram Language code: FactorialMoment[{1, 2, 3, 4}, 1]

Wolfram Language code: FactorialMoment[{π, E, 2}, 2]//Together

近似输入产生近似输出：

Wolfram Language code: FactorialMoment[{1., 2., 3., 4.}, 2]

Wolfram Language code: FactorialMoment[N[{1, 2, 3, 4}, 30], 2]

求 WeightedData 的阶乘矩：

Wolfram Language code: FactorialMoment[WeightedData[{1, 2, 3}, {Subscript[w, 1], Subscript[w, 2], Subscript[w, 3]}], 1]

Wolfram Language code:

data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};

Wolfram Language code: FactorialMoment[WeightedData[data, weights], 2]

求 EventData 的阶乘矩：

Wolfram Language code:

e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};

Wolfram Language code: FactorialMoment[EventData[e, ci], 2]

求 TimeSeries 的阶乘矩：

Wolfram Language code:

FactorialMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.], 2]

矩仅与值有关：

Wolfram Language code:

FactorialMoment[TemporalData[TimeSeries, {{{2.3, 1.2, 6.7, 5.8, 7.1, 4.6}}, {{0, 5, 1}}, 1, {"Discrete", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]["Values"], 2]

数组数据 (4)

对于矩阵而言，FactorialMoment 给出列向矩：

Wolfram Language code:

FactorialMoment[(⁠|       |       |
| ----- | ----- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠), 2]

对于数组而言，FactorialMoment 给出第一层的列向矩：

Wolfram Language code: FactorialMoment[Array[Subscript[a, ##]&, {2, 2, 2}], 2]//Simplify//MatrixForm

数组的多元 FactorialMoment：

Wolfram Language code: FactorialMoment[Array[Subscript[a, ##]&, {2, 2, 2}], {2, 2}]//Simplify//TraditionalForm

Wolfram Language code: %//FunctionExpand//Simplify

适用于大型数组：

Wolfram Language code: FactorialMoment[RandomReal[1, 10 ^ 7], 2]

Wolfram Language code: FactorialMoment[RandomReal[1, {10 ^ 6, 5}], 1]

当输入是 Association 时，FactorialMoment 会作用于其值：

Wolfram Language code:

mat = RandomReal[1, {2, 2}];
assoc = AssociationThread[Range[2], mat]

Wolfram Language code: FactorialMoment[assoc, 3]

SparseArray 数据可以像稠密数组一样使用：

Wolfram Language code: FactorialMoment[SparseArray[{{1} -> 1, {100} -> 1}], 1]

Wolfram Language code: FactorialMoment[SparseArray[{{1, 1} -> 1, {2, 2} -> 2, {3, 3} -> 3, {1, 3} -> 4}], 2]

图像和音频数据 (2)

RGB 图像的通道阶乘矩：

Wolfram Language code: FactorialMoment[[image], 5]

Wolfram Language code: RGBColor[%]

灰度图像的阶乘矩强度值：

Wolfram Language code: FactorialMoment[[image], 4]

对于音频对象，FactorialMoment 按通道工作：

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}]

Wolfram Language code: AudioMeasurements[a, "Channels"]

Wolfram Language code: FactorialMoment[a, 3]

分布与过程矩 (5)

单变量分布的标量阶乘矩：

Wolfram Language code: FactorialMoment[BinomialDistribution[n, p], 1]//Together

Wolfram Language code: FactorialMoment[NormalDistribution[μ, σ], 2]

多元分布的标量阶乘矩：

Wolfram Language code: FactorialMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], 2]

Wolfram Language code: FactorialMoment[DirichletDistribution[{a, b, c}], 2]//Simplify

多元分布的联合阶乘矩：

Wolfram Language code: FactorialMoment[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {1, 1, 1}]

Wolfram Language code:

FactorialMoment[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ], {2, 2}]

计算符号式阶 r 的阶乘矩：

Wolfram Language code: FactorialMoment[PoissonDistribution[μ], r]

阶乘矩仅对具体阶数计算：

Wolfram Language code: FactorialMoment[BorelTannerDistribution[𝒶, n], r]

Wolfram Language code: % /. {r -> 2}

阶乘矩仅能做数值计算：

Wolfram Language code: FactorialMoment[VonMisesDistribution[Pi / 2, 2], 4]

Wolfram Language code: N[%]

导出分布的阶乘矩：

Wolfram Language code: FactorialMoment[TransformedDistribution[x^2, xNormalDistribution[μ, σ]], 1]

Wolfram Language code: FactorialMoment[ProbabilityDistribution[(Sqrt[2] / π)(1 / (1 + (x - 2)^4)), {x, -∞, ∞}], 2]

数据分布：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10 ^ 3];

Wolfram Language code: FactorialMoment[HistogramDistribution[data], 4]

随机过程的阶乘矩函数：

Wolfram Language code: FactorialMoment[BrownianBridgeProcess[μ, σ][t], 2]

Wolfram Language code: Plot[Evaluate[% /. {μ -> 3, σ -> 1}], {t, 0, 1}, PlotRange -> All]

求 TemporalData 在某时刻 t=0.5 的阶乘矩：

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 100]

Wolfram Language code: FactorialMoment[td[0.5], 1]

求相应的矩函数和所有的模拟：

Wolfram Language code:

Show[ListLinePlot[td, PlotStyle -> Directive[Opacity[0.2], Thin]], Plot[FactorialMoment[td[t], 1], {t, 0, 10}, PlotStyle -> Thick]]

形式矩 (4)

形式矩的 TraditionalForm 格式：

Wolfram Language code: FactorialMoment[r]//TraditionalForm

Wolfram Language code: FactorialMoment[{p, q, r}]//TraditionalForm

将形式矩的组合转换为含 FactorialMoment 的表达式：

Wolfram Language code: MomentConvert[Moment[2], FactorialMoment]//TraditionalForm

Wolfram Language code: MomentConvert[CentralMoment[2]Cumulant[2], FactorialMoment]//TraditionalForm

计算一个包含形式矩的分布的表达式：

Wolfram Language code: MomentEvaluate[FactorialMoment[2] + FactorialMoment[3], PoissonDistribution[λ]]

对数据计算：

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[FactorialMoment[2] + FactorialMoment[3], data]

求包含 FactorialMoment 的一个表达式的样本估计量：

Wolfram Language code: estimator = MomentConvert[FactorialMoment[2], "UnbiasedSampleEstimator"]

计算数据所产生的估计量：

Wolfram Language code: data = RandomVariate[PoissonDistribution[1], 10^4];

Wolfram Language code: MomentEvaluate[estimator, data]

应用 (4)

使用阶乘矩法估算分布参数：

Wolfram Language code: data = RandomVariate[SkellamDistribution[2, 5], 10 ^ 4];

Wolfram Language code: NSolve[Table[FactorialMoment[data, k] == FactorialMoment[SkellamDistribution[m1, m2], k], {k, 1, 2}], {m1, m2}]

比较数据与估计的参数分布：

Wolfram Language code:

Show[Histogram[data, Automatic, "ProbabilityDensity"], DiscretePlot[Evaluate[PDF[SkellamDistribution[m1, m2], x] /. %], {x, -10, 10}, PlotStyle -> PointSize[Medium]]]

从阶乘矩的序列重建概率质量函数：

Wolfram Language code: fm[r_] = (7 / 3)^-r(3 + (-1)^r) / 4;

求阶乘矩量生成函数 (fmgf)：

Wolfram Language code: fmgf = Sum[fm[r](t - 1) ^ r / r!, {r, 0, Infinity}]

使用 fmgf 和概率生成函数的等价性：

Wolfram Language code:

dist = ProbabilityDistribution[
	SeriesCoefficient[fmgf, {t, 0, k}], {k, 0, Infinity, 1}]

验证求得的分布的阶乘矩与原分布匹配：

Wolfram Language code: Table[FactorialMoment[dist, r], {r, 0, 6}]

Wolfram Language code: Table[fm[r], {r, 0, 6}]

计算一些数据的移动阶乘矩：

Wolfram Language code:

data = TemporalData[TimeSeries, {{{0., -0.1658757846470872, -0.2728638398721067, -0.20572896599603147, 
    -0.10538217461042272, -0.05347321047935807, -0.09210914812542037, -0.19681903814874602, 
    -0.2868001703261339, -0.39654025546507443, -0.42843667 ... 4643, -0.020432977410382067, 0.061353433083862305, 
    -0.05763556841195196}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

使用长度为 .1 的窗口：

Wolfram Language code: md = MovingMap[FactorialMoment[#, 2]&, data, .1];

Wolfram Language code: ListLinePlot[md, PlotRange -> All]

计算随机过程的路径集合的切片的阶乘矩：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

选择一些切片时间：

Wolfram Language code: times = Range[0, 1, .1];

Wolfram Language code: fm = Map[{#, FactorialMoment[data[#], 2]}&, times];

在这些路径上绘制阶乘矩的图线：

Wolfram Language code: Show[ListPlot[data], ListLinePlot[fm, PlotStyle -> Black]]

属性和关系 (5)

阶乘矩与 FactorialPower 的期望等价：

Wolfram Language code: FactorialMoment[PoissonDistribution[μ], 2]

Wolfram Language code: Expectation[FactorialPower[x, 2], xPoissonDistribution[μ]]

第一阶乘矩与 Mean 等价：

Wolfram Language code: FactorialMoment[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}, 1]

Wolfram Language code: Mean[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]

FactorialMoment 可以由 Moment 通过 $mu^__r=sum_(k=1)^rTemplateBox[{r, k}, StirlingS1]mu_k$ 计算：

Wolfram Language code: With[{r = 5, 𝒟 = BinomialDistribution[n, p]}, Subsuperscript[∑, k = 1, r]StirlingS1[r, k]Moment[𝒟, k]]

Wolfram Language code: With[{r = 5, 𝒟 = BinomialDistribution[n, p]}, FactorialMoment[𝒟, r]]

Wolfram Language code: Simplify[%% - %]

MomentConvert 产生相同的结果：

Wolfram Language code: MomentConvert[FactorialMoment[5], Moment]

Wolfram Language code: Subsuperscript[∑, k = 1, r]StirlingS1[r, k]Moment[k] /. r -> 5

Moment 可由 FactorialMoment 通过 $mu_r=sum_(k=0)^rmu^__k TemplateBox[{r, k}, StirlingS2]$ 计算：

Wolfram Language code:

With[{r = 5, 𝒟 = ExponentialDistribution[λ]}, Underoverscript[∑, k = 0, r]StirlingS2[r, k]FactorialMoment[𝒟, k]]

Wolfram Language code: With[{r = 5, 𝒟 = ExponentialDistribution[λ]}, Moment[𝒟, r]]

Wolfram Language code: Simplify[%% - %]

MomentConvert 产生相同的结果：

Wolfram Language code: MomentConvert[Moment[5], FactorialMoment]

Wolfram Language code: Subsuperscript[∑, k = 1, r]StirlingS2[r, k]FactorialMoment[k] /. r -> 5

深度为的数组的多元阶乘矩的深度为：

Wolfram Language code:

arr = Array[Subscript[a, Row@{##}]&, {n = 4, m = 3, 2, 3}];
rs = {2, 2, 2};
Length[rs] == m

Wolfram Language code:

FactorialMoment[arr, rs] == 
	 ArrayReduce[Mean, 
	ArrayReduce[Times@@FactorialPower[#, rs]&, arr, 2], 
	1]//Simplify

巧妙范例 (1)

估计 30、100 和 300 个样本的 FactorialMoment 的分布：

Wolfram Language code: FactorialMoment[ExponentialDistribution[0.9], 2]

Wolfram Language code:

SmoothHistogram[Table[FactorialMoment[RandomVariate[ExponentialDistribution[0.9], {s, 1000}], 2], {s, {30, 100, 300}}], Filling -> Axis, PlotLegends -> {30, 100, 300}, PlotRange -> {{0, 4}, Automatic}]

Top

			r 次阶乘幂之和 »
			r 次阶乘幂列式之和 »
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		r 次阶乘幂列式之和 »

	Association	值（忽略键值） »
	WeightedData	加权平均值，基于底层 EmpiricalDistribution »
	EventData	基于底层 SurvivalDistribution »
	TimeSeries, TemporalData, …	值的向量或数组（忽略时间戳） »
	Image,Image3D	RGB 通道值或灰度强度值 »
	Audio	所有通道的振幅值 »

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

FactorialMoment

更多信息

范例

基本范例 (2)

范围 (20)

基础用法 (5)

数组数据 (4)

图像和音频数据 (2)

分布与过程矩 (5)

形式矩 (4)

应用 (4)

属性和关系 (5)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

			第 j 列中的 r_j 次阶乘和
	$x in TemplateBox[{Arrays, paclet:ref/Arrays}, RefLink, BaseStyle -> {3ColumnTableMod}][{n_(1),...,n_(k)}]$		第 j 列中求和 r_j 次阶乘幂 »

FactorialMoment

更多信息

范例

基本范例 (2)

范围 (20)

基础用法 (5)

数组数据 (4)

图像和音频数据 (2)

分布与过程矩 (5)

形式矩 (4)

应用 (4)

属性和关系 (5)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX