WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BandstopFilter[data,{ω1,ω2}]

カットオフ周波数が ω1と ω2のバンドストップフィルタをデータの配列に適用する．

BandstopFilter[data,{{ω,q}}]

中心周波数 ω，Q値 q を使う．

BandstopFilter[data,spec,n]

長さ n のフィルタカーネルを使う．

BandstopFilter[data,spec,n,wfun]

平滑化窓 wfun をフィルタカーネルに適用する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
データ  
パラメータ  
オプション  
Padding  
SampleRate  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

BandstopFilter

BandstopFilter[data,{ω1,ω2}]

カットオフ周波数が ω1と ω2のバンドストップフィルタをデータの配列に適用する．

BandstopFilter[data,{{ω,q}}]

中心周波数 ω，Q値 q を使う．

BandstopFilter[data,spec,n]

長さ n のフィルタカーネルを使う．

BandstopFilter[data,spec,n,wfun]

平滑化窓 wfun をフィルタカーネルに適用する．

詳細とオプション

  • バンドパスフィルタリングは，音声増幅器，補聴器，拡声装置にしばしば使われるもので，信号の高周波数および低周波数はそのまま残しつつ中間波数を減衰させる．
  • BandstopFilterは，窓法で作成された有限インパルス応答 (FIR) カーネルを使用してデジタル信号をたたみ込みむ
  • カーネルが長くなると周波数の識別が向上する．
  • data は次のいずれでもよい．
  • list任意階数の数値配列
    tseriesTimeSeriesやTemporalDataのような時間データ
    image任意のImageオブジェクトまたはImage3Dオブジェクト
    audioAudioオブジェクトまたはSoundオブジェクト
    videoVideoオブジェクト
  • 減衰される周波数の範囲はカットオフ周波数 ω1および ω2 (ω2>ω1)に依存する．
  • 画像や多次元配列に適用された場合，フィルタリングはレベル1から始めて各次元に連続的に適用される．BandstopFilter[data,{{ω11,ω21},…}]は i 次元で周波数{ω1i,ω2i}を使う．
  • 周波数値 ωiは0から まででなければならない．
  • BandstopFilter[data,{ω1,ω2}]はカットオフ周波数{ω1,ω2}と入力 data に適したフィルタカーネル長と平滑化窓を使う．
  • よく使われる平滑化窓 wfun
  • BlackmanWindowBlackman窓で平滑化する
    DirichletWindow平滑化は行わない
    HammingWindowハミング窓で平滑化する
    {v1,v2,…}値 viの窓を使う
    fからの範囲で f をサンプリングすることで窓を作る
  • 使用可能なオプション
  • Padding "Fixed"使用する充填値
    SampleRate Automatic入力に想定されるサンプルレート
  • デフォルトで，データと同様画像にもSampleRate->1が想定される．音声信号と時系列については，サンプルレートは抽出されるか入力データから計算されるかする．
  • SampleRatesr の場合，カットオフ周波数 ωcは0から sr まででなければならない．

例題

すべて開く すべて閉じる

例  (3)

余弦の和にバンドストップフィルタをかける：

Wolfram Language code: data = Table[Cos[x] + Cos[10x] + Cos[20x], {x, 0, 2Pi, 0.04}]; filtered = BandstopFilter[data, {.2, .6}, 31]; ListLinePlot[{data, filtered}, PlotLegends -> {"original", "filtered"}]

中間周波数の余弦がない理想的な結果と比較する：

Wolfram Language code: ideal = Table[Cos[x] + Cos[20x], {x, 0, 2Pi, 0.04}]; ListLinePlot[{ideal, filtered}]

音声にバンドストップフィルタをかける：

Wolfram Language code: BandstopFilter[\!\(\*AudioBox["![Embedded Audio Player](audio://content-1323j)"]\), {Quantity[500, "Hertz"], Quantity[2500, "Hertz"]}]

画像にバンドストップフィルタをかける：

Wolfram Language code: BandstopFilter[[image], {0.25, 1.}]//ImageAdjust

スコープ  (13)

データ  (8)

1Dパルス列にフィルタをかける：

Wolfram Language code: data = BoxMatrix[5, {41}]; ListLinePlot[{data, BandstopFilter[data, {.5, 1.5}, 15]}, PlotRange -> All]

2Dパルス列にフィルタをかける：

Wolfram Language code: data = Table[UnitBox[(n/7), (m/7)], {n, -7, 7}, {m, -7, 7}]; ListPlot3D[data]
Wolfram Language code: BandstopFilter[data, {0.5, 1.5}]//ListPlot3D

TimeSeriesにフィルタをかける：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1]; filtered = BandstopFilter[ts, {Quantity[5, "Hertz"], Quantity[10, "Hertz"]}];
Wolfram Language code: ListLinePlot[{ts, filtered}, PlotLegends -> {"original data", "filtered"}]

3全音信号のSoundオブジェクトにバンドストップフィルタをかける：

Wolfram Language code: snd = Sound[SampledSoundList[Table[Sin[2 π 697 t] + Sin[2 π 1209 t] + Sin[2π 1633 t], {t, 0., 0.3, 1 / 8000.}], 8000]]

長さ101のBlackman窓でバンドストップフィルタを使って中間の音を除去する：

Wolfram Language code: BandstopFilter[snd, {Quantity[900, "Hertz"], Quantity[1400, "Hertz"]}, 101, BlackmanWindow]

半音画像にバンドストップフィルタをかける：

Wolfram Language code: BandstopFilter[[image], {0.5, 1.}]

動画のフレームにフィルタをかける：

Wolfram Language code: BandstopFilter[Video["ExampleData/fish.mp4"], {0.5, 1}]

3D画像にバンドストップフィルタをかける：

Wolfram Language code: BandstopFilter[[image], {0.5, 1.}]

厳密精度でフィルタをかける：

Wolfram Language code: BandstopFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, {Pi / 2, Pi}, 5]

パラメータ  (5)

数値カットオフ周波数は弧度秒を単位とした数量として解釈される：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-1323j)"]\);
Wolfram Language code: BandstopFilter[a, {2000 π, 4000 π}] === BandstopFilter[a, {Quantity[2000*Pi, "Radians"/"Seconds"], Quantity[4000*Pi, "Radians"/"Seconds"]}] === BandstopFilter[a, {Quantity[1000, "Hertz"], Quantity[2000, "Hertz"]}]

カットオフ周波数がとのバンドストップフィルタを使ってホワイトノイズ信号にフィルタをかける：

Wolfram Language code: noise = AudioGenerator["White", 0.2]; Periodogram[noise]
Wolfram Language code: Periodogram[BandstopFilter[noise, {Quantity[5000, "Hertz"], Quantity[15000, "Hertz"]}]]

中心周波数8660Hz， 値1を使う：

Wolfram Language code: Periodogram[BandstopFilter[noise, {{Quantity[8660, "Hertz"], 1}}]]

Q因子を小さくする：

Wolfram Language code: Periodogram[BandstopFilter[noise, {{Quantity[8660, "Hertz"], 0.66}}]]

長さ33のフィルタを使う：

Wolfram Language code: noise = AudioGenerator["White", 0.2]; Periodogram[BandstopFilter[noise, {Quantity[5000, "Hertz"], Quantity[15000, "Hertz"]}, 33]]

より長いカーネルを使って周波数弁別を大きくする：

Wolfram Language code: Periodogram[BandstopFilter[noise, {Quantity[5000, "Hertz"], Quantity[15000, "Hertz"]}, 55]]

さまざまな窓関数を使って減衰量を変える：

Wolfram Language code: a = AudioGenerator[Sin[11025 2 π #^2]&]; Periodogram[BandstopFilter[a, {Quantity[5000, "Hertz"], Quantity[15000, "Hertz"]}, 33, #]& /@ {DirichletWindow, HammingWindow, BlackmanWindow}, PlotLegends -> {"Dirichlet", "Hamming", "Hann"}]

調節可能なカイザー(Kaiser)窓を使って減衰量を変える：

Wolfram Language code: Periodogram[Table[BandstopFilter[a, {Quantity[5000, "Hertz"], Quantity[15000, "Hertz"]}, 33, KaiserWindow[#, b]&], {b, {3, 5, 7}}], PlotLegends -> {3, 5, 7}]

各次元で異なる中心周波数を使う：

Wolfram Language code: BandstopFilter[[image], {{0.5, 1.33}, {0.75, 1.}}, 33]

オプション  (3)

Padding  (1)

充填法を変えるとエッジ効果も変わる：

Wolfram Language code: ramp = Range[21] / 21. + RandomReal[.1, 21]; GraphicsRow@(ListLinePlot[{ramp, BandstopFilter[ramp, {0.5, 1.5}, 13, Padding -> #]}, ...]& /@ {"Fixed", "Periodic", 0})

SampleRate  (2)

サンプルレート sr=1を仮定して周波数 π/2に中心を置くフィルタを使う：

Wolfram Language code: BandstopFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, {{π / 2., 1}}]

サンプルレート sr=3を仮定する：

Wolfram Language code: BandstopFilter[{0, 0, 0, 0, 0, 1, 1, 1, 1, 1}, {{3π / 2., 1}}, SampleRate -> 3]

レートTemplateBox[{44100, "Hz", hertz, "Hertz"}, QuantityTF]でサンプリングされた音声にバンドストップフィルタを適用する：

Wolfram Language code: noise = AudioGenerator["White", 0.2]; sr = QuantityMagnitude@AudioSampleRate[noise]
Wolfram Language code: BandstopFilter[noise, {{sr π / 2., 1}}]//Periodogram

アプリケーション  (1)

現代の88鍵のピアノでは，55番目のキー(C5)の基本周波数は約523Hzである．BandstopFilterを使って，以下の音声クリップにあるその他の周波数は保持しつつ，このキーの最初の倍音(1046Hz) を効率的に削除する：

Wolfram Language code: key55 = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sglcp)"]\);

基本周波数(1046Hz)を中心とした長さ101の狭いフィルタ(Q=3)を使う：

Wolfram Language code: f = 2 523; res = BandstopFilter[key55, {{2 π f, 3}}, 101]

2つの音声クリップの周波数スペクトルを比較する：

Wolfram Language code: Periodogram[{key55, res}, PlotRange -> All, GridLines -> All, PlotLegends -> {"original", "filtered"}]

特性と関係  (5)

0と π のカットオフ周波数を使って零列を返す：

Wolfram Language code: BandstopFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, {0, Pi}]

LeastSquaresFilterKernelおよびハミング窓を使ってバンドストップフィルタを作る：

Wolfram Language code: n = 5; ω = {1, 1.5}; win = Array[HammingWindow, n, {-1 / 2, 1 / 2}]; ker = win LeastSquaresFilterKernel[{"Bandstop", ω}, n]
Wolfram Language code: ListConvolve[ker, {0, 0, 0, 1, 1, 1, 0, 0, 0}, Ceiling[n / 2], 0]

BandstopFilterの結果と比較する：

Wolfram Language code: BandstopFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, ω, n, win, Padding -> 0]

長さ21のバンドストップフィルタのインパルス応答：

Wolfram Language code: h = BandstopFilter[ArrayPad[{1}, 10], {0.5, 2.5}, 21]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

フィルタの振幅スペクトル：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

平滑化窓なしでの長さ21のバンドストップフィルタのインパルス応答：

Wolfram Language code: h = BandstopFilter[ArrayPad[{1}, 10], {0.5, 2.5}, 21, None]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

フィルタの振幅スペクトル：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

バンドストップフィルタの周波数弁別はフィルタの長さが長くなるにつれて向上する：

Wolfram Language code: Manipulate[ ListLinePlot[Abs[Fourier[BandstopFilter[ArrayPad[{1.}, 128], {Pi / 4., 3 Pi / 4.}, n, None], FourierParameters -> {1, -1}]][[ ;; 129]], ...], {{n, 21}, 3, 63, 2}]

考えられる問題  (1)

PaddingNoneとすると，出力は入力より短くなる：

Wolfram Language code: BandstopFilter[{0, 0, 0, 1, 1, 1}, {0.5, 1.5}, Padding -> None]
Wolfram Research (2012), BandstopFilter, Wolfram言語関数， https://reference.wolfram.com/language/ref/BandstopFilter.html （2025年に更新）.

テキスト

Wolfram Research (2012), BandstopFilter, Wolfram言語関数， https://reference.wolfram.com/language/ref/BandstopFilter.html （2025年に更新）.

CMS

Wolfram Language. 2012. "BandstopFilter." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/BandstopFilter.html.

APA

Wolfram Language. (2012). BandstopFilter. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BandstopFilter.html

BibTeX

@misc{reference.wolfram_2026_bandstopfilter, author="Wolfram Research", title="{BandstopFilter}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/BandstopFilter.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_bandstopfilter, organization={Wolfram Research}, title={BandstopFilter}, year={2025}, url={https://reference.wolfram.com/language/ref/BandstopFilter.html}, note=[Accessed: 08-September-2026]}