WOLFRAM

Wolfram 语言与系统参考资料中心

BilateralLaplaceTransform[expr,t,s]

给出 expr 的双侧拉普拉斯变换.

BilateralLaplaceTransform[expr,{t1,t2,…,tn},{s1,s2,…,sn}]

给出 expr 的多维度双侧拉普拉斯变换.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
单变量函数  
多元函数  
数值计算  
形式属性  
选项  
Assumptions  
GenerateConditions  
PrincipalValue  
WorkingPrecision  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BilateralLaplaceTransform

BilateralLaplaceTransform[expr,t,s]

给出 expr 的双侧拉普拉斯变换.

BilateralLaplaceTransform[expr,{t1,t2,…,tn},{s1,s2,…,sn}]

给出 expr 的多维度双侧拉普拉斯变换.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

定义一个实数轴上的指数衰减函数：

Wolfram Language code: f[t_] := E ^ (-Abs[t])
Wolfram Language code: Plot[f[t], {t, -3, 3}]

计算其双侧拉普拉斯变换：

Wolfram Language code: BilateralLaplaceTransform[f[t], t, s]

双侧拉普拉斯变换的复变函数图：

Wolfram Language code: ComplexPlot[%[[1]], {s, -2 - 2I, 2 + 2I}]

在单个点上计算双侧拉普拉斯变换：

Wolfram Language code: BilateralLaplaceTransform[E ^ (-3Abs[t]), t, 0.3]

计算多元函数的双侧拉普拉斯变换：

Wolfram Language code: BilateralLaplaceTransform[Exp[-Abs[x]]UnitStep[y], {x, y}, {s, p}]

范围  (20)

单变量函数  (8)

UnitStep 函数的双侧拉普拉斯变换：:

Wolfram Language code: BilateralLaplaceTransform[UnitStep[t], t, s]

UnitBox 函数的双侧拉普拉斯变换：

Wolfram Language code: BilateralLaplaceTransform[UnitBox[t], t, s]

UnitTriangle 函数：

Wolfram Language code: BilateralLaplaceTransform[UnitTriangle[t], t, s]

幂函数：

Wolfram Language code: BilateralLaplaceTransform[(t^n - 1/(n - 1)!)UnitStep[t], t, s]
Wolfram Language code: FullSimplify[%, n∈ PositiveIntegers]

指数函数：

Wolfram Language code: BilateralLaplaceTransform[Exp[-Abs[t / 2 - 1]], t, s]
Wolfram Language code: ComplexPlot[%[[1]], {s, -1 - I, +1 + I}]

DiracDelta：

Wolfram Language code: BilateralLaplaceTransform[DiracDelta[t - T], t, s]

分段函数：

Wolfram Language code: BilateralLaplaceTransform[Piecewise[{{Exp[-2t], t > 1}, {Exp[-t], t ≤ 1}}], t, s]

余弦函数和指数函数之积：

Wolfram Language code: f[t_] := Cos[10t]Exp[-Abs[t]]
Wolfram Language code: Plot[f[t], {t, -3, 3}]
Wolfram Language code: BilateralLaplaceTransform[f[t], t, s]

双侧拉普拉斯变换的复值图：

Wolfram Language code: ComplexPlot[%[[1]], {s, -15 - 15I, 15 + 15I}]

多元函数  (2)

多元函数的双侧拉普拉斯变换：

Wolfram Language code: BilateralLaplaceTransform[E ^ (-x ^ 2 - y ^ 2), {x, y}, {s, p}]

多元分段函数：

Wolfram Language code: BilateralLaplaceTransform[UnitStep[x - y]UnitStep[y], {x, y}, {s, p}]

数值计算  (2)

计算单点处的双侧拉普拉斯变换：

Wolfram Language code: BilateralLaplaceTransform[UnitTriangle[t ^ 2 - 1], t, 5.6]

或者，可以先用符号计算拉普拉斯变换：

Wolfram Language code: BilateralLaplaceTransform[UnitTriangle[t ^ 2 - 1], t, s]

然后给 指定特定数值进行计算：

Wolfram Language code: % /.  s -> 5.6

对于某些函数，双侧拉普拉斯变换只能用数值计算：

Wolfram Language code: F[s_ ? NumericQ] := BilateralLaplaceTransform[UnitTriangle[t / 10] BesselJ[1, Cos[t ^ 2]], t, s]
Wolfram Language code: F[1.67]

仅使用数值绘制双侧拉普拉斯变换：

Wolfram Language code: DiscretePlot[F[n / 100.], {n, -150, 150}, PlotRange -> {-1, 1}]

形式属性  (8)

BilateralLaplaceTransform 是线性操作符：

Wolfram Language code: BilateralLaplaceTransform[a f1[t] + b f2[t], t, s]

的双侧拉普拉斯变换是 在 处的拉普拉斯变换：

Wolfram Language code: BilateralLaplaceTransform[Exp[a t]f[t], t, s]

缩放：

Wolfram Language code: BilateralLaplaceTransform[f[a * t], t, s]

时间平移：

Wolfram Language code: BilateralLaplaceTransform[f[t - a], t, s]

双侧拉普拉斯变换的卷积属性：

Wolfram Language code: BilateralLaplaceTransform[Convolve[f[τ], g[τ], τ, t], t, s]

时域中的微分：

Wolfram Language code: BilateralLaplaceTransform[f'[t], t, s]

函数乘以一个有正整数幂的 t：

Wolfram Language code: BilateralLaplaceTransform[t ^ 2f[t], t, s]
Wolfram Language code: BilateralLaplaceTransform[t ^ 5f[t], t, s]

时域中的积分：

Wolfram Language code: BilateralLaplaceTransform[Integrate[f[τ], {τ, -Infinity, t}], t, s]

选项  (4)

Assumptions  (1)

使用 Assumptions 指定参数值域：

Wolfram Language code: BilateralLaplaceTransform[Exp[ -a t ^ 2], t, s, Assumptions -> a > 0]

GenerateConditions  (1)

将 GenerateConditions 设置为 False 可获取没有条件的结果：

Wolfram Language code: BilateralLaplaceTransform[UnitStep[t + 5] Exp[-t], t, s, GenerateConditions -> False]

PrincipalValue  (1)

由于 处的奇点，下面函数的双侧变换没有定义：

Wolfram Language code: BilateralLaplaceTransform[(UnitStep[-t]/t + 1), t, s]

使用 PrincipalValue 可获取积分的柯西主值：

Wolfram Language code: BilateralLaplaceTransform[(UnitStep[-t]/t + 1), t, s, PrincipalValue -> True]

WorkingPrecision  (1)

使用 WorkingPrecision 可获取任意精度的结果：

Wolfram Language code: BilateralLaplaceTransform[Exp[-(5t^4/t^2 + 1)]Sin[t], t, 5.1]
Wolfram Language code: BilateralLaplaceTransform[Exp[-(5t^4/t^2 + 1)]Sin[t], t, 5.1, WorkingPrecision -> 10]
Wolfram Language code: BilateralLaplaceTransform[Exp[-(5t^4/t^2 + 1)]Sin[t], t, 5.1, WorkingPrecision -> 20]

属性和关系  (2)

BilateralLaplaceTransform 和 InverseBilateralLaplaceTransform 互为反函数：

Wolfram Language code: BilateralLaplaceTransform[InverseBilateralLaplaceTransform[F[s], s, t], t, s]
Wolfram Language code: InverseBilateralLaplaceTransform[BilateralLaplaceTransform[f[t], t, s], s, t]

使用 NIntegrate 可获取近似数值：

Wolfram Language code: BilateralLaplaceTransform[Exp[-t ^ 2] Sin[t], t, s]
Wolfram Language code: % /. {s -> 1.4}

NIntegrate 计算双侧拉普拉斯参数 s 的数值：

Wolfram Language code: NIntegrate[Exp[-1.4 t] Exp[-t ^ 2]Sin[t], {t, -Infinity, Infinity}]

巧妙范例  (1)

创建一个基础双侧拉普拉斯变换的表格：

Wolfram Language code: flist = {DiracDelta[t], Derivative[1][DiracDelta][t], UnitStep[t], -UnitStep[-t], (t^n - 1 UnitStep[t]/Gamma[n]), -(t^n - 1 UnitStep[-t]/Gamma[n]), Exp[-a t] UnitStep[t], -Exp[-a t] UnitStep[-t], ((Exp[-a t] UnitStep[t]) t^n - 1/Gamma[n]), -((Exp[-a t] UnitStep[-t]) t^n - 1/Gamma[n]), DiracDelta[t - T], Cos[t] UnitStep[t], -Cos[t] UnitStep[-t], Sin[t] UnitStep[t], -Sin[t] UnitStep[-t], (Cos[t] UnitStep[t]) Exp[-a t], (-Cos[t] UnitStep[-t]) Exp[-a t], (Sin[t] UnitStep[t]) Exp[-a t], (-Sin[t] UnitStep[-t]) Exp[-a t]};
Wolfram Language code: Grid[Prepend[{#, Assuming[{b∈ℝ, a∈ℝ}, Simplify[BilateralLaplaceTransform[#1, t, s]]]}& /@ flist, {f[t], BilateralLaplaceTransform[f[t], t, s]}], IconizedObject[«Grid options»]]//TraditionalForm
Wolfram Research (2021)，BilateralLaplaceTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BilateralLaplaceTransform.html.

文本

Wolfram Research (2021)，BilateralLaplaceTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BilateralLaplaceTransform.html.

CMS

Wolfram 语言. 2021. "BilateralLaplaceTransform." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BilateralLaplaceTransform.html.

APA

Wolfram 语言. (2021). BilateralLaplaceTransform. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BilateralLaplaceTransform.html 年

BibTeX

@misc{reference.wolfram_2026_bilaterallaplacetransform, author="Wolfram Research", title="{BilateralLaplaceTransform}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/BilateralLaplaceTransform.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_bilaterallaplacetransform, organization={Wolfram Research}, title={BilateralLaplaceTransform}, year={2021}, url={https://reference.wolfram.com/language/ref/BilateralLaplaceTransform.html}, note=[Accessed: 16-September-2026]}