Wolfram 语言与系统参考资料中心

Fit

Fit[data,{f₁,…,f_n},{x,y,…}]

求变量{x,y,…} 的函数 f₁,…,f_n 的 data 列表拟合 a₁ f₁+…+a_n f_n.

Fit[{m,v}]

求最小化设计矩阵 m 的的拟合向量 a.

Fit[…,"prop"]

指定应返回哪些拟合属性 prop.

范例

打开所有单元关闭所有单元

基本范例 (2)

这里有一些数据：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};

求对数据进行最佳拟合的线：

Wolfram Language code: line = Fit[data, {1, x}, x]

Wolfram Language code: DesignMatrix[data, {1, x}, x]

求数据的最小二乘拟合：

Wolfram Language code: parabola = Fit[data, {1, x, x ^ 2}, x]

用 2 条曲线显示数据：

Wolfram Language code: Show[ListPlot[data, PlotStyle -> Red], Plot[{line, parabola}, {x, 0, 5}]]

求给出设计矩阵和响应向量的最佳拟合参数：

Wolfram Language code:

m = N[HilbertMatrix[4]];
v = Range[4];
a = Fit[{m, v}]

范围 (2)

以下是一些用精确值定义的数据：

Wolfram Language code: data = {{-Pi, 4}, {-Pi / 2, 0}, {0, 1}, {Pi / 2, -1}, {Pi, -4}};

使用机器算术将数据拟合为正弦函数的线性组合：

Wolfram Language code: Fit[data, {Sin[x / 2], Sin[x], Sin[2 x]}, x]

使用 24 位精度算术拟合数据：

Wolfram Language code: Fit[N[data, 24], {Sin[x / 2], Sin[x], Sin[2 x]}, x]

用曲线显示数据：

Wolfram Language code: Show[ListPlot[data], Plot[%, {x, -Pi, Pi}], PlotRange -> All]

以下是三维中的一些数据：

Wolfram Language code: data = {{0, 0, 0}, {1, 0, 1}, {0, 1, 2}, {1, 1, 0}, {1 / 2, 1 / 2, 1}};

找到可最佳拟合数据的平面：

Wolfram Language code: plane = Fit[data, {1, x, y}, {x, y}]

显示带有数据点的平面：

Wolfram Language code:

Show[Plot3D[plane,   {x, 0, 1}, {y, 0, 1}, PlotStyle -> Opacity[.5], PlotRange -> {0, 2}], Graphics3D[{Red, PointSize[0.05], Map[Point, data]}]]

找到可最佳拟合数据的二次方：

Wolfram Language code: quad = Fit[data, {1, x, y, x ^ 2, x y, y ^ 2}, {x, y}]

二次方实际上是对数据进行插值：

Wolfram Language code:

Show[Plot3D[quad,   {x, 0, 1}, {y, 0, 1}, PlotStyle -> Opacity[.5], PlotRange -> {0, 2}], Graphics3D[{Red, PointSize[0.05], Map[Point, data]}]]

推广和延伸 (1)

这是一个值的列表：

Wolfram Language code: v = {5, 4, 3, 2, 1, 0, 1, 2, 3, 4, 5};

对二次拟合. 当坐标没有给出时，假定植为成对的1，2，…：

Wolfram Language code: quad = Fit[v, {1, x, x ^ 2}, x]

二次拟合：

Wolfram Language code: quart = Fit[v, {1, x, x ^ 2, x ^ 3, x ^ 4}, x]

用曲线显示数据：

Wolfram Language code: Show[ListPlot[v, PlotStyle -> Red], Plot[{quad, quart}, {x, 1, Length[v]}]]

选项 (6)

FitRegularization (2)

Tikhonov 正则化控制最佳拟合参数的大小：

Wolfram Language code: data = {{0., 0.}, {0.001, 1}, {0.01, 1}};

Wolfram Language code: Fit[data, {1, x, x ^ 2}, x, FitRegularization -> {"Tikhonov", 1}]

没有正则化，系数相当大：

Wolfram Language code: Fit[data, {1, x, x ^ 2}, x]

这也可以用 "L2" 或 "RidgerRegression" 指代：

Wolfram Language code: Fit[data, {1, x, x ^ 2}, x, FitRegularization -> {"L2", 1}]

Wolfram Language code: Fit[data, {1, x, x ^ 2}, x, FitRegularization -> {"RidgeRegression", 1}]

LASSO （最小绝对收缩和选择算子）正则化选择最重要的基函数，并对最佳拟合参数的大小进行一些控制：

Wolfram Language code: data = {{0., 0.}, {0.001, 1}, {0.01, 1}, {.1, 0}, {1, 1}};

Wolfram Language code: Fit[data, {1, x, x ^ 2, x ^ 3, x ^ 4}, x, FitRegularization -> {"LASSO", 1}]

没有正则化，系数是相当大的：

Wolfram Language code: Fit[data, {1, x, x ^ 2, x ^ 3, x ^ 4}, x]

这也可以被 "L1" 引用：

Wolfram Language code: Fit[data, {1, x, x ^ 2, x ^ 3, x ^ 4}, x, FitRegularization -> {"L1", 1}]

NormFunction (3)

使用 1-范数度量“最佳”拟合:

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};

Wolfram Language code: l1 = Fit[data, {1, x}, x, NormFunction -> Function[Norm[#, 1]]]

Wolfram Language code: Show[ListPlot[data, PlotStyle -> PointSize[0.025]], Plot[l1, {x, 0, 5}], PlotRange -> All]

与最小二乘（金色）和最大范数（绿色）拟合比较：

Wolfram Language code:

l2 = Fit[data, {1, x}, x];
l∞ = Fit[data, {1, x}, x, NormFunction -> Function[Norm[#, ∞]]];
Show[ListPlot[data, PlotStyle -> PointSize[0.025]], Plot[{l1, l2, l∞}, {x, 0, 5}], PlotRange -> All]

交互式操作范数 p：

Wolfram Language code:

Manipulate[Plot[Evaluate[With[{q = 1 / pr}, Fit[data, {1, x}, x, NormFunction -> Function[Norm[#, q]]]]], {x, 0, 5}, PlotRange -> {-1, 4}, Epilog -> {PointSize[.025], Point[data], Text["p = " <> ToString[1 / pr], {1, 3}]}], {{pr, 1 / 2, "1/p"}, 0.0001, .9999}, SaveDefinitions -> True]

使用 Huber 惩罚函数来平衡具有最小二乘的异常值的影响：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};

Wolfram Language code: hfit = Fit[data, {1, x}, x, NormFunction -> {"HuberPenalty", .1}]

Wolfram Language code: Show[ListPlot[data, PlotStyle -> PointSize[0.025]], Plot[hfit, {x, 0, 5}], PlotRange -> All]

交互式操作参数：

Wolfram Language code:

Manipulate[Plot[Evaluate[Fit[data, {1, x}, x, NormFunction -> {"HuberPenalty", α}]], {x, 0, 5}, PlotRange -> {-1, 4}, Epilog -> {PointSize[.025], Point[data], Text["α = " <> ToString[α], {1, 3}]}], {{α, .1}, 0.0001, 2}, SaveDefinitions -> True]

计算加权最小二乘拟合：

Wolfram Language code:

data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};
fit = Fit[data, {1, x}, x, NormFunction -> Function[Norm[#  Range[4]]]];
Show[ListPlot[data, PlotStyle -> PointSize[0.025]], Plot[fit, {x, 0, 5}], PlotRange -> All]

WorkingPrecision (1)

使用 24 位精度计算拟合：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};

Wolfram Language code: Fit[data, {1, x, x ^ 2}, x, WorkingPrecision -> 24]

使用精确计算：

Wolfram Language code: Fit[data, {1, x, x ^ 2}, x, WorkingPrecision -> ∞]

应用 (6)

使用 Chebyshev 基础计算适合数据的高次多项式：

Wolfram Language code:

coord = RandomReal[{-1, 1}, 100];
data = Transpose[{coord, Sinc[10 coord]}];

Wolfram Language code:

degree  = 47;
basis = Table[ChebyshevT[k, x], {k, 0, degree}];
fit = Fit[data, basis, x];

Wolfram Language code: Plot[fit, {x, -1, 1}, Epilog -> Point[data]]

使用正则化将数值解稳定到，其中，被扰动：

Wolfram Language code:

a = N[HilbertMatrix[47]];
xexact = Table[t * (1 - t), {t, 0., 1., 1 / 46}];
b = a.xexact + 10^ - 8 RandomReal[{-1, 1}, 47];

LinearSolve 找到的解有很大的项：

Wolfram Language code: ListPlot[LinearSolve[a, b]]

正则化的解更接近于未扰动问题的解：

Wolfram Language code: xreg = Table[Fit[{a, b}, FitRegularization -> {"Tikhonov", 10 ^ -ll}], {ll, 0, 3, 2}];

Wolfram Language code: ListPlot[Prepend[xreg, xexact], PlotStyle -> PointSize[0.025]]

使用变正则化求输入信号的平滑近似：

Wolfram Language code:

n = 201;
m = 201;
times = Range[m];

输出目标是阶跃函数：

Wolfram Language code:

m1 = Round[m / 5]; m2 = Round[m / 4]; m3 = Round[m / 4];output = ConstantArray[0, m];
output[[m1 + Range[m2]]] = 1;
output[[m1 + m2 + Range[m3]]] = -1;
op = ListLinePlot[output]

输入由输出通过与卷积决定：

Wolfram Language code: h = (1/9)(1 - .4Cos[2 times]) * .9 ^ times;hmat = ToeplitzMatrix[h, Prepend[ConstantArray[0, n - 1], h[[1]]]];

没有正则化，谓词响应非常接近地匹配信号，但计算的输入有很多振荡：

Wolfram Language code:

{input, predicted} = Fit[{hmat, output}, {"BestFitParameters", "PredictedResponse"}];
Row[{ListLinePlot[input], ListLinePlot[{predicted, output}]}]

通过变换的正则化，可以找到更平滑的近似值：

Wolfram Language code:

{input, predicted} = Fit[{hmat, output}, {"BestFitParameters", "PredictedResponse"}, FitRegularization -> {"Variation", .3}];
Row[{ListLinePlot[input], ListLinePlot[{predicted, output}]}]

也可以包括输入大小的正则化：

Wolfram Language code:

{input, predicted} = Fit[{hmat, output}, {"BestFitParameters", "PredictedResponse"}, FitRegularization -> {{"Variation", .3}, {"Tikhonov", .01}}];
Row[{ListLinePlot[input], ListLinePlot[{predicted, output}]}]

使用变化正则化平滑损坏的信号：

Wolfram Language code:

n = 4000;
times = N[Range[0, n - 1]];
original = .5 Sin[2 Pi times / n] * Sin[.01 times];
corrupted = original + RandomReal[{-.05, .05}, n];
ListLinePlot[corrupted]

绘制残差范数与变化范数之间的权衡：

Wolfram Language code: id = IdentityMatrix[n, SparseArray];

Wolfram Language code:

tradeoff = Table[{smoothed, residual} = Fit[{id, corrupted}, {"BestFitParameters", "FitResiduals"}, FitRegularization -> {"Variation", 2 ^ logλ}];Tooltip[{Norm[Differences[smoothed]], Norm[residual]}, 2. ^ logλ], {logλ, -10, 20}];

Wolfram Language code: ListPlot[tradeoff, Joined -> True, Mesh -> All]

在曲线急剧弯曲的位置附近选择的值：

Wolfram Language code: smoothed = Fit[{id, corrupted}, "BestFitParameters", FitRegularization -> {"Variation", 100}];

Wolfram Language code: ListLinePlot[{corrupted, smoothed}]

使用总变差正则化来平滑带有跳跃的损坏信号：

Wolfram Language code:

n = 2000; 
id = IdentityMatrix[n, SparseArray];
times = Range[0, n - 1];
temp = ConstantArray[1, n / 4];
original = Join[temp, -temp, temp, -temp] + .5 Sin[2 Pi times / n];
corrupted = original + RandomReal[{-.1, .1}, n];
ListLinePlot[{corrupted, original}]

参数的正则化：

Wolfram Language code: smoothed = Fit[{id, corrupted}, "BestFitParameters", FitRegularization -> {"TotalVariation", 2.}];

Wolfram Language code: ListLinePlot[{smoothed, original}]

较小的值给出较少的平滑，但残差范数较小：

Wolfram Language code: lesssmoothed = Fit[{id, corrupted}, "BestFitParameters", FitRegularization -> {"TotalVariation", .1}];

Wolfram Language code: ListLinePlot[{lesssmoothed, original}]

Wolfram Language code: {Norm[original - smoothed], Norm[original - lesssmoothed]}

使用 LASSO (L1) 正则化来找到稀疏拟合（基追踪）：

Wolfram Language code:

σ = 0.05;
nτ = 500;
times = Subdivide[0., 1., nτ];
nω = 30;

信号：

Wolfram Language code:

signal = (1 + .5 Sin[11 times])Sin[30 Sin[5 times]];
sdata = Transpose[{times, signal}];
ListLinePlot[sdata]

目标是用几千个 Gabor 基函数中的少数几个来近似信号：

Wolfram Language code:

Length[basis = Flatten[
	Table[Exp[-(((t - τ)/σ))^2]
	{1, Table[{Cos[ω t], Sin[ω t]}, {ω, Drop[Subdivide[0., 150., nω], 1]}]}, 
	{τ, Subdivide[0., 1., nτ]}]]]

当，只需要 41 个基元素就可以找到拟合：

Wolfram Language code: AbsoluteTiming[sparseFit = Fit[sdata, basis, t, "BestFitParameters", FitRegularization -> {"LASSO", 1.}]]

误差相当小：

Wolfram Language code:

fitt = basis.sparseFit /. t -> times;
ListLinePlot[Transpose[{times, signal - fitt}]]

一旦找到基础的重要元素，就可以通过找到最小二乘拟合这些这些元素来减少误差：

Wolfram Language code:

bpos = Flatten[sparseFit["NonzeroPositions"]];
sbasis = basis[[bpos]];
sbfit = Fit[sdata, sbasis, t];
ListLinePlot[Transpose[{times, signal - (sbfit /. t -> times)}], PlotRange -> All]

当更小的值，使用更多的基本元素找到拟合：

Wolfram Language code: AbsoluteTiming[sparseFit = Fit[sdata, basis, t, "BestFitParameters", FitRegularization -> {"LASSO", 0.1}]]

误差更小：

Wolfram Language code:

fitt = basis.sparseFit /. t -> times;
ListLinePlot[Transpose[{times, signal - fitt}]]

属性和关系 (5)

Fit 给出最佳拟合函数：

Wolfram Language code: Fit[Range[10], {1, x ^ 2}, x]

LinearModelFit 允许提取拟合的其他信息：

Wolfram Language code: lm = LinearModelFit[Range[10], x ^ 2, x]

从拟合函数中提取信息：

Wolfram Language code: lm["BestFit"]

提取其他结果和诊断：

Wolfram Language code: lm[{"RSquared", "FitResiduals", "ANOVATable"}]

这是一些数据：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};

这是直线 a+b x 的二次误差的和：

Wolfram Language code: ss[a_, b_] = Block[{x = data[[All, 1]], y = data[[All, 2]], res}, res = y - (a + b x);res.res]

求符号最小值：

Wolfram Language code: Minimize[ss[a, b], {a, b}]

Wolfram Language code: N[a + b x /. %[[2]]]

这是 Fit 给出的系数：

Wolfram Language code: Fit[data, {1, x}, x]

精确系数可以通过使用 WorkingPrecision->Infinity 找到：

Wolfram Language code: Fit[data, {1, x}, x, "BestFitParameters", WorkingPrecision -> Infinity]

这是二次表达式 a+b x+c x^2 的二次误差的和：

Wolfram Language code: ss[a_, b_, c_] = Block[{x = data[[All, 1]], y = data[[All, 2]], res}, res = y - (a + b x + c x ^ 2);res.res]

求符号最小值：

Wolfram Language code: Minimize[ss[a, b, c], {a, b, c}]

Wolfram Language code: N[a + b x + c x ^ 2 /. %[[2]]]

这是 Fit 给出的系数：

Wolfram Language code: Fit[data, {1, x, x ^ 2}, x, "BestFitParameters", WorkingPrecision -> Infinity]

当一个多项式拟合执行到足够的次数，Fit 返回插值多项式：

Wolfram Language code:

data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};
Fit[data, {1, x, x ^ 2, x ^ 3}, x]

结果与 InterpolatingPolynomial 给出的一致：

Wolfram Language code: InterpolatingPolynomial[data, x]

Wolfram Language code: N[Expand[%]]

Fit 以变量的形式使用 TimeSeries 的时间戳：

Wolfram Language code:

ts1 = TemporalData[TimeSeries, {{{1.102448341846048, 6.331833897009389, 7.5843632999043455, 
    44.59969789743589, 98.76273258351092, 150.00729051003992, 644.7367359379259, 
    1724.3968817536402, 5903.697723461762, 19468.09340765025}}, {{0, 9, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1];

Wolfram Language code: ts1["Times"]

Wolfram Language code: base = {1, Exp[x], Exp[2 x], Exp[x ^ 2]};

Wolfram Language code: Fit[ts1, base, x]

缩放时间戳并且再次拟合：

Wolfram Language code: ts2 = TimeSeriesRescale[ts1, {.1, 2}]

Wolfram Language code: ts2["Times"]

Wolfram Language code: Fit[ts2, base, x]

求数值的拟合：

Wolfram Language code: Fit[ts1["Values"], base, x]

Fit 按路径作用于多条路径的 TemporalData:

Wolfram Language code:

Fit[TemporalData[Automatic, {{{1.102448341846048, 6.331833897009389, 7.5843632999043455, 
    44.59969789743589, 98.76273258351092, 150.00729051003992, 644.7367359379259, 
    1724.3968817536402, 5903.697723461762, 19468.09340765025}, 
   {1.1024483418 ... 7359379259, 1724.3968817536402, 5903.697723461762, 
    19468.09340765025}}, {{0, 9, 1}, {0.1, 2., 0.2111111111111111}}, 2, {"Continuous", 2}, 
  {"Discrete", 2}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1], {1, Exp[x], Exp[2 x]}, x]

可能存在的问题 (2)

这是一些高斯随机波动产生的数据：

Wolfram Language code:

data = Block[{r = RandomReal[100, 100]}, Transpose[{r, Exp[-(r - 50) ^ 2 / 10] + RandomReal[.1, 100]}]];
lp = ListPlot[data, PlotRange -> All]

这个函数给出了多项式的标准基：

Wolfram Language code: nbasis[n_Integer][x_] := Table[x ^ k, {k, 0, n}]

Wolfram Language code: nbasis[10][x]

显示连续高阶多项式的拟合计算：

Wolfram Language code:

Table[
	fit = Fit[data, nbasis[n][x], x];
	Show[Plot[fit, {x, 0, 100}, PlotRange -> All], lp, PlotRange -> {-.25, 1}, PlotLabel -> "n = " <> ToString[n]], 
	{n, 10, 40, 10}]

问题时对高阶幂而言，系数非常小：

Wolfram Language code: Fit[data, nbasis[10][x], x]

给出根据比例和位移值的基，有助于解决这个问题：

Wolfram Language code:

Table[
	fit = Fit[data, nbasis[n][(x - 50) / 50], x];
	Show[Plot[fit, {x, 0, 100}, PlotRange -> All], lp, PlotRange -> {-.25, 1}, PlotLabel -> "n = " <> ToString[n]], 
	{n, 10, 40, 10}]

从压缩传感数据重建稀疏信号：

Wolfram Language code:

k = 7;
n = 1000;
signal = Normal[SparseArray[RandomInteger[{1, n}, k] -> RandomReal[{-1, 1}, k], {n}]];
ListPlot[signal, Filling -> Axis]

压缩感知包括将信号乘以矩阵，其中，因此只需传输长度为的数据. 如果足够大，具有独立相同分布的正态条目的随机矩阵将满足受限制的等距属性，并且可以非常高的概率恢复原始信号：

Wolfram Language code: m = Ceiling[6 k Log[n / k]]

Wolfram Language code: a = RandomVariate[NormalDistribution[0, 1 / m], {m, n}];

要发送的样本是通过将信号与矩阵相乘来构造的：

Wolfram Language code: samples = a.signal;

对于的所有可能解决方案，可以通过最小化进行重建：

Wolfram Language code: AbsoluteTiming[reconstructed = NArgMin[{Norm[x, 1], a.x == samples}, x];]

Wolfram Language code: Max[Abs[reconstructed - signal]]

即使最小化是通过线性优化解决的，但它相对较慢，因为所有约束都是等式约束. 使用基础追踪（L1 正则化）可以更快地找到解决方案：

Wolfram Language code: AbsoluteTiming[bpsol = Fit[{a, samples}, FitRegularization -> {"L1", 0.0001}]]

这给出了基本要素. 要找到最佳解，求出与这些分量对应的线性方程：

Wolfram Language code:

basisPositions = bpsol["NonzeroPositions"];
values = LinearSolve[a[[All, Flatten[basisPositions]]], samples];
bpReconstructed = SparseArray[basisPositions -> values, {n}]

Wolfram Language code: Max[Abs[bpReconstructed - signal]]

Top

	{v₁,…,v_n}	等同于 {{1,v₁},…,{n,v_n}}
	{{x₁,v₁},…,{x_n,v_n}}	在坐标 x_i 具有值 v_i 的单变量数据
	{{x₁,y₁,v₁},…}	在坐标 {x_i,y_i} 具有值 v_i 的双变量数据
	{{x₁,y₁,…,v₁},…}	在坐标 {x_i,y_i,…} 具有值 v_i 的多变量数据

"BasisFunctions	funs	基本函数
"BestFit"		基本函数的最佳拟合线性组合
"BestFitParameters"		给出最佳拟合的向量
"Coordinates"	{{x₁,y₁,…},…}	data 中 vars 的坐标
"Data"	data	数据
"DesignMatrix"	m
"FitResiduals"		坐标中模型和拟合之间的差
"Function"	Function[{x,y,…},a₁ f₁+…+a_n f_n]	最佳拟合纯函数
"PredictedResponse"		data 坐标的拟合值
"Response"		来自输入 data 的响应向量
{"prop₁","prop₂",…}		多个拟合属性

	normf	应用于偏差的函数 normf
	{"Penalty", pf}	应用于偏差的每个分量的惩罚函数 pf 之和
	{"HuberPenalty",α}	每个分量的 Huber 惩罚函数之和
	{"DeadzoneLinearPenalty",α}	每个分量的死区线性惩罚函数之和

	None	无正则化
	rfun	用 rfun[a] 正则化
	{"Tikhonov",λ}	用正则化
	{"LASSO",λ}	用正则化
	{"Variation",λ}	用 $lambda\|\|TemplateBox[{Differences, paclet:ref/Differences}, RefLink, BaseStyle -> {2ColumnTableMod}][a]\|\|^2$ 正则化
	{"TotalVariation",λ}	用 $lambda\|\|TemplateBox[{Differences, paclet:ref/Differences}, RefLink, BaseStyle -> {2ColumnTableMod}][a]\|\|_1$ 正则化
	{"Curvature",λ}	$lambda\|\|TemplateBox[{Differences, paclet:ref/Differences}, RefLink, BaseStyle -> {2ColumnTableMod}][a,2]\|\|^2$ 正则化
	{r₁,r₂,…}	用来自于 r₁,… 项之和正则化

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Fit

更多信息和选项

范例

基本范例 (2)

范围 (2)

推广和延伸 (1)

选项 (6)

FitRegularization (2)

NormFunction (3)

WorkingPrecision (1)

应用 (6)

属性和关系 (5)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

NormFunction	Norm	衡量最小化偏差
FitRegularization	None	拟合参数的正则化
WorkingPrecision	Automatic	使用的精度

Fit

更多信息和选项

范例

基本范例 (2)

范围 (2)

推广和延伸 (1)

选项 (6)

FitRegularization (2)

NormFunction (3)

WorkingPrecision (1)

应用 (6)

属性和关系 (5)

可能存在的问题 (2)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX