WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Column[{expr1,expr2,…}]

expr1が expr2の上にという具合になるようにして expriを列にフォーマットするオブジェクトである．

Column[list,alignment]

指定の方法で，各要素を水平方向に並べる．

Column[list,alignment,spacing]

連続する要素間に指定した個数分の x の高さのスペースを残す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Alignment  
Background  
BaselinePosition  
Show More Show More
Dividers  
Frame  
FrameStyle  
ItemSize  
ItemStyle  
Spacings  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

Column

Column[{expr1,expr2,…}]

expr1が expr2の上にという具合になるようにして expriを列にフォーマットするオブジェクトである．

Column[list,alignment]

指定の方法で，各要素を水平方向に並べる．

Column[list,alignment,spacing]

連続する要素間に指定した個数分の x の高さのスペースを残す．

詳細とオプション

  • 可能な並べ方
  • Center中央揃え
    Left左揃え（デフォルト）
    Right右揃え
    "c" 文字"c"揃え
    {h,v}水平の揃え方と垂直の揃え方を別に行う
  • StandardForm，TraditionalForm，OutputFormでは，Column[…]は列にフォーマットする．
  • InputFormでは，Column[…]は文字通りColumn[…]にフォーマットする．
  • First[col]は，列を作るリストを抽出する．
  • expriは，グラフィックスやコントロール等，どのような種類の式でもよい．
  • テキストを文字列として与えることでColumnの要素として入力できる．Text["string"]あるいはStyle["string","style"]を使って特定のスタイルを指定することができる．
  • 次のオプションが設定できる．
  • Alignment {Left,Baseline}項目の水平方向および垂直方向の並べ方
    Background None使用する背景色
    BaselinePosition Automatic周囲のテキストのベースラインとの揃え方
    BaseStyle{}列のベーススタイル指定
    DefaultElement"∖[Placeholder]"空の項目にどのような要素を挿入するか
    Dividers {}列中のどこに分割線を描くか
    Frame None枠線をどこに描くか
    FrameStyle Automatic枠線のスタイル
    ItemSize Automatic各項目の幅と高さ
    ItemStyle None個々の項目のスタイル
    Spacings Automatic水平および垂直方向のスペース
  • Frameの一般的な設定値には次のようなものがある．
  • Noneフレームは描かない
    True列全体の周囲に枠を描く
    All列内の個々の要素の周囲に枠を描く
  • Column[list,alignment]はColumn[list,Alignment->alignment]に等しい．
  • Column[list,alignment,spacing]はSpacings->spacing の設定に相当する．
  • BackgroundとItemStyleは列内の各項目の設定値を与えるリストでもよい．
  • オプションAlignment，Background，Frame，ItemSize，ItemStyleの設定値は，次のように，列中の連続する項目に別々に適用することができる．
  • {s1,s2,…,sn}s1から snまでを使い，次にデフォルトを使う
    {{c}}すべての場合に c を使う
    {{c1,c2}}c1と c2を交互に使う
    {{c1,c2,…}}すべての ciを循環的に使う
    {s,{c}}s を使い，次に c を繰り返し使う
    {s1,{c},sn}s1を使い，次に c を繰り返し使うが，最後には snを使う
    { s 1 , s 2 , … , { c 1 , c 2 , … }, s m , … , s n }
    		最初の一続きの siを使い，次に ciを循環的に使い，次に siの最後の一続きを使う
    {s1,s2,…,{},sm,…,sn}はじめに siの最初の一続きを使い，最後に終りの一続きを使う
    {i1->v1,i2->v2,…}位置 ikで何を使うかを指定する
    {spec,rules}spec における指定を無効にするために rules を使う
  • {s1,s2,…,{…},sm,…,sn}の形の設定のとき，列中の項目数よりも指定された siの方が多い場合は，最初の方の siが最初の項目に使われ，最後の方の siは最後の方の項目に使われる．
  • オプションAlignment，Background，Frame等の設定は，実質的にItemを使って個々の項目に指定することができる．
  • デフォルト設定のItemSize->Automaticのとき，Columnは必要であれば複数の線を横断して要素を分割する．
  • Columnは，明示的なImageSizeの設定があるグラフィックスその他のオブジェクトの大きさは変更しない．
  • n 個の要素を持つ列の場合，DividersとSpacingsを使って，最初の要素の前から最後の要素の後ろまでの n+1個の要素間の隙間の設定を指定することができる．
  • DividersとSpacingsの設定値には次の形を使うことができる．
  • specspec を項目間のすべての隙間に適用する
    {specx,specy}speciを連続する水平方向および垂直方向の隙間に適用する
  • speci は，Alignment，Backgroundその他の項目指向のオプションと同じ形でよい．
  • BaselinePositionには次の設定を使うことができる．
  • Axis列の中央行の軸（デフォルト）
    Baseline列の中央行のベースライン
    Bottom列全体の一番下
    Center一番上と一番下の中間
    Top列全体の一番上
    {i,pos}要素 i の位置 pos
  • BaseStyleの設定値は，一般に現行スタイルシートの"Column"スタイルで与えられるデフォルトスタイルに追加される．

例題

すべて開く すべて閉じる

例  (2)

列として表示する：

Wolfram Language code: Column[{1, 12, 123, 1234}]

各要素を中央揃えにする：

Wolfram Language code: Column[{1, 12, 123, 1234}, Center]

スコープ  (4)

列の周囲に枠を加える：

Wolfram Language code: Column[{1, 22, 333, 4444}, Frame -> True]

背景色を設定する：

Wolfram Language code: Column[{1, 22, 333, 4444}, Background -> Pink]

2色の背景色を交互に使う：

Wolfram Language code: Column[Table[n!, {n, 20, 25}], Background -> {{LightRed, Pink}}, Frame -> True]

改行のための項目の大きさを設定する：

Wolfram Language code: e = Expand[(x + y) ^ 10]; f = TrigExpand[Sin[9 x]];
Wolfram Language code: Column[{e, f}, ItemSize -> {20, Automatic}, Frame -> All]

オプション  (19)

Alignment  (1)

列内で揃える：

Wolfram Language code: Table[Column[{1, 22, 333}, Alignment -> a], {a, {Left, Center, Right}}]

Background  (1)

全体的な背景色を変える：

Wolfram Language code: Table[Column[{1, 22, 333}, Background -> c], {c, {LightRed, LightGreen, Pink}}]

各行の背景色を変える：

Wolfram Language code: Column[{1, 22, 333}, Background -> {LightRed, LightGreen, Pink}]

背景色として2色を交互に使う：

Wolfram Language code: Column[{1, 22, 333, 4444}, Background -> {{LightRed, Pink}}, Frame -> True]

BaselinePosition  (1)

列を周囲のテキストと揃える：

Wolfram Language code: Row[Table[Column[{1, 22, 333}, BaselinePosition -> p, Frame -> True], {p, {Top, Center, Bottom}}], "xxx"]

Dividers  (5)

すべての区切り線を描く：

Wolfram Language code: Column[{1, 22, 333}, Dividers -> All]

外側の区切り線だけを描く：

Wolfram Language code: Column[{1, 22, 333}, Dividers -> True]

内側の区切り線だけを描く：

Wolfram Language code: Column[{1, 22, 333}, Dividers -> Center]

特に指定した区切り線を描く：

Wolfram Language code: Column[{1, 22}, Dividers -> {None, {1 -> Red, 2 -> Green, 3 -> Blue}}]

負の位置指標を使う：

Wolfram Language code: Column[{1, 22}, Dividers -> {None, {-3 -> Red, -2 -> Green, -1 -> Blue}}]

列の外側の区切り線を描く：

Wolfram Language code: Column[{1, 22}, Dividers -> {{1 -> Red, 2 -> Blue}, None}]

負の位置指標を使う：

Wolfram Language code: Column[{1, 22}, Dividers -> {{-2 -> Red, -1 -> Blue}, None}]

Frame  (3)

すべての要素に枠を付ける：

Wolfram Language code: Column[{1, 22, 333}, Frame -> All]

外側だけに枠を付ける：

Wolfram Language code: Column[{1, 22, 333}, Frame -> True]

特定の要素に枠を付ける：

Wolfram Language code: Column[{1, 22, 333}, Frame -> {None, True, True}]

FrameStyle  (1)

枠のスタイルを設定する：

Wolfram Language code: Table[Column[{1, 22, 333}, Frame -> True, FrameStyle -> s], {s, {Orange, Thick, Dashed, Directive[Orange, Thick, Dashed]}}]

ItemSize  (2)

各項目の大きさを制御し，場合によっては強制的に改行する：

Wolfram Language code: Table[Column[{1, 22, 333}, ItemSize -> {w, h}, Frame -> True], {h, {1, 2, 3}}, {w, {4, 8, 12}}]//Grid

ItemSizeを設定すると，コンテンツが改行するようになる：

Wolfram Language code: t = StringJoin@Riffle[Table["text", {10}], " "];
Wolfram Language code: e = Expand[(x + y) ^ 10];
Wolfram Language code: Column[{e, t}, ItemSize -> {20, Automatic}, Frame -> All]

ItemStyle  (4)

全体的なスタイルを変える：

Wolfram Language code: Table[Column[{1, 22, 333}, ItemStyle -> s], {s, {Blue, Gray, Purple}}]

特定の要素のスタイルを変える：

Wolfram Language code: Column[{1, 22, 333}, ItemStyle -> {1 -> Purple, 2 -> Red, 3 -> Bold}]

スタイルを与えられている要素を動的に変える：

Wolfram Language code: Slider[Dynamic[x], {1, 3, 1}]
Wolfram Language code: Column[{1, 22, 333}, ItemStyle -> {Dynamic[x] -> Large}]

特定要素のスタイルを動的に変える：

Wolfram Language code: Slider[Dynamic[x]]
Wolfram Language code: Column[{1, 22, 333}, ItemStyle -> {3 -> Hue[Dynamic[x]]}]

Spacings  (1)

要素間の間隔を変える：

Wolfram Language code: Table[Column[{1, 22, 333}, Spacings -> s, Frame -> True], {s, {0, 1, 2, 3, 4, 5}}]

特性と関係  (1)

ColumnはGridの特殊ケースである：

Wolfram Language code: Column[{1, 12, 123}]
Wolfram Language code: Grid[Transpose[{{1, 12, 123}}], Alignment -> Left]
Wolfram Research (2007), Column, Wolfram言語関数， https://reference.wolfram.com/language/ref/Column.html.

テキスト

Wolfram Research (2007), Column, Wolfram言語関数， https://reference.wolfram.com/language/ref/Column.html.

CMS

Wolfram Language. 2007. "Column." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Column.html.

APA

Wolfram Language. (2007). Column. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Column.html

BibTeX

@misc{reference.wolfram_2026_column, author="Wolfram Research", title="{Column}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Column.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_column, organization={Wolfram Research}, title={Column}, year={2007}, url={https://reference.wolfram.com/language/ref/Column.html}, note=[Accessed: 04-September-2026]}