WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

SnDispersion[list]

list 中の要素の 統計量を与える．

SnDispersion[list,c]

尺度係数 c を使って 統計量を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Method  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

SnDispersion

SnDispersion[list]

list 中の要素の 統計量を与える．

SnDispersion[list,c]

尺度係数 c を使って 統計量を与える．

詳細とオプション

  • SnDispersionはロバストな分散測度である．
  • SnDispersionは，その統計量がペアごとの絶対差に基づく，順序に基づいた推定器である．この統計には位置推定は必要ない．
  • リスト{x1,x2,…,xn}についての 推定器の値は，{zi,1≤i≤n}の中央値に尺度係数 c を掛けたもので与えられる．ziは j 上の{xi– xj,1≤j≤n}の中央値である．
  • c が指定されていない場合は，統計量が正規分布に従うデータについての尺度母数の一定した推定器となるように，を満足する正の尺度係数 c*が適用される．また，サンプル量が少ない場合に推定器に偏りが生まれないように，デフォルトで有限サンプル修正が使われる．
  • SnDispersion[{{x1,y1,…},{x2,y2,…},…}]は{SnDispersion[{x1,x2,…}],SnDispersion[{y1,y2,…}],…}を与える．
  • SnDispersionはMethodオプションをサポートする．次は，指定可能な明示的設定である．
  • "FiniteSample"有限サンプル修正を使う（デフォルト）
    "None"修正は行わない
  • 尺度係数 c が入力で指定されている場合は，オプションMethodは無視される．

例題

すべて開く すべて閉じる

例  (4)

リストのSnDispersion：

Wolfram Language code: SnDispersion[{6.5, 3.8, 6.6, 5.7, 6.0, 6.4, 5.3}]

行列の列のSnDispersion：

Wolfram Language code: SnDispersion[{{1., 2.}, {4., 8.}, {5., 3.}, {2., 15.}}]

尺度係数が1のリストのSnDispersion：

Wolfram Language code: SnDispersion[{1, 2, 3, 2, 1}, 1]

日付のリストのSnDispersion：

Wolfram Language code: SnDispersion[{Yesterday, Today, Tomorrow}]

スコープ  (8)

厳密な入力は，尺度係数が厳密である場合は厳密な出力を与える：

Wolfram Language code: SnDispersion[{1, 20, 3, 4}, 1]
Wolfram Language code: SnDispersion[{Sqrt[2], E, Pi, Pi ^ 2, 1, 2, 3}, 2]

尺度母数が異なるSnDispersion：

Wolfram Language code: SnDispersion[{1.2, 3.8, 4.2, -0.5, -5.2}, 3]
Wolfram Language code: SnDispersion[{1.2, 3.8, 4.2, -0.5, -5.2}, 4]

行列についてのSnDispersionは列ごとの推定を与える：

Wolfram Language code: SnDispersion[RandomReal[1, {50, 3}]]

大きい配列のSnDispersion：

Wolfram Language code: SnDispersion[RandomReal[1, 10 ^ 6]]
Wolfram Language code: SnDispersion[RandomReal[1, {10 ^ 6, 2}]]

TimeSeriesのSnDispersionを求める：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{3, 8, 4, 11, 9, 2}}, {{{1, 3, 5, 7, 8, 10}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: SnDispersion[ts]

SnDispersionは値のみに依存する：

Wolfram Language code: SnDispersion[ts["Values"]]

SnDispersionは単位付き数量を含むデータに使うことができる：

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]
Wolfram Language code: SnDispersion[data]

日付のSnDispersionを計算する：

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];
Wolfram Language code: DateHistogram[dates]
Wolfram Language code: SnDispersion[dates]
Wolfram Language code: UnitConvert[%, "Years"]

時間のSnDispersionを計算する：

Wolfram Language code: RandomTime[3]
Wolfram Language code: SnDispersion[%]

異なる時刻帯指定の時刻のリスト：

Wolfram Language code: {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}
Wolfram Language code: SnDispersion[%]

オプション  (1)

Method  (1)

デフォルトで有限サンプル修正が適用される：

Wolfram Language code: data = RandomVariate[NormalDistribution[0, 2], {10 ^ 4, 5}];
Wolfram Language code: Mean[SnDispersion /@ data]

小さいサンプル修正なしで：

Wolfram Language code: Mean[SnDispersion[#, Method -> "None"]& /@ data]

アプリケーション  (6)

極値が存在する場合に分散のロバスト推定を得る：

Wolfram Language code: SnDispersion[{3, 10, 10 ^ 6, 20, 5, 6}]

サンプルの標準偏差は極値に大きく影響される：

Wolfram Language code: StandardDeviation[{3, 10, 10 ^ 6, 20, 5, 6}]//N

5年間の移動 分散を使って株式データの大幅変動周期を特定する：

Wolfram Language code: data = TemporalData[«4»];
Wolfram Language code: smooth = Sqrt[MovingMap[SnDispersion, data, {Quantity[5, "Year"]}]];
Wolfram Language code: DateListPlot[smooth]

ランダム過程の経路集合のスライスの 分散を計算する：

Wolfram Language code: data = RandomFunction[WienerProcess[], {0, 1, .01}, 10 ^ 3];

いくつかのスライス時間を選択する：

Wolfram Language code: times = Range[0, 1, .1];
Wolfram Language code: sd = Map[{#, SnDispersion[data["SliceData", #]]}&, times];

分散を経路上にプロットする：

Wolfram Language code: Show[ListPlot[data], ListLinePlot[sd, PlotStyle -> Black]]

学級の生徒の身長の 分散を求める：

Wolfram Language code: heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147, 150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];
Wolfram Language code: ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic]
Wolfram Language code: snd = SnDispersion[heights]

中央値についての 分散をプロットする：

Wolfram Language code: md = Median[heights]; n = Length[heights];
Wolfram Language code: ListPlot[{heights, {{0, md}, {n, md}}, {{0, md - snd}, {n, md - snd}}, {{0, md + sd}, {n, md + sd}}}, Filling -> {1 -> 0, 3 -> {4}}, Joined -> {False, True, True, True}, PlotStyle -> {Automatic, Automatic, Gray, Gray}, PlotLegends -> {"heights", "median", "Sn-bands"}, AxesLabel -> Automatic]

広がりが大きい別の正規分布で外れ値がモデル化された，標準正規分布からのデータについて考察する：

Wolfram Language code: BlockRandom[ SeedRandom[10]; data = RandomVariate[MixtureDistribution[{0.95, 0.05}, {NormalDistribution[], NormalDistribution[0, 10]}], 10 ^ 4]; ]

データを標準正規分布に対して検定する：

Wolfram Language code: DistributionFitTest[data, NormalDistribution[], "TestConclusion"]

分散を計算する：

Wolfram Language code: sd = SnDispersion[data]

サンプル中央値から 分散の3倍内にあるデータ点を選択することで外れ値を除く：

Wolfram Language code: med = Median[data];
Wolfram Language code: ndata = Pick[data, Sign[Abs[data - med] - 3 sd], -1];

新たなデータを標準正規分布に対して検定する：

Wolfram Language code: DistributionFitTest[ndata, NormalDistribution[], "TestConclusion"]

スチューデント t 分布からデータを生成する：

Wolfram Language code: data = RandomVariate[StudentTDistribution[1, 2, 1], 10 ^ 4];
Wolfram Language code: Histogram[data, {0.5}]

標準偏差，刈込み分散の平方根，分散の3つの測度でデータの分散を計算する：

Wolfram Language code: ests = {StandardDeviation, Sqrt[TrimmedVariance[#]]&, SnDispersion};
Wolfram Language code: {sd, tsd, sn} = Through[ests[data]]

ブートストラップ法を使ってこれら3つの分散推定器の確度を査定する：

Wolfram Language code: res = Table[Through[ests[RandomChoice[data, Length[data]]]], {10 ^ 3}];

推定器は与えられたデータに対して最も小さい広がりを与える：

Wolfram Language code: StandardDeviation[res]

特性と関係  (2)

SnDispersionは順序に基づいた分散推定器で，その統計量はペアごとの絶対差に基づいている：

Wolfram Language code: data = RandomReal[1, 100]; diffs = Abs[Outer[Subtract, data, data]];

RankedMinを使って高中央値の低中央値を計算する：

Wolfram Language code: RankedMin[RankedMin[#, 51]& /@ diffs, 50]

尺度係数が1に等しいSnDispersionと比較する：

Wolfram Language code: SnDispersion[data, 1]

QnDispersion，SnDispersion，StandardDeviationはNormalDistributionの尺度母数の推定器である：

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2], 10 ^ 4]; est = {QnDispersion, SnDispersion, StandardDeviation};
Wolfram Language code: TableForm[Through[est[data]], TableHeadings -> {est}]

ブートストラップ法で推定器の確度を査定する：

Wolfram Language code: {qnerror, snerror, stderror} = Variance[Table[Through[est[RandomChoice[data, 10 ^ 4]]], {10 ^ 3}]];

推定された結果を使ってStandardDeviationについての相対効率を計算する：

Wolfram Language code: {stderror / qnerror, stderror / snerror}
Wolfram Research (2017), SnDispersion, Wolfram言語関数， https://reference.wolfram.com/language/ref/SnDispersion.html （2024年に更新）.

テキスト

Wolfram Research (2017), SnDispersion, Wolfram言語関数， https://reference.wolfram.com/language/ref/SnDispersion.html （2024年に更新）.

CMS

Wolfram Language. 2017. "SnDispersion." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/SnDispersion.html.

APA

Wolfram Language. (2017). SnDispersion. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SnDispersion.html

BibTeX

@misc{reference.wolfram_2026_sndispersion, author="Wolfram Research", title="{SnDispersion}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/SnDispersion.html}", note=[Accessed: 15-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_sndispersion, organization={Wolfram Research}, title={SnDispersion}, year={2024}, url={https://reference.wolfram.com/language/ref/SnDispersion.html}, note=[Accessed: 15-July-2026]}