WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ArcCot[z]

複素数 の逆余接を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
積分変換  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ArcCot

ArcCot[z]

複素数 の逆余接を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 答はラジアンで求まる．
  • が実数のとき，答は必ず0を除くから の範囲にある．
  • 特別な引数の場合，ArcCotは自動的に厳密値を計算する．
  • ArcCotは任意の数値精度で評価できる．
  • ArcCotは自動的にリストに関数の並列的な適用を行う．
  • ArcCot[z]は，複素 平面上， 〜 の範囲で不連続な分枝切断線を持つ．
  • ArcCotはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • ArcCotは逆余接関数である．ArcCot[x]は，実数 について， となるような（0を除く）のラジアン角を表す．
  • ArcCotは自動的にリストに縫い込まれる．特別な引数の場合，ArcCotは自動的に厳密値を計算する．厳密な数式が引数として与えられると，ArcCotは任意の数値精度に評価できることがある．ArcCotを含む記号式の操作に便利なその他の演算には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
  • ArcCotは，複素引数 について，によって定義される．ArcCot[z]は複素 平面上で不連続な分枝切断線を持つ．
  • 関連する数学関数には，Cot，ArcTan，ArcCothがある．

例題

すべて開く すべて閉じる

例  (5)

結果はラジアンで与えられる：

Wolfram Language code: ArcCot[1]

Degreeで割って結果を度で得る：

Wolfram Language code: ArcCot[0] / Degree//FullSimplify

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcCot[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcCot[z], {z, -3 - 2I, 3 + 2I}, PlotLegends -> Automatic]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcCot[x], {x, ∞, 5}]

特異点における漸近展開：

Wolfram Language code: Series[ArcCot[x], {x, I, 3}, Assumptions -> x > 0]//FullSimplify

スコープ  (46)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ArcCot[2.5]

高精度で評価する：

Wolfram Language code: N[ArcCot[2 / 3], 50]

出力精度は入力精度に従う：

Wolfram Language code: ArcCot[0.66666666666666666666666666666666666666666667]

複素引数について評価する：

Wolfram Language code: ArcCot[1.5 + 0.3I]

ArcCotを高精度で効率的に評価する：

Wolfram Language code: ArcCot[2.5`500]//Timing
Wolfram Language code: ArcCot[2.5`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcCot[Interval[{1, Sqrt[3]}]]
Wolfram Language code: ArcCot[CenteredInterval[1, 1 / 100]]
Wolfram Language code: ArcCot[CenteredInterval[1 + 2I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArcCot[Around[.9, 0.1]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcCot[{{1, Sqrt[3]}, {0, Sqrt[3]}}]

MatrixFunctionを使って行列のArcCot関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcCot[#]&, {{1, Sqrt[3]}, {0, Sqrt[3]}}]

特定の値  (4)

固定点におけるArcCotの値：

Wolfram Language code: Table[ArcCot[(n /2)], {n, -2, 2}]

無限大における値：

Wolfram Language code: ArcCot[Infinity]
Wolfram Language code: ArcCot[ComplexInfinity]

ArcCotの特異点：

Wolfram Language code: {ArcCot[I ], ArcCot[-I ]}

方程式を満足する の値を求める：

Wolfram Language code: f[x_] := ArcCot[x] - (π/3);
Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 0, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化  (3)

ArcCot関数をプロットする：

Wolfram Language code: Plot[ArcCot[x], {x, -10, 10}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcCot[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcCot[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code: Table[PolarPlot[ArcCot[k ϕ], {ϕ, -3π, 3π}, Sequence[Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotRange -> {All, {-1, 1}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> All]], {k, 1, 4}]

関数の特性  (12)

ArcCotはすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcCot[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ArcCot[z], z, Complexes]

ArcCotは，区間からの0を除くすべての実数値に達する：

Wolfram Language code: FunctionRange[ArcCot[x], x, y]

複素領域からの引数についての関数の範囲：

Wolfram Language code: FunctionRange[ArcCot[z], z, y, Complexes]

ArcCotは奇関数である：

Wolfram Language code: ArcCot[-x]

ArcCotは鏡面性cot^(-1)(TemplateBox[{x}, Conjugate])=TemplateBox[{{{cot, ^, {(, {-, 1}, )}}, (, x, )}}, Conjugate]を有する：

Wolfram Language code: FullSimplify[ArcCot[Conjugate[x]] == Conjugate[ArcCot[x]]]

ArcCotは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ArcCot[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ArcCot[x], x]

ArcCotは非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[ArcCot[x], x]

ArcCotは単射である：

Wolfram Language code: FunctionInjective[ArcCot[x], x]
Wolfram Language code: Plot[{ArcCot[x], 1 / 2}, {x, -2π, 2π}]

ArcCotは全射ではない：

Wolfram Language code: FunctionSurjective[ArcCot[x], x]
Wolfram Language code: Plot[{ArcCot[x], 2, 0}, {x, -π, π}]

ArcCotは非負でも非正でもない：

Wolfram Language code: FunctionSign[ArcCot[x], x]

ArcCotは零点で特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ArcCot[x], x]
Wolfram Language code: FunctionDiscontinuities[ArcCot[x], x]

ArcCotは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcCot[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcCot[x]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[ArcCot[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcCot[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcCot[x], {x, n}]

積分  (3)

ArcCotの不定積分：

Wolfram Language code: Integrate[ArcCot[x], x]

原点を中心として区間上で積分されるArcCotの定積分は0である：

Wolfram Language code: Integrate[ArcCot[x], {x, -1, 1}]

その他の積分例：

Wolfram Language code: Integrate[x ArcCot[x], x]
Wolfram Language code: Integrate[z ^ k ArcCot[z], z]

級数展開  (4)

Seriesを使ってのテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ArcCot[x], {x, 1, 7}]

の周囲のArcCotについての最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[ArcCot[x], {x, 1, m}], {m, 1, 5, 2}]; Plot[{ArcCot[x], terms}, {x, 0, 2}]

ArcCotの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ArcCot[x], {x, 0, n}]

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcCot[x], {x, I, 1}]
Wolfram Language code: Series[ArcCot[x], {x, I / 2, 1}]

ArcCotはベキ級数に適用できる：

Wolfram Language code: ArcCot[SeriesData[x, 0, {1, 0, -1/3, 0, -1/45, 0, -2/945, 0, -1/4725, 0, -2/93555}, -1, 10, 1]]

積分変換  (3)

InverseLaplaceTransformを使って逆ラプラス(Laplace)変換を計算する：

Wolfram Language code: InverseLaplaceTransform[ArcCot[s], s, t]

InverseFourierTransform：

Wolfram Language code: InverseFourierTransform[ArcCot[ω], ω, t ]

MellinTransform：

Wolfram Language code: MellinTransform[ArcCot[x], x, s ]

関数の恒等式と簡約  (3)

ArcCotを含む式を簡約する：

Wolfram Language code: FullSimplify[Tan[ArcCot[x]]]

TrigToExpを使い，Logを使ってArcCotを表す：

Wolfram Language code: TrigToExp[ArcCot[z]]
Wolfram Language code: ExpToTrig[%]//FullSimplify

実変数 および を仮定して展開する：

Wolfram Language code: ComplexExpand[ArcCot[x + I y]]

関数表現  (5)

ArcTanを使って表現する：

Wolfram Language code: ArcTan[1 / x]//FullSimplify

逆ヤコビ関数を介した表現：

Wolfram Language code: InverseJacobiCS[z, 0]//FullSimplify
Wolfram Language code: InverseJacobiSC[(1/z), 0]//FullSimplify

Hypergeometric2F1を使って表現する：

Wolfram Language code: (HypergeometricPFQ[{1, (1/2)}, {(3/2)}, -(1/z^2)]/z)//FullSimplify

MeijerGによる表現：

Wolfram Language code: MeijerGReduce[ArcCot[x], x]
Wolfram Language code: Activate[%]//FullSimplify

ArcCotはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcCot[x], x]

アプリケーション  (4)

辺の長さが3と4で斜辺が5の直角三角形の角度を求める：

Wolfram Language code: N[{ArcCot[4 / 3], ArcCot[3 / 4]} / Degree]

合計90°になる：

Wolfram Language code: Total[%]

余接関数の加法定理：

Wolfram Language code: Cot[ArcCot[x] + ArcCot[y]]//TrigExpand//Simplify

微分方程式を解く：

Wolfram Language code: DSolve[{(1 + x^2) y''[x] + 2 x y'[x] == ArcCot[x], y[0] == 0, y'[0] == 1}, y[x], x]

ArcCotの分枝切断線は虚軸に沿っている：

Wolfram Language code: Plot3D[Re[ArcCot[x + I y]], {y, -2, 2}, {x, -2.5, 2.5}]

特性と関係  (4)

TrigToExpを使ってArcCotをLogで表す：

Wolfram Language code: TrigToExp[ArcCot[z]]
Wolfram Language code: ExpToTrig[%]//FullSimplify

FullSimplifyを使ってArcCotを含む式を簡約する：

Wolfram Language code: FullSimplify[16 ArcCot[5] - 4 ArcCot[239]]

ArcCotは角度をラジアンで与えるのに対し，ArcCotDegreesは同じ角度を度で与える：

Wolfram Language code: ArcCot[1]
Wolfram Language code: ArcCotDegrees[1]

Reduceを使ってArcCotを含む不等式を解く：

Wolfram Language code: Reduce[ArcCot[x] > Pi / 3, x]
Wolfram Research (1988), ArcCot, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcCot.html （2021年に更新）.

テキスト

Wolfram Research (1988), ArcCot, Wolfram言語関数， https://reference.wolfram.com/language/ref/ArcCot.html （2021年に更新）.

CMS

Wolfram Language. 1988. "ArcCot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ArcCot.html.

APA

Wolfram Language. (1988). ArcCot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcCot.html

BibTeX

@misc{reference.wolfram_2026_arccot, author="Wolfram Research", title="{ArcCot}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ArcCot.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_arccot, organization={Wolfram Research}, title={ArcCot}, year={2021}, url={https://reference.wolfram.com/language/ref/ArcCot.html}, note=[Accessed: 18-August-2026]}