WOLFRAM

Wolfram 语言与系统参考资料中心

CorrelationFunction[data,hspec]

估计数据 data 在滞后 hspec 处的相关函数.

CorrelationFunction[proc,hspec]

表示随机过程 proc 在滞后 hspec 处的相关函数.

CorrelationFunction[proc,s,t]

表示随机过程 proc 在时刻 s 和 t 的相关函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
经验估计  
随机过程  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

CorrelationFunction

CorrelationFunction[data,hspec]

估计数据 data 在滞后 hspec 处的相关函数.

CorrelationFunction[proc,hspec]

表示随机过程 proc 在滞后 hspec 处的相关函数.

CorrelationFunction[proc,s,t]

表示随机过程 proc 在时刻 s 和 t 的相关函数.

更多信息

  • CorrelationFunction 也被称为自相关或互相关函数（ACF 或 CCF）.
  • 可以给予 hspec 以下规范：
  • τ在时刻或滞后 τ
    {τmax}单位间隔从0到τmax
    {τmin,τmax}单位间隔从 τmin 到 τmax
    {τmin,τmax,dτ}从 τmin 到 τmax，步长为 dτ
    {{τ1,τ2,…}}使用显式的 {τ1,τ2,…}
  • CorrelationFunction[{x1,…,xn},h] 等价于 ，其中 =Mean[{x1,…,xn}].
  • 当 data 是包含一组路径的 TemporalData 时，输出表示在所有路径上的平均值.
  • 过程 proc 的 CorrelationFunction 是 CovarianceFunction c，由标准偏差函数 σ 的外积在时刻 s 和 t 进行正态化：
  • c[s,t]/(σ[s]σ[t])对于标量值数据或过程
    c[s,t]/(σ[s] ⊗ σ[t])对于向量值数据或过程
  • 符号 ⊗ 表示 KroneckerProduct.
  • CorrelationFunction[proc,h] 仅当 proc 是一个弱平稳过程的时候有定义，且等价于 CorrelationFunction[proc,h,0].
  • 过程 proc 可以是诸如 ARMAProcess 或 WienerProcess 的任意随机过程.

范例

打开所有单元 关闭所有单元

基本范例  (4)

估计在滞后2处的相关函数：

Wolfram Language code: CorrelationFunction[{2, 3, 4, 3}, 2]

自回归时间序列随机样本的样本相关函数：

Wolfram Language code: data = RandomFunction[ARProcess[{.2, .3, .4}, 1], {1, 10 ^ 4}];
Wolfram Language code: ListPlot[CorrelationFunction[data, {20}], Filling -> Axis, PlotRange -> All]

离散时间过程的相关函数：

Wolfram Language code: CorrelationFunction[BinomialProcess[p], s, t]
Wolfram Language code: DiscretePlot3D[Evaluate[% /. {p -> 2 / 3}], {s, 1, 10}, {t, 1, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

连续时间过程的相关函数：

Wolfram Language code: CorrelationFunction[WienerProcess[μ, σ], s, t]
Wolfram Language code: Plot3D[Evaluate[% /. {μ -> 1, σ -> 2}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

范围  (13)

经验估计  (7)

估计某些数据在滞后9处的相关函数：

Wolfram Language code: CorrelationFunction[Range[10], 9]

获取在滞后9以内的相关函数的经验估计：

Wolfram Language code: CorrelationFunction[Range[10], {9}]

计算步长为2、滞后从1到9的相关函数：

Wolfram Language code: CorrelationFunction[Range[10], {1, 9, 2}]

计算时间序列的相关函数：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{-2.9904395734335427, -1.5547517217370468, -2.007044987914736, -0.7114933373063236, -1.5920036118254968, 0.23183536513859127, 0.056774681349179124, 0.32394041932443046, 0.10382798659711348, -0.684046765274114, - ... 1687325555, 3.410933732368106, 2.5200924558212163, 2.008558601261935, 0.43151331467691206, 0.6249727955196763}}, {{1, 1000, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];

多个滞后时间序列的相关函数由时间序列给出：

Wolfram Language code: corr = CorrelationFunction[ts, {100}]
Wolfram Language code: ListPlot[corr, Filling -> Axis]

估计一组路径的相关函数：

Wolfram Language code: data = RandomFunction[ARProcess[{.8}, 1], {0, 500}, 10]
Wolfram Language code: corr = CorrelationFunction[data, {12}];
Wolfram Language code: ListPlot[corr, Filling -> 0]

比较经验和理论相关函数：

Wolfram Language code: proc = MAProcess[{.4, .3, .5, .6, .3}, 1.];
Wolfram Language code: data = RandomFunction[proc, {0, 1000}];
Wolfram Language code: ListPlot[TemporalData[CorrelationFunction[#, {10}]& /@ {proc, data}], Filling -> {1 -> {2}}, PlotStyle -> PointSize[Medium]]

绘制向量数据的互相关：

Wolfram Language code: proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}]; data = RandomFunction[proc, {100}]; cov = CorrelationFunction[data, {-6, 6}];
Wolfram Language code: Table[ListPlot[cov["Values"][[All, i, j]], Filling -> 0, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]

随机过程  (6)

一个弱平稳离散时间过程的相关函数：

Wolfram Language code: CorrelationFunction[ARProcess[{a}, σ^2], s, t]//PiecewiseExpand
Wolfram Language code: DiscretePlot3D[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

相关函数只取决于反对角线 ：

Wolfram Language code: CorrelationFunction[ARProcess[{a}, σ^2], h]//PiecewiseExpand
Wolfram Language code: DiscretePlot[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {h, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow", AxesLabel -> {h, None}]

一个弱平稳连续时间过程的相关函数：

Wolfram Language code: CorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], s, t]
Wolfram Language code: Plot3D[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

相关函数只取决于反对角线 ：

Wolfram Language code: CorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], h]
Wolfram Language code: Plot[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {h, 0, 10}, ColorFunction -> "Rainbow", Filling -> Axis, AxesLabel -> {h, None}]

一个非弱平稳离散时间过程的相关函数：

Wolfram Language code: CorrelationFunction[BinomialProcess[p], s, t]
Wolfram Language code: DiscretePlot3D[Evaluate[% /. p -> 1 / 3], {s, 1, 10}, {t, 1, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

相关函数与两个时间参数均有关：

Wolfram Language code: antidiagonals = CorrelationFunction[BinomialProcess[1 / 3], t, t + h]
Wolfram Language code: DiscretePlot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 5}, ExtentSize -> 1 / 2, PlotLegends -> (Row[{"t = ", #}]& /@ Range[1, 4]), AxesLabel -> {h, None}]

一个非弱平稳连续时间过程的相关函数：

Wolfram Language code: CorrelationFunction[PoissonProcess[μ], s, t]
Wolfram Language code: Plot3D[Evaluate[% /. μ -> 3], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

相关函数与两个时间参数均有关：

Wolfram Language code: antidiagonals = CorrelationFunction[PoissonProcess[3], t, t + h]
Wolfram Language code: Plot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 5}, PlotLegends -> (Row[{"t = ", #}]& /@ Range[1, 4]), AxesLabel -> {h, None}]

一些时间序列过程的相关函数：

Wolfram Language code: proc1 = ARProcess[{.8}, 1]; proc2 = MAProcess[{-.4, -.7, .6, -1}, 1]; proc3 = SARMAProcess[{}, {}, {3, {.6}, {.1}}, 1]; proc4 = FARIMAProcess[{}, 1 / 3, {}, 1];
Wolfram Language code: DiscretePlot[CorrelationFunction[#, h], {h, 0, 15}, ExtentSize -> 1 / 2, PlotRange -> All, PlotLabel -> Head[#]]& /@ {proc1, proc2, proc3, proc4}

向量 ARProcess 的互相关图形：

Wolfram Language code: proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}]; cov = CorrelationFunction[proc, h];
Wolfram Language code: Table[DiscretePlot[cov[[i, j]], {h, -6, 6}, ExtentSize -> 1 / 2, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]

应用  (2)

确定下列数据是用 MAProcess 模拟还是用 ARProcess 模拟效果最好：

Wolfram Language code: ListLinePlot[data = TemporalData[TimeSeries, {{{-1.4735257611469446, -0.9158187257309729, -1.9060205147226934, -1.6174582169404574, -2.633459084244463, -2.104839842098871, -2.8701276893108894, -2.4118183939601607, -0.5125633448622677, -1.2356329399850385, 1. ... 26394036266876, -0.16380797769527589, 0.3559909972777121, 1.5343047104249412, 0.10763337590714506}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1]]

很难从样本路径确定底层过程：

Wolfram Language code: candidates = {MAProcess[{.5, .4}, 1], ARProcess[{.5, .4}, 1]};
Wolfram Language code: SeedRandom[2];ListLinePlot[RandomFunction[#, {0, 100}]]& /@ candidates

数据的相关性函数缓慢衰减：

Wolfram Language code: ListPlot[CorrelationFunction[data, {10}], Filling -> 0]

显然，ARProcess 是一个比 MAProcess 更好的候选模型：

Wolfram Language code: ListPlot[CorrelationFunction[#, {10}], PlotLabel -> Head[#], Filling -> 0]& /@ candidates

建立白噪声置信带的 ACF 图：

Wolfram Language code: data = RandomFunction[MAProcess[{.6, .4, .5}, .1], {1, 500}];
Wolfram Language code: acf[data_, lmax_, clev_ : 0.95] := Show[ListPlot[CorrelationFunction[data, {0, lmax}], Filling -> Axis, PlotRange -> {{0, lmax}, All}, PlotStyle -> PointSize[Medium]], Graphics[{Dashed, Line[{{0, #}, {lmax, #}}]}]& /@ (Quantile[NormalDistribution[], {(1 - clev/2), 1 - (1 - clev/2)}]/Sqrt[data["PathLengths"][[1]]])]

在95％的白噪声置信区间上绘制滞后0到20的相关：

Wolfram Language code: acf[data, 20, .95]

比较不相关的白噪声：

Wolfram Language code: acf[TemporalData[RandomVariate[NormalDistribution[], 500], Automatic], 20, .95]

属性和关系  (12)

样本相关函数是过程相关函数的有偏估计量：

Wolfram Language code: proc = ARMAProcess[1, {5 / 6, -1 / 6}, {2 / 3}, 1]; paths = RandomFunction[proc, {0, n = 10}, 10 ^ 3];

计算样本相关性函数：

Wolfram Language code: CorrelationFunction[paths, {10}]
Wolfram Language code: scorr = TimeSeriesMapThread[#2(n + 1) / (n + 1 - #1)&, %]

过程的相关函数：

Wolfram Language code: corr = CorrelationFunction[proc, {10}]

绘制两个函数：

Wolfram Language code: ListPlot[{scorr, corr}, Filling -> 0]

过程的相关函数是 Correlation 矩阵的非对角线项：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];
Wolfram Language code: Correlation[𝒫[{s, t}], 1, 2]
Wolfram Language code: CorrelationFunction[𝒫, s, t]
Wolfram Language code: Simplify[%% - %, 0 < s < t]

滞后0的样本相关始终为1：

Wolfram Language code: Simplify[CorrelationFunction[{x, y, z}, 0], {x, y, z}∈Reals]

样本相关函数与 CovarianceFunction 相关：

Wolfram Language code: data = Range[10];
Wolfram Language code: CorrelationFunction[data, {Length[data] - 1}]

经缩放的样本协方差函数：

Wolfram Language code: CovarianceFunction[data, {Length[data] - 1}] / CovarianceFunction[data, 0]
Wolfram Language code: % - %%

样本相关函数与 AbsoluteCorrelationFunction 相关：

Wolfram Language code: data = Range[10]; n = Length[data];
Wolfram Language code: AbsoluteCorrelationFunction[data - Mean[data], {n - 1}]

按第一个元素进行缩放：

Wolfram Language code: % / First[%]

与样本相关函数比较：

Wolfram Language code: CorrelationFunction[data, {n - 1}]
Wolfram Language code: % - %%

使用 Expectation 计算相关：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];

定义均值和标准差函数：

Wolfram Language code: sd[s_] := StandardDeviation[𝒫[s]] m[s_] := Mean[𝒫[s]]
Wolfram Language code: Expectation[(x[s] - m[s])(x[t] - m[t]) / (sd[s] sd[t]), x𝒫]
Wolfram Language code: CorrelationFunction[𝒫, s, t]
Wolfram Language code: Simplify[% - %%, 0 < s < t]

相同时间的相关函数减少为1：

Wolfram Language code: CorrelationFunction[PoissonProcess[μ], t, t]//Simplify[#, t > 0]&

相关函数 与 CovarianceFunction 有关：

Wolfram Language code: 𝒫 = OrnsteinUhlenbeckProcess[μ, σ, θ]; sd[s_] := StandardDeviation[𝒫[s]]
Wolfram Language code: CorrelationFunction[𝒫, s, t]

对于 ，标准差函数为 ：

Wolfram Language code: CovarianceFunction[𝒫, s, t] / (sd[s] sd[t])
Wolfram Language code: % - %%

相关函数与 Correlation 有关：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];
Wolfram Language code: CorrelationFunction[𝒫, s, t]

这是协方差矩阵的非对角项：

Wolfram Language code: Correlation[𝒫[{s, t}], 1, 2]
Wolfram Language code: Simplify[%% - %, 0 < s < t]

相关函数对于 ToInvertibleTimeSeries 是不变的：

Wolfram Language code: TimeSeriesInvertibility[proc = MAProcess[{2, 4}, 1]]
Wolfram Language code: iproc = ToInvertibleTimeSeries@proc
Wolfram Language code: CorrelationFunction[#, s, t]& /@ {proc, iproc}

相关函数对于集中化是不变的：

Wolfram Language code: data = RandomFunction[ARIMAProcess[{}, 1, {}, 1], {0, 100}];

数据的均值非零：

Wolfram Language code: Mean[data]

集中化数据：

Wolfram Language code: newdata = Standardize[data, Mean, 1&];

比较相关函数：

Wolfram Language code: ListPlot[CorrelationFunction[#, {20}], Filling -> 0]& /@ {data, newdata}

样本相关函数之和是一个常数：

Wolfram Language code: n = 100; sample = RandomInteger[n, n];

样本是随机的：

Wolfram Language code: ListPlot[sample, Filling -> Axis]

计算从 1 到 n-1 的样本相关函数：

Wolfram Language code: corr = CorrelationFunction[sample, {1, n - 1}]; ListLinePlot[corr]

计算和：

Wolfram Language code: Total@corr

可能存在的问题  (1)

CorrelationFunction 的输出可能包含 DifferenceRoot：

Wolfram Language code: CorrelationFunction[ARProcess[{a, b}, σ^2], t] //Simplify[#, t > 0]&

使用 FunctionExpand 来恢复显式的幂：

Wolfram Language code: %//FunctionExpand
Wolfram Research (2012)，CorrelationFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CorrelationFunction.html.

文本

Wolfram Research (2012)，CorrelationFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CorrelationFunction.html.

CMS

Wolfram 语言. 2012. "CorrelationFunction." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CorrelationFunction.html.

APA

Wolfram 语言. (2012). CorrelationFunction. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CorrelationFunction.html 年

BibTeX

@misc{reference.wolfram_2026_correlationfunction, author="Wolfram Research", title="{CorrelationFunction}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CorrelationFunction.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_correlationfunction, organization={Wolfram Research}, title={CorrelationFunction}, year={2012}, url={https://reference.wolfram.com/language/ref/CorrelationFunction.html}, note=[Accessed: 07-October-2026]}