Wolfram言語＆システムドキュメントセンター

FindMinimum

FindMinimum[f,x]

自動的に選んだ点から始めて f の極小値を求める．

FindMinimum[f,{x,x₀}]

点 x=x₀から始めて f の極小値を求める．

FindMinimum[f,{{x,x₀},{y,y₀},…}]

複数の変数を持つ関数の極小値を求める．

FindMinimum[{f,cons},{{x,x₀},{y,y₀},…}]

制約条件 cons のもとで極小値を求める．

FindMinimum[{f,cons},{x,y,…}]

制約条件で定義された範囲内の点から始める．

FindMinimum

FindMinimum[f,x]

自動的に選んだ点から始めて f の極小値を求める．

FindMinimum[f,{x,x₀}]

点 x=x₀から始めて f の極小値を求める．

FindMinimum[f,{{x,x₀},{y,y₀},…}]

複数の変数を持つ関数の極小値を求める．

FindMinimum[{f,cons},{{x,x₀},{y,y₀},…}]

制約条件 cons のもとで極小値を求める．

FindMinimum[{f,cons},{x,y,…}]

制約条件で定義された範囲内の点から始める．

詳細とオプション

FindMinimumは{f_min,{x->x_min}}の形式のリストを返す．ただし，f_minは f の見出された極小値で，x_minは x の値である．
変数の初期値がリストで与えられている場合は，変数の値は同じ次元のリストであると解釈される．
制約条件 cons は，方程式，不等式，あるいはこれらの論理結合を含むことができる．
制約条件 cons は以下の論理結合でよい．
lhs==rhs 方程式

lhs>rhs または lhs>=rhs 不等式

{x,y,…}∈reg 領域指定
FindMinimumは，まずすべての変数の値を局所化し，次に記号的となった変数で f を評価し，繰り返して結果を数値的に評価する．
FindMinimumは属性HoldAllを持ち，Blockを用いて実質的に変数を局所化する．
FindMinimum[f,{x,x₀,x₁}]は x₀と x₁を x の最初の2つの値として用い，導関数を使用せずに f の極小値を求める．
FindMinimum[f,{x,x₀,x_min,x_max}]は極小値を求める．x が x_minから x_maxまでの区間からはみ出したところで探索を中止する．
f と cons の両方が線形の場合を除き，FindMinimumが求めた結果は極小値のみに対応し，大域的である最小値には対応しない．
デフォルトで，変数はすべて実数であると仮定される．
線形の f と cons については，x∈Integersを使って変数が整数値のみを取るように指定することができる．
可能なオプション

AccuracyGoal	Automatic	目標確度
EvaluationMonitor	None	f が評価されたときに常に評価される式
Gradient	Automatic	f の勾配要素のリスト
MaxIterations	Automatic	使用する最大反復回数
Method	Automatic	使用するアルゴリズム
PrecisionGoal	Automatic	目標精度
StepMonitor	None	段階を取るたびに常に評価される式
WorkingPrecision	MachinePrecision	内部計算で使用する精度

AccuracyGoalとPrecisionGoalの設定値で，極小値の位置の値と極小値に達したときの関数の値の両方で目標とする有効桁精度を指定する．
FindMinimumは，AccuracyGoalまたはPrecisionGoalで指定された精度（または確度）に達するまで計算を続ける．
Methodが取り得る設定には，"ConjugateGradient"，"PrincipalAxis"，"LevenbergMarquardt"，"Newton"，"QuasiNewton"，"InteriorPoint"，"LinearProgramming"等がある．デフォルト値はAutomaticである．

例題

すべて開くすべて閉じる

例 (4)

から探索を始めて極小値を求める：

Wolfram Language code: FindMinimum[x Cos[x], {x, 2}]

Wolfram Language code: Plot[x Cos[x], {x, 0, 20}]

極小値における x の値を抽出する：

Wolfram Language code: x /. Last[FindMinimum[x Cos[x], {x, 2}]]

から始め，制約条件に従って極小値を求める：

Wolfram Language code: FindMinimum[{x Cos[x], 1 ≤ x ≤ 15}, {x, 7}]

線形制約条件と整数制約条件に従って線形関数の最小値を求める：

Wolfram Language code: FindMinimum[{x + y, x + 2y ≥ 3 && x ≥ 0 && y ≥ 0 && y∈Integers}, {x, y}]

幾何学領域上で関数の最小値を求める：

Wolfram Language code: FindMinimum[{x + y, {x, y}∈Disk[]}, {x, y}]

これをプロットする：

Wolfram Language code: Show[ContourPlot[x + y, {x, y}∈Disk[]], Graphics[{Red, PointSize[Large], Point[{x, y} /. Last[%]]}]]

スコープ (12)

始点を変えると異なる極小値が求まることがある：

Wolfram Language code: FindMinimum[x Cos[x], {x, 5}]

Wolfram Language code: FindMinimum[x Cos[x], {x, 10}]

x=2, y=2から始めた二変数関数の極小値：

Wolfram Language code: FindMinimum[Sin[x]Sin[2y], {{x, 2}, {y, 2}}]

円板内という制約条件を持つ極小値：

Wolfram Language code: FindMinimum[{Sin[x]Sin[2y], x ^ 2 + y ^ 2 < 3}, {{x, 2}, {y, 2}}]

初期値は与えなくてもよい：

Wolfram Language code: FindMinimum[{Sin[x ]Sin[2y], x ^ 2 + y ^ 2 < 3}, {x, y}]

線形目的および制約条件には，整数制約条件を強制することができる：

Wolfram Language code: FindMinimum[{x + y, 3x + 2y ≥ 7 && x ≥ 0 && y ≥ 0}, {x, y}]

Wolfram Language code: FindMinimum[{x + y, 3x + 2y ≥ 7 && x ≥ 0 && y ≥ 0 && x∈Integers}, {x, y}]

Or制約条件を指定することができる：

Wolfram Language code: FindMinimum[{x + y, x ^ 2 + y ^ 2 ≤ 1 || (x + 2) ^ 2 + (y + 2) ^ 2 ≤ 1}, {x, y}]

領域内の最小値を求める：

Wolfram Language code:

t = RotationTransform[{{0, 0, 1}, {1, 1, 1}}];
ℛ = TransformedRegion[Ellipsoid[{0, 0, 0}, {1, 2, 3}], t];

Wolfram Language code: FindMinimum[{z, {x, y, z}∈ℛ}, {x, y, z}]

これをプロットする：

Wolfram Language code:

Graphics3D[{{Opacity[0.5], Green, GeometricTransformation[Ellipsoid[{0, 0, 0}, {1, 2, 3}], t]}, {Red, PointSize[Large], Point[{x, y, z} /. Last[%]]}}]

2領域間の最短距離を求める：

Wolfram Language code:

Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = InfiniteLine[{{-2, 0}, {0, 2}}];

Wolfram Language code: FindMinimum[{(x - u)^2 + (y - v)^2, {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}}, {x, y, u, v}]

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{{x, y}, {u, v}} /. Last[%]]}}]

三角形と楕円が交差する最小のを求める：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Disk[{1, 1}, {2r, r}];

Wolfram Language code: FindMinimum[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]

これを可視化する：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Last[%]]

指定された3点を含む，半径が最小の円板を求める：

Wolfram Language code: Subscript[ℛ, 3] = Disk[{a, b}, r];

Wolfram Language code: FindMinimum[{r, ({0, 0} | {1, 0} | {0, 1})∈Subscript[ℛ, 3]}, {a, b, r}]

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 3]} /. %[[2]], {Red, Point[{{0, 0}, {1, 0}, {0, 1}}]}}]

Circumsphereを使うと同じ結果が直接与えられる：

Wolfram Language code: Circumsphere[{{0, 0}, {1, 0}, {0, 1}}]//N

を使い，が内のベクトルであると指定する：

Wolfram Language code: ℛ = Sphere[];

Wolfram Language code: FindMinimum[{x.{1, 2, 3}, x∈ℛ}, x]

2領域間の最短距離を求める：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Disk[{2, 2}, 1];

Wolfram Language code: FindMinimum[{EuclideanDistance[x, y], {x∈Subscript[ℛ, 1], y∈Subscript[ℛ, 2]}}, {x, y}]

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. %[[2]]]

オプション (7)

AccuracyGoalとPrecisionGoal (2)

次は，収束基準とを強制する：

Wolfram Language code: FindMinimum[Sin[x / 2], {x, 1}, AccuracyGoal -> 9, PrecisionGoal -> 8]

次は，収束基準とを強制する：

Wolfram Language code: FindMinimum[Sin[x / 2], {x, 1}, AccuracyGoal -> 20, PrecisionGoal -> 18]

WorkingPrecisionの設定値を高くするとこのプロセスは収束する：

Wolfram Language code: FindMinimum[Sin[x / 2], {x, 1}, AccuracyGoal -> 20, PrecisionGoal -> 18, WorkingPrecision -> 40]

EvaluationMonitor (1)

極小値への収束をプロットする：

Wolfram Language code: ListPlot[Last[Reap[FindMinimum[x Cos[x], {x, 2}, EvaluationMonitor :> Sow[x]]]]]

Gradient (1)

与えられた勾配を使う．ヘッシアンは自動的に計算される：

Wolfram Language code: FindMinimum[Sin[x]Sin[2 y], {x, y}, Gradient -> {Cos[x] Sin[2 y], 2 Cos[2 y] Sin[x]}, Method -> "Newton"]

勾配とヘッシアンの両方を与える：

Wolfram Language code:

FindMinimum[Sin[x]Sin[2y], {x, y}, Gradient -> {Cos[x] Sin[2 y], 2 Cos[2 y] Sin[x]}, Method -> {"Newton", Hessian -> {{-Sin[x] Sin[2 y], 2 Cos[x] Cos[2 y]}, {2 Cos[x] Cos[2 y], -4 Sin[x] Sin[2 y]}}}]

Method (1)

この場合は，デフォルトの導関数に基づいたメソッドではうまくいかない：

Wolfram Language code: FindMinimum[Abs[x + 1] + Abs[x + 1.01] + Abs[y + 1], {x, y}]

Wolfram Language code: FindMinimum[Abs[x + 1] + Abs[x + 1.01] + Abs[y + 1], {x, y}, Method -> "ConjugateGradient"]

これらの場合には，導関数を必要としない直接探索法が役に立つ：

Wolfram Language code: FindMinimum[Abs[x + 1] + Abs[x + 1.01] + Abs[y + 1], {x, y}, Method -> "PrincipalAxis"]

NMinimizeもまた，さまざまな直接探索法を使う：

Wolfram Language code: NMinimize[{Abs[x + 1] + Abs[x + 1.01] + Abs[y + 1], 0 > x > -2}, {x, y}]

StepMonitor (1)

関数の最小値を求める際にFindMinimumが取るステップ：

Wolfram Language code:

pts = Reap[FindMinimum[(1 - x) ^ 2 + 100(-x ^ 2 - y) ^ 2 + 1, {{x, -1.2}, {y, 1}}, StepMonitor :> Sow[{x, y}]]][[2, 1]];
pts  = Join[{{-1.2, 1}}, pts];

Wolfram Language code:

ContourPlot[(1 - x) ^ 2 + 100(-x ^ 2 - y) ^ 2 + 1//Log, {x, -1.3, 1.5}, {y, -1.5, 1.4}, Epilog -> {Red, Line[pts], Point[pts]}]

WorkingPrecision (1)

作業精度をにする．デフォルトでAccuracyGoalとPrecisionGoalはに設定されている：

Wolfram Language code: FindMinimum[Cos[x ^ 2 - 3 y] + Sin[x ^ 2 + y ^ 2], {x, y}, Method -> "Newton", WorkingPrecision -> 20]

アプリケーション (3)

1973年から1994年までのS&P 500からの長期債券の年間配当(R)：

Wolfram Language code:

R = {{0.942, 1.02, 1.056, 1.175, 1.002, 0.982, 0.978, 0.947, 1.003, 1.465, 0.985, 1.159, 1.366, 1.309, 0.925, 1.086, 1.212, 1.054, 1.193, 1.079, 1.217, 0.889}, {0.852, 0.735, 1.371, 1.236, 0.926, 1.064, 1.184, 1.323, 0.949, 1.215, 1.224, 1.061, 1.316, 1.186, 1.052, 1.165, 1.316, 0.968, 1.304, 1.076, 1.1, 1.012}};

配当から平均と共分散を計算する：

Wolfram Language code: μ = Mean[Transpose@R]

Wolfram Language code: Σ = Covariance[Transpose[R]]

Wolfram Language code: X = Map[Subscript[x, #]&, {"long T-bond", "SP500"}]

最低10%の配当という制約下で変動を最小にする：

Wolfram Language code: FindMinimum[{X.Σ.X, Total[X] == 1 && μ.X ≥ 1.10 && Apply[And, Thread[X ≥ {0, 0}]]}, X]

について，半径の重なり合ない個の円が入る最小の正方形を求める．円の数と各円の半径を指定する：

Wolfram Language code:

n = 20;
r = BlockRandom[RandomReal[{0.5, 1.5}, n], RandomSeeding -> 123];

が円の中心なら，目的はを最小化することになる．この目的は，のときにを最小化することに変形できる：

Wolfram Language code: objectiveConstraint = Table[-s <= Norm[c[i], Infinity] + r[[i]] <= s, {i, n}];

円は重なり合ってはならない：

Wolfram Language code:

nonOverlapConstraint = Table[Norm[c[i] - c[j]] >= r[[i]] + r[[j]], 
	{i, 1, n}, {j, i + 1, n}];

変数をまとめる：

Wolfram Language code: vars = Append[Table[Element[c[i], Vectors[2, Reals]], {i, n}], Element[s, Reals]];

を最小化する：

Wolfram Language code: Short[res = FindMinimum[{s, objectiveConstraint, nonOverlapConstraint}, vars], 5]

円は正方形の中に収まる：

Wolfram Language code:

Graphics[{Table[Circle[c[i], r[[i]]], {i, n}], {FaceForm[None], EdgeForm[StandardGray], Rectangle[{-s, -s}, {s, s}]}}] /. res[[2]]

円に覆われた正方形の割合を計算する：

Wolfram Language code: Sum[Area[Disk[c[i], r[[i]]]], {i, n}] / Area[Rectangle[{-s, -s}, {s, s}]] /. res[[2]]

出発点と到着点の間の距離が最小になるようにして，円形の障害物の間を通る経路を求める：

Wolfram Language code:

p = {{2, 2}, {7, 6}, {3, 5}, {4, 8}, {8, 9}, {6, 2.5}};
r = {1, 1.3, 1.5, 1, 0.7, 1.5};
{start, end} = {{0, 0}, {10, 10}};
domain = Graphics[{MapThread[Circle[#1, #2]&, {p, r}], 
	{PointSize[0.02], Point[{start, end}]}}, Frame -> True]

点と点の間の距離をとして，経路を個に離散化する．は最小化する経路の長さである：

Wolfram Language code:

n = 30;
distanceConstraints = Table[Inactive[Norm][x[i] - x[i - 1]] <= l / n, {i, n}];

各点は円形オブジェクトの中にあってはならない：

Wolfram Language code: objectConstraints = Table[Inactive[Norm][-p[[j]] + x[i]] >= r[[j]], {i, 1, n}, {j, 1, 6}];

出発点と到着点は既知である：

Wolfram Language code: positionConstraints = {x[0] == start, x[n] == end};

変数をまとめる：

Wolfram Language code: vars = Append[Table[x[i]∈Vectors[2, Reals], {i, 0, n}], l∈Reals];

制約条件に従って長さを最小化する：

Wolfram Language code:

Short[res = FindMinimum[{l, distanceConstraints, 
	objectConstraints, positionConstraints}, vars], 2]

結果を可視化する：

Wolfram Language code:

pts = vars[[1 ;; -2, 1]] /. res[[2]];
Show[domain, Graphics[{Red, Point[pts]}]]

特性と関係 (2)

FindMinimumは極小を求めようとするのに対し，NMinimizeは大域的最小を求めようとする：

Wolfram Language code:

objective = -100 / ((x - 1)^2 + (y - 1)^2 + 1) - 200 / ((x + 1)^2 + (y + 2)^2 + 1);
FindMinimum[{objective, x^2 + y^2 > 3 }, {{x, 2}, y}]

Wolfram Language code: NMinimize[{objective, x^2 + y^2 > 3 }, {x, y}]

Wolfram Language code: ContourPlot[objective, {x, -3, 2}, {y, -3, 2}, ...]

Minimizeは最小値を求め，無限大の精度でも使うことができる：

Wolfram Language code: Minimize[{-100 / ((x - 1)^2 + (y - 1)^2 + 1) - 200 / ((x + 1)^2 + (y + 2)^2 + 1), x^2 + y^2 > 3 }, {x, y}]

Wolfram Language code: N[%]

FindMinimumは最小値と最小となる点の両方を与える：

Wolfram Language code: FindMinimum[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

FindArgMinは最小となる位置を与える：

Wolfram Language code: FindArgMin[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

FindMinValueは最小値を与える：

Wolfram Language code: FindMinValue[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

考えられる問題 (6)

機械精度の計算では，スムーズな極小値を持つ関数でも凸凹に見えることがある：

Wolfram Language code: opt = FindMinimum[x Cos[x], {x, 1}]

Wolfram Language code:

yopt = First[opt];
xopt = x /. Last[opt];

Wolfram Language code: Plot[x Cos[x] - yopt, Evaluate[{x, xopt - 1.*^-7, xopt + 1.*^-7}], PlotRange -> All]

機械精度以上の精度にするとこのような問題が避けられることがある：

Wolfram Language code: FindMinimum[x Cos[x], {x, 1}, WorkingPrecision -> 30]

制約範囲が空の場合，アルゴリズムは収束しない：

Wolfram Language code: FindMinimum[{x + y, x ^ 2 + y ^ 2 ≥ 2 && x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

最小値が有限ではない場合，アルゴリズムは収束しない：

Wolfram Language code: FindMinimum[Tan[x], {x, 2}]

Wolfram Language code: FindMinimum[{-x ^ 2 - y ^ 2, x ^ 2 + y ^ 2 > 10}, {x, y}]

整数線形計画法アルゴリズムは機械数問題にしか使えない：

Wolfram Language code: FindMinimum[{x + y, x + 2y ≥ 3 && x > 1 && y > 1 && x∈Integers}, {x, y}, WorkingPrecision -> 20]

初期値を与えることでアルゴリズムの収束を助けられる場合がある：

Wolfram Language code: FindMinimum[{Cos[x] - Exp[(x - 0.5) y], x ^ 2 + y ^ 2 < 1}, {x, y}]

Wolfram Language code: FindMinimum[{Cos[x] - Exp[(x - 0.5) y], x ^ 2 + y ^ 2 < 1}, {{x, -1}, {y, -1}}]

関数を記号的に計算するのには時間がかかることがある：

Wolfram Language code: f[x_] := Nest[Sin[# + Sin[2#]]&, x, 15]

Wolfram Language code: FindMinimum[f[x], {x, 0}]//Timing

関数定義を制限すると記号評価が避けられる：

Wolfram Language code: g[x_ ? NumericQ] := Nest[Sin[# + Sin[2#]]&, x, 15]

Wolfram Language code: FindMinimum[g[x], {x, 0}]//Timing

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

FindMinimum

詳細とオプション

例題

例 (4)

スコープ (12)

オプション (7)

AccuracyGoalとPrecisionGoal (2)

EvaluationMonitor (1)

Gradient (1)

Method (1)

StepMonitor (1)

WorkingPrecision (1)

アプリケーション (3)

特性と関係 (2)

考えられる問題 (6)

テキスト

CMS

APA

BibTeX

BibLaTeX

	lhs==rhs	方程式
	lhs>rhs または lhs>=rhs	不等式
	{x,y,…}∈reg	領域指定

FindMinimum

詳細とオプション

例題

例 (4)

スコープ (12)

オプション (7)

AccuracyGoalとPrecisionGoal (2)

EvaluationMonitor (1)

Gradient (1)

Method (1)

StepMonitor (1)

WorkingPrecision (1)

アプリケーション (3)

特性と関係 (2)

考えられる問題 (6)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX