WOLFRAM

Wolfram 语言与系统参考资料中心

InverseZTransform[expr,z,n]

给出 expr 的 Z 反变换.

InverseZTransform[expr,{z1,…,zm},{n1,…,nm}]

给出 expr 的多维 Z 反变换.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Assumptions  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

InverseZTransform

InverseZTransform[expr,z,n]

给出 expr 的 Z 反变换.

InverseZTransform[expr,{z1,…,zm},{n1,…,nm}]

给出 expr 的多维 Z 反变换.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

单元反变换：

Wolfram Language code: InverseZTransform[z / (z - a), z, n]
Wolfram Language code: InverseZTransform[z / (z ^ 2 - 3z + 1), z, n]

多元反变换：

Wolfram Language code: InverseZTransform[(z1 z2/(z1 - 1)^2(z2 - 1)^2), {z1, z2}, {n1, n2}]
Wolfram Language code: InverseZTransform[E ^ (1 / z1) / z2, {z1, z2}, {n1, n2}]

范围  (4)

常量导致脉冲序列：

Wolfram Language code: InverseZTransform[1, z, n]

移动脉冲序列：

Wolfram Language code: InverseZTransform[z ^ -3, z, n]

有理变换产生指数和三角序列：

Wolfram Language code: InverseZTransform[z / (z - a), z, n]
Wolfram Language code: InverseZTransform[z / (z - a) ^ 2, z, n]
Wolfram Language code: InverseZTransform[1 / ((-3 + z) (-2 + z) (-1 + z) z), z, n]

在某些情况下，需要额外的化简和变换：

Wolfram Language code: InverseZTransform[z Sin[w] / (z ^ 2 - 2z Cos[w] + 1), z, n]
Wolfram Language code: FullSimplify[%, Element[w, Reals] && Element[n, Integers]]
Wolfram Language code: InverseZTransform[(E^I z (4 - 8 E^I z + z^2 + E^2 I (4 + z^2))/(2 z + 2 E^2 I z - E^I (4 + z^2))^2), z, n]//ExpToTrig//FullSimplify

基本函数：

Wolfram Language code: InverseZTransform[E ^ (1 / z), z, n]
Wolfram Language code: InverseZTransform[Cos[Sqrt[1 / z]], z, n]
Wolfram Language code: InverseZTransform[Log[z / (z + 1)], z, n]
Wolfram Language code: InverseZTransform[Sqrt[1 + z ^ -2], z, n]

特殊函数：

Wolfram Language code: InverseZTransform[PolyLog[-k, c / z], z, n]
Wolfram Language code: InverseZTransform[z ^ 3 BesselI[3, 2 / z], z, n]

选项  (1)

Assumptions  (1)

如果 p 的范围没有限制，不会进行该转换：

Wolfram Language code: InverseZTransform[z / (z - a) ^ p, z, n]

用 Assumptions 限制 p 的范围：

Wolfram Language code: InverseZTransform[z / (z - a) ^ p, z, n, Assumptions -> p∈Integers && p > 0]

应用  (3)

求解一个线性微分方程：

Wolfram Language code: ZTransform[y[n + 1] + 2y[n] == 1, n, z]

对变换增加一个初值并求解代数方程：

Wolfram Language code: Solve[% /. {y[0] -> 3}, ZTransform[y[n], n, z]]

获得反变换中的解：

Wolfram Language code: InverseZTransform[ZTransform[y[n], n, z] /. First[%], z, n]

用 RSolve：

Wolfram Language code: RSolve[{y[n + 1] + 2y[n] == 1, y[0] == 3}, y[n], n]

求解一个线性差分和的方程：

Wolfram Language code: ZTransform[y[n + 1] == 2y[n] - Sum[2 ^ (n - r)y[r], {r, 0, n}], n, z]
Wolfram Language code: Solve[% /. {y[0] -> 1}, ZTransform[y[n], n, z]]

用反变换得到原问题的解：

