FindDistributionParameters

FindDistributionParameters[data,dist]

data から分布 dist の母数推定を求める．

FindDistributionParameters[data,dist,{{p,p₀},{q,q₀},…}]

初期値が p₀, q₀, …の母数 p, q, …を求める．

詳細とオプション

FindDistributionParametersは dist 中の母数のための置換規則のリストを返す．
data は与えられた分布 dist からの可能な結果のリストでなければならない．
分布 dist は任意の一変量あるいは多変量のパラメトリック分布，あるいは母数が不明の派生分布でよい．
使用可能なオプション

AccuracyGoal	Automatic	目標確度
ParameterEstimator	"MaximumLikelihood"	使用する母数推定量
PrecisionGoal	Automatic	目標精度
WorkingPrecision	Automatic	内部計算に使用する精度

ParameterEstimatorでは次の基本的な設定値が使用できる．

	"MaximumLikelihood"	対数尤度関数を最大化
	"MethodOfMoments"	原点の周りのモーメントをマッチ
	"MethodOfCentralMoments"	中心モーメントをマッチ
	"MethodOfCumulants"	キュムラントをマッチ
	"MethodOfFactorialMoments"	階乗モーメントをマッチ

最尤法は対数尤度関数を最大化しようとする．ただし，は分布母数でありは分布の確率密度関数である．
モーメント法は , , を解く．ただし，は次サンプルモーメントであり，は母数の分布の次モーメントである．
モーメント法に基づく推定量は母数についてのすべての制約を満たさないことがある．

例題

すべて開くすべて閉じる

例 (3)

ラプラス(Laplace)分布を仮定して母数の最尤推定量を求める：

Wolfram Language code: FindDistributionParameters[{1.5, 2.8, 4.3, .5}, LaplaceDistribution[μ, σ]]

モーメント法による推定を求める：

Wolfram Language code: FindDistributionParameters[{1.5, 2.8, 4.3, .5}, LaplaceDistribution[μ, σ], ParameterEstimator -> "MethodOfMoments"]

多変量分布の母数を推定する：

Wolfram Language code: data = RandomVariate[DirichletDistribution[{3, 4, 5}], 100];

Wolfram Language code: params = FindDistributionParameters[data, DirichletDistribution[{Subscript[α, 1], Subscript[α, 2], Subscript[α, 3]}]]

もとの確率密度関数と推定された確率密度関数の差を比較する：

Wolfram Language code:

Plot3D[PDF[DirichletDistribution[{Subscript[α, 1], Subscript[α, 2], Subscript[α, 3]}] /. params, {x, y}] - PDF[DirichletDistribution[{3, 4, 5}], {x, y}], {x, 0, 1}, {y, 0, 1}, PlotRange -> All]

単位付きの数量から母数を推定する：

Wolfram Language code: data = RandomVariate[LaplaceDistribution[Quantity[100, "Grams"], Quantity[500, "Milligrams"]], 100]

Wolfram Language code: FindDistributionParameters[data, LaplaceDistribution[m, s]]

スコープ (15)

基本的な用法 (5)

二項分布の両方の母数を推定する：

Wolfram Language code: bdata = {23, 16, 24, 17, 16, 17, 18, 17, 19, 23, 19, 13, 19, 18, 22, 21, 19, 22, 19, 23};

Wolfram Language code: FindDistributionParameters[bdata, BinomialDistribution[n, p]]

nが既知であると仮定してpを推定する：

Wolfram Language code: FindDistributionParameters[bdata, BinomialDistribution[50, p]]

pが既知であると仮定してnを推定する：

Wolfram Language code: FindDistributionParameters[bdata, BinomialDistribution[n, 2 / 5]]

特定の族に対する母数の最尤推定量を持つ分布を得る：

Wolfram Language code: vals = RandomReal[ChiSquareDistribution[20], 1000];

Wolfram Language code: res = FindDistributionParameters[vals, ChiSquareDistribution[n]]

データのヒストグラムと推定値の確率密度関数を比較することで適合度をチェックする：

Wolfram Language code: Show[Histogram[vals, Automatic, "ProbabilityDensity"], Plot[PDF[ChiSquareDistribution[n] /. res, x], {x, 0, 50}]]

res からの零分布で適合度検定を行う：

Wolfram Language code: DistributionFitTest[vals, ChiSquareDistribution[n] /. res, {"TestDataTable", All}]

母数推定を補正して検定を行う：

Wolfram Language code: DistributionFitTest[vals, ChiSquareDistribution[n], {"TestDataTable", All}]

対数尤度を最大化することで母数を推定する：

Wolfram Language code: data = RandomVariate[GeometricDistribution[.4], 100];

Wolfram Language code: phat = FindDistributionParameters[data, GeometricDistribution[p]]

対数尤度関数をプロットし，解が最適であることを視覚的に確かめる：

Wolfram Language code:

Show[Plot[LogLikelihood[GeometricDistribution[p], data], {p, 0, 1}], Graphics[{PointSize[Large], Red, Point[{p, LogLikelihood[GeometricDistribution[p], data]} /. phat]}]]

対数尤度曲面を可視化して母数の大まかな数値を求める：

Wolfram Language code: data = BlockRandom[SeedRandom[100];RandomVariate[WeibullDistribution[4, 5], 50]];

Wolfram Language code: cp = ContourPlot[LogLikelihood[WeibullDistribution[α, β], data], {α, 2, 6}, {β, 3, 8}]

