WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

SphericalBesselJ[n,z]

第1種球ベッセル関数 TemplateBox[{n, z}, SphericalBesselJ]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

SphericalBesselJ

SphericalBesselJ[n,z]

第1種球ベッセル関数 TemplateBox[{n, z}, SphericalBesselJ]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • SphericalBesselJは，TemplateBox[{n, z}, SphericalBesselJ]=sqrt(pi/2)/sqrt(z)TemplateBox[{{n, +, {1, /, 2}}, z}, BesselJ]で，通常のベッセル関数によって与えられる．
  • SphericalBesselJ[n,z]は，非整数 に関してとの間の複素 平面上に不連続な分枝切断線を持つ．
  • 整数 n の明示的な記号形はFunctionExpandを使って求められる．
  • 特別な引数の場合，SphericalBesselJは，自動的に厳密値を計算する．
  • SphericalBesselJは任意の数値精度で評価できる．
  • SphericalBesselJは自動的にリストに縫い込まれる．
  • SphericalBesselJはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (5)

数値的に評価する：

Wolfram Language code: SphericalBesselJ[1, 5.2]

実数の部分集合上で をプロットする：

Wolfram Language code: Plot[SphericalBesselJ[1, x], {x, 0, 20}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[SphericalBesselJ[1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: SphericalBesselJ[1 / 2, x] + O[x] ^ 3

Infinityにおける級数展開：

Wolfram Language code: Series[SphericalBesselJ[1 / 2, x], {x, ∞, 3}]//Normal//Simplify

スコープ  (39)

数値評価  (6)

数値的に評価する：

Wolfram Language code: N[SphericalBesselJ[2, -5]]
Wolfram Language code: N[SphericalBesselJ[-0.5, 1]]

高精度で評価する：

Wolfram Language code: N[SphericalBesselJ[1, 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: SphericalBesselJ[1, 2.0004444000000045000]

複素数入力：

Wolfram Language code: N[SphericalBesselJ[2 + I, 5 + I]]

高精度で効率的に評価する：

Wolfram Language code: N[SphericalBesselJ[10, 7 / 2`100]]//Timing
Wolfram Language code: N[SphericalBesselJ[0, 28`10000]];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: SphericalBesselJ[0.4, Interval[{0.5, 0.6}]]
Wolfram Language code: SphericalBesselJ[1 / 4, CenteredInterval[2, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: SphericalBesselJ[2, Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: SphericalBesselJ[0.5, {{1, 2}, {3, 4}}]

MatrixFunctionを使って行列のSphericalBesselJ関数を計算することもできる：

Wolfram Language code: MatrixFunction[SphericalBesselJ[0.5, #]&, {{1, 2}, {3, 4}}]

特定の値  (4)

無限大における極限値：

Wolfram Language code: Limit[SphericalBesselJ[n, x], x -> Infinity]

記号的な n についてのSphericalBesselJ：

Wolfram Language code: SphericalBesselJ[n, 1]//FunctionExpand

SphericalBesselJの最初の正の零点を求める：

Wolfram Language code: xzero = x /. FindRoot[SphericalBesselJ[0, x] == 0, {x, 1}]
Wolfram Language code: Plot[SphericalBesselJ[0, x], {x, -1, 8}, Epilog -> Style[Point[{xzero, SphericalBesselJ[0, xzero]}], PointSize[Large], Red]]

異なるタイプのSphericalBesselJは異なる記号形式を与える：

Wolfram Language code: Table[SphericalBesselJ[n, x], {n, 0, 2, 1 / 2}]//FunctionExpand

可視化  (3)

整数()と半整数()の次数について，SphericalBesselJ関数をプロットする：

Wolfram Language code: Plot[{SphericalBesselJ[0, x], SphericalBesselJ[1, x], SphericalBesselJ[-1 / 2, x]}, {x, -10, 10}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[SphericalBesselJ[0, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[SphericalBesselJ[0, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[SphericalBesselJ[-1 / 4, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[SphericalBesselJ[-1 / 4, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

関数の特性  (12)

TemplateBox[{0, x}, SphericalBesselJ]はすべての実数と複素数について定義される：

Wolfram Language code: FunctionDomain[SphericalBesselJ[0, x], x]
Wolfram Language code: FunctionDomain[SphericalBesselJ[0, z], z, Complexes]

TemplateBox[{{-, {1, /, 2}}, x}, SphericalBesselJ]は，0より大きいすべての実数値について定義される：

Wolfram Language code: FunctionDomain[SphericalBesselJ[-1 / 2, x], x]

複素領域は，を除く平面全体である：

Wolfram Language code: FunctionDomain[SphericalBesselJ[-1 / 2, z], z, Complexes]

TemplateBox[{0, x}, SphericalBesselJ]の値域を近似する：

Wolfram Language code: FunctionRange[SphericalBesselJ[0, x], x, y]//Quiet

整数 について， が偶数か奇数かによって，TemplateBox[{n, z}, SphericalBesselJ]は の偶関数または奇関数である：

Wolfram Language code: SphericalBesselJ[0, -z]
Wolfram Language code: SphericalBesselJ[1, -z]

これは，TemplateBox[{n, z}, BesselJ]=(-1)^n TemplateBox[{n, {-, z}}, BesselJ]として表すことができる：

Wolfram Language code: FullSimplify[SphericalBesselJ[n, z] == (-1)^n SphericalBesselJ[n, -z], n∈ℤ]

SphericalBesselJは要素単位でリストに縫い込まれる：

Wolfram Language code: SphericalBesselJ[{1, 2, 3}, 4.5]

TemplateBox[{n, x}, SphericalBesselJ]は，非整数の の偶数値については の解析関数ではない：

Wolfram Language code: Table[FunctionAnalytic[SphericalBesselJ[n, z], z], {n, {-2, -1 / 2, Sqrt[2], π}}]

SphericalBesselJは非減少でも非増加でもない：

Wolfram Language code: Table[FunctionMonotonicity[{SphericalBesselJ[n, z], z > 0}, z], {n, 5}]
Wolfram Language code: Table[FunctionMonotonicity[{SphericalBesselJ[1 / n, z], z > 0}, z], {n, 5}]

SphericalBesselJは単射ではない：

Wolfram Language code: Table[FunctionInjective[{SphericalBesselJ[n, z], z > 0}, z], {n, 5}]
Wolfram Language code: Table[FunctionInjective[{SphericalBesselJ[1 / n, z], z > 0}, z], {n, 5}]
Wolfram Language code: Plot[{SphericalBesselJ[1, x], SphericalBesselJ[2, x], SphericalBesselJ[1 / 3, x], .1}, {x, 0, 10}]

SphericalBesselJは非負でも非正でもない：

Wolfram Language code: Table[FunctionSign[SphericalBesselJ[a, x], x], {a, 4}]

が非整数で （を含む可能性もあり）のとき，TemplateBox[{n, z}, SphericalBesselJ]は特異である：

Wolfram Language code: FunctionSingularities[SphericalBesselJ[a, x], x]
Wolfram Language code: FunctionDiscontinuities[SphericalBesselJ[a, x], x]

SphericalBesselJは凸でも凹でもない：

Wolfram Language code: Table[FunctionConvexity[SphericalBesselJ[a, x], x], {a, 5}]

TraditionalFormによる表示：

Wolfram Language code: SphericalBesselJ[n, r]//TraditionalForm

微分  (3)

z についての一次導関数：

Wolfram Language code: D[SphericalBesselJ[n, z], z]

z についての高次導関数：

Wolfram Language code: Table[D[SphericalBesselJ[n, z], {z, k}], {k, 1, 4}]//FullSimplify

z について高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[% /. n -> 2], {z, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

z についての 次導関数の式：

Wolfram Language code: D[SphericalBesselJ[n, z], {z, k}]// FullSimplify

積分  (3)

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[SphericalBesselJ[n, z], z]

不定積分を確かめる：

Wolfram Language code: FullSimplify[D[%, z]]

定積分：

Wolfram Language code: Integrate[SphericalBesselJ[1 / 2, z], {z, 0, 5}]

その他の積分例：

Wolfram Language code: Integrate[SphericalBesselJ[1 / 2, z]SphericalBesselY[1 / 2, z], z]//FullSimplify
Wolfram Language code: Integrate[SphericalBesselJ[3 / 2, z^2], {z, 0, 5}]

級数展開  (6)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[SphericalBesselJ[n, x], {x, 0, 5}]

の周りの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[SphericalBesselJ[1 / 2, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{SphericalBesselJ[1 / 2, x], terms}, {x, 0, 10}, PlotRange -> {-1.5, 1.5}]

SeriesCoefficientを使った級数展開の一般項：

Wolfram Language code: SeriesCoefficient[SphericalBesselJ[n, x], {x, 1, m}]

FourierSeries：

Wolfram Language code: FourierSeries[SphericalBesselJ[n, x], x, 1]// FullSimplify

Infinityにおける級数展開を求める：

Wolfram Language code: Series[SphericalBesselJ[n, x], {x, Infinity, 1}]

任意の記号的方向 についての級数展開を求める：

Wolfram Language code: Series[SphericalBesselJ[n, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]//FullSimplify

生成点におけるテイラー展開：

Wolfram Language code: Series[SphericalBesselJ[n, x], {x, x0, 2}]//FullSimplify

関数の恒等式と簡約  (2)

FullSimplifyを使って第1種球ベッセル関数を簡約する：

Wolfram Language code: FullSimplify[x SphericalBesselJ[2, x] + x SphericalBesselJ[0, x]]

漸化式：

Wolfram Language code: SphericalBesselJ[n, z] == (2n + 3/z)SphericalBesselJ[n + 1, z] - SphericalBesselJ[n + 2, z]//FullSimplify

アプリケーション  (1)

3Dにおけるラプラス演算子のラジアル部分を解く：

Wolfram Language code: DSolve[f''[r] + (2 /r)f'[r] + f[r] - (n(n + 1)/r^2)f[r] == 0, f[r], r]

特性と関係  (2)

積分を閉じた形で計算する：

Wolfram Language code: Integrate[SphericalBesselJ[1, r]^2, {r, 0, ∞}]

SphericalBesselJはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[SphericalBesselJ[n, x], x]
Wolfram Research (2007), SphericalBesselJ, Wolfram言語関数， https://reference.wolfram.com/language/ref/SphericalBesselJ.html.

テキスト

Wolfram Research (2007), SphericalBesselJ, Wolfram言語関数， https://reference.wolfram.com/language/ref/SphericalBesselJ.html.

CMS

Wolfram Language. 2007. "SphericalBesselJ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SphericalBesselJ.html.

APA

Wolfram Language. (2007). SphericalBesselJ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SphericalBesselJ.html

BibTeX

@misc{reference.wolfram_2026_sphericalbesselj, author="Wolfram Research", title="{SphericalBesselJ}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/SphericalBesselJ.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_sphericalbesselj, organization={Wolfram Research}, title={SphericalBesselJ}, year={2007}, url={https://reference.wolfram.com/language/ref/SphericalBesselJ.html}, note=[Accessed: 01-November-2026]}