Wolfram Language code: InverseZTransform[ZTransform[y[n], n, z] /. First[%], z, n]

用 RSolve：

Wolfram Language code: RSolve[{y[n + 1] == 2y[n] - Sum[2 ^ (n - r)y[r], {r, 0, n}], y[0] == 1}, y[n], n]

一个离散系统的转移函数：

Wolfram Language code: h = 1 / ((z - 1 / 2)(z - 2))

脉冲响应：

Wolfram Language code: u = ZTransform[DiscreteDelta[n], n, z]
Wolfram Language code: InverseZTransform[h u, z, n]

阶越响应：

Wolfram Language code: u = ZTransform[UnitStep[n], n, z]
Wolfram Language code: InverseZTransform[h u, z, n]

斜坡响应：

Wolfram Language code: u = ZTransform[UnitStep[n]n, n, z]
Wolfram Language code: InverseZTransform[h u, z, n]

属性和关系  (6)

用 DiscreteAsymptotic 计算渐近近似：

Wolfram Language code: DiscreteAsymptotic[Inactive[InverseZTransform][1 / (z(-6 + 6 * z ^ 2 + z ^ 3)), z, n], n -> ∞]

ZTransform 是逆操作：

Wolfram Language code: ZTransform[InverseZTransform[F[z], z, n], n, z]
Wolfram Language code: InverseZTransform[ZTransform[f[n], n, z], z, n]
Wolfram Language code: ZTransform[2 ^ n n, n, z]
Wolfram Language code: InverseZTransform[%, z, n]

线性特性：

Wolfram Language code: InverseZTransform[a F[z] + b G[z], z, n]

偏移性：

Wolfram Language code: InverseZTransform[z ^ (-1) ZTransform[f[n], n, z], z, n]
Wolfram Language code: InverseZTransform[z ^ (-2) ZTransform[f[n], n, z], z, n]

可导性：

Wolfram Language code: InverseZTransform[ D[ZTransform[f[n], n, z], z], z, n]
Wolfram Language code: InverseZTransform[ D[ZTransform[f[n], n, z], {z, 2}], z, n]

初值属性：

Wolfram Language code: InverseZTransform[z / ((z - 1 / 2)(z - 1 / 3)), z, n]
Wolfram Language code: Limit[%, n -> 0] == Limit[z / ((z - 1 / 2)(z - 1 / 3)), z -> Infinity]

终值属性：

Wolfram Language code: InverseZTransform[z / ((z - 1 / 2)(z - 1 / 3)), z, n]
Wolfram Language code: Limit[%, n -> Infinity] == Limit[z / ((z - 1 / 2)(z - 1 / 3)), z -> 0]

InverseZTransform 和 SeriesCoefficient 是密切相关的：

Wolfram Language code: InverseZTransform[E ^ (1 / z), z, n]
Wolfram Language code: SeriesCoefficient[E ^ z, {z, 0, n}]

巧妙范例  (1)

超几何函数的反变换：

Wolfram Language code: InverseZTransform[HypergeometricPFQ[{}, {2 / 3, 1, 4 / 3}, 1 / z], z, n]
Wolfram Language code: ZTransform[%, n, z]
Wolfram Research (1999)，InverseZTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/InverseZTransform.html （更新于 2008 年）.

文本

Wolfram Research (1999)，InverseZTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/InverseZTransform.html （更新于 2008 年）.

CMS

Wolfram 语言. 1999. "InverseZTransform." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2008. https://reference.wolfram.com/language/ref/InverseZTransform.html.

APA

Wolfram 语言. (1999). InverseZTransform. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/InverseZTransform.html 年

BibTeX

@misc{reference.wolfram_2026_inverseztransform, author="Wolfram Research", title="{InverseZTransform}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/InverseZTransform.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_inverseztransform, organization={Wolfram Research}, title={InverseZTransform}, year={2008}, url={https://reference.wolfram.com/language/ref/InverseZTransform.html}, note=[Accessed: 03-November-2026]}