WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Tetrahedron[]

中心が原点で辺の長さが単位長の正四面体を表す．

Tetrahedron[l]

辺の長さが l の四面体を表す．

Tetrahedron[{θ,ϕ},…]

z 軸について角度 θ，y 軸について角度 ϕ 回転された四面体を表す．

Tetrahedron[{x,y,z},…]

{x,y,z}を中心とする四面体を表す．

Tetrahedron[{p1,p2,p3,p4}]

p1，p2，p3，p4をコーナーとする一般的な塗り潰された四面体を表す．

Tetrahedron[{{p1,1,p1,2,p1,3,p1,4},{p2,1,…},…}]

四面体の集合を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
座標  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

Tetrahedron

Tetrahedron[]

中心が原点で辺の長さが単位長の正四面体を表す．

Tetrahedron[l]

辺の長さが l の四面体を表す．

Tetrahedron[{θ,ϕ},…]

z 軸について角度 θ，y 軸について角度 ϕ 回転された四面体を表す．

Tetrahedron[{x,y,z},…]

{x,y,z}を中心とする四面体を表す．

Tetrahedron[{p1,p2,p3,p4}]

p1，p2，p3，p4をコーナーとする一般的な塗り潰された四面体を表す．

Tetrahedron[{{p1,1,p1,2,p1,3,p1,4},{p2,1,…},…}]

四面体の集合を表す．

詳細とオプション

例題

すべて開く すべて閉じる

例  (3)

標準単位四面体：

Wolfram Language code: Graphics3D[Tetrahedron[]]

スタイルの付いた四面体：

Wolfram Language code: ℛ = Tetrahedron[{{1, 0, 0}, {1, 0, 1}, {1, 1, 1}, {0, 0, 1}}];
Wolfram Language code: {Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], ℛ}], Graphics3D[{EdgeForm[Dashed], ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

体積と重心：

Wolfram Language code: ℛ = Tetrahedron[{{1, 0, 0}, {1, 0, 1}, {1, 1, 1}, {0, 0, 1}}];
Wolfram Language code: Volume[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

スコープ  (22)

グラフィックス  (12)

指定  (6)

単位四面体：

Wolfram Language code: Graphics3D[Tetrahedron[]]

単一の四面体：

Wolfram Language code: Graphics3D[Tetrahedron[{{1, 0, 0}, {1, 0, 1}, {1, 1, 1}, {0, 0, 1}}]]

複数の四面体：

Wolfram Language code: v1 = {{1, 0, 0}, {1, 0, 1}, {1, 1, 1}, {0, 0, 1}}; v2 = v1 + 1;
Wolfram Language code: Graphics3D[Tetrahedron[{v1, v2}]]

辺の長さが明示的に指定された単位四面体：

Wolfram Language code: Graphics3D[Tetrahedron[1], PlotRange -> 1.5]

辺の長さが2の四面体：

Wolfram Language code: Graphics3D[Tetrahedron[2], PlotRange -> 1.5]

辺の長さが1/2で中心が(1/2, 1/2, 1/2)の四面体：

Wolfram Language code: Graphics3D[Tetrahedron[{1, 1, 1} / 2, 1 / 2], PlotRange -> 1.1]

軸の周りで45°回転された単位四面体：

Wolfram Language code: Graphics3D[Tetrahedron[{45°, 0}], PlotRange -> 2]

軸の周りで45°回転された単位四面体：

Wolfram Language code: Graphics3D[Tetrahedron[{0, 45°}], PlotRange -> 2]

辺の長さが2で， 軸の周りで45°， 軸の周りで45°回転された四面体：

Wolfram Language code: Graphics3D[Tetrahedron[{45°, 45°}, 2], PlotRange -> 2]

辺の長さが1，中心(1/2, 1/2, 1/2)で， 軸の周りで45°， 軸の周りで45°回転された四面体：

Wolfram Language code: Graphics3D[Tetrahedron[{1, 1, 1} / 2, {45°, 45°}, 1], PlotRange -> 2]

スタイリング  (3)

FaceFormとEdgeFormを使って，面と辺のスタイルを指定することができる：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Graphics3D[{EdgeForm[{Thick, Dashed, Blue}], FaceForm[{Pink, Opacity[0.7]}], ℛ}, Boxed -> False]

Textureを面に適用する：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}];
Wolfram Language code: Graphics3D[{Texture[[image]], ℛ}, Lighting -> "Neutral"]

VertexColorsを頂点に割り当てる：

Wolfram Language code: Graphics3D[Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, VertexColors -> {Red, Green, Blue, Opacity[.1, White]}]]

座標  (3)

座標をプロット範囲の比で指定する：

Wolfram Language code: Graphics3D[Tetrahedron[{Scaled[{0, 0, 0}], Scaled[{0.5, 0, 0}], Scaled[{0, 0.5, 0}], Scaled[{0, 0, 0.5}]}], PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

通常の座標からスケールされたオフセットを指定する：

Wolfram Language code: Graphics3D[Tetrahedron[{Scaled[{0, 0, 0.5}, {0, 0, 0}], Scaled[{0, 0, 0.5}, {1, 0, 0}], Scaled[{0, 0, 0.5}, {0, 1, 0}], Scaled[{0, 0, 0.5}, {0, 0, 1}]}], PlotRange -> {{0, 2}, {0, 2}, {0, 2}}, Axes -> True]

点はDynamicでもよい：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {0, 1}], Graphics3D[Tetrahedron[{Dynamic[{1, 1, 1}x], {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]]}]

領域  (10)

埋込み次元は，四面体が存在する空間の次元である：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

幾何次元は，形それ自体の次元である：

Wolfram Language code: RegionDimension[ℛ]

帰属判定：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: {RegionMember[ℛ, {(1/3), (1/3), (1/3)}], RegionMember[ℛ, {1, 1, 1}]}

点の帰属条件を得る：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

体積：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = Tetrahedron[{{1, 0, 0}, {1, 0, 1}, {1, 1, 1}, {0, 0, 1}}];
Wolfram Language code: {RegionDistance[ℛ, {1, 1, 1}], RegionDistance[ℛ, {0, 0, 0}]}

四面体の等距離等高線：

Wolfram Language code: ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -1, 2.5}, {y, -2, 2}, {z, -1, 2.5}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

点からの符号付き距離：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 1, 1}], SignedRegionDistance[ℛ, {(1/3), (1/4), (1/5)}]}

領域内の最近点：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: {RegionNearest[ℛ, {1, 1, 1}], RegionNearest[ℛ, {(1/3), (1/4), (1/5)}]}

包み込んでいる球に最も近い点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 1]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

四面体は有界である：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: BoundedRegionQ[ℛ]

範囲を求める：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

四面体の領域上で積分(Integrate)する：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Integrate[x + y + z, {x, y, z}∈ℛ]

四面体の領域上で最適化する：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

四面体の領域内で方程式を解く：

Wolfram Language code: ℛ = Tetrahedron[{{0, 0, 0}, {2, 0, 0}, {0, 2, 0}, {0, 0, 2}}];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

アプリケーション  (5)

標準的な四面体は，点で与えられる：

Wolfram Language code: Graphics3D[Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}], Axes -> True, AxesLabel -> {x, y, z}]

クーンの四面体は，点で与えられる：

Wolfram Language code: Graphics3D[Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}, {1, 1, 1}}], Axes -> True, AxesLabel -> {x, y, z}]

中心からコーナーまでの半径で正四面体を定義する：

Wolfram Language code: RegularTetrahedron[r_] := Tetrahedron[r{{1, 0, -(1/Sqrt[2])}, {-1, 0, -(1/Sqrt[2])}, {0, -1, (1/Sqrt[2])}, {0, 1, (1/Sqrt[2])}}]

その体積を計算する：

Wolfram Language code: Volume[RegularTetrahedron[r]]

これを可視化する：

Wolfram Language code: Graphics3D[RegularTetrahedron[3]]

2つの正四面体を組み合せる：

Wolfram Language code: pts = {{1, 0, -(1/Sqrt[2])}, {-1, 0, -(1/Sqrt[2])}, {0, -1, (1/Sqrt[2])}, {0, 1, (1/Sqrt[2])}};
Wolfram Language code: ct = {Tetrahedron[pts], Tetrahedron[-pts]};
Wolfram Language code: Graphics3D[ct]

四面体の4つの面の面積が等しいとき，その四面体は二等辺四面体である：

Wolfram Language code: ℛ = Tetrahedron[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 1}, {0, 1, -1}}];

領域の面を得る：

Wolfram Language code: faces = MeshPrimitives[BoundaryDiscretizeRegion[ℛ], "Faces"];

各面の面積を比較する：

Wolfram Language code: SameQ[Area /@ faces]

領域を可視化する：

Wolfram Language code: Region[ℛ]

四面体は8つの部分四面体に分割できる：

Wolfram Language code: SymmetricSubdivision[Tetrahedron[pl_], k_] /; 0 ≤ k < 2 ^ Length[pl] := Module[{n = Length[pl] - 1, i0, bl, pos}, i0 = DigitCount[k, 2, 1]; bl = IntegerDigits[k, 2, n]; pos = FoldList[If[#2 == 0, #1 + {0, 1}, #1 + {1, 0}]&, {0, i0}, Reverse[bl]]; Tetrahedron@Map[Mean, Extract[pl, #]& /@ Map[{#}&, pos + 1, {2}]] ]
Wolfram Language code: Graphics3D[SymmetricSubdivision[Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}, {1, 1, 1}}], #]& /@ Range[0, 7], BaseStyle -> Opacity[0.5]]

この分割は，再帰的に行うことができる：

Wolfram Language code: NestedSymmetricSubdivision[Tetrahedron[pl_], level_Integer] /; level == 0 := Tetrahedron[pl] NestedSymmetricSubdivision[Tetrahedron[pl_], level_Integer] /; level > 0 := Flatten[NestedSymmetricSubdivision[SymmetricSubdivision[Tetrahedron[pl], #], level - 1]& /@ Range[0, 7]]
Wolfram Language code: Graphics3D[NestedSymmetricSubdivision[Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}, {1, 1, 1}}], 3], BaseStyle -> Opacity[0.5]]

特性と関係  (8)

TriangulateMeshを使って体積メッシュを四面体に分解することができる：

Wolfram Language code: Subscript[ℛ, 1] = DiscretizeGraphics[Cuboid[]]
Wolfram Language code: Subscript[ℛ, 2] = TriangulateMesh[Subscript[ℛ, 1]]
Wolfram Language code: MeshCells[Subscript[ℛ, 2], 3]//Short

MaxCellMeasureのようなオプションを使って四面体の数を制御する：

Wolfram Language code: TriangulateMesh[Subscript[ℛ, 1], MaxCellMeasure -> 1]

六面体は5つの四面体の和集合として表すことができる：

Wolfram Language code: pts = {{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}, {-1, -1, 1}, {1, -1, 1}, {1, 1, 1}, {-1, 1, 1}};
Wolfram Language code: Graphics3D[Hexahedron[pts], Boxed -> False]

四面体の頂点の指標リストを指す：

Wolfram Language code: ti = {{1, 2, 3, 6}, {1, 3, 8, 6}, {1, 3, 4, 8}, {1, 6, 8, 5}, {3, 8, 6, 7}};
Wolfram Language code: Graphics3D[{Opacity@0.4, Table[Tetrahedron[pts[[i]]], {i, ti}]}, Boxed -> False]

六面体は6つの四面体の和集合としても表すことができる：

Wolfram Language code: pts = {{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}, {-1, -1, 1}, {1, -1, 1}, {1, 1, 1}, {-1, 1, 1}};
Wolfram Language code: ti = {{1, 6, 8, 5}, {1, 2, 8, 6}, {2, 7, 8, 6}, {1, 8, 3, 4}, {1, 8, 2, 3}, {1, 8, 7, 3}};
Wolfram Language code: Graphics3D[{Opacity@0.4, Table[Tetrahedron[pts[[i]]], {i, ti}]}, Boxed -> False]

任意の四面体は標準四面体をアフィン変換したものである：

Wolfram Language code: {p0, p1, p2, p3} = {{1, 1, 1}, {1, 2, 3}, {2, 1, 3}, {3, 2, 1}};

変換は で与えられる．ただし A=TemplateBox[{{{, {{{p, _, 1}, -, {p, _, 0}}, ,, ..., ,, {{p, _, 3}, -, {p, _, 0}}}, }}}, Transpose]である：

Wolfram Language code: A = {p1 - p0, p2 - p0, p3 - p0};
Wolfram Language code: t = AffineTransform[{A, p0}];

もとの四面体と変換された単位四面体を比較する：

Wolfram Language code: Subscript[ℛ, 1] = Tetrahedron[{p0, p1, p2, p3}]; Subscript[ℛ, 2] = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: {Graphics3D[{Opacity[.35], Blue, Subscript[ℛ, 1]}], Graphics3D[{Opacity[.35], Red, GeometricTransformation[Subscript[ℛ, 2], t]}]}

Tetrahedronは，Simplexの特殊形である：

Wolfram Language code: Subscript[ℛ, 1] = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]; Subscript[ℛ, 2] = Simplex[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegionは，任意のTetrahedronの領域を表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[Subscript[t, 1] ≥ 0 && Subscript[t, 2] ≥ 0 && Subscript[t, 3] ≥ 0 && Subscript[t, 1] + Subscript[t, 2] + Subscript[t, 3] ≤ 1, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}]; Subscript[ℛ, 2] = Tetrahedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Tetrahedronは，その頂点の凸結合の集合である：

Wolfram Language code: {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3], Subscript[p, 4]} = {{1, 2, 3}, {1, 2, 4}, {1, 3, 4}, {2, 3, 4}}; Subscript[ℛ, 1] = ParametricRegion[{Subscript[t, 1]Subscript[p, 1] + Subscript[t, 2]Subscript[p, 2] + Subscript[t, 3]Subscript[p, 3] + Subscript[t, 4]Subscript[p, 4], Subscript[t, 1] ≥ 0 && Subscript[t, 2] ≥ 0 && Subscript[t, 3] ≥ 0 && Subscript[t, 4] ≥ 0 && Subscript[t, 1] + Subscript[t, 2] + Subscript[t, 3] + Subscript[t, 4] == 1}, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3], Subscript[t, 4]}]; Subscript[ℛ, 2] = Tetrahedron[{Subscript[p, 1], Subscript[p, 2], Subscript[p, 3], Subscript[p, 4]}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Tetrahedronの頂点は，それを囲むCircumsphereを形成するのに使える：

Wolfram Language code: pts = {{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}};
Wolfram Language code: Graphics3D[{Tetrahedron[pts], Opacity@0.5, Circumsphere[pts]}]

おもしろい例題  (2)

四面体のランダムな集合：

Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Tetrahedron[RandomReal[1, {4, 3}]]}, {10}]]

軸の周りで四面体を急速に動かす：

Wolfram Language code: Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[Tetrahedron[], RotationTransform[c, {0, 0, 1}, {0.5, 0, 0}]]}, {c, 0, 2Pi, 2Pi / 30}]}]
Wolfram Research (2014), Tetrahedron, Wolfram言語関数， https://reference.wolfram.com/language/ref/Tetrahedron.html （2019年に更新）.

テキスト

Wolfram Research (2014), Tetrahedron, Wolfram言語関数， https://reference.wolfram.com/language/ref/Tetrahedron.html （2019年に更新）.

CMS

Wolfram Language. 2014. "Tetrahedron." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Tetrahedron.html.

APA

Wolfram Language. (2014). Tetrahedron. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Tetrahedron.html

BibTeX

@misc{reference.wolfram_2026_tetrahedron, author="Wolfram Research", title="{Tetrahedron}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Tetrahedron.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_tetrahedron, organization={Wolfram Research}, title={Tetrahedron}, year={2019}, url={https://reference.wolfram.com/language/ref/Tetrahedron.html}, note=[Accessed: 03-November-2026]}