この大まかな値を推定のための初期値として与える：

Wolfram Language code: params = FindDistributionParameters[data, WeibullDistribution[α, β], {{α, 3}, {β, 5.5}}]

等高線プロット上で最適な点をマークする：

Wolfram Language code: Show[cp, Graphics[{PointSize[Large], Red, Point[{α, β} /. params]}]]

ポアソン(Poisson)データの正規近似を推定する：

Wolfram Language code: data = RandomVariate[PoissonDistribution[20], 100];

Wolfram Language code: FindDistributionParameters[data, NormalDistribution[μ, σ]]

推定値を20桁まで求める：

Wolfram Language code: FindDistributionParameters[data, NormalDistribution[μ, σ], WorkingPrecision -> 20]

一変量パラメトリック分布 (2)

連続分布の母数を推定する：

Wolfram Language code:

data = {0.8, 0.98, 0.66, 0.09, 0.03, 0.16, 0.88, 0.32, 0.56, 0.3, 0.82, 0.34, 0.93, 0.33, 0.25, 0.74, 0.3, 0.74, 0.16, 0.02};

Wolfram Language code: FindDistributionParameters[data, BetaDistribution[α, β]]

離散分布の母数を推定する：

Wolfram Language code: data = {16, 1, 2, 5, 3, 5, 1, 6, 4, 14, 2, 9, 1, 1, 2, 2, 8, 1, 3, 1};

Wolfram Language code: param = FindDistributionParameters[data, LogSeriesDistribution[θ]]

フィットされた累積分布関数と経験累積分布関数を比較する：

Wolfram Language code: Plot[{CDF[LogSeriesDistribution[θ] /. param, x], CDF[EmpiricalDistribution[data], x]}, {x, 0, 20}, Exclusions -> None]

多変量パラメトリック分布 (2)

多変量離散分布の母数を推定する：

Wolfram Language code: mdata = RandomVariate[MultinomialDistribution[20, {1 / 3, 1 / 6, 1 / 10, 2 / 5}], 1000];

Wolfram Language code:

FindDistributionParameters[mdata, MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3], Subscript[p, 4]}]]

多変量連続分布の母数を推定する：

Wolfram Language code: data = RandomVariate[BinormalDistribution[{1, 2}, {1 / 3, 4}, 3 / 4], 1000];

Wolfram Language code:

params = FindDistributionParameters[data, BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {Subscript[σ, 1], Subscript[σ, 2]}, ρ]]

周辺分布の密度関数を可視化する：

Wolfram Language code:

Table[Plot[PDF[NormalDistribution[Subscript[μ, i], Subscript[σ, i]] /. params, x], {x, Min[data[[All, i]]], Max[data[[All, i]]]}, PlotRange -> All], {i, 2}]//Row

式から共分散行列を得る：

Wolfram Language code:

{{Subscript[σ, 1]^2, Subscript[σ, 1] Subscript[σ, 2] ρ}, {Subscript[σ, 1] Subscript[σ, 2] ρ, Subscript[σ, 2]^2}} /. params//MatrixForm

派生分布 (6)

切断正規分布の母数を推定する：

Wolfram Language code:

SeedRandom[1];
data = RandomVariate[TruncatedDistribution[{-1, 2}, NormalDistribution[1, 1 / 3]], 100];

Wolfram Language code: FindDistributionParameters[data, TruncatedDistribution[{min, max}, NormalDistribution[μ, σ]]]

構成分布の母数を推定する：

Wolfram Language code: dist = ProbabilityDistribution[λ Exp[λ(1 - x)], {x, 1, Infinity}, Assumptions -> λ > 0]

Wolfram Language code: data = {1.4, 5.1, 1.7, 1.6, 1.1, 3.9, 2.2, 1.3, 2., 1.5};

Wolfram Language code: param = FindDistributionParameters[data, dist]

最適点を可視化する：

Wolfram Language code:

Plot[LogLikelihood[dist, data], {λ, .1, 2}, Epilog -> {PointSize[Medium], Red, Point[{λ, LogLikelihood[dist, data]} /. param]}]

積分布の母数を推定する：

Wolfram Language code: data = RandomVariate[ProductDistribution[BetaDistribution[2, 3], LaplaceDistribution[10, 1]], 100];

Wolfram Language code: FindDistributionParameters[data, ProductDistribution[BetaDistribution[α, β], LaplaceDistribution[μ, σ]]]

コピュラ分布の母数を推定する：

Wolfram Language code: data = RandomVariate[CopulaDistribution[{"Frank", 1 / 2}, {GammaDistribution[2, 3], ChiSquareDistribution[10]}], 100];

Wolfram Language code:

FindDistributionParameters[data, CopulaDistribution[{"Frank", c}, {GammaDistribution[α, β], ChiSquareDistribution[n]}]]

成分混合分布の母数を推定する：

Wolfram Language code: data = RandomVariate[MixtureDistribution[{2 / 3, 1 / 3}, {GammaDistribution[2, 3], NormalDistribution[1, 1 / 4]}], 100];

Wolfram Language code: 𝒟1 = MixtureDistribution[{p, 1 - p}, {GammaDistribution[α, β], NormalDistribution[μ, σ]}];

Wolfram Language code: param1 = FindDistributionParameters[data, 𝒟1]//Quiet

成分分布が既知であると仮定して混合確率を推定する：

Wolfram Language code: 𝒟2 = MixtureDistribution[{p, 1 - p}, {GammaDistribution[2, 3], NormalDistribution[1, 1 / 4]}];

Wolfram Language code: param2 = FindDistributionParameters[data, 𝒟2]

データに対する2つの推定を可視化する：

Wolfram Language code:

Show[Histogram[data, {0, 20, .5}, "PDF"], Plot[{PDF[𝒟1 /. param1, x], PDF[𝒟2 /. param2, x]}, {x, 0, 20}, PlotRange -> All, PlotLegends -> {"𝒟1", "𝒟2"}]]

指定された単位の分布についての母数を推定する：

Wolfram Language code: data = RandomVariate[QuantityDistribution[ParetoDistribution[2, 3], "Mega" * "USDollars"], 100]

Wolfram Language code: FindDistributionParameters[data, QuantityDistribution[ParetoDistribution[minSalary, α], "USDollars"]]

オプション (4)

ParameterEstimator (3)

キュムラントをマッチして母数を推定する：

Wolfram Language code: data = RandomVariate[ParetoDistribution[2, 8, 5], 1000];

Wolfram Language code: FindDistributionParameters[data, ParetoDistribution[α, β, μ], ParameterEstimator -> "MethodOfCumulants"]

他のモーメントに基づくメソッドも一般に同じような結果を与える：

Wolfram Language code: FindDistributionParameters[data, ParetoDistribution[α, β, μ], ParameterEstimator -> "MethodOfCentralMoments"]

Wolfram Language code: FindDistributionParameters[data, ParetoDistribution[α, β, μ], ParameterEstimator -> "MethodOfFactorialMoments"]

デフォルトモーメントに基づく母数を推定する：

Wolfram Language code: data = RandomVariate[NormalDistribution[2, 3], 1000];

Wolfram Language code: FindDistributionParameters[data, NormalDistribution[μ, σ], ParameterEstimator -> "MethodOfMoments"]

第1および第4モーメントから母数を推定する：

Wolfram Language code:

FindDistributionParameters[data, NormalDistribution[μ, σ], ParameterEstimator -> {"MethodOfMoments", "MomentOrders" -> {1, 4}}]

デフォルトのメソッドで最尤度推定を得る：

Wolfram Language code: data = RandomVariate[BetaDistribution[2, 3], 1000];

Wolfram Language code: FindDistributionParameters[data, BetaDistribution[α, β]]

FindMaximumを使って推定する：

Wolfram Language code:

FindDistributionParameters[data, BetaDistribution[α, β], ParameterEstimator -> {"MaximumLikelihood", Method -> "FindMaximum"}]

EvaluationMonitorを使ってサンプル点を抽出する：

Wolfram Language code:

{params, {points}} = Reap[FindDistributionParameters[data, BetaDistribution[α, β], ParameterEstimator -> {"MaximumLikelihood", Method -> {"FindMaximum", EvaluationMonitor :> Sow[{α, β}]}}]];

サンプルとしての一連のとの値を可視化する：

Wolfram Language code: ListLogPlot[Transpose[points], PlotLegends -> {"α", "β"}]

WorkingPrecision (1)

デフォルトで，連続母数に機械精度を使う：

Wolfram Language code: data = RandomVariate[GumbelDistribution[2, 5], 100, WorkingPrecision -> 50];

Wolfram Language code: FindDistributionParameters[data, GumbelDistribution[α, β]]

より高精度の結果を得る：

Wolfram Language code: FindDistributionParameters[data, GumbelDistribution[α, β], WorkingPrecision -> 25]

アプリケーション (17)

母数が1つの推定器を使って別の推定器の初期値を求める (1)

Wolfram Language code: data = {11.3, 19.2, 8.7, 17.5, 7., 17.1, 8.5, 9.8, 15.2, 10.4, 17.9, 20.3, 6.5, 7.9, 11.8, 8.5, 12.8, 14.2, 6.6, 9.};

モーメント法による推定値を求める：

Wolfram Language code: mm = FindDistributionParameters[data, ChiSquareDistribution[n], ParameterEstimator -> "MethodOfMoments"]

モーメント法による推定値を最尤法推定の初期値として使う：

Wolfram Language code: FindDistributionParameters[data, ChiSquareDistribution[n], mm /. Rule -> List]

ガンマ分布の最尤法推定を求める：

Wolfram Language code: mle = FindDistributionParameters[data, GammaDistribution[α, β]]

これらをモーメント法の初期値として使う：

Wolfram Language code:

FindDistributionParameters[data, GammaDistribution[α, β], mle /. Rule -> List, ParameterEstimator -> "MethodOfMoments"]

他の推定のための初期値を得る (1)

ExponentialPowerDistributionからデータのラプラス母数を推定する：

Wolfram Language code: data = RandomVariate[ExponentialPowerDistribution[1.4, 2, 1 / 3], 1000];

Wolfram Language code: lparams = FindDistributionParameters[data, LaplaceDistribution[μ, σ]]

指数ベキの母数推定のための初期点としてラプラス推定を使う：

Wolfram Language code:

exppow = FindDistributionParameters[data, ExponentialPowerDistribution[k, μ, σ], Join[{{k, 1}}, lparams /. Rule -> List]]

データをラプラス推定および指数ベキ推定と比較する：

Wolfram Language code:

Show[Histogram[data, Automatic, "PDF"], Plot[{PDF[LaplaceDistribution[μ, σ] /. lparams, x], PDF[ExponentialPowerDistribution[k, μ, σ] /. exppow, x]}, {x, 0, 5}, PlotRange -> All, PlotLegends -> {LaplaceDistribution, ExponentialPowerDistribution}]]

形状が類似した分布の母数推定 (1)

対数正規分布に従うデータをガンマ分布でモデル化する：

Wolfram Language code: lnorm = LogNormalDistribution[2, 0.3];

Wolfram Language code: sample = RandomVariate[lnorm, 10 ^ 4];

Wolfram Language code: edist = FindDistributionParameters[sample, GammaDistribution[α, β]]

シミュレーションの分布を推定分布と比較する：

Wolfram Language code:

Plot[{PDF[lnorm, x], PDF[GammaDistribution[α, β] /. edist, x]}, {x, 0, 25}, PlotLegends -> {LogNormalDistribution, GammaDistribution}]

事故による保険金請求 (1)

保険会社の保険契約1件あたりの1年間の保険金請求額：

Wolfram Language code:

AccidentsPerPolicy = {ConstantArray[0, {81714}], ConstantArray[1, {11306}], ConstantArray[2, {1618}], ConstantArray[3, {250}], ConstantArray[4, {40}], ConstantArray[5, {7}]}//Flatten;

保険金請求についての1シフトした対数級数分布の母数を推定する：

Wolfram Language code: edist = FindDistributionParameters[AccidentsPerPolicy + 1, LogSeriesDistribution[θ]]

推定が最大結果を与えることに注意：

Wolfram Language code:

Show[Plot[LogLikelihood[LogSeriesDistribution[θ], AccidentsPerPolicy + 1], {θ, 0.2, .3}], Graphics[{PointSize[Medium], Red, Point[{θ, LogLikelihood[LogSeriesDistribution[θ], AccidentsPerPolicy + 1]} /. edist]}]]

さまざまな言語における単語長 (1)

いくつかの言語について単語の長さを調べる：

Wolfram Language code: languages = {"Dutch", "English", "French", "German", "Hebrew", "Polish", "Russian", "Spanish", "Swedish"};

Wolfram Language code: worddata = Table[StringLength /@ DictionaryLookup[{l, All}], {l, languages}];

各言語の単語長をの二項分布としてモデル化する：

Wolfram Language code: binom = Table[FindDistributionParameters[i, BinomialDistribution[40, p]], {i, worddata}]

実際の分布と推定分布を比較する：

Wolfram Language code:

Partition[Table[Show[Histogram[worddata[[i]], {Range[25] - 1 / 2}, "ProbabilityDensity", PlotLabel -> languages[[i]]], DiscretePlot[PDF[BinomialDistribution[40, p /. binom[[i]]], x], {x, 0, 25}, PlotRange -> All, PlotStyle -> PointSize[.02]]], {i, Length[languages]}], 3]//Grid

この9つの結果に基づいて p 値の分布をブートストラップする：

Wolfram Language code: bootstrap = Mean[RandomChoice[p /. binom, {9, 10000}]];

Wolfram Language code: Histogram[bootstrap, Automatic, "ProbabilityDensity"]

p の期待値と推定のための標準偏差を推定する：

Wolfram Language code: FindDistributionParameters[bootstrap, NormalDistribution[p, Subscript[σ, p]]]

テキスト頻度 (1)

テキスト中の語数はZipf分布に従う：

Wolfram Language code: text = ExampleData[{"Text", "OriginOfSpecies"}, "Words"];

Wolfram Language code: wordCount = Tally[text][[All, 2]];

ZipfDistributionを単語の頻度データにフィットする：

Wolfram Language code: rhohat = FindDistributionParameters[wordCount, ZipfDistribution[ρ]]

rhohat を初期値として使い，切断ZipfDistributionを最大50カウントでフィットする：

Wolfram Language code: rhohat50 = FindDistributionParameters[Select[wordCount, # ≤ 50&], ZipfDistribution[50, ρ], rhohat /. Rule -> List]

切断値までの累積分布関数を可視化する：

Wolfram Language code:

Plot[{CDF[d1 = ZipfDistribution[ρ] /. rhohat, x], CDF[d2 = ZipfDistribution[50, ρ] /. rhohat50, x]}, {x, 0, 50}, PlotLegends -> {d1, d2}]

もとのデータの切断モデルに含まれない部分を推定する：

Wolfram Language code: Probability[x > 50, xZipfDistribution[ρ]]

Wolfram Language code: % /. rhohat

地震のマグニチュード (1)

多峰MixtureDistributionモデルの推定値を求める：

Wolfram Language code: ExampleData[{"Statistics", "USEarthquakes"}, "ColumnDescriptions"]

Wolfram Language code: magnitudes = Select[ExampleData[{"Statistics", "USEarthquakes"}], #[[1]] ≥ 1935&][[All, 7]];

選択された年代における米国の地震のマグニチュードには2つのモードがある：

Wolfram Language code: h = Histogram[magnitudes, 20, "ProbabilityDensity"]

あるNormalDistributionと別の正規分布との可能な混合から分布をフィットする：

Wolfram Language code: dist = MixtureDistribution[{p, 1 - p}, {NormalDistribution[a, b], NormalDistribution[c, d]}];

Wolfram Language code: params = FindDistributionParameters[magnitudes, dist]//Quiet

成分の平均を抽出する：

Wolfram Language code: means = {a, c} /. params

成分の平均は非常に離れているので，それぞれがモードであると十分に考えられる：

Wolfram Language code:

Plot[PDF[dist /. params, x], {x, 2, 8}, PlotRange -> All, Epilog -> {Red, PointSize[Medium], Point[Table[{i, PDF[dist /. params, i]}, {i, means}]]}]

風速分析 (1)

ボストンの月間最大風速をモデル化する：

Wolfram Language code: maxWinds = WeatherData["Boston", "MaxWindSpeed", {{1950, 1, 1}, {2009, 12, 31}, "Month"}, "Value"]//QuantityMagnitude;

データをRayleighDistributionにフィットする：

Wolfram Language code: rparam = FindDistributionParameters[maxWinds, RayleighDistribution[θ]]

ExtremeValueDistributionにフィットする：

Wolfram Language code: evparams = FindDistributionParameters[maxWinds, ExtremeValueDistribution[a, b]]

経験的変位値とフィットされた変位値を比較してどこでモデルがデータから逸脱しているかを見る：

Wolfram Language code:

Row[Table[QuantilePlot[maxWinds, i, PlotLabel -> Head[i]], {i, {RayleighDistribution[θ] /. rparam, ExtremeValueDistribution[a, b] /. evparams}}]]

所得分布 (1)

大規模州立大学の所得をモデル化する：

Wolfram Language code: ExampleData[{"Statistics", "UniversitySalaries"}, "ColumnDescriptions"]

Wolfram Language code:

universityA = Cases[ExampleData[{"Statistics", "UniversitySalaries"}], {dept_, perc_, salary_, campus : "A"} :> {perc, salary}];

Wolfram Language code: salaries = Cases[universityA, {p_ ? Positive, s_ ? Positive} :> s / p];

給与がDagum分布に従うと仮定する：

Wolfram Language code: dparams = FindDistributionParameters[salaries, DagumDistribution[p, a, b]]

給与がより一般的なパレート分布に従うと仮定する：

Wolfram Language code:

pparams = FindDistributionParameters[salaries, ParetoDistribution[k, α, γ, μ], ParameterEstimator -> {"MaximumLikelihood", "Method" -> "SimulatedAnnealing"}]

推定分布の微妙な違いを比較する：

Wolfram Language code:

Show[Histogram[salaries, {0, 200000, 10000}, "PDF"], Plot[{PDF[DagumDistribution[p, a, b] /. dparams, x], PDF[ParetoDistribution[k, α, γ, μ] /. pparams, x]}, {x, 0, 200000}, PlotLegends -> {DagumDistribution, ParetoDistribution}]]

株式価値の市場変動 (1)

ベータ分布を使ってダウ平均の株式のうちその日に値上がりしたものの割合をモデル化する：

Wolfram Language code: dji = EntityList[EntityClass["Financial", "DowJonesIndustrialAverageComponents"]]

ダウ平均の株価の日々の値動きを求める：

Wolfram Language code:

Clear[djichange];djichange = DeleteMissing @Table[FinancialData[tick, "FractionalChange", {{2009, 3, 1}, {2013, 3, 1}, "Day"}, "Value"], {tick, dji}];

各金融実体についての日数：

Wolfram Language code: days = First[djichange]["PathLength"]

各実体についての時系列から値を抽出し，数値量を正規化する：

Wolfram Language code: djichangevals = Normal /@ Values /@ djichange;

各実体のデータが同じ長さかどうかチェックする：

Wolfram Language code: ArrayQ[djichangevals]

Wolfram Language code: MatrixPlot[djichangevals, AspectRatio -> 1, FrameLabel -> {"Company", "Day"}]

1日のうちで株価が上昇した企業の割合を計算する：

Wolfram Language code: ratios = Table[Count[djichangevals[[All, i]], _ ? Positive] / Length[dji], {i, days}];

株価が上昇した企業がない日とすべての企業の株価が上昇した日を除き，母数推定を求める：

Wolfram Language code:

posratios = Select[ratios, 0 < # < 1&];
bparams = FindDistributionParameters[posratios, BetaDistribution[α, β]]

尤度曲線を可視化し最適点に印を付ける：

Wolfram Language code:

ContourPlot[LogLikelihood[BetaDistribution[α, β], posratios], {α, 1, 1.5}, {β, 1, 1.4}, Epilog -> {Red, PointSize[Large], Point[{α, β} /. bparams]}]

自動車の燃費 (1)

中型車の市街地と高速道路における平均走行可能距離は二変量正規分布に従う：

Wolfram Language code:

midsizeMPG2009 = {{16, 22}, {18, 26}, {17, 25}, {16, 23}, {16, 23}, {14, 19}, {13, 19}, {10, 14}, {10, 17}, {18, 28}, {18, 27}, {17, 25}, {17, 25}, {17, 26}, {17, 26}, {16, 25}, {17, 25}, {15, 22}, {15, 23}, {11, 17}, {11, 17}, {17, 28}, {16, 24}, {16, 25}, {16, 25}, {17, 26}, {18, 26}, {17, 26}, {17, 25}, {17, 26}, {13, 19}, {15, 24}, {17, 26}, {15, 22}, {22, 33}, {22, 30}, {18, 29}, {17, 26}, {26, 34}, {21, 30}, {13, 20}, {19, 27}, {16, 27}, {21, 30}, {13, 20}, {19, 27}, {16, 27}, {24, 30}, {23, 27}, {23, 29}, {21, 25}, {19, 27}, {10, 15}, {9, 16}, {17, 25}, {20, 29}, {20, 28}, {18, 26}, {24, 33}, {25, 33}, {16, 25}, {15, 23}, {22, 32}, {22, 32}, {20, 28}, {23, 30}, {24, 32}, {19, 27}, {19, 26}, {18, 25}, {17, 24}, {16, 24}, {16, 23}, {16, 24}, {16, 23}, {20, 22}, {17, 25}, {20, 29}, {20, 28}, {18, 26}, {17, 24}, {18, 28}, {20, 29}, {21, 30}, {17, 25}, {18, 25}, {23, 32}, {17, 24}, {16, 22}, {15, 22}, {13, 19}, {13, 20}, {20, 27}, {16, 25}, {23, 32}, {23, 31}, {18, 27}, {19, 26}, {35, 33}, {19, 26}, {24, 30}, {21, 29}, {26, 31}, {27, 33}, {24, 32}, {11, 18}, {24, 30}, {24, 32}, {22, 33}, {17, 26}, {26, 34}, {21, 31}, {21, 31}, {19, 28}, {33, 34}, {48, 45}, {19, 29}, {15, 23}, {15, 22}, {16, 25}};

市街地と高速道路の1ガロンあたりの走行マイル数は正規分布に従い，相関関係があると仮定する：

Wolfram Language code: bparams = FindDistributionParameters[midsizeMPG2009, BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ]]

市街地と高速道路における推定される平均走行可能距離を抽出する：

Wolfram Language code: {μ1, μ2} /. bparams

市街地と高速道路における走行可能距離の推定相関を抽出する：

Wolfram Language code: ρ /. bparams

対数スケールで結合密度を可視化し，平均走行可能距離に青い印を付ける：

Wolfram Language code:

Show[ContourPlot[Log[PDF[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ] /. bparams, {x, y}]], {x, 0, 50}, {y, 0, 50}, Contours -> 50], Graphics[{PointSize[Medium], Red, Point[{μ1, μ2} /. bparams]}]]

地震と地震の間隔 (1)

次のデータは1902年12月16日から1977年3月4日までに世界中で発生した大きい（マグニチュードが7.5以上のあるいは死者が1000人を超える）地震から次の大きい地震までの日数を含んでいる：

Wolfram Language code: earthquakesWaitingTimes = ExampleData[{"Statistics", "EarthquakeWaitingTimes"}];

ExponentialDistributionで地震の間隔をモデル化する：

Wolfram Language code: param = FindDistributionParameters[earthquakesWaitingTimes, ExponentialDistribution[λ]]

大きい地震間の平均日数とその中央値を推定する：

Wolfram Language code: {Mean[ExponentialDistribution[λ]], Median[ExponentialDistribution[λ]]} /. param

地震頻度 (1)

1年間の地震の回数はSinghMaddalaDistributionでモデル化することができる：

Wolfram Language code: ExampleData[{"Statistics", "USEarthquakes"}, "Description"]

Wolfram Language code: earthquakes = Tally[Select[ExampleData[{"Statistics", "USEarthquakes"}], #[[1]] ≥ 1935&][[All, 1]]][[All, 2]]

分布をデータにフィットする：

Wolfram Language code: params = FindDistributionParameters[earthquakes, SinghMaddalaDistribution[q, a, b]]

最大化した対数尤度を計算する：

Wolfram Language code: ll = LogLikelihood[SinghMaddalaDistribution[q, a, b], earthquakes] /. params

最適母数値の付近での対数尤度の統計データを可視化する：

Wolfram Language code:

Table[With[{var = params[[i, 1]], est = params[[i, 2]]}, Plot[LogLikelihood[SinghMaddalaDistribution[q, a, b] /. Drop[params, {i}], earthquakes], {var, .8est, 1.2est}, Epilog -> {PointSize[Medium], Point[{est, ll}]}, PlotRange -> {Floor[ll], Ceiling[ll]}, PlotLabel -> params[[i]]]], {i, 3}]//Row

間欠泉噴出までの時間 (1)

多峰データのモデル化には混合分布を使うことができる：

Wolfram Language code: ExampleData[{"Statistics", "OldFaithful"}, "ColumnDescriptions"]

Wolfram Language code: waiting = ExampleData[{"Statistics", "OldFaithful"}][[All, 2]];

オールド・フェイスフル・ガイザーの噴出から次の噴出までの時間のヒストグラムには2つのモードがある：

Wolfram Language code: h = Histogram[waiting, 25, "ProbabilityDensity"]

ガンマ分布と正規分布の混合分布をデータにフィットする：

Wolfram Language code: mdist = MixtureDistribution[{p, 1 - p}, {GammaDistribution[α, β], NormalDistribution[μ, σ]}];

Wolfram Language code: mparams = FindDistributionParameters[waiting, mdist, {{p, 1 / 3}, {α, 90}, {β, .5}, {μ, 80}, {σ, 5}}]

そのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[h, Plot[PDF[mdist /. mparams, x], {x, 0, 100}, PlotStyle -> Thick]]

株価分布 (1)

対数正規分布を使って株価をモデル化することができる：

Wolfram Language code: googleStock = QuantityMagnitude@FinancialData["GOOGL", {{2006, 3, 10}, {2018, 3, 15}, "Day"}, "Value"];

分布をデータにフィットする：

Wolfram Language code: params = FindDistributionParameters[googleStock, LogNormalDistribution[μ, σ]]

1つの母数をフィットされた値に固定して統計データの尤度を可視化する：

Wolfram Language code:

Block[{ml = LogLikelihood[LogNormalDistribution[μ, σ] /. params, googleStock], llh1 = LogLikelihood[LogNormalDistribution[mu, σ /. params], googleStock], 
	llh2 = LogLikelihood[LogNormalDistribution[μ /. params, s], googleStock]
	}, GraphicsRow[{Plot[llh1, {mu, 5.5, 6.5}, Epilog -> {PointSize[Large], Point[{μ /. params, ml}]}, AxesLabel -> {μ, None}, PlotLabel -> First[params]], Plot[llh2, {s, .1, 1}, Epilog -> {PointSize[Large], Point[{σ /. params, ml}]}, AxesLabel -> {σ, None}, PlotLabel -> Last[params]]}]]

出水率 (1)

マハナディ川の1日あたりの最低出水量を1年ごとに計算したもの（立方メートル／秒）を考える：

Wolfram Language code: minFlow = ExampleData[{"Statistics", "MahanadiRiverFlow"}];

1日あたりの最低出水量を1年ごとに計算したものをMinStableDistributionでモデル化する：

Wolfram Language code: params = FindDistributionParameters[minFlow, MinStableDistribution[a, b, c]]

次の30年間について，1日あたりの最低出水量を1年ごとに計算したもののシミュレーションを行う：

Wolfram Language code: ListPlot[RandomVariate[MinStableDistribution[a, b, c] /. params, 30], Filling -> 0, AxesOrigin -> {0, 0}]

人口規模 (1)

パレート(Pareto)分布を使ってオーストラリアの都市の人口をモデル化する：

Wolfram Language code: cities = CityData[{All, "Australia"}];

Wolfram Language code: populations = QuantityMagnitude[CityData[#, "Population"]& /@ cities];

Wolfram Language code: params = FindDistributionParameters[populations, ParetoDistribution[k, α, γ, μ]]

パレート分布を使ってある都市の人口が少なくとも1万人である確率を推定する：

Wolfram Language code: Probability[x ≥ 10000, xParetoDistribution[k, α, γ, μ]]

母数推定が与えられているものとして確率を計算する：

Wolfram Language code: % /. params

もとのデータに基づいて確率を計算する：

Wolfram Language code: Probability[x ≥ 10000, xpopulations]//N

特性と関係 (8)

FindDistributionParametersは推定を置換規則として与える：

Wolfram Language code: FindDistributionParameters[{5, 8, 3, 4, 9, 6}, PoissonDistribution[μ]]

EstimatedDistributionは母数推定を挿入した分布を与える：

Wolfram Language code: EstimatedDistribution[{5, 8, 3, 4, 9, 6}, PoissonDistribution[μ]]

FindProcessParametersはランダム過程についての母数推定のリストを返す：

Wolfram Language code: data = RandomFunction[BernoulliProcess[0.4], {0, 10 ^ 5}];

Wolfram Language code: FindProcessParameters[data, BernoulliProcess[p]]

FindDistributionParametersは分布についての母数推定のリストを返す：

Wolfram Language code: data = RandomVariate[BernoulliDistribution[0.4], 10 ^ 5];

Wolfram Language code: FindDistributionParameters[data, BernoulliDistribution[p]]

最尤法を使って分布母数を推定する：

Wolfram Language code: data = RandomVariate[ExponentialDistribution[3], 1000];

Wolfram Language code: FindDistributionParameters[data, ExponentialDistribution[λ]]

DistributionFitTestを使ってフィットの質を検証する：

Wolfram Language code: ℋ = DistributionFitTest[data, ExponentialDistribution[λ], "HypothesisTestData"]

フィットされた分布母数を抽出する：

Wolfram Language code: ℋ["FittedDistributionParameters"]

関連する検定統計と p 値の表を得る：

Wolfram Language code: ℋ[{"TestDataTable", All}]

パラメトリック分布の母数を推定する：

Wolfram Language code: data = RandomVariate[NormalDistribution[0, 1], 50];

Wolfram Language code: pars = FindDistributionParameters[data, NormalDistribution[μ, σ]]

SmoothKernelDistributionでノンパラメトリックカーネル密度推定を得る：

Wolfram Language code: skdist = SmoothKernelDistribution[data]

ノンパラメトリック分布とパラメトリック分布の確率密度関数を比較する：

Wolfram Language code:

Plot[{PDF[skdist, x], PDF[NormalDistribution[μ, σ] /. pars, x]}, {x, -3, 3}, PlotLegends -> {SmoothKernelDistribution, NormalDistribution}]

SmoothHistogramを使ってノンパラメトリック密度を可視化する：

Wolfram Language code: SmoothHistogram[data, PlotStyle -> Thick]

母数の最尤推定量を得る：

Wolfram Language code: data = RandomVariate[GammaDistribution[4, 10], 25];

Wolfram Language code: edist = FindDistributionParameters[data, GammaDistribution[α, β]]

Likelihoodを使って尤度を計算する：

Wolfram Language code: Likelihood[GammaDistribution[α, β] /. edist, data]

LogLikelihoodを使って対数尤度を計算する：

Wolfram Language code: LogLikelihood[GammaDistribution[α, β] /. edist, data]

原点の周りのモーメントをマッチさせることで母数を推定する：

Wolfram Language code: data = RandomVariate[BetaDistribution[2, 5], 100];

Wolfram Language code: edist = FindDistributionParameters[data, BetaDistribution[α, β], ParameterEstimator -> "MethodOfMoments"]

Momentを使ってデータから原点の周りのモーメントを計算する：

Wolfram Language code: {Moment[data, 1], Moment[data, 2]}

推定母数のベータ分布から同じモーメントを計算する：

Wolfram Language code: {Moment[BetaDistribution[α, β], 1], Moment[BetaDistribution[α, β], 2]} /. edist

ワイブル(Weibull)分布の母数を推定する：

Wolfram Language code: data = RandomVariate[WeibullDistribution[3, 15], 100];

Wolfram Language code: edist = FindDistributionParameters[data, WeibullDistribution[α, β]]

QuantilePlotを使って経験的変位値と理論的変位値を可視化する：

Wolfram Language code: QuantilePlot[data, WeibullDistribution[α, β] /. edist]

推定がQuantilePlot内で行われる場合に同じ可視化を行う：

Wolfram Language code: QuantilePlot[data, WeibullDistribution[α, β]]

FindDistributionParametersは，TimeSeriesとEventSeriesのタイムスタンプを無視する：

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{1, 0, 1, 0, 0, 1, 0, 1, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 1, 0, 0, 1, 
    0, 1, 0, 1, 0, 0, 0, 1, 0, 1, 0, 1, 0, 0, 1, 0, 0, 1, 1, 0, 0, 1, 0, 1, 1, 1, 0, 1, 1, 1, 0, 0, 
    0, 0, 0, 1, 0, 0, 0, 1, 0, 1, 1, 0, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 1, 0, 1, 0, 1, 1, 1, 0, 0, 
    1, 0, 0, 0, 1, 1, 1, 0, 1, 1, 1, 1}}, {{0, 99, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, 
  {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];

Wolfram Language code: FindDistributionParameters[ts, BernoulliDistribution[p]]

以下と同じである：

Wolfram Language code: FindDistributionParameters[ts["Values"], BernoulliDistribution[p]]

TemporalDataについては，すべての経路構造が無視される：

Wolfram Language code: td = TemporalData[«4»];

Wolfram Language code: FindDistributionParameters[td, NormalDistribution[a, b]]

以下と同じである：

Wolfram Language code: FindDistributionParameters[td["ValueList"]//Flatten, NormalDistribution[a, b]]

考えられる問題 (3)

モーメント法方程式の解は有効ではない母数を与えることがある：

Wolfram Language code: FindDistributionParameters[{10, 12, 8, 15}, BinomialDistribution[n, p], ParameterEstimator -> "MethodOfMoments"]

Wolfram Language code: DistributionParameterAssumptions[BinomialDistribution[n, p]] /. %

連続分布の場合：

Wolfram Language code: data = RandomVariate[NormalDistribution[-1, .1], 10 ^ 3];

Wolfram Language code: FindDistributionParameters[data, NormalDistribution[m, m], ParameterEstimator -> "MethodOfMoments"]

Wolfram Language code: DistributionParameterQ[NormalDistribution[m, m] /. %]

よい解を得るためには初期値をうまく選ぶ必要があるかもしれない：

Wolfram Language code: data = {4.1, 5.8, 4.3, 5.6, 3.8, 2.5, 3.1, 5.3, 5.4, 3.3};

Wolfram Language code: FindDistributionParameters[data, RiceDistribution[.01, α, β], ParameterEstimator -> "MethodOfMoments"]

Wolfram Language code:

FindDistributionParameters[data, RiceDistribution[.01, α, β], {{α, 4}, {β, .02}}, ParameterEstimator -> "MethodOfMoments"]

初期値をうまく選ぶと結果が早く得られることがある：

Wolfram Language code: data = RandomVariate[DirichletDistribution[Range[25]], 10 ^ 4];

Wolfram Language code: FindDistributionParameters[data, DirichletDistribution[Array[g, 25]]]//AbsoluteTiming

Wolfram Language code:

FindDistributionParameters[data, DirichletDistribution[Array[g, 25]], Transpose[{Array[g, 25], Range[25]}]]//AbsoluteTiming

Top

FindDistributionParameters

詳細とオプション

例題

例 (3)

スコープ (15)

基本的な用法 (5)

一変量パラメトリック分布 (2)

多変量パラメトリック分布 (2)

派生分布 (6)

オプション (4)

ParameterEstimator (3)

WorkingPrecision (1)

アプリケーション (17)

母数が1つの推定器を使って別の推定器の初期値を求める (1)

他の推定のための初期値を得る (1)

形状が類似した分布の母数推定 (1)

事故による保険金請求 (1)

さまざまな言語における単語長 (1)

テキスト頻度 (1)

地震のマグニチュード (1)

風速分析 (1)

所得分布 (1)

株式価値の市場変動 (1)

自動車の燃費 (1)

地震と地震の間隔 (1)

地震頻度 (1)

間欠泉噴出までの時間 (1)

株価分布 (1)

出水率 (1)

人口規模 (1)

特性と関係 (8)

考えられる問題 (3)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX