Wolfram 语言与系统参考资料中心

MatrixPower

MatrixPower[m,n]

给出 m 的 n 次矩阵幂.

MatrixPower[m,n,v]

给出矩阵 m 用于矢量 v 的 n 次矩阵幂.

范例

打开所有单元关闭所有单元

基本范例 (4)

符号矩阵的平方：

Wolfram Language code:

m = (|   |   |
| - | - |
| a | b |
| c | d |);

Wolfram Language code: MatrixPower[m, 2]//MatrixForm

这是：

Wolfram Language code: % == m.m

求符号矩阵的逆矩阵的平方：

Wolfram Language code:

m = (|   |   |
| - | - |
| a | b |
| c | d |);

Wolfram Language code: MatrixPower[m, -2]//Simplify//MatrixForm

即是：

Wolfram Language code: % == Inverse[m].Inverse[m]//Simplify

矩阵的 10 次幂：

Wolfram Language code: MatrixPower[{{1, 1}, {1, 2}}, 10]

注意这与求每项的 10 次幂不同：

Wolfram Language code: {{1, 1}, {1, 2}} ^ 10

计算符号矩阵的幂：

Wolfram Language code: MatrixPower[{{0, 0, 1}, {0, 2, 0}, {-1, 0, 0}}, n]

范围 (15)

基本用法 (9)

机器精度矩阵的一个正整数幂：

Wolfram Language code: MatrixPower[{{1.2, 2.5, -3.2}, {0.7, -9.4, 5.8}, {-0.2, 0.3, 6.4}}, 5]

求分数幂：

Wolfram Language code: MatrixPower[{{1.2, 2.5, -3.2}, {0.7, -9.4, 5.8}, {-0.2, 0.3, 6.4}}, 3 / 2]

复矩阵的平方：

Wolfram Language code: MatrixPower[{{1. + I, 2, 3 - 2 I}, {0, 4 π, 5I}, {E, 0, 6}}, 2]//MatrixForm

精确矩阵的整数幂：

Wolfram Language code: MatrixPower[{{2, 3, 0}, {4, 9, 0}, {0, 0, 4}}, 14]//MatrixForm

求分数幂：

Wolfram Language code: MatrixPower[{{2, 3, 0}, {4, 9, 0}, {0, 0, 4}}, -3 / 2]//MatrixForm

随机精度矩阵的负整数幂：

Wolfram Language code: m = RandomReal[1, {2, 2}, WorkingPrecision -> 20]

Wolfram Language code: MatrixPower[m, -5]

求无理数幂：

Wolfram Language code: MatrixPower[m, Pi]

符号矩阵的整数幂：

Wolfram Language code: MatrixPower[{{a, b}, {0, c}}, 4]

矩阵的符号幂：

Wolfram Language code: MatrixPower[{{0, a}, {b, 0}}, n]

快速求大型机器精度矩阵的幂：

Wolfram Language code: m = RandomReal[{0, 1}, {800, 800}];

Wolfram Language code: MatrixPower[m, 2]; //AbsoluteTiming

求单个向量的幂甚至更快：

Wolfram Language code: MatrixPower[m, 2, Range[800]]; //AbsoluteTiming

将有限域元素矩阵提升到整数幂：

Wolfram Language code:

ℱ = FiniteField[29, 4];
m = {{ℱ[12], ℱ[23], ℱ[34]}, {ℱ[45], ℱ[56], ℱ[67]}, {ℱ[78], ℱ[89], ℱ[90]}};
MatrixPower[m, 123456789]//MatrixForm

将其提升为负幂：

Wolfram Language code: MatrixPower[m, -987654321]//MatrixForm

将 CenteredInterval 矩阵提升到整数幂：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm

Wolfram Language code: (mpow = MatrixPower[m, 17])//MatrixForm

找出 m 的随机代表 mrep：

Wolfram Language code:

ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"]
(mrep = Map[ranrep, m, {2}])//MatrixForm

验证 mpow 是否包含 MatrixPower[mrep,17]：

Wolfram Language code: MapThread[IntervalMemberQ, {mpow, MatrixPower[mrep, 17]}, 2]//MatrixForm

特殊矩阵 (6)

对稀疏矩阵开正整数次方，以稀疏矩阵的形式返回结果：

Wolfram Language code: mat = SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]

Wolfram Language code: MatrixPower[mat, 2]

格式化结果：

Wolfram Language code: %//MatrixForm

对稀疏矩阵开非正整数次方，通常会生成正常矩阵：

Wolfram Language code: MatrixPower[mat, 2.5]

将稀疏矩阵的幂运算应用于稀疏向量：

Wolfram Language code: m = SparseArray[Band[{1, 2}] -> 2, {1000, 1000}]

Wolfram Language code: v = SparseArray[{{1} -> 1, {-1} -> -1.5}, {1000}]

Wolfram Language code: MatrixPower[m, 4, v]//Short

可能的情况下，对结构化数组开方将返回结构化数组：

Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}}, "Meters"]

Wolfram Language code: MatrixPower[%, 2]

但并不总是可行的：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 3, {2, 2} -> 1, {3, 1} -> -5}, {3, 3}, Symmetric[All]]

Wolfram Language code: MatrixPower[%, -2]

IdentityMatrix 的幂是其自身：

Wolfram Language code: MatrixPower[IdentityMatrix[3], n]

更广义地说，对角矩阵的幂即是对角元素的幂：

Wolfram Language code: MatrixPower[DiagonalMatrix[{a, b, c}], n]

对 HilbertMatrix 开负数次方：

Wolfram Language code: MatrixPower[HilbertMatrix[2], -2]//MatrixForm

计算一个的次一元多项式矩阵的次幂：

Wolfram Language code:

rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n]
SeedRandom[1234];
m = Table[rpoly[100], {10}, {10}];

Wolfram Language code: MatrixPower[m, 20]//Short[#, 5]&//AbsoluteTiming

应用 (5)

求差分方程组的常系数的基本解：

Wolfram Language code: a = {{0, 1, 0}, {1, 0, 0}, {0, 1, 1}};

使用 MatrixPower 定义基本解：

Wolfram Language code: ϕ[n_] = MatrixPower[a, n]

该解满足方程：

Wolfram Language code: Simplify[ϕ[n + 1] == a.ϕ[n]]

满足基本解的初始条件：

Wolfram Language code: Simplify[ϕ[0] == IdentityMatrix[3]]

不使用全部特征向量求的矩阵的矩阵指数：

Wolfram Language code: m = {{1, 1, 1, 1}, {0, 1, 1, 1}, {0, 0, 1, 1}, {0, 0, 0, 1}};

Wolfram Language code: mp = MatrixPower[m, n]

计算每项的幂级数作为指数：

Wolfram Language code: Sum[(%/n!), {n, 0, ∞}]

Wolfram Language code: % == MatrixExp[m]

构建重复无穷变换极限作为旋转矩阵：

Wolfram Language code: MatrixPower[{{1, θ / n}, {-θ / n, 1}}, n]

Wolfram Language code: Limit[%, n -> Infinity] // FullSimplify

稀疏正定矩阵的最小特征值的取逆幂迭代：

Wolfram Language code: n = 100;m = SparseArray[{{i_, i_} -> 2., {i_, j_} /; Abs[i - j] == 1 -> -1.}, {n, n}, 0.]

Wolfram Language code:

v = Normalize[MatrixPower[m, -20, RandomReal[1, n]]];
val = Norm[m.v]

确认 m.v-val v 的误差：

Wolfram Language code: Norm[m.v - val v]

最大特征值的移位取逆幂迭代：

Wolfram Language code:

v = Normalize[MatrixPower[m - 4 MatrixPower[m, 0], -20, RandomReal[1, n]]];
val = Norm[m.v]

确认 m.v-val v 的误差：

Wolfram Language code: Norm[m.v - val v]

计算矩阵多项式的简单方法：

Wolfram Language code:

mpe[p_, x_, m_] := Module[{cl = CoefficientList[p, x]}, 
	Sum[MatrixPower[m, i - 1] cl[[i]], {i, Length[cl]}]]

Wolfram Language code: mpe[1 + 2 x + 3 x ^ 3, x, {{1, 2}, {3, 4}}]

计算特征多项式：

Wolfram Language code: m = Reverse[IdentityMatrix[4]];

Wolfram Language code: p = CharacteristicPolynomial[m, x]

Wolfram Language code: mpe[p, x, m]

属性和关系 (10)

对于正整数幂，MatrixPower[m,n] 等价于 ( 次):

Wolfram Language code:

m = {{1, 2}, {π, .5}};
MatrixPower[m, 3] == m.m.m

使用 Apply (@@) 可更简洁地表达该方程式：

Wolfram Language code: MatrixPower[m, 100] == Dot@@ConstantArray[m, {100}]

对于负整数幂，MatrixPower[m,-n] 等价于 ( 次):

Wolfram Language code:

m = {{1, 2}, {π, .5}};
MatrixPower[m, -3] == Inverse[m].Inverse[m].Inverse[m]

使用 Apply 可更简洁地表达该方程式：

Wolfram Language code: MatrixPower[m, -100] == Dot@@ConstantArray[Inverse[m], {100}]

特别注意的是，奇异矩阵对负矩阵幂没有定义：

Wolfram Language code: MatrixPower[{{1, 2}, {0, 0}}, -1]

对非奇异矩阵 m，MatrixPower[m,0] 是单位矩阵：

Wolfram Language code: m = {{1, 2}, {3, 4}};

Wolfram Language code: Det[m]

Wolfram Language code: MatrixPower[m, 0]//MatrixForm

如果 m 为非奇异，MatrixPower[m, n].MatrixPower[m,-n] 为单位矩阵：

Wolfram Language code:

m = RandomReal[1, {5, 5}];
n = RandomInteger[{1, 9}];

Wolfram Language code: Chop[MatrixPower[m, n].MatrixPower[m, -n]]//MatrixForm

对于非整数幂，MatrixPower 可用 MatrixPower 代换 Power 有效使用幂级数：

Wolfram Language code: a = {{1, -(1/6)}, {1, (1/6)}};

Wolfram Language code: MatrixPower[a, 1 / 2] == Sum[(Derivative[k][Sqrt][1]/k!) MatrixPower[a - IdentityMatrix[2], k], {k, 0, ∞}]

同样，MatrixPower 是将幂应用于适当函数的 MatrixFunction：

Wolfram Language code: MatrixPower[a, 1 / 2] == MatrixFunction[x |-> x^1 / 2, a]

对角矩阵的矩阵幂是对对角项求幂：

Wolfram Language code:

d = {1, 2, 3, 4};
s = 2 / 3;

Wolfram Language code: MatrixPower[DiagonalMatrix[d], s]

Wolfram Language code: DiagonalMatrix[d ^ s]

对于任何幂和可对角化矩阵，MatrixPower[m,s] 等于 $v.d^s.TemplateBox[{v}, Inverse]$ ：

Wolfram Language code: m = {{1, 2}, {π, .5}};

Wolfram Language code: DiagonalizableMatrixQ[m]

使用 JordanDecomposition 可求得对角化：

Wolfram Language code: {v, d} = JordanDecomposition[m];

Wolfram Language code: m == v.d.Inverse[v]

确认相等：

Wolfram Language code: MatrixPower[m, 1 / 2]

Wolfram Language code: % == v.Sqrt[d].Inverse[v]

对于实对称矩阵 s 和整数幂 n，MatrixPower[s,n] 也是实对称：

Wolfram Language code:

s = {{1, 2}, {2, 1}};
{SymmetricMatrixQ[s], SymmetricMatrixQ[MatrixPower[s, -5]]}

埃尔米特矩阵的相似陈述 (analogous statement) 判定为真：

Wolfram Language code:

h = {{1, 2 + 3 I}, {2 - 3 I, 4}};
{HermitianMatrixQ[h], HermitianMatrixQ[MatrixPower[h, 7]]}

对于正交矩阵 o 和任何幂 s，MatrixPower[o,s] 也为正交：

Wolfram Language code:

o = RotationMatrix[π / 6];
{OrthogonalMatrixQ[o], OrthogonalMatrixQ[MatrixPower[o, Sqrt[2]]]}

酉矩阵的相似陈述 (analogous statement) 判定为真：

Wolfram Language code:

u = {{0, -I}, {I, 0}};
{UnitaryMatrixQ[u], UnitaryMatrixQ[MatrixPower[u, -π]]}

可通过 JordanDecomposition 作为 $v.j^s.TemplateBox[{v}, Inverse]$ 计算得到：

Wolfram Language code:

m = {{2, 0, 0, 0}, {0, 1, 0, 0}, {1, -1, 1, 0}, {1, -1, 1, 1}};
{v, j} = JordanDecomposition[m];
MatrixPower[m, -1 / 2] == v.MatrixPower[j, -1 / 2].Inverse[v]

而且，除了在超对角元中由划定的上方三角形区块外，为零：

Wolfram Language code: MatrixForm /@ {j, MatrixPower[j, -1 / 2]}

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

MatrixPower

更多信息和选项

范例

基本范例 (4)

范围 (15)

基本用法 (9)

特殊矩阵 (6)

应用 (5)

属性和关系 (10)

文本

CMS

APA

BibTeX

BibLaTeX

MatrixPower

更多信息和选项

范例

基本范例 (4)

范围 (15)

基本用法 (9)

特殊矩阵 (6)

应用 (5)

属性和关系 (10)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX