WOLFRAM

Wolfram 语言与系统参考资料中心

FisherRatioTest[data]

检验 data 的方差是否为 1.

FisherRatioTest[{data1,data2}]

检验 data1 和 data2 的方差是否相等.

FisherRatioTest[dspec,]

检验一个离散量数和 的关系.

FisherRatioTest[dspec,,"property"]

返回 "property" 的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
检验  
报告  
选项  
AlternativeHypothesis  
SignificanceLevel  
VerifyTestAssumptions  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

FisherRatioTest

FisherRatioTest[data]

检验 data 的方差是否为 1.

FisherRatioTest[{data1,data2}]

检验 data1 和 data2 的方差是否相等.

FisherRatioTest[dspec,]

检验一个离散量数和 的关系.

FisherRatioTest[dspec,,"property"]

返回 "property" 的值.

更多信息和选项

  • FisherRatioTest 检验零假设 与备择假设 ：
  • data
    {data1,data2}
  • 其中 σi2 是 datai 的总体方差.
  • 默认情况下，返回一个概率值或者 值.
  • 一个较小的 值表明 不可能为真.
  • dspec 中的 data 必须是单变量 {x1,x2,…}.
  • 变量 可以是任意正实数.
  • FisherRatioTest 要求数据服从正态分布.
  • FisherRatioTest[data,,"HypothesisTestData"] 返回一个 HypothesisTestData 对象 htd，可以使用 htd["property"] 的形式提取额外检验结果和属性.
  • FisherRatioTest[data,,"property"] 可以用来直接给出 "property" 值.
  • 与检验结果报告相关的属性包括：
  • "DegreesOfFreedom"检验中所用的自由度
    "PValue" 值列表
    "PValueTable" 值组成的格式化表格
    "ShortTestConclusion"检验结论的简短描述
    "TestConclusion"检验结论的描述
    "TestData"检验统计量和 值对组成的列表
    "TestDataTable" 值和检验统计量组成的格式化表格
    "TestStatistic"检验统计量组成的列表
    "TestStatisticTable"检验统计量组成的格式化的表格
  • 当样本数 给定，检验统计量基于 ，并且在 下，假定服从 ChiSquareDistribution[n-1].
  • 当给出的两个样本数分别为 和 时，检验统计量基于 ，并且在 下假定服从FRatioDistribution[n-1,m-1].
  • FisherRatioTest 通常称为用于相等方差的 F-检验.
  • 可以使用下来选项：
  • AlternativeHypothesis "Unequal"备择假设的不等性
    SignificanceLevel 0.05用于诊断和报告的分界点
    VerifyTestAssumptions Automatic设置要运行哪个诊断检验
  • 对于 FisherRatioTest，选择一个临界值 ，使得只有当 时，拒绝 . 用于 "TestConclusion" 和 "ShortTestConclusion" 属性的 值由 SignificanceLevel 选项控制. 值 也用于包含正态性和对称性的假设诊断检验. 默认情况下， 设置为 0.05.
  • 在 FisherRatioTest 中 VerifyTestAssumptions 的已命名设置包括：
  • "Normality"验证所有数据是否服从正态分布

范例

打开所有单元 关闭所有单元

基本范例  (2)

检验两个总体方差的相等性：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];
Wolfram Language code: htd = FisherRatioTest[data]

创建一个 HypothesisTestData 对象，用于进一步的属性提取：

Wolfram Language code: ℋ = FisherRatioTest[data, Automatic, "HypothesisTestData"]

检验属性：

Wolfram Language code: ℋ["Properties"]

将一个总体方差与一个特定的值进行比较：

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2.1], 10^3];
Wolfram Language code: FisherRatioTest[data, 4, "TestDataTable"]
Wolfram Language code: Variance[data]

对备择假设 进行检验：

Wolfram Language code: FisherRatioTest[data, 4, "TestDataTable", AlternativeHypothesis -> "Greater"]

范围  (9)

检验  (7)

检验一个总体的方差是否为 1：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 500]; data2 = RandomVariate[NormalDistribution[1, .3], 500];

在 下， 值通常较大：

Wolfram Language code: FisherRatioTest[data1]

当 为假时， 值通常较小：

Wolfram Language code: FisherRatioTest[data2]

将一个总体的方差与一个特定的值比较：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 2], 10^4]; data2 = RandomVariate[NormalDistribution[0, 2.1], 10^4];
Wolfram Language code: FisherRatioTest[data1, 2^2]
Wolfram Language code: FisherRatioTest[data2, 2^2]

比较两个总体的方差：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 3], 500]; data2 = RandomVariate[NormalDistribution[1, 3], 500]; data3 = RandomVariate[NormalDistribution[10, 1], 350];

当方差相等时， 值通常较大：

Wolfram Language code: FisherRatioTest[{data1, data2}]

当方差不相等时， 值通常较小：

Wolfram Language code: FisherRatioTest[{data1, data3}]

检验两个数据集方差的比率是否为一个特定的值：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 2], 500]; data2 = RandomVariate[NormalDistribution[0, 1], 500];
Wolfram Language code: Subscript[σ, 0] = 4;

以下形式是等价的：

Wolfram Language code: FisherRatioTest[{data2, data1}, 1 / Subscript[σ, 0]]
Wolfram Language code: FisherRatioTest[{data1, data2}, Subscript[σ, 0]]

当决定 时，需要考虑数据集的顺序：

Wolfram Language code: FisherRatioTest[{data2, data1}, Subscript[σ, 0]]

创建一个 HypothesisTestData 对象，以进行重复属性提取：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = FisherRatioTest[data, 1, "HypothesisTestData"];

可用于提取的属性：

Wolfram Language code: ℋ["Properties"]

从一个 HypothesisTestData 对象提取某些属性：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = FisherRatioTest[data, 1, "HypothesisTestData"];

值、检验统计量和自由度：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatistic"]
Wolfram Language code: ℋ["DegreesOfFreedom"]

同时提取任意数目的属性：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];
Wolfram Language code: ℋ = FisherRatioTest[data, 1, "HypothesisTestData"];

值、检验统计量和自由度：

Wolfram Language code: ℋ["PValue", "TestStatistic", "DegreesOfFreedom"]

报告  (2)

将检验结果制作成表格：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^3}];
Wolfram Language code: ℋ = FisherRatioTest[data, 1, "HypothesisTestData"];
Wolfram Language code: ℋ["TestDataTable"]

使用 "TestData" 可以提取表格中的值：

Wolfram Language code: ℋ["TestData"]

将 值或者检验统计量制作成表格：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = FisherRatioTest[data, 1, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable"]

来自表格的 值：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatisticTable"]

来自表格的检验统计量：

Wolfram Language code: ℋ["TestStatistic"]

选项  (8)

AlternativeHypothesis  (3)

默认情况下，执行一个双侧检验：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];

检验 ⟷ :

Wolfram Language code: FisherRatioTest[data, 1, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: FisherRatioTest[data, 1, AlternativeHypothesis -> Automatic]

执行一个双侧检验或者一个单侧检验：

Wolfram Language code: data = RandomVariate[NormalDistribution[0, 1.25], 100];

检验 ⟷ :

Wolfram Language code: FisherRatioTest[data, Automatic, AlternativeHypothesis -> "Unequal"]

检验 ⟷ :

Wolfram Language code: FisherRatioTest[data, Automatic, AlternativeHypothesis -> "Less"]

检验 ⟷ :

Wolfram Language code: FisherRatioTest[data, Automatic, AlternativeHypothesis -> "Greater"]

当均值为零时，执行单侧检验：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, .9], 100]; data2 = RandomVariate[NormalDistribution[0, 1], 100];
Wolfram Language code: Variance[data1] / Variance[data2]

检验 ⟷ :

Wolfram Language code: FisherRatioTest[{data1, data2}, 1, AlternativeHypothesis -> "Less"]

检验 ⟷ :

Wolfram Language code: FisherRatioTest[{data1, data2}, 1.5, AlternativeHypothesis -> "Less"]

SignificanceLevel  (2)

设置诊断检验的显著性水平：

Wolfram Language code: data = BlockRandom[SeedRandom[5];RandomVariate[StudentTDistribution[3], 50]];
Wolfram Language code: FisherRatioTest[data, 1, SignificanceLevel -> .005]

默认情况下，使用 0.05：

Wolfram Language code: FisherRatioTest[data, 1, SignificanceLevel -> Automatic]

对 "TestConclusion" 和 "ShortTestConclusion" 也使用显著性水平：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[NormalDistribution[0, 1], 100]];
Wolfram Language code: ℋ1 = FisherRatioTest[data, 1.5, "HypothesisTestData", SignificanceLevel -> .05];
Wolfram Language code: ℋ2 = FisherRatioTest[data, 1.5, "HypothesisTestData", SignificanceLevel -> .01];
Wolfram Language code: ℋ1["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ2["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ1["ShortTestConclusion"]
Wolfram Language code: ℋ2["ShortTestConclusion"]

VerifyTestAssumptions  (3)

使用 All 或者 None，可以以分组方式控制诊断：

Wolfram Language code: data1 = RandomVariate[StudentTDistribution[3], 1000]; data2 = RandomVariate[NormalDistribution[0, Sqrt[3]], 1000];

验证所有假定：

Wolfram Language code: FisherRatioTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> All]

不对假定进行检查：

Wolfram Language code: FisherRatioTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> None]

诊断可以独立控制：

Wolfram Language code: data1 = RandomVariate[StudentTDistribution[3], 1000]; data2 = RandomVariate[NormalDistribution[0, Sqrt[3]], 1000];

检查正态性：

Wolfram Language code: FisherRatioTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> "Normality"]

把正态性假定设为 True:

Wolfram Language code: FisherRatioTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> "Normality" -> True]

为了进行模拟，避开诊断检验通常是有用的：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {1000, 100}];
Wolfram Language code: AbsoluteTiming[T = Quiet@FisherRatioTest[#, Automatic, "TestStatistic"]& /@ data;]

设计中已经包含了检验假定，因此我们可以节省大量时间：

Wolfram Language code: AbsoluteTiming[T2 = FisherRatioTest[#, Automatic, "TestStatistic", VerifyTestAssumptions -> None]& /@ data;]

结果是相同的：

Wolfram Language code: SmoothHistogram[{T, T2}]

应用  (1)

某实验室考虑将一个电压表用更准确的电表替换. 新电表的制造商允许进行统计检验以确定它的有效性. 一位实验室技术人员测量由 15 个电压设为 9 伏的电源产生的电压：

Wolfram Language code: Subscript[m, old] = QuantityArray[{10.37, 8.28, 9.04, 8.96, 9.36, 8.18, 8.92, 8.44, 8.9, 9.82, 6.94, 9.67, 9.38, 10.43, 8.26}, "Volts"];
Wolfram Language code: Subscript[m, new] = QuantityArray[{9.52, 8.85, 9.17, 9.15, 9.19, 8.70, 9.09, 8.88, 8.98, 9.36, 8.19, 9.32, 9.26, 9.61, 8.73}, "Volts"];
Wolfram Language code: SmoothHistogram[{Subscript[m, old], Subscript[m, new]}//QuantityMagnitude]

PairedTTest 的结果表明来自两个电表的读数没有显著差异：

Wolfram Language code: PairedTTest[{Subscript[m, old], Subscript[m, new]}, Quantity[0, "Volts"], "TestDataTable"]

对相等方差的检验表明新电表的误差比旧电表少：

Wolfram Language code: FisherRatioTest[{Subscript[m, new], Subscript[m, old]}, 1, "TestDataTable", AlternativeHypothesis -> "Less"]

属性和关系  (8)

Fisher ratio 检验等价于单个数据集的 LeveneTest：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: FisherRatioTest[data]
Wolfram Language code: LeveneTest[data]

它也等价于单个数据集的 BrownForsytheTest：

Wolfram Language code: BrownForsytheTest[data]

给定长度为 的单个数据集，在 下检验统计量服从 ChiSquareDistribution[n-1]：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {1000, 100}];
Wolfram Language code: T = FisherRatioTest[#, Automatic, "TestStatistic", VerifyTestAssumptions -> None]& /@ data;
Wolfram Language code: Show[SmoothHistogram[T, PlotStyle -> Orange], Plot[PDF[ChiSquareDistribution[99], x], {x, 50, 160}], PlotRange -> All]

自由度的最大似然估计接近 ：

Wolfram Language code: EstimatedDistribution[T, ChiSquareDistribution[df]]
Wolfram Language code: DistributionFitTest[T, ChiSquareDistribution[99]]

对于双样本，FisherRatioTest 的检验统计量：

Wolfram Language code: Subscript[σ, 1] = 1;Subscript[σ, 2] = 3;
Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, Sqrt@Subscript[σ, 1]], 50]; data2 = RandomVariate[NormalDistribution[0, Sqrt@Subscript[σ, 2]], 70];
Wolfram Language code: (Subscript[σ, 2]/Subscript[σ, 1])(Variance[data1]/ Variance[data2])
Wolfram Language code: FisherRatioTest[{data1, data2}, Subscript[σ, 1] / Subscript[σ, 2], "TestStatistic"]

给定长度分别为 和 的两个数据集，在 下，检验统计量服从一个 FRatioDistribution[n-1,m-1]:

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], {1000, 100}]; data2 = RandomVariate[NormalDistribution[], {1000, 75}];
Wolfram Language code: T = MapThread[FisherRatioTest[{#1, #2}, Automatic, "TestStatistic", VerifyTestAssumptions -> None]&, {data1, data2}];
Wolfram Language code: Show[SmoothHistogram[T, PlotStyle -> Orange], Plot[PDF[FRatioDistribution[99, 74], x], {x, 0, 2}]]
Wolfram Language code: DistributionFitTest[T, FRatioDistribution[99, 74]]

Fisher ratio 检验对于正态性假设很灵敏：

Wolfram Language code: data = RandomVariate[ExponentialDistribution[10], {1000, 100}];
Wolfram Language code: Subscript[σ, 0] = Variance[ExponentialDistribution[10]]
Wolfram Language code: T = FisherRatioTest[#, Subscript[σ, 0], "TestStatistic", VerifyTestAssumptions -> None]& /@ data;

检验统计量的分布不是一个 ChiSquareDistribution[n-1]：

Wolfram Language code: Show[SmoothHistogram[T, PlotStyle -> Orange, PlotRange -> {0, .03}], Plot[PDF[ChiSquareDistribution[99], x], {x, 50, 160}]]

对于样本数为 、样本方差为 并且服从 NormalDistribution[μ,σ] 的样本，随机变量 服从 ChiSquareDistribution[n-1]：

Wolfram Language code: 𝒟 = TransformedDistribution[((x - μ)^2/σ^2), xNormalDistribution[μ, σ]];
Wolfram Language code: MomentGeneratingFunction[𝒟, t]^n - 1 == MomentGeneratingFunction[ChiSquareDistribution[n - 1], t]

下面服从 FRatioDistribution[n-1,m-1]：

Wolfram Language code: f = (((n - 1)Subscript[s, 1]^2/σ^2) / (n - 1)) / (((m - 1)Subscript[s, 2]^2/σ^2) / (m - 1))
Wolfram Language code: TransformedDistribution[(x / (n - 1)/y / (m - 1)), {xChiSquareDistribution[n - 1], yChiSquareDistribution[m - 1]}]

FisherRatioTest 的检验统计量服从 FRatioDistribution[n-1,m-1]：

Wolfram Language code: {Subscript[s, 1], Subscript[s, 2]} = StandardDeviation[data = RandomVariate[NormalDistribution[], {100, 2}]];
Wolfram Language code: (Subscript[s, 1]^2/Subscript[s, 2]^2)
Wolfram Language code: FisherRatioTest[Transpose@data, Automatic, "TestStatistic"]

只有当输入是 TimeSeries 时，Fisher ratio 检验作用于数值：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: FisherRatioTest[ts]
Wolfram Language code: FisherRatioTest[ts["Values"]]

当输入是 TemporalData 时，Fisher ratio 检验作用于所有数值：

Wolfram Language code: td = TemporalData[Automatic, {{{-0.25275046867718637, -0.7175779198306353, -1.9370139837317764, 0.006665621735740701, -0.3730807122324292, 0.6740106823161018, 0.8562214990564344, 0.955785083955732, 1.7020898014886303, 1.8523009430646802, 0.244 ... 3951759101545, -1.1611722313627828, 1.1602446901533021, 1.1052173095128992, 1.1089143920161917, -0.13837156328402}}, {{0, 100, 1}}, 2, {"Continuous", 2}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: FisherRatioTest[td]

检验所有数值：

Wolfram Language code: data = td["ValueList"]//Flatten; FisherRatioTest[data]

检测两条路径的方差是否相等：

Wolfram Language code: {data1, data2} = td["ValueList"];
Wolfram Language code: FisherRatioTest[{data1, data2}]

可能存在的问题  (1)

Fisher ratio 检验只适用于正态分布数据：

Wolfram Language code: data = RandomVariate[CauchyDistribution[0, 1], {2, 100}];
Wolfram Language code: FisherRatioTest[data]

当数据不服从正态分布时，使用 ConoverTest 或者 SiegelTukeyTest：

Wolfram Language code: ConoverTest[data]
Wolfram Language code: SiegelTukeyTest[data]

巧妙范例  (1)

当零假设 为真时，计算统计量：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2500, 100}];
Wolfram Language code: T1 = FisherRatioTest[#, 1, "TestStatistic", VerifyTestAssumptions -> None]& /@ data;

给出一个特定选择时的检验统计量：

Wolfram Language code: T2 = FisherRatioTest[#, 3, "TestStatistic", VerifyTestAssumptions -> None]& /@ data;

比较检验统计量的分布：

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}, PlotStyle -> Thick]
Wolfram Research (2010)，FisherRatioTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FisherRatioTest.html.

文本

Wolfram Research (2010)，FisherRatioTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FisherRatioTest.html.

CMS

Wolfram 语言. 2010. "FisherRatioTest." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FisherRatioTest.html.

APA

Wolfram 语言. (2010). FisherRatioTest. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FisherRatioTest.html 年

BibTeX

@misc{reference.wolfram_2026_fisherratiotest, author="Wolfram Research", title="{FisherRatioTest}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/FisherRatioTest.html}", note=[Accessed: 05-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_fisherratiotest, organization={Wolfram Research}, title={FisherRatioTest}, year={2010}, url={https://reference.wolfram.com/language/ref/FisherRatioTest.html}, note=[Accessed: 05-October-2026]}