Wolfram 语言与系统参考资料中心

"Shell" (外部计算系统)

ExternalEvaluate 用法

ExternalEvaluate["Shell",code] 在操作系统 shell 中执行代码字符串并以 Wolfram 语言表达式的形式返回结果.
ExternalEvaluate["Shell"form,code] 执行命令字符串并以指定 form 的形式返回结果. form 可能的规格有 "Expression"、"StandardOutput"、"StandardError"、"ExitCode" 和 "Association".

使用说明

字符串模板 (<*…*>) 可用于计算并将 Wolfram 语言表达式插入 shell 代码字符串.

范例

打开所有单元关闭所有单元

基本范例 (2)

用默认 shell 运行命令并返回结果：

Wolfram Language code: ExternalEvaluate["Shell", "hostname"]

若命令 "ExitCode" 非零，则会返回一个 Failure 对象：

Wolfram Language code: ExternalEvaluate["Shell", "not a command"]

类型 > 可得到一个使用 ExternalEvaluate 进行计算的 Shell 代码单元格：

echo $(date)

用 File 封装运行文件中包含的代码：

Wolfram Language code: path = Export[CreateFile[], "echo 'hello from file!'", "String"]

在 Unix 系统上，确保文件是可执行的：

Wolfram Language code: ExternalEvaluate["Shell", "chmod +x <* path *>"]

Wolfram Language code: ExternalEvaluate["Shell", File[path]]

用 CloudDeploy 部署代码，从 CloudObject 直接运行代码：

Wolfram Language code: cobj = CloudExport["echo 'hello from cloud'", "String"]

Wolfram Language code: ExternalEvaluate["Shell", cobj]

用 URL 封装直接运行在线上托管的代码：

Wolfram Language code: ExternalEvaluate["Shell", URL["https://exampledata.wolfram.com/script.sh"]]

范围 (20)

启用会话：

Wolfram Language code: session = StartExternalSession["Shell"]

执行命令并返回结果：

Wolfram Language code: res = ExternalEvaluate[session, "hostname"]

从结果中提取 "ExitCode"：

Wolfram Language code: res["ExitCode"]

从结果中提取原始命令：

Wolfram Language code: res["Command"]

从结果中提取 "StandardOutput" 和 "StandardError"：

Wolfram Language code: res[{"StandardOutput", "StandardError"}]

关闭会话：

Wolfram Language code: DeleteObject[session]

使用 "ReturnType" 指定不同的返回类型：

Wolfram Language code:

ExternalEvaluate[
	{"Shell", "ReturnType" -> "ExitCode"}, 
	 "not a command"
	]

Wolfram Language code:

ExternalEvaluate[
	{"Shell", "ReturnType" -> "StandardOutput"}, 
	 "hostname"
	]

Wolfram Language code:

ExternalEvaluate[
	{"Shell", "ReturnType" -> "Association"}, 
	 "hostname"
	]

会话的选项 (10)

"ReturnType" (3)

对于 Shell 系统，默认返回的类型是 "Expression"：

Wolfram Language code: ExternalEvaluate["Shell", "hostname"]

对于 "Expression" 返回类型，结果会是 Success 或 Failure，取决于退出代码：

Wolfram Language code: result = ExternalEvaluate["Shell", "rm not/a/folder"]

可用 "StandardOutput"、"StandardError" 和 "ExitCode" 属性提取其他有关程序输出的信息：

Wolfram Language code: result["ExitCode"]

Wolfram Language code: result[{"StandardError", "StandardOutput"}]

"ReturnType" 可取的值有 "Expression"、"StandardOutput"、"StandardError" 和 "ExitCode"：

Wolfram Language code: ExternalEvaluate[{"Shell", "ReturnType" -> "ExitCode"}, "hostname"]

Wolfram Language code: ExternalEvaluate[{"Shell", "ReturnType" -> "StandardOutput"}, "date"]

Wolfram Language code: ExternalEvaluate[{"Shell", "ReturnType" -> "StandardError"}, "rm not/a/file"]

Wolfram Language code: ExternalEvaluate[{"Shell", "ReturnType" -> "Expression"}, "date"]

可用 Rule 快速指定 "ReturnType"：

Wolfram Language code: ExternalEvaluate["Shell" -> "ExitCode", "hostname"]

“Evaluator" (2)

用指定的 "Evaluator" 计算代码：

Wolfram Language code: ExternalEvaluate[{"Shell", "Evaluator" -> "/bin/sh"}, "ps -p $$"]

在 Windows 上，通过以下方式用 cmd.exe 运行指令：

Wolfram Language code: ExternalEvaluate[{"Shell", "Evaluator" -> Environment["ComSpec"]}, "Whoami"]

如果想要在 Windows PowerShell 上运行指令，可使用以下方式：

Wolfram Language code:

ExternalEvaluate[{"Shell", "Evaluator" -> FileNameJoin@{Environment["SystemRoot"], "system32", "WindowsPowerShell", "v1.0", "powershell.exe"}}, "hostname"]

"SessionProlog" (2)

用 "SessionProlog" 在会话开始时执行一些小指令：

Wolfram Language code: ExternalEvaluate[{"Shell", "SessionProlog" -> "echo 'session started'>&2"}, "echo 'hello world!'"]

开启外部会话，并导入初始化文件：

Wolfram Language code: ExternalEvaluate[<|"System" -> "Shell", "SessionProlog" -> "source .zshrc"|>, "mycommand"]

"SessionEpilog" (1)

用 "SessionEpilog" 在会话结束时执行一些小指令：

Wolfram Language code: ExternalEvaluate[{"Shell", "SessionEpilog" -> "echo 'closing session'>&2"}, "date"]

"Prolog" (1)

用 "Prolog" 在每次计算之前执行一些小指令：

Wolfram Language code:

ExternalEvaluate[
	{"Shell", "Prolog" -> "echo 'running a command' >&2"}, {"echo 'hello 1'", "echo 'hello 2'"}
	]

"Epilog" (1)

用 "Epilog" 在每次计算后执行一些小指令：

Wolfram Language code:

ExternalEvaluate[
	{"Shell", "Epilog" -> "echo 'running a command' >&2"}, {"echo 'hello 1'", "echo 'hello 2'"}
	]

指令的选项 (8)

"Command" (5)

提供的是字符串时，直接执行命令：

Wolfram Language code: ExternalEvaluate["Shell", "date"]

相当于用以下形式编写命令：

Wolfram Language code: ExternalEvaluate["Shell", <|"Command" -> "date"|>]

创建一个包含脚本的文件：

Wolfram Language code: path = Export[CreateFile[], "echo 'hello from file!'", "String"]

在 Unix 系统上，确保文件是可执行的：

Wolfram Language code: ExternalEvaluate["Shell", "chmod +x <* path *>"]

用 File 封装运行文件中的代码：

Wolfram Language code: ExternalEvaluate["Shell", <|"Command" -> File[path]|>]

相当于用以下形式编写命令：

Wolfram Language code: ExternalEvaluate["Shell", File[path]]

Wolfram Language code: ExternalEvaluate["Shell", helloWorld]

用 URL 封装直接运行线上的代码：

Wolfram Language code: ExternalEvaluate["Shell", <|"Command" -> URL["https://exampledata.wolfram.com/script.sh"]|>]

相当于用以下形式编写命令：

Wolfram Language code: ExternalEvaluate["Shell", URL["https://exampledata.wolfram.com/script.sh"]]

将代码放入 CloudObject 中：

Wolfram Language code: cloudObj = CloudExport["echo 'hello from cloud'", "Text", CloudObject["hello-world-sh"]]

从云端直接运行：

Wolfram Language code: ExternalEvaluate["Shell", <|"Command" -> cloudObj|>]

相当于用以下形式编写命令：

Wolfram Language code: ExternalEvaluate["Shell", cloudObj]

"ReturnType" (1)

Specifying a "ReturnType" in the command overrides the "ReturnType" for the session:

Wolfram Language code:

ExternalEvaluate[
	{"Shell", "ReturnType" -> "ExitCode"}, 
	{
	<|"Command" -> "hostname"|>, 
	<|"Command" -> "hostname", "ReturnType" -> "StandardOutput"|>
	}
	]

"TemplateArguments" (2)

运行命令时可内嵌一个 TemplateExpression：

Wolfram Language code:

x = RandomReal[]
ExternalEvaluate["Shell", "echo <* x *>"]

可用 "TemplateArguments" 填充 TemplateSlot：

Wolfram Language code:

ExternalEvaluate[
	"Shell", 
	<|"Command" -> "echo ``", "TemplateArguments" -> 1|>
	]

如果需要多个参数，可以使用 List：

Wolfram Language code:

ExternalEvaluate[
	"Shell", 
	{
	<|"Command" -> "echo `` ``", "TemplateArguments" -> {1, 2}|>, 
	<|"Command" -> "echo `1` `2`", "TemplateArguments" -> {1, 2}|>, 
	<|"Command" -> "echo `2` `1`", "TemplateArguments" -> {1, 2}|>
	}
	]

可以命名模板插槽，并用 Association 将已命名参数传递给模板：

Wolfram Language code:

ExternalEvaluate[
	"Shell", 
	<|"Command" -> "echo `year`/`month`/`day`", "TemplateArguments" -> <|"year" -> 2021, "month" -> 10, "day" -> 2|>|>
	]

应用 (3)

获取本地网络地址：

ifconfig en0 | awk '$1 == "inet" {print $2}'

使用 Spotlight 在你的 Mac 上查找特定文件：

mdfind PersonalNotebook

显示 10 个最大的已打开文件：

lsof / | awk '{ if($7 > 1048576) print $7/1048576 "MB" " " $9 " " $1 }' | sort -n -u | tail

创建一个函数，确保本地 Git 存储库是最新的：

Wolfram Language code:

cloneRepo[url_, dest_, branch_ : "master"] := 
		ExternalEvaluate[
			"Shell", Flatten @ {
				If[
				! FileExistsQ[FileNameJoin[{dest, ".git"}]], 
				"git clone " <> url <> " " <> dest, 
				{}
			], 
			"cd " <> dest, 
			"git checkout " <> branch, 
			"git pull --all"
			}
		]

使用函数：

Wolfram Language code:

cloneRepo[
		"https://github.com/hpaluch/rust-hello-world", 
		"~/Downloads/myClonePath", 
		"master"
	]

用 Shell 自动下载 Git 存储库，从源代码构建程序并运行该程序：

Wolfram Language code:

ExternalEvaluate[
	"Shell", {
	 "echo 🧹 cleanup the environment", 
	"rm -rf ~/Downloads/rust-hello-world", 
	"echo 🧑‍🔬 download latest code", 
	"cd ~/Downloads", 
	"git clone https://github.com/hpaluch/rust-hello-world.git", 
	"cd    ~/Downloads/rust-hello-world", 
	"echo 👷‍♀️ build the program", 
	"cargo update", 
	"cargo build", 
	"echo 🚀 run the program", 
	"cargo run"
	}]

属性和关系 (2)

用 FindExternalEvaluators 找出机器中所有可用的运算器：

Wolfram Language code: FindExternalEvaluators["Shell"]

用 "Evaluator" 在你的机器上手动指定一个 shell：

Wolfram Language code: ExternalEvaluate[{"Shell", "Evaluator" -> "/bin/zsh"}, "hostname"]

Powershell.exe 在 Windows 系统中是一个有效 "Evaluator"：

Wolfram Language code: powershell = FileNameJoin@{Environment["SystemRoot"], "system32", "WindowsPowerShell", "v1.0", "powershell.exe"}

Wolfram Language code: ExternalEvaluate[{"Shell", "Evaluator" -> powershell}, "hostname"]

RunProcess 也可用于执行 shell 命令，但并不会交互式打印输出：

Wolfram Language code: RunProcess[{"ping", "wikipedia.com", "-c", "4"}]

Wolfram Language code: ExternalEvaluate["Shell", "ping wikipedia.com -c 4"]

可能存在的问题 (2)

若程序要求输入，则 ExternalEvaluate 无法中断：

Wolfram Language code:

TimeConstrained[
	ExternalEvaluate[
	"Shell", 
	"echo 'Hello, who am I talking to?' && read varname"
	], 
	2
	]

当运行要求用户输入的外部命令时，建议将其在非交互模式下运行：

Wolfram Language code: ExternalEvaluate["Shell", "python3 -m pip uninstall numpy -y"]

ExternalEvaluate 实时打印输出：

Wolfram Language code: ExternalEvaluate["Shell", "ping wikipedia.com -c 4"];

$Output 可用于抑制 Print 输出：

Wolfram Language code:

Block[
	{$Output = {}}, 
	ExternalEvaluate[
	"Shell" -> "StandardOutput", 
	"ping wikipedia.com -c 4"
	]
	]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

"Shell" (外部计算系统)

更多信息

ExternalEvaluate 用法

使用说明

范例

基本范例 (2)

范围 (20)

会话的选项 (10)

"ReturnType" (3)

“Evaluator" (2)

"SessionProlog" (2)

"SessionEpilog" (1)

"Prolog" (1)

"Epilog" (1)

指令的选项 (8)

"Command" (5)

"ReturnType" (1)

"TemplateArguments" (2)

应用 (3)

属性和关系 (2)

可能存在的问题 (2)

"Shell" (外部计算系统)

更多信息

ExternalEvaluate 用法

使用说明

范例

基本范例 (2)

范围 (20)

会话的选项 (10)

"ReturnType" (3)

“Evaluator" (2)

"SessionProlog" (2)

"SessionEpilog" (1)

"Prolog" (1)

"Epilog" (1)

指令的选项 (8)

"Command" (5)

"ReturnType" (1)

"TemplateArguments" (2)

应用 (3)

属性和关系 (2)

可能存在的问题 (2)

参见

相关指南

历史