WOLFRAM

Wolfram 语言与系统参考资料中心

Array[f,n]

生成长度为 n、元素为 f[i] 的列表.

Array[f,n,r]

生成使用索引原点 r 的列表.

Array[f,n,{a,b}]

生成使用 n 个从 a 到 b 的数值组成的列表.

Array[f,{n1,n2,…}]

生成嵌套列表的 n1×n2×… 数组，元素为 f[i1,i2,…].

Array[f,{n1,n2,…},{r1,r2,…}]

生成一个列表，该列表使用指标起点 ri (缺省为 1).

Array[f,{n1,n2,…},{{a1,b1},{a2,b2},…}]

生成使用 ni 个从 ai 到 bi 的数值组成的列表.

Array[f,dims,origin,h]

对数组的每一层使用头部 h，而不是 List.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数组元素规范  
索引规范  
标头规范  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关的工作流程
相关链接
历史
按以下格式引用：

Array

Array[f,n]

生成长度为 n、元素为 f[i] 的列表.

Array[f,n,r]

生成使用索引原点 r 的列表.

Array[f,n,{a,b}]

生成使用 n 个从 a 到 b 的数值组成的列表.

Array[f,{n1,n2,…}]

生成嵌套列表的 n1×n2×… 数组，元素为 f[i1,i2,…].

Array[f,{n1,n2,…},{r1,r2,…}]

生成一个列表，该列表使用指标起点 ri (缺省为 1).

Array[f,{n1,n2,…},{{a1,b1},{a2,b2},…}]

生成使用 ni 个从 ai 到 bi 的数值组成的列表.

Array[f,dims,origin,h]

对数组的每一层使用头部 h，而不是 List.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (5)

Wolfram Language code: Array[f, 10]
Wolfram Language code: Array[1 + # ^ 2&, 10]

生成一个 3×2 数组：

Wolfram Language code: Array[f, {3, 2}]

生成一个 3×4 数组：

Wolfram Language code: Array[10#1 + #2&, {3, 4}]

使用指标起点 0 而不是 1：

Wolfram Language code: Array[f, 10, 0]

起点指标为 0 和 4 而不是 1：

Wolfram Language code: Array[f, {2, 3}, {0, 4}]

在 0 和 1 之间采样：

Wolfram Language code: Array[f, 10, {0, 1}]

使用范围 {-1/2,1/2} 和 {0,1}：

Wolfram Language code: Array[f, {2, 3}, {{-1 / 2, 1 / 2}, {0, 1}}]

范围  (11)

数组元素规范  (5)

使用索引符号创建一个 3×2 数组：

Wolfram Language code: Array[a, {3, 2}]

使用下角标创建一个 4×4 数组：

Wolfram Language code: Array[Subscript[a, ##]&, {4, 4}]

创建希尔伯特矩阵：

Wolfram Language code: Array[(1/# + #2 - 1)&, {3, 3}]

使用已命名的函数插槽：

Wolfram Language code: Array[Function[{i, j}, (1/i + j - 1)], {3, 3}]

与内置函数进行比较：

Wolfram Language code: % == %% == HilbertMatrix[3]

创建常量数组：

Wolfram Language code: Array[x&, {5, 5}]

使用 ## 识别一串索引：

Wolfram Language code: Array[FromDigits[{##}]&, {2, 3, 4}]

索引规范  (4)

创建一维数组：

Wolfram Language code: Array[f, 10]

创建一维数组，从 0 开始索引：

Wolfram Language code: Array[f, 10, 0]

创建一个 3×2 数组：

Wolfram Language code: Array[f, {3, 2}]

创建一个 4×3×2 数组，该数组的原点取决于索引：

Wolfram Language code: Array[f, {4, 3, 2}, {0, -1, -2}]

标头规范  (2)

为数组的每一层级使用一个非默认标头：

Wolfram Language code: Array[f, {3, 3}, 1, g]

使用 Plus 而非 List 来连接元素：

Wolfram Language code: Array[a, {2, 3}, 1, Plus]

任何带有 Flat 属性的符号都会产生相同的形状：

Wolfram Language code: SetAttributes[f, Flat]; Array[a, {2, 3}, 1, f]

应用  (4)

完全反对称张量：

Wolfram Language code: Array[Signature[{##}]&, {3, 3, 3}]

与内置的 LeviCivitaTensor 进行比较：

Wolfram Language code: % == LeviCivitaTensor[3]

下三角矩阵：

Wolfram Language code: Boole[Array[Greater, {5, 5}]]//MatrixForm

通用的符号下标的矩阵：

Wolfram Language code: m = Array[Subscript[a, ##]&, {3, 4}]
Wolfram Language code: MatrixForm[m]

使用它来查看一些线性代数函数的结果：

Wolfram Language code: RowReduce[m]//MatrixForm
Wolfram Language code: Det[Take[m, All, 3]]

对在区间上均匀分布的函数采样：

Wolfram Language code: ListPlot[Array[Sin[2 #] - Cos[3 #]&, 50, {0, 2π}], Filling -> Axis, DataRange -> {0, 2π}]

属性和关系  (4)

ConstantArray[c,dims] 和 Array[c&,dims] 是等价的：

Wolfram Language code: dims = RandomInteger[{1, 4}, {5}];
Wolfram Language code: ConstantArray[c, dims] === Array[c&, dims]

当 c 是一个机器数时，ConstantArray 对大型数组的运算速度要快得多：

Wolfram Language code: {First[Timing[ca = ConstantArray[0., {2000, 2000}]]], First[Timing[a = Array[0.&, {2000, 2000}]]], ca === a}

Array[f,dims] 可以使用 Table 函数生成：

Wolfram Language code: dims = RandomInteger[{1, 5}, {RandomInteger[{2, 5}]}]; f[args___] := Total[{args}]
Wolfram Language code: a = Array[f, dims];

设置 Table 的大小规范：

Wolfram Language code: v = Array[x, Length[dims]]; tl = Transpose[{v, dims}]

使用 Apply 连接它们到一个 Table 函数：

Wolfram Language code: t = Table[f@@v, ##]&@@ tl;

这个结果等同于用 Array 函数生成的数组：

Wolfram Language code: a === t

SparseArray[{i_,j_}->f[i,j],dims] 给出一个 Array[f,dims] 的稀疏表示：

Wolfram Language code: dims = RandomInteger[{1, 10}, {2}]; f[i_, j_] := i - 2 j
Wolfram Language code: s = SparseArray[{i_, j_} -> f[i, j], dims]
Wolfram Language code: a = Array[f, dims]

结果是 Equal：

Wolfram Language code: s == a

虽然对象不相同，但代表的数组相同：

Wolfram Language code: {SameQ[s, a], SameQ[Normal[s], a]}

并行计算 Array：

Wolfram Language code: Parallelize[Array[Prime, 20]]

巧妙范例  (3)

幂级数数组：

Wolfram Language code: Array[Power, {5, 5}]

最大公约数数组：

Wolfram Language code: ArrayPlot[Array[GCD, {20, 20}]]

数组的数组：

Wolfram Language code: Array[Array[x&, #]&, {6}]
Wolfram Research (1988)，Array，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Array.html （更新于 2012 年）.

文本

Wolfram Research (1988)，Array，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Array.html （更新于 2012 年）.

CMS

Wolfram 语言. 1988. "Array." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2012. https://reference.wolfram.com/language/ref/Array.html.

APA

Wolfram 语言. (1988). Array. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Array.html 年

BibTeX

@misc{reference.wolfram_2026_array, author="Wolfram Research", title="{Array}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/Array.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_array, organization={Wolfram Research}, title={Array}, year={2012}, url={https://reference.wolfram.com/language/ref/Array.html}, note=[Accessed: 13-August-2026]}