Wolfram 语言与系统参考资料中心

ConvexHullRegion

ConvexHullRegion[{p₁,p₂,…}]

给出点 p₁、p₂、… 的凸包.

ConvexHullRegion[reg]

给出区域 reg 的凸包.

范例

打开所有单元关闭所有单元

基本范例 (3)

点的二维凸包网格：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 2}];

Wolfram Language code: ℛ = ConvexHullRegion[pts]

该区域是包括该点的最小凸区域：

Wolfram Language code: Region[ℛ, Epilog -> {Black, Point[pts]}]

带状区域的凸包：

Wolfram Language code: ℛ = Annulus[{0, 0}, {1 / 2, 1}, {0, 3Pi / 2}];

Wolfram Language code: ConvexHullRegion[ℛ]

将带状区域和其凸包可视化：

Wolfram Language code: {Region[ℛ], Region[%]}

网格区域的凸包：

Wolfram Language code: mr = ExampleData[{"Geometry3D", "Cow"}, "MeshRegion"]

Wolfram Language code: ℛ = ConvexHullRegion[mr];

凸包包含了该区域内每条两点间的线段：

Wolfram Language code: Show[HighlightMesh[ℛ, Style[2, Opacity[0.5]]], mr]

范围 (20)

点 (1)

从一点集中创建一个一维凸包区域：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 1}];

Wolfram Language code: ℛ = ConvexHullRegion[pts]

二维凸包区域：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 2}];

Wolfram Language code: ℛ = ConvexHullRegion[pts]

三维凸包区域：

Wolfram Language code: pts = RandomReal[{-1, 1}, {50, 3}];

Wolfram Language code: ℛ = ConvexHullRegion[pts]

特殊区域 (4)

中包括 Point 的区域：

Wolfram Language code: ConvexHullRegion[Point[{1}]]

Interval：

Wolfram Language code:

ℛ = Interval[{1, 2}];
Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

Line：

Wolfram Language code: ConvexHullRegion[Line[{{1}, {2}}]]

中包括 Point 的区域：

Wolfram Language code:

ℛ = Point[Table[{t, Sin[t]}, {t, 0, 2π, 2π / 10}]];
Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

Line：

Wolfram Language code:

ℛ = Line[{{1, 0}, {2, 1}, {3, 0}, {4, 1}}];
Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

Polygon：

Wolfram Language code: ℛ = Polygon[{{0, 0}, {1, 0}, {0.2, 1}, {0.9, 1}}]

Wolfram Language code: ConvexHullRegion[ℛ]

Circle：

Wolfram Language code:

ℛ = Circle[{1, 2}, 3];
Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

Disk：

Wolfram Language code:

ℛ = Disk[{0, 0}, {3, 4}, {1, 1 + 5}];
Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

中包括 Point 的区域：

Wolfram Language code:

ℛ = Point[Tuples[Range[2], 3]];
Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

Line：

Wolfram Language code:

ℛ = Line[{{1, 2, 3}, {6, 5, 4}, {3, 4, 7}}];
Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

Polygon：

Wolfram Language code: ℛ = Polygon[Table[{Cos[2π k / 6], Sin[2π k / 6], 0}, {k, 0, 5}], {Range[6]}]

Wolfram Language code: ConvexHullRegion[ℛ]

Prism：

Wolfram Language code:

r = Prism[{{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}, {{3, 2, 3}, {2, 2, 2}, {4, 2, 2}, {3, 4, 3}, {2, 4, 2}, {4, 4, 2}}}];

Wolfram Language code:

ℛ = Prism[{{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}, {{3, 2, 3}, {2, 2, 2}, {4, 2, 2}, {3, 4, 3}, {2, 4, 2}, {4, 4, 2}}}];
Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

中包含中 Simplex 的区域:

Wolfram Language code: ConvexHullRegion[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}]]

中的 Cuboid：

Wolfram Language code: ConvexHullRegion[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}]]

中的Ball：

Wolfram Language code: ConvexHullRegion[Ball[{1, 2, 3, 4, 5, 6, 7}, 8]]

网格区域 (2)

一维空间中的 MeshRegion i

Wolfram Language code: MeshRegion[{{0}, {1}, {5}}, Line[{1, 2, 3}]]

Wolfram Language code: ConvexHullRegion[%]

二维空间：

Wolfram Language code: MeshRegion[{{0, 0}, {2, 0}, {3, 1}, {2, 3}, {1, 2}}, Polygon[{1, 3, 2, 4, 5}]]

Wolfram Language code: ConvexHullRegion[%]

三维空间：

Wolfram Language code: MengerMesh[1, 3]

Wolfram Language code: ConvexHullRegion[%]

一维空间中的 BoundaryMeshRegion：

Wolfram Language code: BoundaryMeshRegion[{{0}, {1}}, Point[{1, 2}]]

Wolfram Language code: ConvexHullRegion[%]

二维空间：

Wolfram Language code: BoundaryMeshRegion[{{0, 0}, {1, 3}, {0, 1}, {-1, 0}}, Line[{1, 2, 3, 4, 1}]]

Wolfram Language code: ConvexHullRegion[%]

三维空间：

Wolfram Language code: ℛ = [image];

Wolfram Language code: ConvexHullRegion[%]

方程式区域 (3)

以 ImplicitRegion 呈现的抛物线区域：

Wolfram Language code: ℛ = ImplicitRegion[x + 3y ≤ 3 && 2x + y ≥ 1, {x, y}];

Wolfram Language code: Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

表示为 ParametricRegion 的抛物线：

Wolfram Language code: ℛ = ParametricRegion[{t, t^2}, {t}];

Wolfram Language code: Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

ImplicitRegion 在不同维度上可以有数个分量：

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1∨(x + 1)^2 + y^2 == 1, {x, y}];

Wolfram Language code: Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

衍生区域 (6)

两个区域的 RegionIntersection：

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];

Wolfram Language code: Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

混合维度区域的 RegionUnion：

Wolfram Language code: ℛ = RegionUnion[Circle[{0, 0}, 1], Disk[{2, 0}, 1]];

Wolfram Language code: Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

一般 BooleanRegion 组合：

Wolfram Language code:

ℛ = BooleanRegion[Xor, {Disk[{-1 / 3, 0}, 1], Disk[{1 / 3, 0}, 1]}];
Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

TransformedRegion：

Wolfram Language code:

ℛ = TransformedRegion[Disk[], {Indexed[#1, 1] + Indexed[#1, 2], Indexed[#1, 1] - Indexed[#1, 2], Indexed[#1, 1] Indexed[#1, 2]}& ];

Wolfram Language code: Region[ℛ]

Wolfram Language code: ConvexHullRegion[ℛ]

InverseTransformedRegion：

Wolfram Language code:

ℛ = InverseTransformedRegion[Disk[], {Indexed[#1, 1] + Indexed[#1, 2] + Indexed[#1, 3], Indexed[#1, 1] Indexed[#1, 2]Indexed[#1, 3]}& , 3];

Wolfram Language code: Region[%]

Wolfram Language code: ConvexHullRegion[ℛ]

RegionBoundary：

Wolfram Language code: ℛ = RegionBoundary[Ball[]];

Wolfram Language code: ConvexHullRegion[ℛ]

地理区域 (2)

带有 GeoPosition 的多边形的凸包区域：

Wolfram Language code:

ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149}, 
   {40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558}, 
   {40.083686, -88.271512}, {40.083659999999995, -88.267046},  ... 33323}, {40.098112, -88.228687}, 
   {40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546}, 
   {40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477}, 
   {40.090741, -88.235745}}}]];

Wolfram Language code: ConvexHullRegion[ℛ]

含有 GeoGridPosition 的多边形的凸包区域：

Wolfram Language code:

ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015}, 
   {-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167}, 
   {-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449}, 
   {-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654}, 
   {-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825}, 
   {-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];

Wolfram Language code: ConvexHullRegion[ℛ]

CSG 区域 (1)

二维 CSGRegion：

Wolfram Language code: CSGRegion["Difference", {Disk[], Disk[{0, 0}, 1 / 2]}]

Wolfram Language code: ConvexHullRegion[%]

三维：

Wolfram Language code: CSGRegion["Difference", {Cube[2], Cylinder[{{0, 1, 0}, {0, -1, 0}}, 1 / 2]}]

Wolfram Language code: ConvexHullRegion[%]

Subdivision 区域 (1)

二维 SubdivisionRegion：

Wolfram Language code: SubdivisionRegion[[image]]

Wolfram Language code: ConvexHullRegion[%]

三维：

Wolfram Language code: SubdivisionRegion[[image]]

Wolfram Language code: ConvexHullRegion[%]

选项 (97)

AlignmentPoint (1)

使用坐标，指定在三维 Inset 中要对其的位置：

Wolfram Language code:

Table[Graphics[{Inset[ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], AlignmentPoint -> {a, 0}], {0, 0}]}, ImageSize -> 100, Axes -> True, Ticks -> None], {a, {0, 1 / 2, 1}}]

Wolfram Language code:

Table[Graphics[{Inset[ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], AlignmentPoint -> {1 / 2, a}], {0, 0}]}, ImageSize -> 100, Axes -> True, Ticks -> None], {a, {0, 1 / 2, 1}}]

AspectRatio (1)

使用数字值的 AspectRatio：

Wolfram Language code: Table[ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], AspectRatio -> 1 / k], {k, 1, 3}]

Axes (2)

绘制所有轴：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], Axes -> True]

绘制轴但不绘制轴：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], Axes -> {False, True}]

AxesEdge (2)

自动选择绘制轴的边界框：

Wolfram Language code: ConvexHullRegion[Pyramid[], Boxed -> True, Axes -> True, AxesEdge -> Automatic]

自动选择绘制轴的边界框：

Wolfram Language code: ConvexHullRegion[Pyramid[], Boxed -> True, Axes -> True, AxesEdge -> {{1, 1}, None, None}]

AxesLabel (2)

为轴放置一个标签：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], Axes -> True, AxesLabel -> y]

为每条轴指定一个标签：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], Axes -> True, AxesLabel -> {x, y}]

AxesOrigin (2)

自动决定坐标轴相交的位置：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], Axes -> True, AxesOrigin -> Automatic]

明确指定轴的原点：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], Axes -> True, AxesOrigin -> {0, -1}]

AxesStyle (2)

指定整体坐标轴样式，包括刻度和刻度标签：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Axes -> True, AxesStyle -> Directive[Orange, 12]]

为每条坐标轴指定样式：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Axes -> True, AxesStyle -> {Directive[Dashed, Red], Blue}]

Background (1)

指定一个背景色：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Background -> LightBlue]

BaselinePosition (3)

将图形的中心与文本的基线对齐：

Wolfram Language code: {x, ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImageSize -> 50, BaselinePosition -> Center], y}

通过使用 Scaled 可将高度的某个分数比例指定为图形的基线：

Wolfram Language code:

Table[{x, ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImageSize -> 50, BaselinePosition -> Scaled[b]]}, {b, {0, 0.5, 1}}]

使用坐标轴当作图形的基线：

Wolfram Language code: {x, ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImageSize -> 50, BaselinePosition -> Axis], y}

BaseStyle (2)

设置初始样式：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], BaseStyle -> Blue]

设置多个初始样式：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], BaseStyle -> {Green, EdgeForm[{Dashed, Thick}]}]

Boxed (2)

绘制边界框的边：

Wolfram Language code: ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Boxed -> True]

不绘制边界框的边：

Wolfram Language code: ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Boxed -> False]

BoxRatios (2)

指定边界框的边之间的比例：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Boxed -> True, BoxRatios -> {1, 2, 3}]

使用实际的坐标值作为比例：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Boxed -> True, Axes -> True, BoxRatios -> Automatic]

BoxStyle (1)

使用虚线绘制边界框：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Boxed -> True, BoxStyle -> Directive[Dashed]]

Epilog (1)

在图形和轴上方绘制一个圆盘：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 0}, {2, -1}, {2, 1}}], Axes -> True, Epilog -> {Blue, Disk[{1, 0}, .4]}]

FaceGrids (4)

将网格放置在三维图形的每一面：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Axes -> True, Boxed -> True, FaceGrids -> All]

在 ‐ 面上都放置网格：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Axes -> True, Boxed -> True, FaceGrids -> {{0, 0, 1}, {0, 0, -1}}]

在平面上放置面网格：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Axes -> True, Boxed -> True, FaceGrids -> {{0, -1, 0}}]

在平面，在、和上放置网格线：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Axes -> True, Boxed -> True, FaceGrids -> {{{0, -1, 0}, {{1}, {2 / 3, 4 / 3}}}}]

FaceGridsStyle (1)

指定面网格的整体样式：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], FaceGrids -> All, FaceGridsStyle -> Directive[Orange, Dashed]]

Frame (2)

在整个图形周围绘制一个边框：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True]

在左边和右边绘制边框：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> {{True, True}, {False, False}}]

FrameLabel (2)

为底边和左边指定边框标签：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameLabel -> {x, y}]

为每条边指定标签：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameLabel -> {{a, b}, {c, d}}]

FrameStyle (2)

指定整体边框样式：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameStyle -> Directive[Thick, Gray]]

为每条边框的边指定样式：

Wolfram Language code:

ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameStyle -> {{Thick, Directive[Thick, Dashed]}, {Blue, Red}}]

FrameTicks (3)

添加无刻度的边框：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameTicks -> None]

在边框底边和左边的刻度标记标签：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameTicks -> Automatic]

在底边和右边的边框刻度：

Wolfram Language code:

ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameTicks -> {{None, Automatic}, {Automatic, None}}]

FrameTicksStyle (2)

指定边框刻度和边框刻度标签样式：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameTicksStyle -> Directive[Orange, 12]]

为每条边指定边框刻度样式：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameTicksStyle -> {{Black, Blue}, {Red, Green}}]

GridLines (3)

在二维图形中放置网格：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], GridLines -> Automatic]

在特定位置绘制网格线：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Axes -> True, GridLines -> {{.5, 1.5}, {.5, 1.5}}]

指定每个网格的样式：

Wolfram Language code:

Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Axes -> True, GridLines -> {{{-1, Orange}, {-.5, Dotted}, {.5, Dotted}, {1, Orange}}, {-1, {-.5, Dotted}, {.5, Dotted}, 1}}]

GridLinesStyle (1)

指定整体网格样式：

Wolfram Language code:

Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Axes -> True, GridLines -> Automatic, GridLinesStyle -> Directive[Red, Dotted]]

ImageMargins (3)

ImageSize 外围不允许有边距：

Wolfram Language code: Framed[Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}]]]

在所有边都设置 20 点边距：

Wolfram Language code: Framed[Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImageMargins -> 20]]

在指定位置绘制网格线：

Wolfram Language code: Framed[Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImageMargins -> {{5, 10}, {20, 30}}]]

ImagePadding (4)

在绘图范围外不留任何填充：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImagePadding -> None, Frame -> True, FrameLabel -> {x, y}]

为所有现有的对象和标签预留足够的填充：

Wolfram Language code:

Framed[Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImagePadding -> All, Frame -> True, FrameLabel -> {x, y}], FrameMargins -> 0]

为所有边指定同样的填充打印机点数设置：

Wolfram Language code: Framed[Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImagePadding -> 40, Frame -> True]]

为所有边指定同样的填充打印机点数设置：

Wolfram Language code: Framed[Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImagePadding -> {{40, 10}, {20, 5}}, Frame -> True]]

ImageSize (3)

使用预先定义好的符号尺寸：

Wolfram Language code: Table[Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImageSize -> s], {s, {Tiny, Small}}]

使用明确的图像宽度：

Wolfram Language code:

{Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImageSize -> 100], Region[Triangle[{{0, 2}, {2, 0}, {2, 4}}], ImageSize -> 100]}

使用明确的图像宽度和高度：

Wolfram Language code:

{Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], ImageSize -> {100, 100}], Region[Triangle[{{0, 2}, {2, 0}, {2, 4}}], ImageSize -> {100, 100}]}

LabelStyle (1)

明确所有标签类元素的整体样式：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Axes -> True, AxesLabel -> {x, y}, LabelStyle -> Orange]

Lighting (4)

环境光线均匀地应用于该场景中所有表面上：

Wolfram Language code: Region[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Lighting -> {{"Ambient", Orange}}]

不同颜色的有向光线：

Wolfram Language code:

Table[Region[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Lighting -> {{"Directional", c, {{1.5, 0, 2}, {0, 0, 0}}}}], {c, {Red, Yellow, Blue}}]

不同颜色的点光源：

Wolfram Language code:

Table[Region[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Lighting -> {{"Point", c, {1.5, 0, 3}}}], {c, {Red, Yellow, Blue}}]

不同颜色的聚光线：

Wolfram Language code:

Table[Region[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], Lighting -> {{"Spot", c, {{1, 1, 2.5}, {1, 1, 2}}, Pi / 8}}], {c, {Red, Yellow, Blue}}]

PlotLabel (2)

在 TraditionalForm 中在图形上方显示标签：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], PlotLabel -> x ^ 2 + y ^ 2 == 1]

使用 Style 和其他排版函数来调整标签显示的方式：

Wolfram Language code:

Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], PlotLabel -> Style[Framed[x ^ 2 + y ^ 2 == 1], 16, Red, Background -> Yellow]]

PlotRange (3)

显示所有对象：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, PlotRange -> All]

明确选择和的值域：

Wolfram Language code: Region[Triangle[{{-1, 0}, {1, -1}, {1, 1}}], PlotRange -> {{-1, 1}, {0, 1}}, Frame -> True]

强制以 PlotRange 范围为准进行裁剪：

Wolfram Language code:

Region[Triangle[{{-1, 0}, {1, -1}, {1, 1}}], PlotRange -> {{-1, 1}, {0, 1}}, PlotRange -> {{-1, 1}, {0, 1}}, PlotRangeClipping -> True, Frame -> True]

PlotRange->s 等价于 PlotRange->{{-s,s},{-s,s}}:

Wolfram Language code: Region[Triangle[{{-2, 0}, {2, -2}, {2, 2}}], Frame -> True, PlotRange -> 1]

PlotRangeClipping (2)

允许图形对象超过 PlotRange 的范围：

Wolfram Language code: Region[Triangle[{{-2, 0}, {2, -2}, {2, 2}}], Frame -> True, PlotRange -> 1, PlotRangeClipping -> False]

以 PlotRange 范围为准裁剪所有图形对象：

Wolfram Language code: Region[Triangle[{{-2, 0}, {2, -2}, {2, 2}}], Frame -> True, PlotRange -> 1, PlotRangeClipping -> True]

PlotRangePadding (3)

在所有边都设置 1 个坐标单元的填充：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], PlotRangePadding -> 1, Frame -> True]

使用 Scaled 坐标进行填充设置：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], PlotRangePadding -> Scaled[0.1], Frame -> True]

对每一边都设置不同的填充：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], PlotRangePadding -> {{0.5, 1}, {0.3, 0.3}}, Frame -> True]

PlotRegion (3)

图形内容使用整个区域：

Wolfram Language code: Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameTicks -> False, Background -> LightBlue]

在每个方向上都将图形内容限制在区域中间一半的位置：

Wolfram Language code:

Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameTicks -> False, PlotRegion -> {{0.25, 0.75}, {0.25, 0.75}}, Background -> LightBlue]

ImagePadding 也可用于在图形周围添加填充：

Wolfram Language code:

Region[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameTicks -> False, ImagePadding -> 30, Background -> LightBlue]

PlotTheme (3)

基础主题 (2)

使用通用基础主题：

Wolfram Language code: ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], PlotTheme -> "Detailed"]

使用黑白主题：

Wolfram Language code: ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], PlotTheme -> "Monochrome"]

特色主题 (1)

使用主题从网格单元中绘制抽样点：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], PlotTheme -> "SampledPoints"]

Prolog (1)

定义一个简单图形作为背景使用：

Wolfram Language code:

bg = Graphics[Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, VertexColors -> {Orange, Orange, White, White}], AspectRatio -> Full];

将其使用在多个网格区域中：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Prolog -> Inset[bg, Scaled[{0, 0}], Scaled[{0, 0}]]]

Wolfram Language code:

ConvexHullRegion[Line[{{0, 0}, {1, 0}, {2, 1 / 2}, {2, -1 / 2}, {1, 0}}], Prolog -> Inset[bg, Scaled[{0, 0}], Scaled[{0, 0}]]]

RotateLabel (2)

旋转竖直边框标签：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameLabel -> {None, "y axis"}, RotateLabel -> True]

不旋转竖直边框标签：

Wolfram Language code:

ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Frame -> True, FrameLabel -> {None, "y axis"}, RotateLabel -> False]

SphericalRegion (2)

不考虑方向，统一设置一系列图像的尺寸：

Wolfram Language code:

Table[ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], SphericalRegion -> True, ImageSize -> 80, ViewPoint -> 3.{ Sin[t], Cos[t], 1}], {t, 0, 4}]

不使用 SphericalRegion，将每个图像的尺寸尽可能设置到最大：

Wolfram Language code:

Table[ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ImageSize -> 80, ViewPoint -> 3.{ Sin[t], Cos[t], 1}], {t, 0, 4}]

Ticks (3)

绘制坐标轴但不添加刻度记号：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Axes -> True, Ticks -> None]

自动放置标签记号：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Axes -> True, Ticks -> Automatic]

在特定位置绘制刻度记号：

Wolfram Language code: ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Ticks -> {{1, 2, 3}, {1, 3}}, Axes -> True]

TicksStyle (2)

指定刻度和刻度标签的样式：

Wolfram Language code:

ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Ticks -> {{1, 2, 3}, {1, 3}}, Axes -> True, TicksStyle -> Directive[Red, Bold]]

分开指定和轴的刻度样式：

Wolfram Language code:

ConvexHullRegion[Triangle[{{0, 1}, {2, 0}, {2, 2}}], Axes -> True, TicksStyle -> {Directive[Red, Bold], Directive[Blue, 12]}]

ViewAngle (1)

为模拟相机使用特定角度：

Wolfram Language code:

Table[ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewAngle -> d °], {d, {20, 35, 50}}]

ViewCenter (1)

将对象的右上角放在最终图像的中心位置：

Wolfram Language code:

Framed[ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewCenter -> {1, .5, .5}, SphericalRegion -> True]]

ViewMatrix (1)

从负方向观察网格区域的正交投影视图：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewMatrix -> {TransformationMatrix[RescalingTransform[{{-1, 1}, {-1, 1}, {-1, 1}}]], {{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, -1, 0}, {0, 0, 0, 1}}}]

ViewPoint (3)

使用特殊缩放坐标指定视点：

Wolfram Language code: ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewPoint -> {Pi, Pi / 2, 2}]

使用符号视点：

Wolfram Language code:

{ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewPoint -> Front], 
	Region[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewPoint -> Top]}

指定正交视角：

Wolfram Language code:

{ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewPoint -> {0, -Infinity, 0}], 
	Region[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewPoint -> {0, 0, Infinity}]}

ViewProjection (1)

默认情况下，使用透视投影：

Wolfram Language code: ConvexHullRegion[Cuboid[], ViewProjection -> "Perspective"]

指定正交投影：

Wolfram Language code: ConvexHullRegion[Cuboid[], ViewProjection -> "Orthographic"]

ViewRange (2)

默认情况下，范围足够包括所有的对象：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewPoint -> {1, 0, 1.5}, SphericalRegion -> True]

指定要包括的距模拟相机的最小和最大距离：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewPoint -> {1, 0, 1.5}, ViewRange -> {3.5, 7.2}, SphericalRegion -> True]

ViewVector (1)

使用普通坐标指定视点向量：

Wolfram Language code:

ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewVector -> {{5, -5, 5}, {5, 0, -5}}]

ViewVertical (2)

使用轴方向作为最终图像中的垂直方向：

Wolfram Language code: ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewVertical -> {1, 0, 0}]

垂直方向的不同视点：

Wolfram Language code:

Table[ConvexHullRegion[Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}], ViewVertical -> v], {v, {{1, 0, 1}, {.5, 0, 1}, {0, -.5, 1}, {0, -1, 1}}}]

应用 (3)

创建一组基础区域和其凸包：

Wolfram Language code:

Multicolumn[Table[Row[{Region[f, ImageSize -> 30], [image], Region[ConvexHullRegion[f], ImageSize -> 30]}], {f, {...}}], 4, Spacings -> 3]

五个四面体合成的凸包是一个十二面体:

Wolfram Language code: ℛ = DiscretizeGraphics[PolyhedronData["TetrahedronFiveCompound"]]

Wolfram Language code: ConvexHullRegion[MeshCoordinates[ℛ]]

计算一个奶牛图像的凸包：

Wolfram Language code: cowPoints = ExampleData[{"Geometry3D", "Cow"}, "VertexData"];

Wolfram Language code: cowvexHull = ConvexHullRegion[cowPoints];

可视化奶牛图像和其凸包：

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "Graphics3D"];

Wolfram Language code: Show[HighlightMesh[cowvexHull, {Style[1, {Brown}], Style[2, Opacity[0.3, Brown]]}], cow]

属性和关系 (4)

二维空间中点的 ConvexHullRegion 是一个 Polygon：

Wolfram Language code: pts = RandomReal[1, {10, 2}];

Wolfram Language code: ℛ = ConvexHullRegion[pts]

有界区域：

Wolfram Language code: {BoundedRegionQ[ℛ], RegionBounds[ℛ]}

全维度：

Wolfram Language code: {RegionDimension[ℛ], RegionEmbeddingDimension[ℛ]}

使用 ConvexRegionQ 检查凸包区域的属性：

Wolfram Language code: ConvexHullRegion[[image]]

Wolfram Language code: ConvexRegionQ[%]

使用 DelaunayMesh 获取凸包内部的德劳内三角：

Wolfram Language code: DelaunayMesh[RandomReal[1, {25, 2}]]

使用 TriangulateMesh 可控制内部的三角化：

Wolfram Language code: ℛ = ConvexHullRegion[RandomReal[1, {25, 2}]];

Wolfram Language code: {TriangulateMesh[ℛ], TriangulateMesh[ℛ, MaxCellMeasure -> ∞]}

可能存在的问题 (1)

无法给出精确结果时，ConvexHullRegion 给出近似结果：

Wolfram Language code: ConvexHullRegion[BooleanRegion[!#1 && #2&, {Cube[{1 / 2, 0, 0}], Ball[]}]]

开启消息的输出：

Wolfram Language code: On[General::approx]

Wolfram Language code: ConvexHullRegion[BooleanRegion[!#1 && #2&, {Cube[{1 / 2, 0, 0}], Ball[]}]]

Top

ConvexHullRegion

更多信息和选项

范例

基本范例 (3)

范围 (20)

点 (1)

特殊区域 (4)

网格区域 (2)

方程式区域 (3)

衍生区域 (6)

地理区域 (2)

CSG 区域 (1)

Subdivision 区域 (1)

选项 (97)

AlignmentPoint (1)

AspectRatio (1)

Axes (2)

AxesEdge (2)

AxesLabel (2)

AxesOrigin (2)

AxesStyle (2)

Background (1)

BaselinePosition (3)

BaseStyle (2)

Boxed (2)

BoxRatios (2)

BoxStyle (1)

Epilog (1)

FaceGrids (4)

FaceGridsStyle (1)

Frame (2)

FrameLabel (2)

FrameStyle (2)

FrameTicks (3)

FrameTicksStyle (2)

GridLines (3)

GridLinesStyle (1)

ImageMargins (3)

ImagePadding (4)

ImageSize (3)

LabelStyle (1)

Lighting (4)

PlotLabel (2)

PlotRange (3)

PlotRangeClipping (2)

PlotRangePadding (3)

PlotRegion (3)

PlotTheme (3)

基础主题 (2)

特色主题 (1)

Prolog (1)

RotateLabel (2)

SphericalRegion (2)

Ticks (3)

TicksStyle (2)

ViewAngle (1)

ViewCenter (1)

ViewMatrix (1)

ViewPoint (3)

ViewProjection (1)

ViewRange (2)

ViewVector (1)

ViewVertical (2)

应用 (3)

属性和关系 (4)

可能存在的问题 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX