WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

InverseZTransform[expr,z,n]

expr の逆Z変換を与える．

InverseZTransform[expr,{z1,…,zm},{n1,…,nm}]

expr の多重逆Z変換を与える

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Assumptions  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

InverseZTransform

InverseZTransform[expr,z,n]

expr の逆Z変換を与える．

InverseZTransform[expr,{z1,…,zm},{n1,…,nm}]

expr の多重逆Z変換を与える

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

一変数逆変換：

Wolfram Language code: InverseZTransform[z / (z - a), z, n]
Wolfram Language code: InverseZTransform[z / (z ^ 2 - 3z + 1), z, n]

多変数逆変換：

Wolfram Language code: InverseZTransform[(z1 z2/(z1 - 1)^2(z2 - 1)^2), {z1, z2}, {n1, n2}]
Wolfram Language code: InverseZTransform[E ^ (1 / z1) / z2, {z1, z2}, {n1, n2}]

スコープ  (4)

定数はインパルス列に至る：

Wolfram Language code: InverseZTransform[1, z, n]

シフトされたインパルス列：

Wolfram Language code: InverseZTransform[z ^ -3, z, n]

有理変換は指数列と三角法の列を与える：

Wolfram Language code: InverseZTransform[z / (z - a), z, n]
Wolfram Language code: InverseZTransform[z / (z - a) ^ 2, z, n]
Wolfram Language code: InverseZTransform[1 / ((-3 + z) (-2 + z) (-1 + z) z), z, n]

場合によっては追加的な簡約と変換が必要な場合もある：

Wolfram Language code: InverseZTransform[z Sin[w] / (z ^ 2 - 2z Cos[w] + 1), z, n]
Wolfram Language code: FullSimplify[%, Element[w, Reals] && Element[n, Integers]]
Wolfram Language code: InverseZTransform[(E^I z (4 - 8 E^I z + z^2 + E^2 I (4 + z^2))/(2 z + 2 E^2 I z - E^I (4 + z^2))^2), z, n]//ExpToTrig//FullSimplify

初等関数：

Wolfram Language code: InverseZTransform[E ^ (1 / z), z, n]
Wolfram Language code: InverseZTransform[Cos[Sqrt[1 / z]], z, n]
Wolfram Language code: InverseZTransform[Log[z / (z + 1)], z, n]
Wolfram Language code: InverseZTransform[Sqrt[1 + z ^ -2], z, n]

特殊関数：

Wolfram Language code: InverseZTransform[PolyLog[-k, c / z], z, n]
Wolfram Language code: InverseZTransform[z ^ 3 BesselI[3, 2 / z], z, n]

オプション  (1)

Assumptions  (1)

この変換は p の範囲についてのなんらかの制約条件なしには評価しない：

Wolfram Language code: InverseZTransform[z / (z - a) ^ p, z, n]

Assumptionsを使って p の範囲を制限する：

Wolfram Language code: InverseZTransform[z / (z - a) ^ p, z, n, Assumptions -> p∈Integers && p > 0]

アプリケーション  (3)

線形差分方程式を解く：

Wolfram Language code: ZTransform[y[n + 1] + 2y[n] == 1, n, z]

初期値方程式を追加し，変換のための代数方程式を解く：

Wolfram Language code: Solve[% /. {y[0] -> 3}, ZTransform[y[n], n, z]]

逆変換を通して解を得る：

Wolfram Language code: InverseZTransform[ZTransform[y[n], n, z] /. First[%], z, n]

RSolveを使う：

Wolfram Language code: RSolve[{y[n + 1] + 2y[n] == 1, y[0] == 3}, y[n], n]

線形差分総和方程式を解く：

Wolfram Language code: ZTransform[y[n + 1] == 2y[n] - Sum[2 ^ (n - r)y[r], {r, 0, n}], n, z]
Wolfram Language code: Solve[% /. {y[0] -> 1}, ZTransform[y[n], n, z]]

逆変換を使ってもとの問題の解を得る：

Wolfram Language code: InverseZTransform[ZTransform[y[n], n, z] /. First[%], z, n]

RSolveを使う：

Wolfram Language code: RSolve[{y[n + 1] == 2y[n] - Sum[2 ^ (n - r)y[r], {r, 0, n}], y[0] == 1}, y[n], n]

離散系伝達関数：

Wolfram Language code: h = 1 / ((z - 1 / 2)(z - 2))

インパルス応答：

Wolfram Language code: u = ZTransform[DiscreteDelta[n], n, z]
Wolfram Language code: InverseZTransform[h u, z, n]

ステップ応答：

Wolfram Language code: u = ZTransform[UnitStep[n], n, z]
Wolfram Language code: InverseZTransform[h u, z, n]

ランプ応答：

Wolfram Language code: u = ZTransform[UnitStep[n]n, n, z]
Wolfram Language code: InverseZTransform[h u, z, n]

特性と関係  (6)

DiscreteAsymptoticを使って漸近近似を計算する：

Wolfram Language code: DiscreteAsymptotic[Inactive[InverseZTransform][1 / (z(-6 + 6 * z ^ 2 + z ^ 3)), z, n], n -> ∞]

ZTransformは逆作用素である：

Wolfram Language code: ZTransform[InverseZTransform[F[z], z, n], n, z]
Wolfram Language code: InverseZTransform[ZTransform[f[n], n, z], z, n]
Wolfram Language code: ZTransform[2 ^ n n, n, z]
Wolfram Language code: InverseZTransform[%, z, n]

線形性：

Wolfram Language code: InverseZTransform[a F[z] + b G[z], z, n]

シフト：

Wolfram Language code: InverseZTransform[z ^ (-1) ZTransform[f[n], n, z], z, n]
Wolfram Language code: InverseZTransform[z ^ (-2) ZTransform[f[n], n, z], z, n]

導関数：

Wolfram Language code: InverseZTransform[ D[ZTransform[f[n], n, z], z], z, n]
Wolfram Language code: InverseZTransform[ D[ZTransform[f[n], n, z], {z, 2}], z, n]

初期値の特性：

Wolfram Language code: InverseZTransform[z / ((z - 1 / 2)(z - 1 / 3)), z, n]
Wolfram Language code: Limit[%, n -> 0] == Limit[z / ((z - 1 / 2)(z - 1 / 3)), z -> Infinity]

最終値の特性：

Wolfram Language code: InverseZTransform[z / ((z - 1 / 2)(z - 1 / 3)), z, n]
Wolfram Language code: Limit[%, n -> Infinity] == Limit[z / ((z - 1 / 2)(z - 1 / 3)), z -> 0]

InverseZTransformはSeriesCoefficientと密接な関係がある：

Wolfram Language code: InverseZTransform[E ^ (1 / z), z, n]
Wolfram Language code: SeriesCoefficient[E ^ z, {z, 0, n}]

おもしろい例題  (1)

超幾何関数の逆変換：

Wolfram Language code: InverseZTransform[HypergeometricPFQ[{}, {2 / 3, 1, 4 / 3}, 1 / z], z, n]
Wolfram Language code: ZTransform[%, n, z]
Wolfram Research (1999), InverseZTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/InverseZTransform.html （2008年に更新）.

テキスト

Wolfram Research (1999), InverseZTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/InverseZTransform.html （2008年に更新）.

CMS

Wolfram Language. 1999. "InverseZTransform." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/InverseZTransform.html.

APA

Wolfram Language. (1999). InverseZTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseZTransform.html

BibTeX

@misc{reference.wolfram_2026_inverseztransform, author="Wolfram Research", title="{InverseZTransform}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/InverseZTransform.html}", note=[Accessed: 04-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_inverseztransform, organization={Wolfram Research}, title={InverseZTransform}, year={2008}, url={https://reference.wolfram.com/language/ref/InverseZTransform.html}, note=[Accessed: 04-October-2026]}