WOLFRAM

Wolfram 语言与系统参考资料中心

AudioMeasurements[audio,"prop"]

为完整音频 audio 计算属性 "prop".

AudioMeasurements[audio,{"prop1","prop2",…}]

计算多个属性 "propi".

AudioMeasurements[audio,"prop",format]

以指定输出格式 format 返回结果.

AudioMeasurements[{audio1,audio2,…},…]

为所有音频 audioi 返回测量结果.

AudioMeasurements[video,…]

返回 video 中第一个音轨的测量值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

AudioMeasurements

AudioMeasurements[audio,"prop"]

为完整音频 audio 计算属性 "prop".

AudioMeasurements[audio,{"prop1","prop2",…}]

计算多个属性 "propi".

AudioMeasurements[audio,"prop",format]

以指定输出格式 format 返回结果.

AudioMeasurements[{audio1,audio2,…},…]

为所有音频 audioi 返回测量结果.

AudioMeasurements[video,…]

返回 video 中第一个音轨的测量值.

更多信息和选项

  • AudioMeasurements[audio,"Properties"] 以字符串列表的形式给出所有可用属性的名称.
  • 全局音频属性：
  • "Channels"通道数量
    "Duration"持续时间
    "Length"样本数量
    "SampleRate"以 Hz 为单位的采样率
    "Type"数据类型
  • 以下所有属性都是用通道值平均数计算的.
  • 基本直方图属性：
  • "Max"最大值
    "MaxAbs"最大绝对值
    "Min"最小值
    "MinAbs"最小绝对值
    "MinMax"最小和最大值
    "MinMaxAbs"最小和最大绝对值
    "Mean"平均值
    "Median"中位数
    "ApproximateMedian"近似中位数
    "StandardDeviation"数值的标准差
    "Total"数值总和
  • 强度属性：
  • "Loudness"使用斯蒂芬幂法则（Steven's power law）() 计算
    "LoudnessEBU"使用 EBU 标准的感知强度（以 LUFS 为单位）
    "LoudnessRangeEBU"使用 EBU 标准的感知强度范围
    "Power"平方值的平均值
    "RMSAmplitude"均方根值
  • 时间域属性：
  • "CrestFactor"最大值除以均方根值
    "PeakToAveragePowerRatio"最大功率除以平均功率
    "TemporalCentroid"数值的时域质心
    "ZeroCrossings"零交叉数量
    "ZeroCrossingRate"零交叉率
  • 频域属性：
  • "SpectralCentroid"功率谱的质心
    "SpectralCrest"功率谱的最大值除以平均值
    "SpectralFlatness"功率谱的几何平均除以平均值
    "SpectralKurtosis"幅度谱的峰度
    "SpectralRollOff"大部分能量频率集中的在该值之下的频率
    "SpectralSkewness"幅度谱的峰度
    "SpectralSlope"幅度谱的估算斜率
    "SpectralSpread"功率谱的带宽计量
  • 默认情况下，返回属性值列表. 其他格式 format 的规格包括：
  • Automatic自动决定输出
    "Association"将结果格式化为一个 Association
    "Dataset"将结果格式化为一个 Dataset
    "List"将结果格式化为一个 List
    "RuleList"将结果格式化为一个 Rule 表达式列表

范例

打开所有单元 关闭所有单元

基本范例  (2)

最小和最大样本值：

Wolfram Language code: a = ExampleData[{"Sound", "Violin"}];
Wolfram Language code: AudioMeasurements[a, "Min"]
Wolfram Language code: AudioMeasurements[a, "Max"]

计算多个属性：

Wolfram Language code: a = ExampleData[{"Audio", "Piano"}];
Wolfram Language code: AudioMeasurements[a, {"Min", "Max", "Median"}]

范围  (4)

在多个音频对象上计算多个属性：

Wolfram Language code: list = {ExampleData[{"Audio", "SubwayTrain"}], ExampleData[{"Audio", "MaleVoice"}]};
Wolfram Language code: AudioMeasurements[list, {"Min", "Max"}]

将结果格式化为一个 Association：

Wolfram Language code: a = ExampleData[{"Audio", "MaleVoice"}];
Wolfram Language code: AudioMeasurements[a, {"Length", "SampleRate", "Type"}, "Association"]

返回数值列表：

Wolfram Language code: AudioMeasurements[a, {"Length", "SampleRate", "Type"}, "List"]

返回规则列表：

Wolfram Language code: AudioMeasurements[a, {"Length", "SampleRate", "Type"}, "RuleList"]

输出类型也可指定为 Dataset：

Wolfram Language code: AudioMeasurements[a, {"Length", "SampleRate", "Type"}, "Dataset"]

在多通道音频对象中，通道在计算属性前被平均化：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}]; props = {"MinMax", "Mean", "StandardDeviation"};
Wolfram Language code: AudioMeasurements[a, props] == AudioMeasurements[AudioChannelMix[a, 1], props]

处理视频的音轨：

Wolfram Language code: AudioMeasurements[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\), "Min"]

应用  (2)

检测音频对象是否有恒定的样本值：

Wolfram Language code: constantQ[audio_] := And@@(SameQ@@AudioMeasurements[audio, {"Min", "Max"}]);
Wolfram Language code: constantQ /@ {AudioGenerator["Sin"], AudioGenerator["Silence"]}

使用波谱特征查找音频对象列表中的群集（cluster）：

Wolfram Language code: list = {\!\(\*AudioBox["![Embedded Audio Player](audio://content-ewxls)"]\), \!\(\*AudioBox["![Embedded Audio Player](audio://content-gcjdl)"]\), \!\(\*AudioBox["![Embedded Audio Player](audio://content-fytkk)"]\), \!\(\*AudioBox["![Embedded Audio Player](audio://content-dkdtd)"]\), \!\(\*AudioBox["![Embedded Audio Player](audio://content-pqo5r)"]\), \!\(\*AudioBox["![Embedded Audio Player](audio://content-1iwl9)"]\), \!\(\*AudioBox["![Embedded Audio Player](audio://content-7qywt)"]\), \!\(\*AudioBox["![Embedded Audio Player](audio://content-nldr6)"]\), \!\(\*AudioBox["![Embedded Audio Player](audio://content-xc09e)"]\)};

在音频对象列表上计算 "SpectralCentroid" 和 "SpectralSpread" 的属性：

Wolfram Language code: props = AudioMeasurements[list, {"SpectralCentroid", "SpectralSpread"}, "List"];

找出声音类似的群集：

Wolfram Language code: clusters = FindClusters[props -> props]

将音频对象当做绘图标记绘制结果：

Wolfram Language code: ListPlot[Partition[props, 1], PlotMarkers -> list, ImageSize -> 300, Prolog -> ({Opacity[.3, RGBColor[1, 0.5, 0.5]], Disk[Mean@#, 400]& /@ clusters}), PlotRange -> {{00, 4000}, {0, 4000}}, AspectRatio -> 1]

属性和关系  (4)

应用于多声道音频的 Min 等函数也适用于被展平的数据：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}];
Wolfram Language code: Min[a]

AudioMeasurements 适用于输入音频信号的单声道版本：

Wolfram Language code: AudioMeasurements[a, "Min"]
Wolfram Language code: AudioMeasurements[AudioChannelMix[a, 1], "Min"]

根据集成响度 EBU 规范计算 "LoudnessEBU"：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];

使用 EBU 瞬时规范计算响度：

Wolfram Language code: l = AudioLoudness[a, "EBUMomentary"]["Values"];
Wolfram Language code: Histogram[l, 10]

丢弃低于 LUFS 的所有值，计算临时平均值：

Wolfram Language code: tempMean = DeleteCases[l, _ ? (# < -70.&)]//Mean

通过去除小于临时平均值减去 10 LUFS 的所有值来计算另一个平均值：

Wolfram Language code: DeleteCases[l, _ ? (# < tempMean - 10.&)]//Mean
Wolfram Language code: AudioMeasurements[a, "LoudnessEBU"]

根据集成响度 EBU 规范计算 "LoudnessRangeEBU"：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];

使用 EBU 瞬时规范计算响度：

Wolfram Language code: l = AudioLoudness[a, "EBUShortTerm", PaddingSize -> 0]["Values"];
Wolfram Language code: Histogram[l, 10]

首先丢弃低于 LUFS 的所有值，计算临时平均值：

Wolfram Language code: tempMean = DeleteCases[l, _ ? (# < -70.&)]//Mean

然后去除小于临时平均值减去 20 LUFS 的所有值：

Wolfram Language code: vals = DeleteCases[l, _ ? (# < tempMean - 20.&)];

用列表的 .1 和 .95 分位数之间的差计算响度：

Wolfram Language code: Quantile[vals, {.95, .1}]
Wolfram Language code: Subtract@@%
Wolfram Language code: AudioMeasurements[a, "LoudnessRangeEBU"]

"LoudnessEBU" 属性被用在 AudioNormalize 计算中：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];
Wolfram Language code: AudioNormalize[a, "LoudnessEBU"]
Wolfram Language code: AudioMeasurements[%, "LoudnessEBU"]
Wolfram Research (2016)，AudioMeasurements，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioMeasurements.html （更新于 2024 年）.

文本

Wolfram Research (2016)，AudioMeasurements，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioMeasurements.html （更新于 2024 年）.

CMS

Wolfram 语言. 2016. "AudioMeasurements." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/AudioMeasurements.html.

APA

Wolfram 语言. (2016). AudioMeasurements. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AudioMeasurements.html 年

BibTeX

@misc{reference.wolfram_2026_audiomeasurements, author="Wolfram Research", title="{AudioMeasurements}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/AudioMeasurements.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audiomeasurements, organization={Wolfram Research}, title={AudioMeasurements}, year={2024}, url={https://reference.wolfram.com/language/ref/AudioMeasurements.html}, note=[Accessed: 10-August-2026]}