WOLFRAM

Wolfram 语言与系统参考资料中心

BoundingRegion[{pt1,pt2,…}]

给出点 pt1、pt2、… 的最小轴对齐边界框.

BoundingRegion[{pt1,pt2,…},form]

给出类型为 form 的边界区域.

BoundingRegion[reg,form]

给出区域 reg 的边界区域.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
一维  
二维  
三维  
维  
选项  
WorkingPrecision  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

BoundingRegion

BoundingRegion[{pt1,pt2,…}]

给出点 pt1、pt2、… 的最小轴对齐边界框.

BoundingRegion[{pt1,pt2,…},form]

给出类型为 form 的边界区域.

BoundingRegion[reg,form]

给出区域 reg 的边界区域.

更多信息和选项

  • BoundingRegion 也被称为封闭区域或有界区域.
  • 点集 的边界区域 是一个满足 的区域.
  • 最优边界区域通常尽量减少边界区域的某些属性，如最小面积为导向的矩形. 它们一般采取更长的时间来计算.
  • 快速边界区域通常迅速为大量的点提供边界区域，但可能不会提供最优的边界区域，如面积最小的定向矩形.
  • 一维中可能的 form 规范：
  • "MinInterval"长度最小的区间
  • 二维中可能的 form 规范：
  • "MinRectangle"面积最小的轴对齐矩形
    "MinOrientedRectangle"面积最小的定向矩形
    "MinConvexPolygon"面积最小的凸多边形
    "MinDisk"面积最小的圆盘
    "MinEllipse"面积最小的椭圆
    "FastOrientedRectangle"快速给出定向边界矩形
    "FastDisk"快速给出边界圆盘
    "FastEllipse"快速给出边界椭圆
    "FastStadium"快速给出运动场形边界区域
  • 三维中可能的 form 规范：
  • "MinCuboid"体积最小的轴对齐长方体
    "MinOrientedCuboid"体积最小的定向长方体
    "MinConvexPolyhedron"体积最小的凸多面体
    "MinBall"体积最小的球体
    "MinEllipsoid"体积最小的椭球
    "FastOrientedCuboid"快速给出定向长方体
    "FastBall"快速给出球体
    "FastEllipsoid"快速给出椭球体
    "FastCylinder"快速给出圆柱体
    "FastCapsule"快速给出胶囊体
  • n 维中可能的 form 规范：
  • "MinCuboid"度量最小的轴对齐长方体
    "MinBall"度量最小的球体
    "MinEllipsoid"度量最小的椭球体
    "FastOrientedCuboid"快速给出定向长方体
    "FastBall"快速给出球体
    "FastEllipsoid"快速给出椭球体
  • BoundingRegion[reg] 等价于 BoundingRegion[reg,"MinCuboid"].
  • 可以给出以下选项：
  • PerformanceGoal$PerformanceGoal优化的目标
    WorkingPrecision MachinePrecision计算所用的精度

范例

打开所有单元 关闭所有单元

基本范例  (4)

包含一组点的最小面积 Disk：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "MinDisk"]
Wolfram Language code: Region[%, Epilog -> {Black, Point[pts]}]

包含一组点的最小面积 Rectangle：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "MinRectangle"]
Wolfram Language code: Region[%, Epilog -> {Black, Point[pts]}]

最小面积、任意方向的矩形：

Wolfram Language code: BoundingRegion[pts, "MinOrientedRectangle"]
Wolfram Language code: Region[%, Epilog -> {Black, Point[pts]}]

包含一组点的最小体积 Ball：

Wolfram Language code: pts = {{7, 6, 2}, {7, 7, 2}, {9, 7, 6}, {2, 9, 3}, {5, 4, 5}};
Wolfram Language code: BoundingRegion[pts, "MinBall"]
Wolfram Language code: Graphics3D[{{Opacity[0.5], %}, Point[pts]}, ImageSize -> Tiny]

包含一组点的最小体积 Cuboid：

Wolfram Language code: pts = {{7, 6, 2}, {7, 7, 2}, {9, 7, 6}, {2, 9, 3}, {5, 4, 5}};
Wolfram Language code: BoundingRegion[pts, "MinCuboid"]
Wolfram Language code: Graphics3D[{{Opacity[0.5], %}, Point[pts]}, ImageSize -> Tiny]

最小体积、任意方向的长方体：

Wolfram Language code: BoundingRegion[pts, "MinOrientedCuboid"]
Wolfram Language code: Graphics3D[{{Opacity[0.5], %}, Point[pts]}, ImageSize -> Tiny]

范围  (28)

一维  (3)

"MinInterval" 用于一维点集：

Wolfram Language code: pts = {{1}, {2}, {4}};
Wolfram Language code: BoundingRegion[pts, "MinInterval"]
Wolfram Language code: NumberLinePlot[{pts, BoundingRegion[pts, "MinInterval"]}]

适用于大型点集：

Wolfram Language code: pts = RandomReal[{0, 1}, {10 ^ 6, 1}];
Wolfram Language code: BoundingRegion[pts, "MinInterval"]//AbsoluteTiming

适用于网格区域：

Wolfram Language code: mr = MeshRegion[{{1}, {2}, {3}, {4}}, Line[{{1, 2}, {3, 4}}], MeshCellStyle -> {Red, Thick}];
Wolfram Language code: BoundingRegion[mr, "MinInterval"]
Wolfram Language code: Show[NumberLinePlot[{%}], mr]

二维  (9)

"MinRectangle" 给出最小面积轴对齐 Rectangle：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "MinRectangle"]
Wolfram Language code: Graphics[{{StandardBlue, %}, Point[pts]}, ImageSize -> Tiny]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Disk[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "MinRectangle"]//AbsoluteTiming

"MinOrientedRectangle" 给出最小面积矩形，不一定是轴对齐的：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "MinOrientedRectangle"]
Wolfram Language code: Graphics[{{StandardBlue, %}, Point[pts]}, ImageSize -> Tiny]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Disk[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "MinOrientedRectangle"]//AbsoluteTiming

"MinConvexPolygon" 给出包含点的最小面积多边形：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "MinConvexPolygon"]
Wolfram Language code: Graphics[{{StandardBlue, %}, Point[pts]}, ImageSize -> Tiny]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Disk[], 10 ^ 4];
Wolfram Language code: BoundingRegion[pts, "MinConvexPolygon"]

"MinDisk" 给出包含点的最小面积 Disk：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "MinDisk"]
Wolfram Language code: Graphics[{{StandardBlue, %}, Point[pts]}, ImageSize -> Tiny]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Disk[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "MinDisk"]//AbsoluteTiming

"FastOrientedRectangle" 给出有向的边界矩形，不一定面积最小：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "FastOrientedRectangle"]
Wolfram Language code: Graphics[{{StandardBlue, %}, Point[pts]}, ImageSize -> Tiny]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Disk[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "FastOrientedRectangle"]//AbsoluteTiming

"FastDisk" 给出边界 Disk，面积不一定最小：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "FastDisk"]
Wolfram Language code: Graphics[{{StandardBlue, %}, Point[pts]}, ImageSize -> Tiny]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Disk[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "FastDisk"]//AbsoluteTiming

"FastEllipse" 给出边界 Ellipsoid，面积不一定最小：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "FastEllipse"]
Wolfram Language code: Graphics[{{StandardBlue, %}, Point[pts]}, ImageSize -> Tiny]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Disk[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "FastEllipse"]//AbsoluteTiming

"FastStadium" 给出边界 StadiumShape，不一定面积最小：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: BoundingRegion[pts, "FastStadium"]
Wolfram Language code: Graphics[{{StandardBlue, %}, Point[pts]}, ImageSize -> Tiny]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Disk[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "FastStadium"]//AbsoluteTiming

求网格区域的边界区域：

Wolfram Language code: mr = MeshRegion[Table[{2Sin[2kPi / 5], Cos[2kPi / 5]}, {k, 5}], Polygon[{1, 3, 5, 2, 4}]];
Wolfram Language code: shapes = {"MinRectangle", "MinDisk", "FastEllipse", "FastStadium"};
Wolfram Language code: regs = Table[BoundingRegion[mr, s], {s, shapes}];
Wolfram Language code: Table[Show[Graphics[{Opacity[0.5], Green, r}], mr], {r, regs}]

三维  (11)

"MinCuboid" 给出最小体积轴对齐 Cuboid：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: BoundingRegion[pts, "MinCuboid"]
Wolfram Language code: Graphics3D[{{Opacity[.5], %}, {Red, Point@pts}}]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Ball[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "MinCuboid"]//AbsoluteTiming

"MinOrientedCuboid" 给出最小体积的长方体，不一定轴对齐：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: BoundingRegion[pts, "MinOrientedCuboid"]
Wolfram Language code: Graphics3D[{{Opacity[.5], %}, {Red, Point@pts}}]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Ball[], 10 ^ 4];
Wolfram Language code: BoundingRegion[pts, "MinOrientedCuboid"]//AbsoluteTiming

"MinConvexPolyhedron" 给出包含点的最小体积多面体：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: BoundingRegion[pts, "MinConvexPolyhedron"];
Wolfram Language code: Graphics3D[{{Opacity[.5], %}, {Red, Point@pts}}]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Ball[], 10 ^ 4];
Wolfram Language code: BoundingRegion[pts, "MinConvexPolyhedron"]//AbsoluteTiming

"MinBall" 给出包含点的体积最小的 Ball：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: BoundingRegion[pts, "MinBall"]
Wolfram Language code: Graphics3D[{{Opacity[.5], %}, {Red, Point@pts}}]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Ball[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "MinBall"]//AbsoluteTiming

"FastOrientedCuboid" 给出定向边界长方体，不一定最小：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: BoundingRegion[pts, "FastOrientedCuboid"]
Wolfram Language code: Graphics3D[{{Opacity[.5], %}, {Red, Point@pts}}]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Ball[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "FastOrientedCuboid"]//AbsoluteTiming

"FastBall" 给出边界 Ball，不一定体积最小：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: BoundingRegion[pts, "FastBall"]
Wolfram Language code: Graphics3D[{{Opacity[.5], %}, {Red, Point@pts}}]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Ball[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "FastBall"]//AbsoluteTiming

"FastEllipsoid" 给出边界 Ellipsoid，不一定具有最小体积：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid"]
Wolfram Language code: Graphics3D[{{Opacity[.5], %}, {Red, Point@pts}}]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Ball[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid"]//AbsoluteTiming

"FastCylinder" 给出 Cylinder，不一定有最小体积：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: BoundingRegion[pts, "FastCylinder"]
Wolfram Language code: Graphics3D[{{Opacity[.5], %}, {Red, Point@pts}}]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Ball[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "FastCylinder"]//AbsoluteTiming

"FastCapsule" 给出边界 CapsuleShape，不一定有最小体积：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: BoundingRegion[pts, "FastCapsule"]
Wolfram Language code: Graphics3D[{{Opacity[.5], %}, {Red, Point@pts}}]

适用于大型点集：

Wolfram Language code: pts = RandomPoint[Ball[], 10 ^ 6];
Wolfram Language code: BoundingRegion[pts, "FastCapsule"]//AbsoluteTiming

比较边界区域的体积：

Wolfram Language code: pts = {{4, 8, 7}, {4, 4, 6}, {0, 10, 6}, {1, 7, 0}, {2, 5, 1}, {3, 7, 3}};
Wolfram Language code: bregs = BoundingRegion[pts, #]& /@ {"MinCuboid", "MinOrientedCuboid", "MinBall", "FastOrientedCuboid", "FastBall", "FastEllipsoid", "FastCylinder", "FastCapsule"};
Wolfram Language code: Volume /@ bregs

求网格区域的边界区域：

Wolfram Language code: mr = MeshRegion[Table[{2Sin[2kPi / 5], Cos[2kPi / 5], Sin[Pi / 4 + 2k Pi / 5]}, {k, 5}], Polygon[{1, 3, 5, 2, 4}]];
Wolfram Language code: shapes = {"MinCuboid", "MinBall", "FastCylinder", "FastCapsule"};
Wolfram Language code: regs = Table[BoundingRegion[mr, s], {s, shapes}];
Wolfram Language code: Table[Show[Graphics3D[{Opacity[0.3], r}], mr], {r, regs}]

维  (5)

"MinCuboid" 给出最小度量轴对齐 Cuboid：

Wolfram Language code: pts = {{7, 6, 2, 3}, {7, 7, 2, 1}, {9, 7, 6, 4}, {2, 9, 3, 7}, {5, 4, 5, 4}};
Wolfram Language code: BoundingRegion[pts, "MinCuboid"]

适用于大型点集：

Wolfram Language code: pts = RandomReal[10, {10 ^ 6, 5}];
Wolfram Language code: BoundingRegion[pts, "MinCuboid"]//AbsoluteTiming

适用于高维度：

Wolfram Language code: pts = RandomReal[10, {10 ^ 3, 10 ^ 4}];
Wolfram Language code: BoundingRegion[pts, "MinCuboid"]//Short//AbsoluteTiming

"MinBall" 给出包含点的最小度量 Ball：

Wolfram Language code: pts = {{7, 6, 2, 3}, {7, 7, 2, 1}, {9, 7, 6, 4}, {2, 9, 3, 7}, {5, 4, 5, 4}};
Wolfram Language code: BoundingRegion[pts, "MinBall"]

适用于大型点集：

Wolfram Language code: pts = RandomReal[10, {10 ^ 6, 5}];
Wolfram Language code: BoundingRegion[pts, "MinBall"]//AbsoluteTiming

适用于高维度：

Wolfram Language code: pts = RandomReal[10, {10 ^ 3, 10 ^ 3}];
Wolfram Language code: BoundingRegion[pts, "MinBall"]//Short//AbsoluteTiming

作用于精确系数：

Wolfram Language code: pts = RandomInteger[10, {10 ^ 3, 10}];
Wolfram Language code: BoundingRegion[pts, "MinBall", WorkingPrecision -> Infinity]//AbsoluteTiming

"FastOrientedCuboid" 给出有向的边界长方体，不一定是最小的：

Wolfram Language code: pts = {{7, 6, 2, 3}, {7, 7, 2, 1}, {9, 7, 6, 4}, {2, 9, 3, 7}, {5, 4, 5, 4}};
Wolfram Language code: BoundingRegion[pts, "FastOrientedCuboid"]

适用于大型点集：

Wolfram Language code: pts = RandomReal[10, {10 ^ 6, 5}];
Wolfram Language code: BoundingRegion[pts, "FastOrientedCuboid"]//AbsoluteTiming

适用于高维度：

Wolfram Language code: pts = RandomReal[10, {10 ^ 3, 100}];
Wolfram Language code: BoundingRegion[pts, "FastOrientedCuboid"]//Short//AbsoluteTiming

"FastBall" 给出边界 Ball，不一定具有最小度量：

Wolfram Language code: pts = {{7, 6, 2, 3}, {7, 7, 2, 1}, {9, 7, 6, 4}, {2, 9, 3, 7}, {5, 4, 5, 4}};
Wolfram Language code: BoundingRegion[pts, "FastBall"]

适用于大型点集：

Wolfram Language code: pts = RandomReal[10, {10 ^ 6, 5}];
Wolfram Language code: BoundingRegion[pts, "FastBall"]//AbsoluteTiming

适用于高维度：

Wolfram Language code: pts = RandomReal[10, {10 ^ 3, 10 ^ 4}];
Wolfram Language code: BoundingRegion[pts, "FastBall"]//Short//AbsoluteTiming

"FastEllipsoid" 给出边界 Ellipsoid，不一定具有最小度量：

Wolfram Language code: pts = {{7, 6, 2, 3}, {7, 7, 2, 1}, {9, 7, 6, 4}, {2, 9, 3, 7}, {5, 4, 5, 4}};
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid"]

适用于大型点集：

Wolfram Language code: pts = RandomReal[10, {10 ^ 6, 5}];
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid"]//AbsoluteTiming

适用于高维度：

Wolfram Language code: pts = RandomReal[10, {10 ^ 3, 100}];
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid"]//Short//AbsoluteTiming

选项  (5)

WorkingPrecision  (5)

默认情况下，WorkingPrecision 是 MachinePrecision：

Wolfram Language code: pts = RandomReal[10, {5, 3}];
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid"]

指定较低的工作精度：

Wolfram Language code: pts = Rationalize[RandomReal[10, {5, 3}], 0];
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid", WorkingPrecision -> 10]

指定较高的工作精度：

Wolfram Language code: pts = Rationalize[RandomReal[10, {5, 3}], 0];
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid", WorkingPrecision -> 20]

WorkingPrecision 为 Infinity 的话，将精确计算边界区域：

Wolfram Language code: pts = Rationalize[RandomReal[10, {5, 3}], 0];
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid", WorkingPrecision -> Infinity]

输出的精度受输入精度的限制：

Wolfram Language code: pts = RandomReal[10, {5, 3}];
Wolfram Language code: BoundingRegion[pts, "FastEllipsoid", WorkingPrecision -> 20]

使用 SetPrecision 增加输入的精度，允许较高的输出精度：

Wolfram Language code: pts2 = SetPrecision[pts, 20];
Wolfram Language code: BoundingRegion[pts2, "FastEllipsoid", WorkingPrecision -> 20]

使用 Rationalize 得到确切的数值. 这将允许精确计算：

Wolfram Language code: pts3 = Rationalize[pts, 0];
Wolfram Language code: BoundingRegion[pts3, "FastEllipsoid", WorkingPrecision -> Infinity]

应用  (4)

求三维图形对象的不同边界区域：

Wolfram Language code: graphics = [image];
Wolfram Language code: mesh = DiscretizeGraphics[graphics];

计算边界区域：

Wolfram Language code: breg = Table[BoundingRegion[mesh, shape], {shape, {"MinCuboid", "MinOrientedCuboid", "MinBall", "FastOrientedCuboid", "FastBall", "FastEllipsoid", "FastCylinder", "FastCapsule"}}];

展示带有边界区域的对象，使用体积作为标签：

Wolfram Language code: Table[Show[graphics, Graphics3D[{Opacity[.5], shape}], PlotLabel -> Volume[shape], ImageSize -> 100], {shape, breg}]

求任意区域的边界区域：

Wolfram Language code: reg = ImplicitRegion[(x^2 == 2 y && -3 ≤ x ≤ 3 || x^2 + y^2 ≤ 16 && 64 x^2 + 49 y (2 + y) > 147 || 4 (x^2 + y + y^2) ≤ 15) && 43 + 16 x (3 + x) + 16 (-2 + y) y > 0 && 43 + 16 (-3 + x) x + 16 (-2 + y) y > 0 || 1243 + 1120 x + 400 x^2 + 400 y^2 ≤ 880 y || 1483 + 400 x^2 + 400 y^2 ≤ 1280 x + 880 y || 28323 + 5520 x + 900 x^2 + 900 y^2 == 8464 y || 28323 + 900 x^2 + 900 y^2 == 5520 x + 8464 y, {x, y}];

使用 DiscretizeRegion 来离散化该区域：

Wolfram Language code: mr = DiscretizeRegion[reg]

计算边界区域：

Wolfram Language code: shapes = {"MinRectangle", "MinDisk", "FastEllipse", "FastStadium"};
Wolfram Language code: regs = Table[BoundingRegion[mr, s], {s, shapes}];
Wolfram Language code: Table[Show[Graphics[{Opacity[0.5], Green, r}], mr], {r, regs}]

通过拒绝抽样，计算任意区域中的随机点：

Wolfram Language code: reg = ImplicitRegion[x^6 - 5 x^4 y + 3 x^4 y^2 + 10 x^2 y^3 + 3 x^2 y^4 - y^5 + y^6 + z^2 ≤ 1, {x, y, z}];

找到一个容易生成随机点的边界区域：

Wolfram Language code: br = BoundingRegion[DiscretizeRegion@reg, "MinCuboid"]

在边界区域生成随机点：

Wolfram Language code: brpts = RandomPoint[br, 10000];

选择属于初始区域的点：

Wolfram Language code: regpts = Select[brpts, RegionMember[reg, #]&]; Length[regpts]

可视化结果：

Wolfram Language code: Graphics3D[{Blue, AbsolutePointSize[1], Point@regpts}]

对使用 RandomPoint 从初始区域生成的点进行比较：

Wolfram Language code: Graphics3D[{Blue, AbsolutePointSize[1], Point@RandomPoint[reg, 5000]}]

边界区域常用于游戏物理，因为在边界区域之间进行碰撞检测比在对象自身之间更简单快速：

Wolfram Language code: obj1 = ImplicitRegion[(x^2 == 2 y && -3 ≤ x ≤ 3 || x^2 + y^2 ≤ 16 && 64 x^2 + 49 y (2 + y) > 147 || 4 (x^2 + y + y^2) ≤ 15) && 43 + 16 x (3 + x) + 16 (-2 + y) y > 0 && 43 + 16 (-3 + x) x + 16 (-2 + y) y > 0 || 1243 + 1120 x + 400 x^2 + 400 y^2 ≤ 880 y || 1483 + 400 x^2 + 400 y^2 ≤ 1280 x + 880 y || 28323 + 5520 x + 900 x^2 + 900 y^2 == 8464 y || 28323 + 900 x^2 + 900 y^2 == 5520 x + 8464 y, {x, y}]; obj2 = RegionIntersection[Disk[{6, 9 / 2}, 3], Disk[{7, 6}, 3]];

计算对象的离散化近似：

Wolfram Language code: mr1 = DiscretizeRegion@obj1; mr2 = DiscretizeRegion@obj2;

通过检查边界区域不相交来显示对象不会碰撞：

Wolfram Language code: br1 = BoundingRegion[mr1, "MinOrientedRectangle"]; br2 = BoundingRegion[mr2, "MinOrientedRectangle"]; Show[Graphics[{Opacity[0.5], Green, br1, br2}], mr1, mr2]

使用 FindInstance 检查边界区域不相交：

Wolfram Language code: FindInstance[Element[{x, y}, br1] && Element[{x, y}, br2], {x, y}, Reals]//RepeatedTiming

直接进行碰撞检测会花费较多时间：

Wolfram Language code: FindInstance[Element[{x, y}, obj1] && Element[{x, y}, obj2], {x, y}, Reals]//RepeatedTiming

然而，即使对象不发生碰撞，边界地区也可能不是分离的：

Wolfram Language code: bd1 = BoundingRegion[mr1, "MinDisk"]; bd2 = BoundingRegion[mr2, "MinDisk"]; FindInstance[Element[{x, y}, bd1] && Element[{x, y}, bd2], {x, y}, Reals]

可视化结果：

Wolfram Language code: Show[Graphics[{{Opacity[0.5], Green, bd1, bd2}, {Red, Point[{x, y} /. %]}}], mr1, mr2]

属性和关系  (9)

所有点都是边界区域的成员：

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: breg = BoundingRegion[pts, "MinDisk"]
Wolfram Language code: RegionMember[breg, pts]

通常边界区域的边界上会有多个点:

Wolfram Language code: pts = {{3, 10}, {6, 3}, {10, 2}, {2, 8}, {3, 3}};
Wolfram Language code: bbreg = RegionBoundary@BoundingRegion[pts, "MinDisk"]
Wolfram Language code: RegionMember[bbreg, pts]
Wolfram Language code: Graphics[{{bbreg}, {Red, PointSize[Medium], Point[pts]}}, ImageSize -> Tiny]

"MinOrientedCuboid" 给出与 "MinCuboid" 相等或更小的体积：

Wolfram Language code: pts2d = RandomInteger[100, {25, 3}];
Wolfram Language code: Volume@BoundingRegion[pts2d, "MinOrientedCuboid"] ≤ Volume@BoundingRegion[pts2d, "MinCuboid"]

"MinOrientedRectangle" 给出与 "MinRectangle" 相等或更小的面积：

Wolfram Language code: pts3d = RandomInteger[100, {25, 2}];
Wolfram Language code: Area@BoundingRegion[pts3d, "MinOrientedRectangle"] ≤ Area@BoundingRegion[pts3d, "MinRectangle"]

"MinConvexPolygon" 将与其它边界区域的面积相等或更小：

Wolfram Language code: pts = RandomInteger[100, {25, 2}];
Wolfram Language code: acvx = Area@BoundingRegion[pts, "MinConvexPolygon"]
Wolfram Language code: Table[acvx ≤ Area[BoundingRegion[pts, shape]], {shape, {"MinRectangle", "MinOrientedRectangle", "MinDisk", "FastOrientedRectangle", "FastDisk", "FastEllipse", "FastStadium"}}]

"MinConvexPolyhedron" 将与其它边界区域的体积相等或更小：

Wolfram Language code: pts = RandomInteger[100, {25, 3}];
Wolfram Language code: vcvx = Volume@BoundingRegion[pts, "MinConvexPolyhedron"]
Wolfram Language code: Table[vcvx ≤ Volume[BoundingRegion[pts, shape]], {shape, {"MinCuboid", "MinOrientedCuboid", "MinBall", "FastOrientedCuboid", "FastBall", "FastEllipsoid", "FastCylinder", "FastCapsule"}}]

"MinConvexPolygon" 对应于二维中的 ConvexHullMesh：

Wolfram Language code: pts = RandomInteger[100, {25, 2}];
Wolfram Language code: {Graphics[{StandardBlue, BoundingRegion[pts, "MinConvexPolygon"]}], ConvexHullMesh[pts]}

"MinConvexPolyhedron" 对应于三维中的 ConvexHullMesh：

Wolfram Language code: pts = RandomInteger[100, {25, 3}];
Wolfram Language code: {Graphics3D[BoundingRegion[pts, "MinConvexPolyhedron"], Boxed -> False], ConvexHullMesh[pts]}

三仿射独立点的 "MinConvexPolygon" 对应于 Triangle：

Wolfram Language code: pts = {{1, 1}, {1, 2}, {3, 3}};
Wolfram Language code: {Graphics[{StandardBlue, BoundingRegion[pts, "MinConvexPolygon"]}], Graphics[{StandardBlue, Triangle[pts]}]}

四仿射独立点的 "MinConvexPolyhedron" 对应于 Tetrahedron：

Wolfram Language code: pts = {{1, 1, 1}, {1, 1, 2}, {3, 1, 3}, {3, 2, 5}};
Wolfram Language code: {Graphics3D[BoundingRegion[pts, "MinConvexPolyhedron"], Boxed -> False], Graphics3D[{Tetrahedron[pts]}, Boxed -> False]}

Circumsphere 给出在二维中三个点的圆. 对应的圆盘是一个边界区域：

Wolfram Language code: pts = {{0, 0}, {1, 0}, {-1, 1}};
Wolfram Language code: d1 = Disk@@Circumsphere[pts]
Wolfram Language code: d2 = Disk@@BoundingRegion[pts, "MinDisk", WorkingPrecision -> ∞]

外接球的 Area 总是大于或等于最小圆盘的面积：

Wolfram Language code: {Area[d1], Area[d2]}//N
Wolfram Language code: Legended[Graphics[{{Opacity[0.5], {Blue, d1}, {Red, d2}}, Point[pts]}], SwatchLegend[{Blue, Red}, {Circumsphere, BoundingRegion}]]

可能存在的问题  (1)

BoundingRegion 可能会给出请求区域的简并形式：

Wolfram Language code: BoundingRegion[{{0, 0}}, "MinCuboid"]
Wolfram Language code: BoundingRegion[{{0, 0, 0, 0}, {1, 0, 0, 0}, {1, 1, 0, 0}}, "MinCuboid"]
Wolfram Research (2016)，BoundingRegion，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BoundingRegion.html （更新于 2020 年）.

文本

Wolfram Research (2016)，BoundingRegion，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BoundingRegion.html （更新于 2020 年）.

CMS

Wolfram 语言. 2016. "BoundingRegion." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/BoundingRegion.html.

APA

Wolfram 语言. (2016). BoundingRegion. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BoundingRegion.html 年

BibTeX

@misc{reference.wolfram_2026_boundingregion, author="Wolfram Research", title="{BoundingRegion}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/BoundingRegion.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_boundingregion, organization={Wolfram Research}, title={BoundingRegion}, year={2020}, url={https://reference.wolfram.com/language/ref/BoundingRegion.html}, note=[Accessed: 16-August-2026]}