WOLFRAM

Wolfram 语言与系统参考资料中心

AbsoluteCorrelationFunction[data,hspec]

从 data 估计延迟 hspec 处的绝对相关函数.

AbsoluteCorrelationFunction[proc,hspec]

表示对于随机过程 proc 延迟 hspec 处的绝对相关函数.

AbsoluteCorrelationFunction[proc,s,t]

表示随机过程 proc 在时间 s 和 t 处的绝对相关函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
经验估值  
随机过程  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

AbsoluteCorrelationFunction

AbsoluteCorrelationFunction[data,hspec]

从 data 估计延迟 hspec 处的绝对相关函数.

AbsoluteCorrelationFunction[proc,hspec]

表示对于随机过程 proc 延迟 hspec 处的绝对相关函数.

AbsoluteCorrelationFunction[proc,s,t]

表示随机过程 proc 在时间 s 和 t 处的绝对相关函数.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (4)

估计延迟 2 处的绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[{2, 3, 4, 3}, 2]

对于来自自回归时间序列的随机样本，对绝对相关函数采样：

Wolfram Language code: data = RandomFunction[ARProcess[{.2, .3, .4}, 1], {1, 10 ^ 4}];
Wolfram Language code: ListPlot[AbsoluteCorrelationFunction[data, {30}], Filling -> Axis, PlotRange -> All]

离散时间序列的绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[BinomialProcess[p], s, t]
Wolfram Language code: DiscretePlot3D[Evaluate[% /. {p -> 2 / 3}], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

连续时间过程的绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[WienerProcess[μ, σ], s, t]
Wolfram Language code: Plot3D[Evaluate[% /. {μ -> 1, σ -> 2}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

范围  (13)

经验估值  (7)

对于延迟 5 处的某些数据，估计绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[Range[10], 5]

获取至多至延迟 9 处的相关函数的经验估值：

Wolfram Language code: AbsoluteCorrelationFunction[Range[10], {9}]

对于延迟 1至 9 以步长 2 计算绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[Range[10], {1, 9, 2}]

计算时间序列的绝对相关函数：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{-2.9904395734335427, -1.5547517217370468, -2.007044987914736, -0.7114933373063236, -1.5920036118254968, 0.23183536513859127, 0.056774681349179124, 0.32394041932443046, 0.10382798659711348, -0.684046765274114, - ... 1687325555, 3.410933732368106, 2.5200924558212163, 2.008558601261935, 0.43151331467691206, 0.6249727955196763}}, {{1, 1000, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];

具有多个滞后的时间序列的绝对相关函数作为时间序列给出：

Wolfram Language code: abscorr = AbsoluteCorrelationFunction[ts, {100}]
Wolfram Language code: ListPlot[abscorr, Filling -> Axis]

估计一组路径的绝对相关函数：

Wolfram Language code: data = RandomFunction[ARProcess[{.8}, 1], {0, 500}, 10]
Wolfram Language code: abscorr = AbsoluteCorrelationFunction[data, {12}];
Wolfram Language code: ListPlot[abscorr, Filling -> 0]

比较经验和理论绝对相关函数：

Wolfram Language code: proc = MAProcess[{.4, .3, .5, .6, .3}, 1.];
Wolfram Language code: data = RandomFunction[proc, {0, 100}];
Wolfram Language code: ListPlot[AbsoluteCorrelationFunction[#, {10}]& /@ {proc, data}, Filling -> {1 -> {2}}, PlotStyle -> PointSize[Medium], PlotLegends -> {"process absolute correlation", "sample absolute correlation"}]

绘制向量数据的绝对互相关：

Wolfram Language code: proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}]; data = RandomFunction[proc, {100}]; cov = AbsoluteCorrelationFunction[data, {-6, 6}];
Wolfram Language code: Table[ListPlot[cov["Values"][[All, i, j]], Filling -> 0, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]

随机过程  (6)

弱平稳离散时间过程的绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[ARProcess[{a}, σ^2], s, t]
Wolfram Language code: DiscretePlot3D[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

绝对相关函数只取决于对角线 ：

Wolfram Language code: AbsoluteCorrelationFunction[ARProcess[{a}, σ^2], h]
Wolfram Language code: DiscretePlot[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {h, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow", AxesLabel -> {h, None}]

弱平稳连续时间过程的绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], s, t]
Wolfram Language code: Plot3D[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

绝对相关函数只取决于对角线 :

Wolfram Language code: AbsoluteCorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], h]
Wolfram Language code: Plot[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {h, 0, 10}, ColorFunction -> "Rainbow", Filling -> Axis, AxesLabel -> {h, None}]

非弱平稳离散时间过程的绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[BinomialProcess[p], s, t]
Wolfram Language code: DiscretePlot3D[Evaluate[% /. p -> 1 / 3], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

绝对相关函数取决于两个时间参数：

Wolfram Language code: antidiagonals = AbsoluteCorrelationFunction[BinomialProcess[1 / 3], t, t + h]
Wolfram Language code: DiscretePlot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 6}, ExtentSize -> 1 / 2, AxesLabel -> {h, None}, PlotLegends -> (Row[{"t =", #}]& /@ Range[1, 4])]

非弱平稳连续时间过程的绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[PoissonProcess[μ], s, t]
Wolfram Language code: Plot3D[Evaluate[% /. μ -> 3], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

绝对相关函数取决于两个时间参数：

Wolfram Language code: antidiagonals = AbsoluteCorrelationFunction[PoissonProcess[3], t, t + h]
Wolfram Language code: Plot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 6}, AxesLabel -> {h, None}, PlotLegends -> (Row[{"t =", #}]& /@ Range[1, 4])]

某些时间序列过程的相关函数：

Wolfram Language code: proc1 = ARProcess[{.8}, 1]; proc2 = MAProcess[{-.4, -.7, .6, -1}, 1]; proc3 = SARMAProcess[{}, {}, {3, {.6}, {.1}}, 1]; proc4 = FARIMAProcess[{}, 1 / 3, {}, 1];
Wolfram Language code: DiscretePlot[AbsoluteCorrelationFunction[#, h], {h, 0, 15}, ExtentSize -> 1 / 2, PlotRange -> All, PlotLabel -> Head[#]]& /@ {proc1, proc2, proc3, proc4}

向量 ARProcess 的绝对互相关图线：

Wolfram Language code: proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}]; cov = AbsoluteCorrelationFunction[proc, h];
Wolfram Language code: Table[DiscretePlot[cov[[i, j]], {h, -6, 6}, ExtentSize -> 1 / 2, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]

应用  (2)

判断下列数据是否可以使用 MAProcess 或者 ARProcess 进行最好的模拟：

Wolfram Language code: ListLinePlot[data = TemporalData[TimeSeries, {{{-1.4735257611469446, -0.9158187257309729, -1.9060205147226934, -1.6174582169404574, -2.633459084244463, -2.104839842098871, -2.8701276893108894, -2.4118183939601607, -0.5125633448622677, -1.2356329399850385, 1. ... 26394036266876, -0.16380797769527589, 0.3559909972777121, 1.5343047104249412, 0.10763337590714506}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1]]

很难从样本路径判断内在过程：

Wolfram Language code: candidates = {MAProcess[{.5, .4}, 1], ARProcess[{.5, .4}, 1]};
Wolfram Language code: SeedRandom[2]; ListLinePlot[RandomFunction[#, {0, 100}]]& /@ candidates

数据的绝对相关函数缓慢衰退：

Wolfram Language code: ListPlot[AbsoluteCorrelationFunction[data, {10}], Filling -> 0]

ARProcess 明显是比 MAProcess 更好的候选模型：

Wolfram Language code: ListPlot[AbsoluteCorrelationFunction[#, {10}], PlotLabel -> Head[#], Filling -> 0]& /@ candidates

使用绝对相关函数来确定一个过程是否为均值遍历：

Wolfram Language code: proc = OrnsteinUhlenbeckProcess[0, σ, θ];

这是个弱平稳过程：

Wolfram Language code: WeakStationarity[proc]

计算绝对相关函数：

Wolfram Language code: abscorr[h_] = AbsoluteCorrelationFunction[proc, h]

求带状积分的值：

Wolfram Language code: int[t_] = 1 / (2 * t)Integrate[(1 - Abs[u] / (2 * t))abscorr[u], {u, -2 * t, 2 * t}, Assumptions -> t > 0]

检查积分极限是否为0，断定均值遍历性：

Wolfram Language code: Limit[int[t], t -> ∞, Assumptions -> σ > 0 && θ > 0]

属性和关系  (13)

样本绝对相关函数是对过程绝对相关函数的一个有偏估计量：

Wolfram Language code: proc = ARMAProcess[1, {5 / 6, -1 / 6}, {2 / 3}, 1]; paths = RandomFunction[proc, {0, n = 10}, 10 ^ 4];

计算样本绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[paths, {10}]
Wolfram Language code: sacf = TimeSeriesMapThread[(#2(n + 1) / (n + 1 - #1))&, %]

过程的绝对相关函数：

Wolfram Language code: acf = AbsoluteCorrelationFunction[proc, {10}]

绘制这两个函数：

Wolfram Language code: ListPlot[{sacf, acf}, Filling -> 0, PlotLegends -> {"sample absolute correlation", "process absolute correlation"}]

列表的绝对相关函数可以利用 AbsoluteCorrelation 计算：

Wolfram Language code: data = Range[10]; n = Length[data];

计算数据的绝对相关函数：

Wolfram Language code: AbsoluteCorrelationFunction[data, {n - 1}] / (Range[n, 1, -1] / n)

利用绝对相关性：

Wolfram Language code: Table[ AbsoluteCorrelation[Drop[data, i], Drop[RotateRight[data, i], i]], {i, 0, n - 1}]
Wolfram Language code: % - %%

AbsoluteCorrelationFunction 是绝对相关矩阵的非对角线项：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];
Wolfram Language code: AbsoluteCorrelation[𝒫[{s, t}], 1, 2]
Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t]
Wolfram Language code: Simplify[%% - %, 0 < s < t]

延迟 0 处的样本绝对相关函数估计第二个 Moment：

Wolfram Language code: data = Range[10]; AbsoluteCorrelationFunction[data, 0]
Wolfram Language code: Moment[data, 2]
Wolfram Language code: % - %%

样本绝对相关函数与 CovarianceFunction 有关：

Wolfram Language code: data = Range[10]; n = Length[data];
Wolfram Language code: AbsoluteCorrelationFunction[data - Mean[data], {n - 1}]
Wolfram Language code: CovarianceFunction[data, {n - 1}]
Wolfram Language code: % - %%

样本绝对相关函数与 CorrelationFunction 有关：

Wolfram Language code: data = Range[10]; n = Length[data];
Wolfram Language code: AbsoluteCorrelationFunction[data - Mean[data], {n - 1}]

根据第一个元素进行尺度缩放：

Wolfram Language code: % / First[%]

与样本相关函数比较：

Wolfram Language code: CorrelationFunction[data, {n - 1}]
Wolfram Language code: % - %%

使用 Expectation 计算绝对相关函数：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];
Wolfram Language code: Expectation[x[s] x[t], x𝒫, Assumptions -> s > 0 && t > 0]
Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t]
Wolfram Language code: Simplify[% - %%, s < t]

绝对相关函数 与 Moment 函数相关：

Wolfram Language code: 𝒫 = GeometricBrownianMotionProcess[μ, σ, θ];
Wolfram Language code: AbsoluteCorrelationFunction[𝒫, t, t]

验证方程 ，其中 是第 个矩函数：

Wolfram Language code: Moment[𝒫[t], 2]
Wolfram Language code: % - %%//Simplify

绝对相关函数 与 CovarianceFunction 相关：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];
Wolfram Language code: CovarianceFunction[𝒫, s, t]

验证方程 ，其中 是均值函数：

Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t] - Mean[𝒫[s]] Mean[𝒫[t]]
Wolfram Language code: % - %%

当过程均值为零，绝对相关函数等于 CovarianceFunction：

Wolfram Language code: AbsoluteCorrelationFunction[WienerProcess[], s, t]
Wolfram Language code: CovarianceFunction[WienerProcess[], s, t]
Wolfram Language code: % - %%

绝对相关函数对于 ToInvertibleTimeSeries 是不变的：

Wolfram Language code: proc = MAProcess[{2, 4}, 1];
Wolfram Language code: TimeSeriesInvertibility[proc]
Wolfram Language code: iproc = ToInvertibleTimeSeries@proc
Wolfram Language code: AbsoluteCorrelationFunction[#, s, t]& /@ {proc, iproc}

绝对相关函数对于中心化而言不是不变的：

Wolfram Language code: data = TemporalData[EventSeries, {{{-0.5997948200136711, -0.6119370022135471, -2.181570597470531, -3.0852015062413294, -2.5597554304014736, -2.724339030053185, -2.1990400702572104, -2.2335014895051946, -1.0488409388108924, -0.1005536745721749, 2 ... 63267114671374, 22.486986202712714, 21.766625417091756, 22.44341047189002, 22.079788501970878, 23.102713685532592}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> None, ValueDimensions -> 1}}, False, 10.1];

数据有非零均值：

Wolfram Language code: Mean[data]

中心化数据：

Wolfram Language code: newdata = Standardize[data, Mean, 1&];

比较绝对相关函数：

Wolfram Language code: ListPlot[AbsoluteCorrelationFunction[#, {20}], Filling -> 0]& /@ {data, newdata}

PowerSpectralDensity 对于零均值过程是绝对相关函数的变换：

Wolfram Language code: proc = ARProcess[{a}, σ^2]; cf = AbsoluteCorrelationFunction[proc, h]

在合适的参数下使用 FourierSequenceTransform：

Wolfram Language code: ft = FourierSequenceTransform[cf, h, z]

与功率谱比较：

Wolfram Language code: PowerSpectralDensity[proc, z]
Wolfram Language code: FullSimplify[% - ft]

可能存在的问题  (1)

AbsoluteCorrelationFunction 输出可能包含 DifferenceRoot：

Wolfram Language code: AbsoluteCorrelationFunction[ARProcess[{a, b}, σ^2], t] //Simplify[#, t > 0]&

使用 FunctionExpand 恢复显式幂：

Wolfram Language code: %//FunctionExpand
Wolfram Research (2012)，AbsoluteCorrelationFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AbsoluteCorrelationFunction.html.

文本

Wolfram Research (2012)，AbsoluteCorrelationFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AbsoluteCorrelationFunction.html.

CMS

Wolfram 语言. 2012. "AbsoluteCorrelationFunction." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AbsoluteCorrelationFunction.html.

APA

Wolfram 语言. (2012). AbsoluteCorrelationFunction. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AbsoluteCorrelationFunction.html 年

BibTeX

@misc{reference.wolfram_2026_absolutecorrelationfunction, author="Wolfram Research", title="{AbsoluteCorrelationFunction}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/AbsoluteCorrelationFunction.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_absolutecorrelationfunction, organization={Wolfram Research}, title={AbsoluteCorrelationFunction}, year={2012}, url={https://reference.wolfram.com/language/ref/AbsoluteCorrelationFunction.html}, note=[Accessed: 16-August-2026]}