Wolfram 语言与系统参考资料中心

FactorialPower

FactorialPower[x,n]

给出阶乘幂 .

FactorialPower[x,n,h]

给出步长为 h 的阶乘幂 .

范例

打开所有单元关闭所有单元

基本范例 (6)

求出 10 的“阶乘平方”：

Wolfram Language code: FactorialPower[10, 2]

FactorialPower 没有自动展开：

Wolfram Language code: FactorialPower[x, 8]

用 FunctionExpand 展开：

Wolfram Language code: FunctionExpand[%]

在实数的子集上绘图：

Wolfram Language code: Plot[FactorialPower[x, 3], {x, -3, 4}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[FactorialPower[z ^ 2, 5], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点处的级数展开式：

Wolfram Language code: Series[FactorialPower[x, 5], {x, 0, 5}]//FullSimplify

Infinity 处的级数展开式：

Wolfram Language code: Series[FactorialPower[x, 5], {x, ∞, 6}]//FullSimplify

范围 (35)

数值计算 (7)

数值计算：

Wolfram Language code: FactorialPower[2, .9]

Wolfram Language code: FactorialPower[4, 2]

高精度计算：

Wolfram Language code: N[FactorialPower[1 / 3, 7, 3], 50]

输出的精度与输入的精度一致：

Wolfram Language code: FactorialPower[0.100000000000000000, 7, 3]

复数输入：

Wolfram Language code: FactorialPower[1 + I, I, 3.]

高精度条件下进行高效计算：

Wolfram Language code: FactorialPower[1 / 3, 7, 3`100]//Timing

Wolfram Language code: FactorialPower[2`1000, 1 / 5, 1 / 3];//Timing

FactorialPower 按照元素作用于列表：

Wolfram Language code: FactorialPower[4, {1, 2, 3, 4, 5}]

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: FactorialPower[0.3, 0.4, Interval[{0.5, 0.6}]]

Wolfram Language code: FactorialPower[1 / 2, 1 / 3, CenteredInterval[1 / 5, 1 / 1000]]

或者用 Around 计算普通的统计区间：

Wolfram Language code: FactorialPower[Around[2, 0.01], 2]

计算数组中每个元素的值：

Wolfram Language code: FactorialPower[{{1, 2}, {3, 4}}, 2]

或者用 MatrixFunction 计算矩阵形式的 FactorialPower 函数：:

Wolfram Language code: MatrixFunction[FactorialPower[#, .2]&, {{1, 2}, {3, 4}}]

特殊值 (6)

在固定点处的 FactorialPower 的值：

Wolfram Language code: Table[FactorialPower[x, 2], {x, 1, 5}]

获取 n 的整数值的多项式表示 FactorialPower[x,n]：

Wolfram Language code: FactorialPower[x, 4]//FunctionExpand

步长时，FactorialPower[x,n,h] 给出升阶乘：

Wolfram Language code: FunctionExpand[FactorialPower[x, 5, -1]]

这与 Pochhammer 等价：

Wolfram Language code: Pochhammer[x, 5]

对固定的 x 值展开 FactorialPower[x,n]：

Wolfram Language code: FactorialPower[(3/2), n]//FunctionExpand

同样，为第三个参数添加整数值：

Wolfram Language code: Table[FactorialPower[(3/2), n, h], {h, 0, 3}]//FunctionExpand

第二个参数为零的值：

Wolfram Language code: FactorialPower[n, 0]

第一个参数为 0，第二个参数为正的值：

Wolfram Language code: FullSimplify[FactorialPower[0, n], n∈PositiveIntegers]//Quiet

求当 FactorialPower[x,1/7]=1.2 时 x 的值：

Wolfram Language code: xval = x /. FindRoot[FactorialPower[ x , 1 / 7] == 1.2, {x, 3}]

Wolfram Language code:

Plot[FactorialPower[x, 1 / 7], {x, 0, 10}, Epilog -> Style[Point[{xval, FactorialPower[xval, 1 / 7]}], PointSize[Large], Red]]

可视化 (3)

绘制各阶 FactorialPower 函数：

Wolfram Language code: Plot[{FactorialPower[x, 1], FactorialPower[x, 2], FactorialPower[x, 3], FactorialPower[x, 4]}, {x, -3, 3}]

绘制作为参数的函数的 FactorialPower:

Wolfram Language code:

Plot[{FactorialPower[1 / 2, n], FactorialPower[1, n], FactorialPower[3 / 2, n], FactorialPower[2, n]}, {n, -4, 4}, PlotLegends -> "Expressions"]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[FactorialPower[z, 5]], {z, -1 - 2I, 1 + 2 I}, Contours -> 20]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[FactorialPower[z, 5]], {z, -1 - 2I, 1 + 2 I}, Contours -> 20]

函数的属性 (10)

阶乘幂的实域：

Wolfram Language code: FunctionDomain[FactorialPower[x, y], {x, y}]

复定义域：

Wolfram Language code: FunctionDomain[FactorialPower[w, z], {w, z}, Complexes]

不同 n 固定值下 FactorialPower[x,n] 的函数范围：

Wolfram Language code: Table[FunctionRange[FactorialPower[x, n], x, y], {n, {0, 1 / 2, 1, 2}}]

是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[FactorialPower[x, 3], x]

既非递减，也非递增：

Wolfram Language code: FunctionMonotonicity[FactorialPower[x, 3], x]

不是单射函数：

Wolfram Language code: FunctionInjective[FactorialPower[x, 3], x]

Wolfram Language code: Plot[{FactorialPower[x, 3], .2}, {x, -1, 3}]

是满射函数：

Wolfram Language code: FunctionSurjective[FactorialPower[x, 3], x]

Wolfram Language code: Plot[{FactorialPower[x, 3], 10}, {x, -5, 5}]

FactorialPower 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[FactorialPower[x, 1], x]

当是负整数时，可能有奇点和断点：

Wolfram Language code: FunctionSingularities[FactorialPower[x, y], {x, y}]

Wolfram Language code: FunctionDiscontinuities[FactorialPower[x, y], {x, y}]

既不凸，也不凹：

Wolfram Language code: FunctionConvexity[FactorialPower[x, 3], x]

TraditionalForm 格式：

Wolfram Language code: FactorialPower[x, n]//TraditionalForm

Wolfram Language code: FactorialPower[x, n, h]//TraditionalForm

微分 (3)

关于的一阶导数：

Wolfram Language code: D[FactorialPower[x, n], x]

关于的一阶导数：

Wolfram Language code: D[FactorialPower[x, n], n]

关于的高次导数：

Wolfram Language code: Table[D[FactorialPower[x, n], {x, k}], {k, 1, 3}]//FullSimplify

绘制当 n=2，关于 x 的更高阶导数：

Wolfram Language code:

Plot[Evaluate[% /. n -> 1 / 2], {x, -3, 0}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

级数展开 (4)

用 Series 求泰勒展开式：

Wolfram Language code: Series[FactorialPower[x, n], {x, 0, 2}]//Normal// FullSimplify

绘制附近前 2 个近似式：

Wolfram Language code:

funcAndSeries = Prepend[Table[Series[FactorialPower[x, 3], {x, 0, m}], {m, 1, 2}], FactorialPower[x, 3]]//Normal;
Plot[funcAndSeries, {x, -10, 10}]

普通点处的泰勒展开式：

Wolfram Language code: Series[FactorialPower[x, n], {x, x0, 2}]//Normal// FullSimplify

奇点处的级数展开式：

Wolfram Language code: Series[FactorialPower[x, 4], {x, -1, 3}]

FactorialPower 可以应用于幂级数中：

Wolfram Language code: FactorialPower[x + O[x] ^ 5, 10]

函数恒等与化简 (2)

对于正整数 $TemplateBox[{x, n}, FactorialPower]= ((-1)^n TemplateBox[{{n, -, x}}, Gamma])/(TemplateBox[{{-, x}}, Gamma])$ ：

Wolfram Language code: FunctionExpand[FactorialPower[x, n], {Element[n, Integers] && n > 0}]

递推关系：

Wolfram Language code: x FactorialPower[x, n] == FactorialPower[x, n + 1] + n FactorialPower[x, n]//FullSimplify

应用 (4)

由 FactorialPower[n,r] 给出一个由不同元素组成的长度为 n 的列表的长度为 r 的排列组合的数量：

Wolfram Language code: Length[Permutations[Range[5], {3}]]

Wolfram Language code: FactorialPower[5, 3]

不同数字的三元组的数量：

Wolfram Language code: FactorialPower[10, 3]

Wolfram Language code: Count[Tuples[Range[10], {3}], x_ /; DeleteDuplicates[x] === x]

用牛顿前向差分公式的一个函数的近似[MathWorld]：

Wolfram Language code: delta[k_, x_] = DifferenceDelta[Sin[x], {x, k}]

通过截取级数来构建一个近似：

Wolfram Language code: approx[a_] = Sum[(FactorialPower[a, k]/k!)delta[k, 0], {k, 0, 10}];

Wolfram Language code: Plot[{Sin[a], approx[a]}, {a, -Pi / 2, Pi / 2}]

前十个诺兰的数字 (Nørlund numbers)：

Wolfram Language code: Table[NorlundB[n, n], {n, 10}]

与其积分定义对比：

Wolfram Language code: Table[Integrate[FactorialPower[x - 1, n], {x, 0, 1}], {n, 10}]//FunctionExpand

属性和关系 (11)

FactorialPower 是关于 Sum 的操作，就像 Power 是关于 Integrate 的操作：

Wolfram Language code: Sum[FactorialPower[x, 5], x]

Wolfram Language code: Integrate[x ^ 5, x]

FactorialPower 满足：

Wolfram Language code: DifferenceDelta[FactorialPower[x, n], x]

这使得 FactorialPower 类似于 Power 及其与 D 的关系：

Wolfram Language code: D[x ^ n, x]

FactorialPower 总可以被表示为伽玛函数的比率：

Wolfram Language code: FunctionExpand[FactorialPower[x, n]]

与的展开相比较：

Wolfram Language code: FunctionExpand[Pochhammer[x - n + 1, n]]

FactorialPower[x,n] 等价于 :

Wolfram Language code: FullSimplify[FactorialPower[x, n] == n!Binomial[x, n]]

FactorialPower[x,x] 等价于 x!：

Wolfram Language code: FunctionExpand[FactorialPower[x, x]]

Wolfram Language code: FunctionExpand[x!]

Pochhammer 可以用一个 FactorialPower 表达式来表示：

Wolfram Language code: Pochhammer[a, n] == FactorialPower[a + n - 1, n]//FullSimplify

验证对于整数有恒等：

Wolfram Language code: FullSimplify[Pochhammer[x, k] == FactorialPower[x, k, -1]//FunctionExpand, k∈ℤ]

这个函数通常被称为升阶乘：

Wolfram Language code: FactorialPower[x, 5, -1]//FunctionExpand

验证前几种情况中用 Pochhammer 对 FactorialPower 的展开：

Wolfram Language code:

Table[FactorialPower[x, n] == Underoverscript[∑, k = 0, n](-1)^n - k(n!/k!)Binomial[n - 1, k - 1]Pochhammer[x, k]//FunctionExpand//Simplify, {n, 0, 9}]

FactorialPower 可用 DifferenceRoot 进行表示：

Wolfram Language code: DifferenceRootReduce[FactorialPower[k, z], k]

Wolfram Language code: DifferenceRootReduce[FactorialPower[z, k], k]

FactorialPower 的母函数：

Wolfram Language code: GeneratingFunction[FactorialPower[n, k], n, x]

FactorialPower 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[FactorialPower[n, k], n, x]

可能存在的问题 (2)

一般，作为时 FactorialPower 的极限，Power 回升：

Wolfram Language code: Series[FactorialPower[x, a, h], {h, 0, 1}]

这可能不为真，然而，如果保持在负实数轴上：

Wolfram Language code: N[FactorialPower[-1 / 3, 1 + I, 10^-7], 20]

Wolfram Language code: N[(-1 / 3)^1 + I, 20]

在原点周围的级数展开可能在整数点没有定义：

Wolfram Language code: Series[FactorialPower[x, n], {x, 0, 2}]

Wolfram Language code: Quiet[% /. n -> 2]

用假设细化结果：

Wolfram Language code: Assuming[Element[n, Integers] && n > 0, Series[FactorialPower[x, n], {x, 0, 2}]]

Wolfram Language code: % /. n -> 2

与的明确值相比较：

Wolfram Language code: Series[FactorialPower[x, 2], {x, 0, 2}]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

FactorialPower

更多信息

范例

基本范例 (6)

范围 (35)

数值计算 (7)

特殊值 (6)

可视化 (3)

函数的属性 (10)

微分 (3)

级数展开 (4)

函数恒等与化简 (2)

应用 (4)

属性和关系 (11)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

FactorialPower

更多信息

范例

基本范例 (6)

范围 (35)

数值计算 (7)

特殊值 (6)

可视化 (3)

函数的属性 (10)

微分 (3)

级数展开 (4)

函数恒等与化简 (2)

应用 (4)

属性和关系 (11)

可能存在的问题 (2)

参见

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX