WOLFRAM

Wolfram 语言与系统参考资料中心

RemoteBatchMapSubmit[env,f,list]

使用远程批处理提交环境 env 提交一个阵列批处理作业，其中 f 应用于 list 的第一层的每个元素.

RemoteBatchMapSubmit[f,list]

使用 $DefaultRemoteBatchSubmissionEnvironment 提交阵列作业.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Initialization  
Method  
可能存在的问题  
参见
相关指南
相关的工作流程
历史
按以下格式引用：

RemoteBatchMapSubmit   

批计算服务商列表 »

RemoteBatchMapSubmit[env,f,list]

使用远程批处理提交环境 env 提交一个阵列批处理作业，其中 f 应用于 list 的第一层的每个元素.

RemoteBatchMapSubmit[f,list]

使用 $DefaultRemoteBatchSubmissionEnvironment 提交阵列作业.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

提交一个阵列批处理作业，该作业将 1 到 100 之间的每个整数平方：

Wolfram Language code: job = RemoteBatchMapSubmit[# ^ 2&, Range[1, 100]]

可视化各个子工作的运算分布：

Wolfram Language code: job["JobPackingVisualization"]

查看每个子作业状态的自动更新的可视化效果：

Wolfram Language code: job["DynamicStatusVisualization"]

在阵列作业运行时，获取一个稀疏阵列，该阵列仅包含已完成的子作业中的元素：

Wolfram Language code: job["SparseEvaluationResults"]

阵列作业全部完成后，获得密集阵列的结果：

Wolfram Language code: job["EvaluationResults"]

范围  (1)

使用默认的远程提交环境提交阵列作业：

Wolfram Language code: $DefaultRemoteBatchSubmissionEnvironment = RemoteBatchSubmissionEnvironment[...];
Wolfram Language code: RemoteBatchMapSubmit[# ^ 3&, Range[10]]

选项  (5)

Initialization  (1)

使用初始化表达式将导入的输入文件分配给变量，然后可以在作业函数中使用它：

Wolfram Language code: job = RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], ImageEffect[img, {"ColorTones", {Hue[#]}}]&, Range[0, 0.95, 0.05], RemoteInputFiles -> <|"image.jpg" -> FindFile["ExampleData/ocelot.jpg"]|>, Initialization :> (img = Import["image.jpg"]) ]
Wolfram Language code: ImageCollage[job["EvaluationResults"]]

Method  (4)

设置 MethodAutomatic 尝试使子作业的数量和每个作业的运算数量尽可能接近：

Wolfram Language code: job = RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], f, Range[1, 64], Method -> Automatic ]; job["JobPackingVisualization"]
Wolfram Language code: job = RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], f, Range[1, 50], Method -> Automatic ]; job["JobPackingVisualization"]

设置 Method"FinestGrained" 在服务商强制执行的最大子作业计数范围内，对每个子作业进行尽可能少的运算：

Wolfram Language code: job = RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], f, Range[1, 64], Method -> "FinestGrained" ]; job["JobPackingVisualization"]

设置 Method"EvaluationsPerJob"n 尝试将恰好 n 个运算打包到每个子作业中，并通过单个附加作业包含剩余部分：

Wolfram Language code: job = RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], f, Range[1, 64], Method -> "EvaluationsPerJob" -> 15 ]; job["JobPackingVisualization"]

设置 Method"JobCount"n 将运算分布在恰好 n 个子作业中：

Wolfram Language code: job = RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], f, Range[1, 64], Method -> "JobCount" -> 7 ]; job["JobPackingVisualization"]

可能存在的问题  (1)

使用默认的按需许可设置，如果您的服务积分余额不足以根据阵列子作业的数量以及子作业处理器的数量和 TimeConstraint 创建许可证授权，RemoteBatchMapSubmit 将拒绝提交作业：

Wolfram Language code: RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], # ^ 2&, Range[1, 100], RemoteProviderSettings -> <|"VCPUCount" -> 4|>, TimeConstraint -> Quantity[5, "Hours"] ]

默认情况下，假设所有子作业将同时运行，RemoteBatchMapSubmit 请求许可证授权. 如果不是这种情况，则可以使用 LicensingSettings 选项减少授权的并发内核限制：

Wolfram Language code: RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], # ^ 2&, Range[1, 100], RemoteProviderSettings -> <|"VCPUCount" -> 4|>, TimeConstraint -> Quantity[5, "Hours"], LicensingSettings -> <|"Entitlement" -> <| (* 5 concurrent child jobs × 4 vCPUs per job *) "StandardKernelLimit" -> 5, "ParallelKernelLimit" -> 5 * 4 |>|> ]

或者，可以减少子作业的数量，每个子作业的处理器内核数和/或子作业 TimeConstraint：

Wolfram Language code: RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], # ^ 2&, Range[1, 100], RemoteProviderSettings -> <|"VCPUCount" -> 4|>, TimeConstraint -> Quantity[5, "Hours"], Method -> "JobCount" -> 5 ]
Wolfram Language code: RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], # ^ 2&, Range[1, 100], RemoteProviderSettings -> <|"VCPUCount" -> 2|>, TimeConstraint -> Quantity[1, "Hours"] ]

最后，可以通过向 LicensingSettings 选项提供 "CheckCreditsBalance"False 授权设置来覆盖余额检查：

Wolfram Language code: job = RemoteBatchMapSubmit[ RemoteBatchSubmissionEnvironment[...], Pause[1200]&, Range[1, 100], RemoteProviderSettings -> <|"VCPUCount" -> 4|>, TimeConstraint -> Quantity[5, "Hours"], LicensingSettings -> <|"Entitlement" -> <|"CheckCreditsBalance" -> False|>|> ]
Wolfram Research (2020)，RemoteBatchMapSubmit，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RemoteBatchMapSubmit.html （更新于 2025 年）.

文本

Wolfram Research (2020)，RemoteBatchMapSubmit，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RemoteBatchMapSubmit.html （更新于 2025 年）.

CMS

Wolfram 语言. 2020. "RemoteBatchMapSubmit." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/RemoteBatchMapSubmit.html.

APA

Wolfram 语言. (2020). RemoteBatchMapSubmit. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/RemoteBatchMapSubmit.html 年

BibTeX

@misc{reference.wolfram_2026_remotebatchmapsubmit, author="Wolfram Research", title="{RemoteBatchMapSubmit}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/RemoteBatchMapSubmit.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_remotebatchmapsubmit, organization={Wolfram Research}, title={RemoteBatchMapSubmit}, year={2025}, url={https://reference.wolfram.com/language/ref/RemoteBatchMapSubmit.html}, note=[Accessed: 03-November-2026]}