Wolfram 语言与系统参考资料中心

AlternatingHarmonicNumber

AlternatingHarmonicNumber[n]

返回第个交替调和数 .

AlternatingHarmonicNumber[n,r]

返回阶数为的第个交替调和数 .

AlternatingHarmonicNumber[n,r,s]

返回阶数为、装饰值为的第个交替调和数 .

范例

打开所有单元关闭所有单元

基本范例 (4)

前 10 个交替调和数：

Wolfram Language code: Table[AlternatingHarmonicNumber[n], {n, 10}]

在实数集的一个子集上绘制：

Wolfram Language code: ReImPlot[AlternatingHarmonicNumber[t], {t, 0, 5}]

在复数集的一个子集上绘制：

Wolfram Language code: ComplexPlot3D[AlternatingHarmonicNumber[z], {z, -1 - I, 1 + I}, ...]

原点处的级数展开：

Wolfram Language code: Series[AlternatingHarmonicNumber[x], {x, 0, 3}]

范围 (22)

数值计算 (6)

进行数值计算：

Wolfram Language code: AlternatingHarmonicNumber[4, 1 / 2]

进行高精度计算：

Wolfram Language code: N[AlternatingHarmonicNumber[3], 50]

Wolfram Language code: N[AlternatingHarmonicNumber[3, 5], 50]

Wolfram Language code: N[AlternatingHarmonicNumber[3, 5, 1 / 2], 50]

复数输入：

Wolfram Language code: AlternatingHarmonicNumber[4, 1 + I]

Wolfram Language code: N[AlternatingHarmonicNumber[27 + I, 5]]

Wolfram Language code: N[AlternatingHarmonicNumber[2 + 1 / 2I, 5 - I, I]]

高效地进行高精度计算：

Wolfram Language code: AlternatingHarmonicNumber[13, 5`100]//Timing

Wolfram Language code: AlternatingHarmonicNumber[5 / 7, 5`1000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的保证区间：

Wolfram Language code: AlternatingHarmonicNumber[2, Interval[{2.1, 2.2}]]

Wolfram Language code: AlternatingHarmonicNumber[1 / 2, CenteredInterval[3 / 4, 1 / 1000]]

或使用 Around 计算平均情况下的统计区间：

Wolfram Language code: AlternatingHarmonicNumber[ 3 / 2, Around[2.1, 0.01]]

计算数组的逐元素值：

Wolfram Language code: AlternatingHarmonicNumber[2, {{1 / 2, 2}, {2, 1 / 2}}]

或者使用 MatrixFunction 计算矩阵的 AlternatingHarmonicNumber 函数：

Wolfram Language code: MatrixFunction[AlternatingHarmonicNumber[2, #]&, {{1 / 2, 2}, {2, 1 / 2}}]//FullSimplify

特定值 (6)

AlternatingHarmonicNumber[n,r]，其中为符号参数：

Wolfram Language code: AlternatingHarmonicNumber[4, r]

AlternatingHarmonicNumber[n,r]，其中为符号参数：

Wolfram Language code: AlternatingHarmonicNumber[n, 4]//FunctionExpand

在零点处的值：

Wolfram Language code: AlternatingHarmonicNumber[0]

在处的值：

Wolfram Language code: AlternatingHarmonicNumber[∞]

Wolfram Language code: AlternatingHarmonicNumber[∞, r]

Wolfram Language code: AlternatingHarmonicNumber[∞, r, s]

求使得 AlternatingHarmonicNumber[n]=0.5 的的值：

Wolfram Language code: nval = Chop[n /. FindRoot[AlternatingHarmonicNumber[n] == 0.5, {n, 1}], 10^-6]//Quiet

Wolfram Language code: Plot[Abs[AlternatingHarmonicNumber[n]], {n, 0, 5}, Rule[...]]

将分数参数的交错调和数用初等函数表示：

Wolfram Language code: AlternatingHarmonicNumber[1 / 2]//FunctionExpand

Wolfram Language code: AlternatingHarmonicNumber[7 / 3]//FunctionExpand

函数性质 (7)

AlternatingHarmonicNumber 的实定义域：

Wolfram Language code: FunctionDomain[AlternatingHarmonicNumber[x], x]

复定义域：

Wolfram Language code: FunctionDomain[AlternatingHarmonicNumber[z], z, Complexes]

AlternatingHarmonicNumber 的实值域：

Wolfram Language code: FunctionRange[AlternatingHarmonicNumber[x], x, y]//Quiet

AlternatingHarmonicNumber 不是解析函数：

Wolfram Language code: FunctionAnalytic[AlternatingHarmonicNumber[x], x]

AlternatingHarmonicNumber 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[AlternatingHarmonicNumber[x], x]

AlternatingHarmonicNumber 在实数轴上无奇点与不连续点：

Wolfram Language code: FunctionSingularities[AlternatingHarmonicNumber[x], x]

Wolfram Language code: FunctionDiscontinuities[AlternatingHarmonicNumber[x], x]

AlternatingHarmonicNumber 既非凸也非凹：

Wolfram Language code: FunctionConvexity[AlternatingHarmonicNumber[x], x]

TraditionalForm 显示：

Wolfram Language code: TraditionalForm[{AlternatingHarmonicNumber[n], AlternatingHarmonicNumber[n, r], AlternatingHarmonicNumber[n, r, s]}]

级数展开 (3)

使用 Series 求泰勒展开：

Wolfram Language code: Series[AlternatingHarmonicNumber[n], {n, 0, 3}]

附近前三种逼近法的图示：

Wolfram Language code:

terms = Normal@Table[Series[AlternatingHarmonicNumber[n], {n, 0, m}], {m, 1, 5, 2}];
ReImPlot[{AlternatingHarmonicNumber[n], terms}, {n, 0, 10}, PlotRange -> {-30, 30}]

在 1 处的级数展开：

Wolfram Language code: Series[AlternatingHarmonicNumber[n], {n, 1, 3}]

无穷处的级数展开：

Wolfram Language code: Series[AlternatingHarmonicNumber[n], {n, ∞, 5}]

应用 (10)

求和 (3)

包含 AlternatingHarmonicNumber 的有限欧拉和：

Wolfram Language code: Sum[n^2AlternatingHarmonicNumber[n, 3], {n, 1, k}]

包含 AlternatingHarmonicNumber 的无限欧拉和：

Wolfram Language code: Sum[((1/2))^n(AlternatingHarmonicNumber[n, 3]/n^4), {n, 1, ∞}]

包含 HarmonicNumber 和 AlternatingHarmonicNumber 乘积的有限欧拉和：

Wolfram Language code: Sum[(HarmonicNumber[n, 2]AlternatingHarmonicNumber[n]/3^nn^2), {n, 1, ∞}]

递推方程 (2)

求解一个在激励项中包含 AlternatingHarmonicNumber 的递推方程：

Wolfram Language code: RSolveValue[{x[k] - 2x[k - 1] == AlternatingHarmonicNumber[k], x[1] == 1}, x[k], k]

激励项为 HarmonicNumber 与 AlternatingHarmonicNumber 的乘积，并且带有一个前因子：

Wolfram Language code: RSolveValue[{x[k] + 6x[k - 1] == k * HarmonicNumber[k] * AlternatingHarmonicNumber[k], x[1] == 1}, x[k], k]

生成函数 (3)

计算 AlternatingHarmonicNumber 的 GeneratingFunction：

Wolfram Language code: GeneratingFunction[AlternatingHarmonicNumber[n, 2], n, x]

计算 HarmonicNumber 与 AlternatingHarmonicNumber 的乘积的 GeneratingFunction：

Wolfram Language code: GeneratingFunction[HarmonicNumber[n]AlternatingHarmonicNumber[n, 3], n, x]

计算 StirlingS1 与 AlternatingHarmonicNumber 的乘积的 ExponentialGeneratingFunction：

Wolfram Language code: ExponentialGeneratingFunction[StirlingS1[n, 3]AlternatingHarmonicNumber[n, 2], n, x]

离散变换 (2)

计算 AlternatingHarmonicNumber 的平方的 ZTransform：

Wolfram Language code: ZTransform[AlternatingHarmonicNumber[n, 2] ^ 2, n, z]

计算 AlternatingHarmonicNumber 的 DirichletTransform（含有理前因子）：

Wolfram Language code: DirichletTransform[(1 / 2)^nAlternatingHarmonicNumber[n, 2], n, s]

属性和关系 (9)

AlternatingHarmonicNumber 的定义恒等式：

Wolfram Language code: Sum[((-1)^i + 1/i), {i, 1, n}] == AlternatingHarmonicNumber[n]

Wolfram Language code: Sum[((-1)^i + 1/i^r), {i, 1, n}] == AlternatingHarmonicNumber[n, r]

Wolfram Language code: Sum[((-1)^i + 1s^i/i^r), {i, 1, n}] == AlternatingHarmonicNumber[n, r, s]

当时，简化为：

Wolfram Language code: AlternatingHarmonicNumber[n, 1] === AlternatingHarmonicNumber[n]

当时，简化为：

Wolfram Language code: AlternatingHarmonicNumber[n, r, 1] === AlternatingHarmonicNumber[n, r]

对于整数，AlternatingHarmonicNumber 可以用 HarmonicNumber 表示：

Wolfram Language code: (AlternatingHarmonicNumber[n] == HarmonicNumber[n] - HarmonicNumber[Floor[n / 2]]) /. n -> 10

AlternatingHarmonicNumber 可以用带装饰的 HarmonicNumber 表示：

Wolfram Language code: AlternatingHarmonicNumber[n] === -HarmonicNumber[n, 1, -1]

Wolfram Language code: AlternatingHarmonicNumber[n, r] === -HarmonicNumber[n, r, -1]

AlternatingHarmonicNumber 可以用带装饰的 MultipleHarmonicNumber 表示：

Wolfram Language code: AlternatingHarmonicNumber[n] === -MultipleHarmonicNumber[n, {1}, {-1}]

Wolfram Language code: AlternatingHarmonicNumber[n, r] === -MultipleHarmonicNumber[n, {r}, {-1}]

递推恒等式：

Wolfram Language code:

(AlternatingHarmonicNumber[z + 1] == AlternatingHarmonicNumber[z] + ((-1)^z/Sqrt[(1 + z)^2]))//FunctionExpand//FullSimplify

AlternatingHarmonicNumber、LerchPhi 与 Zeta 函数之间的关系：

Wolfram Language code: AlternatingHarmonicNumber[n] == -(-1)^n LerchPhi[-1, 1, 1 + n] + Log[2]//FullSimplify

Wolfram Language code:

AlternatingHarmonicNumber[n, r] == 2^-r ((-2 + 2^r) Zeta[r] + (-1)^n (-Zeta[r, (1 + n/2)] + Zeta[r, (2 + n/2)]))//FullSimplify

Wolfram Language code: AlternatingHarmonicNumber[n, r, s] == (-s)^1 + n LerchPhi[-s, r, 1 + n] - PolyLog[r, -s]//FullSimplify

AlternatingHarmonicNumber 在处可以用 Zeta、DirichletEta 和 PolyLog 表示：

Wolfram Language code: AlternatingHarmonicNumber[∞, r] == (1 - 2^-r + 1)Zeta[r] == DirichletEta[r]//FullSimplify

Wolfram Language code: AlternatingHarmonicNumber[∞, r, s] == -PolyLog[r, -s]//FullSimplify

定义费马商，以及用于测试一个有理 expr 在模下是否为的实用函数 modZeroQ：

Wolfram Language code: fermatQuotient[a_, p_Integer ? PrimeQ] := (a ^ (p - 1) - 1) / p;

Wolfram Language code:

modZeroQ[expr_, m_Integer] := Module[{t = Together[expr], num, den}, num = Numerator[t];den = Denominator[t];
	If[CoprimeQ[den, m], Mod[num * PowerMod[den, -1, m], m] == 0, False]
	];

验证 mod-p 的同余式 $TemplateBox[{{p, -, 1}}, AlternatingHarmonicNumber] = 2 q_p(2) (mod p)$ 对多个素数成立：

Wolfram Language code: AllTrue[Prime[Range[100]], modZeroQ[AlternatingHarmonicNumber[# - 1] - 2 fermatQuotient[2, #], #]&]

验证 mod-p² 同余式 $TemplateBox[{{p, -, 1}}, AlternatingHarmonicNumber] = 2 q_p(2) -p q_p(2)^2 (mod p^2)$ （对于 p>3）：

Wolfram Language code:

AllTrue[Prime[Range[3, 100]], modZeroQ[AlternatingHarmonicNumber[# - 1] - (2 fermatQuotient[2, #] - # fermatQuotient[2, #] ^ 2), # ^ 2]&]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

AlternatingHarmonicNumber

更多信息

范例

基本范例 (4)

范围 (22)

数值计算 (6)

特定值 (6)

函数性质 (7)

级数展开 (3)

应用 (10)

求和 (3)

递推方程 (2)

生成函数 (3)

离散变换 (2)

属性和关系 (9)

文本

CMS

APA

BibTeX

BibLaTeX

AlternatingHarmonicNumber

更多信息

范例

基本范例 (4)

范围 (22)

数值计算 (6)

特定值 (6)

函数性质 (7)

级数展开 (3)

应用 (10)

求和 (3)

递推方程 (2)

生成函数 (3)

离散变换 (2)

属性和关系 (9)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX