WOLFRAM

Wolfram 语言与系统参考资料中心

FindMinValue[f,x]

给出 f 的一个局部最小值.

FindMinValue[f,{x,x0}]

给出 f 的一个局部最小值，通过从点 x=x0 开始搜索求出.

FindMinValue[f,{{x,x0},{y,y0},…}]

给出多元函数的一个局部最小值.

FindMinValue[{f,cons},{{x,x0},{y,y0},…}]

给出约束 cons 下的一个局部最小值.

FindMinValue[{f,cons},{x,y,…}]

在约束定义的区域内的一个点开始.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
AccuracyGoal 和 PrecisionGoal  
EvaluationMonitor  
Gradient  
Method  
StepMonitor  
WorkingPrecision  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

FindMinValue

FindMinValue[f,x]

给出 f 的一个局部最小值.

FindMinValue[f,{x,x0}]

给出 f 的一个局部最小值，通过从点 x=x0 开始搜索求出.

FindMinValue[f,{{x,x0},{y,y0},…}]

给出多元函数的一个局部最小值.

FindMinValue[{f,cons},{{x,x0},{y,y0},…}]

给出约束 cons 下的一个局部最小值.

FindMinValue[{f,cons},{x,y,…}]

在约束定义的区域内的一个点开始.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (4)

求出一元函数的一个最小值：

Wolfram Language code: FindMinValue[2x ^ 2 - 3x + 5, x]

求出多元函数的一个最小值：

Wolfram Language code: FindMinValue[Sin[x]Sin[2y], {x, y}]

求出约束条件下一个函数的最小值：

Wolfram Language code: FindMinValue[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

求出一个集合域上的函数的最小值：

Wolfram Language code: FindMinValue[{x + y, {x, y}∈Disk[]}, {x, y}]

范围  (12)

在不同起点下，得到不同局部最小值：

Wolfram Language code: FindMinValue[x Cos[x], {x, 5}]
Wolfram Language code: FindMinValue[x Cos[x], {x, 10}]

x=2，y=2 点开始，二元变量函数的一个局部最小值：

Wolfram Language code: FindMinValue[Sin[x]Sin[2y], {{x, 2}, {y, 2}}]

约束在一个圆内的一个局部最小值：

Wolfram Language code: FindMinValue[{Sin[x]Sin[2y], x ^ 2 + y ^ 2 < 3}, {{x, 2}, {y, 2}}]

不提供起点：

Wolfram Language code: FindMinValue[{Sin[x]Sin[2y], x ^ 2 + y ^ 2 < 3}, {x, y}]

对于线性对象和约束条件，可以加上整数约束条件：

Wolfram Language code: FindMinValue[{x + y, 3x + 2y ≥ 7 && x ≥ 0 && y ≥ 0}, {x, y}]
Wolfram Language code: FindMinValue[{x + y, 3x + 2y ≥ 7 && x ≥ 0 && y ≥ 0 && x∈Integers}, {x, y}]

可以指定 Or 约束：

Wolfram Language code: FindMinValue[{-x - y, x ^ 2 + y ^ 2 ≤ 1 || (x + 2) ^ 2 + (y + 2) ^ 2 ≤ 1}, {x, y}]

求出一个几何域上的函数的最小值：

Wolfram Language code: t = RotationTransform[{{0, 0, 1}, {1, 1, 1}}]; ℛ = TransformedRegion[Ellipsoid[{0, 0, 0}, {1, 2, 3}], t];
Wolfram Language code: FindMinValue[{z, {x, y, z}∈ℛ}, {x, y, z}]

将其画出：

Wolfram Language code: Graphics3D[{Opacity[0.5], {Green, GeometricTransformation[Ellipsoid[{0, 0, 0}, {1, 2, 3}], t]}, {Red, InfinitePlane[{{0, 0, %}, {1, 0, %}, {0, 1, %}}]}}]

求出两个域间的最小距离：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = InfiniteLine[{{-2, 0}, {0, 2}}];
Wolfram Language code: FindMinValue[{(x - u)^2 + (y - v)^2, {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}}, {x, y, u, v}]

将其画出：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Blue, Circle[{0, 0}, 1 + Sqrt[%]]}}]

求出使三角和椭圆仍能相交的最小 ：

Wolfram Language code: Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Disk[{1, 1}, {2r, r}];
Wolfram Language code: FindMinValue[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]

将其画出：

Wolfram Language code: Graphics[{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]} /. r -> %]

求出包含给定的三个点的盘的最小半径：

Wolfram Language code: Subscript[ℛ, 3] = Disk[{a, b}, r];
Wolfram Language code: FindMinValue[{r, ({0, 0} | {1, 0} | {0, 1})∈Subscript[ℛ, 3]}, {a, b, r}]

使用 Circumsphere 可直接给出相同结果：

Wolfram Language code: Circumsphere[{{0, 0}, {1, 0}, {0, 1}}]//N

用 来指定 是 中的向量：

Wolfram Language code: ℛ = Sphere[];
Wolfram Language code: FindMinValue[{x.{1, 2, 3}, x∈ℛ}, x]

求出两个域之间的最小距离：

Wolfram Language code: Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Disk[{2, 2}, 1];
Wolfram Language code: FindMinValue[{EuclideanDistance[x, y], {x∈Subscript[ℛ, 1], y∈Subscript[ℛ, 2]}}, {x, y}]

将其画出：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Blue, Circle[{2, 2}, 1 + %]}}]

选项  (8)

AccuracyGoal 和 PrecisionGoal  (2)

这指定收敛规则 和 ：

Wolfram Language code: FindMinValue[Sin[x / 2], {x, 1}, AccuracyGoal -> 9, PrecisionGoal -> 8]

这指定收敛规则 和 ：

Wolfram Language code: FindMinValue[Sin[x / 2], {x, 1}, AccuracyGoal -> 20, PrecisionGoal -> 18]

提高 WorkingPrecision，将使得过程收敛：

Wolfram Language code: FindMinValue[Sin[x / 2], {x, 1}, AccuracyGoal -> 20, PrecisionGoal -> 18, WorkingPrecision -> 40]

EvaluationMonitor  (1)

绘制收敛于局部最小值：

Wolfram Language code: ListPlot[Last[Reap[FindMinValue[x Cos[x], {x, 5}, EvaluationMonitor :> Sow[x]]]]]

Gradient  (2)

用给定的梯度：

Wolfram Language code: FindMinValue[Sin[x]Sin[2 y], {x, y}, Gradient -> {Cos[x] Sin[2 y], 2 Cos[2 y] Sin[x]}, Method -> "Newton"]

这用提供的梯度和 Hessian：

Wolfram Language code: FindMinValue[Sin[x]Sin[2y], {x, y}, Gradient -> {Cos[x] Sin[2 y], 2 Cos[2 y] Sin[x]}, Method -> {"Newton", Hessian -> {{-Sin[x] Sin[2 y], 2 Cos[x] Cos[2 y]}, {2 Cos[x] Cos[2 y], -4 Sin[x] Sin[2 y]}}}]

Method  (1)

在这个例子中，用缺省的基于导数的方式会有困难:

Wolfram Language code: FindMinValue[Abs[x + 1] + Abs[x + 1.01] + Abs[y + 1], {x, y}]
Wolfram Language code: FindMinValue[Abs[x + 1] + Abs[x + 1.01] + Abs[y + 1], {x, y}, Method -> "ConjugateGradient"]

在这些例子中，不需要导数的直接搜索方式会有帮助:

Wolfram Language code: FindMinValue[Abs[x + 1] + Abs[x + 1.01] + Abs[y + 1], {x, y}, Method -> "PrincipalAxis"]

NMinimize 也可以使用直接搜索方式的范围：

Wolfram Language code: NMinimize[{Abs[x + 1] + Abs[x + 1.01] + Abs[y + 1]}, {x, y}]

StepMonitor  (1)

在求函数的最小值过程中，FindMinValue 采用的步长：

Wolfram Language code: pts = Reap[FindMinValue[(1 - x) ^ 2 + 100(-x ^ 2 - y) ^ 2 + 1, {{x, -1.2}, {y, 1}}, StepMonitor :> Sow[{x, y}]]][[2, 1]]; pts = Join[{{-1.2, 1}}, pts];
Wolfram Language code: ContourPlot[(1 - x) ^ 2 + 100(-x ^ 2 - y) ^ 2 + 1//Log, {x, -1.3, 1.5}, {y, -1.5, 1.4}, Epilog -> {Red, Line[pts], Point[pts]}]

WorkingPrecision  (1)

设置工作精度为 ；缺省情况下 AccuracyGoal 和 PrecisionGoal 设置为 :

Wolfram Language code: FindMinValue[Cos[x ^ 2 - 3 y] + Sin[x ^ 2 + y ^ 2], {x, y}, Method -> "Newton", WorkingPrecision -> 20]

属性和关系  (1)

FindMinimum 给出最小值和最小化参数：

Wolfram Language code: FindMinimum[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

FindArgMin 以列表方式给出最小值的坐标：

Wolfram Language code: FindArgMin[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

FindMinValue 给出最小点的值：

Wolfram Language code: FindMinValue[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

可能存在的问题  (4)

如果限定区域为空，算法不会收敛：

Wolfram Language code: FindMinValue[{x + y, x ^ 2 + y ^ 2 ≥ 2 && x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

如果最小值不是有限的，算法不会收敛：

Wolfram Language code: FindMinValue[Tan[x], {x, 2}]
Wolfram Language code: FindMinValue[{-x ^ 2 - y ^ 2, x ^ 2 + y ^ 2 > 10}, {x, y}]
Wolfram Language code: Plot3D[-x ^ 2 - y ^ 2, {x, -10, 10}, {y, -10, 10}, RegionFunction -> Function[{x, y}, x ^ 2 + y ^ 2 > 10]]

整数的线性程序算法仅对机器数问题有效：

Wolfram Language code: FindMinValue[{x + y, x + 2y ≥ 3 && x > 1 && y > 1 && x∈Integers}, {x, y}, WorkingPrecision -> 20]

某些时候提供一个适当的初始值，对收敛算法会有帮助：

Wolfram Language code: FindMinValue[{Cos[x] - Exp[(x - 0.5) y], x ^ 2 + y ^ 2 < 1}, {x, y}]
Wolfram Language code: FindMinValue[{Cos[x] - Exp[(x - 0.5) y], x ^ 2 + y ^ 2 < 1}, {{x, -1}, {y, -1}}]
Wolfram Research (2008)，FindMinValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindMinValue.html （更新于 2014 年）.

文本

Wolfram Research (2008)，FindMinValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindMinValue.html （更新于 2014 年）.

CMS

Wolfram 语言. 2008. "FindMinValue." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/FindMinValue.html.

APA

Wolfram 语言. (2008). FindMinValue. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FindMinValue.html 年

BibTeX

@misc{reference.wolfram_2026_findminvalue, author="Wolfram Research", title="{FindMinValue}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/FindMinValue.html}", note=[Accessed: 18-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_findminvalue, organization={Wolfram Research}, title={FindMinValue}, year={2014}, url={https://reference.wolfram.com/language/ref/FindMinValue.html}, note=[Accessed: 18-June-2026]}