FactorialPower

FactorialPower[x,n]

階乗ベキを与える．

FactorialPower[x,n,h]

の階乗ベキをステップ h で与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
整数 n に対し，はで与えられ，はで与えられる．
は任意の n に対してで与えられる．
はで与えられ， $sum_xTemplateBox[{x, k}, FactorialPower]$ はで与えられる．
FactorialPower[x,n]は x と n が数のときにのみ自動的に評価される．
FunctionExpandは常にFactorialPowerを多項式かガンマ関数の組合せに変換する．
FactorialPowerはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (6)

10の「階乗平方」を求める：

Wolfram Language code: FactorialPower[10, 2]

FactorialPowerは自動的には展開しない：

Wolfram Language code: FactorialPower[x, 8]

FunctionExpandを使って展開する：

Wolfram Language code: FunctionExpand[%]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[FactorialPower[x, 3], {x, -3, 4}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[FactorialPower[z ^ 2, 5], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[FactorialPower[x, 5], {x, 0, 5}]//FullSimplify

Infinityにおける級数展開：

Wolfram Language code: Series[FactorialPower[x, 5], {x, ∞, 6}]//FullSimplify

スコープ (35)

数値評価 (7)

数値的に評価する：

Wolfram Language code: FactorialPower[2, .9]

Wolfram Language code: FactorialPower[4, 2]

高精度で評価する：

Wolfram Language code: N[FactorialPower[1 / 3, 7, 3], 50]

出力精度は入力精度に従う：

Wolfram Language code: FactorialPower[0.100000000000000000, 7, 3]

複素数入力：

Wolfram Language code: FactorialPower[1 + I, I, 3.]

高精度で効率的に評価する：

Wolfram Language code: FactorialPower[1 / 3, 7, 3`100]//Timing

Wolfram Language code: FactorialPower[2`1000, 1 / 5, 1 / 3];//Timing

FactorialPowerは要素単位でリストに縫い込まれる：

Wolfram Language code: FactorialPower[4, {1, 2, 3, 4, 5}]

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: FactorialPower[0.3, 0.4, Interval[{0.5, 0.6}]]

Wolfram Language code: FactorialPower[1 / 2, 1 / 3, CenteredInterval[1 / 5, 1 / 1000]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: FactorialPower[Around[2, 0.01], 2]

配列の要素ごとの値を計算する

Wolfram Language code: FactorialPower[{{1, 2}, {3, 4}}, 2]

MatrixFunctionを使って行列のFactorialPower関数を計算することもできる：

Wolfram Language code: MatrixFunction[FactorialPower[#, .2]&, {{1, 2}, {3, 4}}]

特定の値 (6)

固定点におけるFactorialPowerの値：

Wolfram Language code: Table[FactorialPower[x, 2], {x, 1, 5}]

n の整数値について多項式表現FactorialPower[x,n]を得る：

Wolfram Language code: FactorialPower[x, 4]//FunctionExpand

刻み幅がのとき，FactorialPower[x,n,h]は昇階乗ベキを与える：

Wolfram Language code: FunctionExpand[FactorialPower[x, 5, -1]]

これはPochhammerに等しい：

Wolfram Language code: Pochhammer[x, 5]

x の固定値についてFactorialPower[x,n]を展開する：

Wolfram Language code: FactorialPower[(3/2), n]//FunctionExpand

第3引数に整数値を加えて同じことを行う：

Wolfram Language code: Table[FactorialPower[(3/2), n, h], {h, 0, 3}]//FunctionExpand

第2引数がゼロのときの値：

Wolfram Language code: FactorialPower[n, 0]

第1引数が0で第2引数が正のときの値：

Wolfram Language code: FullSimplify[FactorialPower[0, n], n∈PositiveIntegers]//Quiet

FactorialPower[x,1/7]=1.2となるような x の値を求める：

Wolfram Language code: xval = x /. FindRoot[FactorialPower[ x , 1 / 7] == 1.2, {x, 3}]

Wolfram Language code:

Plot[FactorialPower[x, 1 / 7], {x, 0, 10}, Epilog -> Style[Point[{xval, FactorialPower[xval, 1 / 7]}], PointSize[Large], Red]]

可視化 (3)

FactorialPower関数をさまざまな次数でプロットする：

Wolfram Language code: Plot[{FactorialPower[x, 1], FactorialPower[x, 2], FactorialPower[x, 3], FactorialPower[x, 4]}, {x, -3, 3}]

FactorialPowerをパラメータの関数としてプロットする：

Wolfram Language code:

Plot[{FactorialPower[1 / 2, n], FactorialPower[1, n], FactorialPower[3 / 2, n], FactorialPower[2, n]}, {n, -4, 4}, PlotLegends -> "Expressions"]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[FactorialPower[z, 5]], {z, -1 - 2I, 1 + 2 I}, Contours -> 20]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[FactorialPower[z, 5]], {z, -1 - 2I, 1 + 2 I}, Contours -> 20]

関数の特性 (10)

階乗ベキの実領域：

Wolfram Language code: FunctionDomain[FactorialPower[x, y], {x, y}]

複素領域：

Wolfram Language code: FunctionDomain[FactorialPower[w, z], {w, z}, Complexes]

n のさまざまな固定値についてのFactorialPower[x,n]の関数領域：

Wolfram Language code: Table[FunctionRange[FactorialPower[x, n], x, y], {n, {0, 1 / 2, 1, 2}}]

は x の解析関数である：

Wolfram Language code: FunctionAnalytic[FactorialPower[x, 3], x]

は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[FactorialPower[x, 3], x]

は単射ではない：

Wolfram Language code: FunctionInjective[FactorialPower[x, 3], x]

Wolfram Language code: Plot[{FactorialPower[x, 3], .2}, {x, -1, 3}]

は全射である：

Wolfram Language code: FunctionSurjective[FactorialPower[x, 3], x]

Wolfram Language code: Plot[{FactorialPower[x, 3], 10}, {x, -5, 5}]

FactorialPowerは非負でも非正でもない：

Wolfram Language code: FunctionSign[FactorialPower[x, 1], x]

は，が負の整数のとき，潜在的な特異点と不連続点を持つ：

Wolfram Language code: FunctionSingularities[FactorialPower[x, y], {x, y}]

Wolfram Language code: FunctionDiscontinuities[FactorialPower[x, y], {x, y}]

は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[FactorialPower[x, 3], x]

TraditionalFormによる表示：

Wolfram Language code: FactorialPower[x, n]//TraditionalForm

Wolfram Language code: FactorialPower[x, n, h]//TraditionalForm

微分 (3)

についてのの一次導関数：

Wolfram Language code: D[FactorialPower[x, n], x]

についてのの一次導関数：

Wolfram Language code: D[FactorialPower[x, n], n]

についてのの高次導関数：

Wolfram Language code: Table[D[FactorialPower[x, n], {x, k}], {k, 1, 3}]//FullSimplify

n=2のとき，x についての高次導関数をプロットする：

Wolfram Language code:

Plot[Evaluate[% /. n -> 1 / 2], {x, -3, 0}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

級数展開 (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[FactorialPower[x, n], {x, 0, 2}]//Normal// FullSimplify

の周りの最初の2つの近似をプロットする：

Wolfram Language code:

funcAndSeries = Prepend[Table[Series[FactorialPower[x, 3], {x, 0, m}], {m, 1, 2}], FactorialPower[x, 3]]//Normal;
Plot[funcAndSeries, {x, -10, 10}]

生成点における級数展開：

Wolfram Language code: Series[FactorialPower[x, n], {x, x0, 2}]//Normal// FullSimplify

特異点における級数展開：

Wolfram Language code: Series[FactorialPower[x, 4], {x, -1, 3}]

FactorialPowerはベキ級数に適用できる：

Wolfram Language code: FactorialPower[x + O[x] ^ 5, 10]

関数の恒等式と簡約 (2)

正の整数について $TemplateBox[{x, n}, FactorialPower]= ((-1)^n TemplateBox[{{n, -, x}}, Gamma])/(TemplateBox[{{-, x}}, Gamma])$ ：

Wolfram Language code: FunctionExpand[FactorialPower[x, n], {Element[n, Integers] && n > 0}]

漸化式：

Wolfram Language code: x FactorialPower[x, n] == FactorialPower[x, n + 1] + n FactorialPower[x, n]//FullSimplify

アプリケーション (4)

異なる要素の長さ n のリストの長さ r の順列の数は，FactorialPower[n,r]によって与えられる：

Wolfram Language code: Length[Permutations[Range[5], {3}]]

Wolfram Language code: FactorialPower[5, 3]

異なる桁の3つ一組の数：

Wolfram Language code: FactorialPower[10, 3]

Wolfram Language code: Count[Tuples[Range[10], {3}], x_ /; DeleteDuplicates[x] === x]

ニュートン(Newton)の前進差分公式[MathWorld]を使って関数を近似する：

Wolfram Language code: delta[k_, x_] = DifferenceDelta[Sin[x], {x, k}]

級数を短縮することで近似を構築する：

Wolfram Language code: approx[a_] = Sum[(FactorialPower[a, k]/k!)delta[k, 0], {k, 0, 10}];

Wolfram Language code: Plot[{Sin[a], approx[a]}, {a, -Pi / 2, Pi / 2}]

ヌールルンド数の最初の10個：

Wolfram Language code: Table[NorlundB[n, n], {n, 10}]

積分定義と比較する：

Wolfram Language code: Table[Integrate[FactorialPower[x - 1, n], {x, 0, 1}], {n, 10}]//FunctionExpand

特性と関係 (11)

FactorialPowerのSumに対する関係はPowerのIntegrateに対する関係に等しい：

Wolfram Language code: Sum[FactorialPower[x, 5], x]

Wolfram Language code: Integrate[x ^ 5, x]

FactorialPowerはを満足する：

Wolfram Language code: DifferenceDelta[FactorialPower[x, n], x]

これで，FactorialPowerはPowerに類似していることになり，Dとの関係が決まる：

Wolfram Language code: D[x ^ n, x]

FactorialPowerは常にガンマ関数の比で表すことができる：

Wolfram Language code: FunctionExpand[FactorialPower[x, n]]

の展開と比較する：

Wolfram Language code: FunctionExpand[Pochhammer[x - n + 1, n]]

FactorialPower[x,n]はに等しい：

Wolfram Language code: FullSimplify[FactorialPower[x, n] == n!Binomial[x, n]]

FactorialPower[x,x]は x!と等価である：

Wolfram Language code: FunctionExpand[FactorialPower[x, x]]

Wolfram Language code: FunctionExpand[x!]

Pochhammerは単一のFactorialPower式で表すことができる：

Wolfram Language code: Pochhammer[a, n] == FactorialPower[a + n - 1, n]//FullSimplify

整数について恒等式を確認する：

Wolfram Language code: FullSimplify[Pochhammer[x, k] == FactorialPower[x, k, -1]//FunctionExpand, k∈ℤ]

この関数はしばしば昇階乗と呼ばれる：

Wolfram Language code: FactorialPower[x, 5, -1]//FunctionExpand

最初のいくつかのケースについて，PochhammerによるFactorialPowerの展開を検証する：

Wolfram Language code:

Table[FactorialPower[x, n] == Underoverscript[∑, k = 0, n](-1)^n - k(n!/k!)Binomial[n - 1, k - 1]Pochhammer[x, k]//FunctionExpand//Simplify, {n, 0, 9}]

FactorialPowerはDifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[FactorialPower[k, z], k]

Wolfram Language code: DifferenceRootReduce[FactorialPower[z, k], k]

FactorialPowerの母関数：

Wolfram Language code: GeneratingFunction[FactorialPower[n, k], n, x]

FactorialPowerの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[FactorialPower[n, k], n, x]

考えられる問題 (2)

一般に，PowerはFactorialPowerののときの極限として復元される：

Wolfram Language code: Series[FactorialPower[x, a, h], {h, 0, 1}]

しかし，が負の実軸上にあればこれは真ではないかもしれない：

Wolfram Language code: N[FactorialPower[-1 / 3, 1 + I, 10^-7], 20]

Wolfram Language code: N[(-1 / 3)^1 + I, 20]

原点付近の一般的な級数展開は整数点では定義されないことがある：

Wolfram Language code: Series[FactorialPower[x, n], {x, 0, 2}]

Wolfram Language code: Quiet[% /. n -> 2]

仮定を使って結果を細分化する：

Wolfram Language code: Assuming[Element[n, Integers] && n > 0, Series[FactorialPower[x, n], {x, 0, 2}]]

Wolfram Language code: % /. n -> 2

の明示的な値についての展開と比較する：

Wolfram Language code: Series[FactorialPower[x, 2], {x, 0, 2}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

FactorialPower

詳細

例題

例 (6)

スコープ (35)

数値評価 (7)

特定の値 (6)

可視化 (3)

関数の特性 (10)

微分 (3)

級数展開 (4)

関数の恒等式と簡約 (2)

アプリケーション (4)

特性と関係 (11)

考えられる問題 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

FactorialPower

詳細

例題

例 (6)

スコープ (35)

数値評価 (7)

特定の値 (6)

可視化 (3)

関数の特性 (10)

微分 (3)

級数展開 (4)

関数の恒等式と簡約 (2)

アプリケーション (4)

特性と関係 (11)

考えられる問題 (2)

関連項目

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX