WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Cos[z]

z の余弦を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
積分変換  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Cos

Cos[z]

z の余弦を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 明示的にQuantityオブジェクトとして与えられていない限り，Cosの引数はラジアン単位であるとみなされる（Degreeをかけて度から変換することができる）． »
  • Cosは，引数が の単純有理倍数である場合は自動的に評価されるが，より複雑な有理倍数の場合はFunctionExpandが使用されることもある． »
  • 特別な引数の場合，Cosは，自動的に厳密値を計算する．
  • Cosは任意の数値精度で評価できる．
  • Cosは，自動的にリストに縫い込まれる． »
  • CosはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • Cosは，余弦関数である．これは，三角法における基本関数の一つである．これは， を単位円の円周に沿って 軸から反時計回りに測定したラジアン角度とすることで，実数について定義する．Cos[x]はその後，弧の端点の水平座標を与える．教科書的な定義では，直角三角形における角度 の余弦は， に接する辺の長さと斜辺の長さの比である．
  • Cosは，引数が の単純な有理倍数である場合に，厳密な値に自動的に評価される．より複雑な有理倍数については，FunctionExpandを使って明示的な厳密値を得ることができることがある．度で測られた角を使って引数を指定するときは，記号Degreeを乗数として使うことができる（例：Cos[30 Degree]）．引数として厳密な数式が与えられると，Cosは任意の数値精度に評価できることがある．Cosを含む記号式の操作に便利なその他の操作には，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
  • Cosは，要素単位でリストと行列に縫い込まれる．対照的に，MatrixFunctionを使って，個々の行列要素の余弦とは対照的に，正方行列の余弦（つまり通常のベキを行列のベキで置き換えた余弦関数のベキ級数）を与えることができる．
  • Cosは，FunctionPeriodにあるように， を周期として周期的である．Cosは，恒等式を満たす．これは，ピタゴラス(Pythagorean)の定理に等しい．余弦関数の定義は，定義を使って，複素引数 まで拡張される．この場合， は自然対数の底である．余弦関数は全縁である．つまり，複素平面の有限点すべてにおいて複素微分することができる．Cos[z]は原点付近で級数展開を持つ．
  • Cosの逆関数は，ArcCosである．双曲線余弦は，Coshで与えられる．他の関連する数学関数にはSec，Sin等がある．

例題

すべて開く すべて閉じる

例  (5)

引数はラジアンで与えられる：

Wolfram Language code: Cos[Pi / 6]

Degreeを用いて引数を度で指定する：

Wolfram Language code: Cos[30Degree]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Cos[x], {x, 0, 2Pi}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Cos[z], {z, -2 π - 2 I, 2 π + 2 I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[Cos[x], {x, 0, 10}]

スコープ  (51)

数値評価  (6)

数値的に評価する：

Wolfram Language code: Cos[1.2]

高精度で評価する：

Wolfram Language code: N[Cos[12 / 10], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: Cos[1.20000000000000000000000]

Cosは複素数を入力として取ることができる：

Wolfram Language code: Cos[2.5 + I]

Cosを高精度で効率よく評価する：

Wolfram Language code: Cos[1.2`500]//Timing
Wolfram Language code: Cos[1.2`100000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: Cos[ {{5π / 6, 0}, {3π / 2, -π / 2}}]

MatrixFunctionを使って行列のCos関数を計算することもできる：

Wolfram Language code: MatrixFunction[Cos[#]&, {{5π / 6, 0}, {3π / 2, -π / 2}}]

IntervalオブジェクトおよびCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Cos[Interval[{π / 2, π / 3}]]
Wolfram Language code: Cos[CenteredInterval[1, 1 / 100]]
Wolfram Language code: Cos[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Cos[Around[2, 0.01]]

特定の値  (5)

固定点におけるCosの値：

Wolfram Language code: Table[Cos[n (π/6)], {n, 0, 6}]

無限大における値：

Wolfram Language code: Cos[Infinity]
Wolfram Language code: Cos[ComplexInfinity]

Cosの零点：

Wolfram Language code: Assuming[m∈Integers, Refine[Cos[π ((1/2) + m)]]]

Cosの極値：

Wolfram Language code: Assuming[m∈Integers, FullSimplify[Refine[Cos[π m]]]]

Cosの最小値を の根として，最小値の近傍で求める：

Wolfram Language code: sol = Solve[D[Cos[x], x] == 0 && 0 < x < 2π, x]

結果を代入する：

Wolfram Language code: xmin = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[Cos[x], {x, 0, 2π}, Epilog -> Style[Point[{xmin, Cos[xmin]}], PointSize[Large], Red]]

簡単な厳密値は自動的に生成される：

Wolfram Language code: Cos[Pi / 5]

より複雑な場合は明示的にFunctionExpandを使う必要がある：

Wolfram Language code: Cos[Pi / 24]
Wolfram Language code: FunctionExpand[%]

可視化  (3)

Cos関数のプロット：

Wolfram Language code: Plot[Cos[x], {x, -2π, 2π}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Cos[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Cos[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code: Table[PolarPlot[Cos[k ϕ], {ϕ, 0, 2π}, Sequence[Frame -> True, FrameTicks -> {{{-1, -0.5, 0, 0.5, 1}, None}, {{-1, -0.5, 0, 0.5, 1}, None}}, PlotLabel -> "k=" <> ToString[k]]], {k, 1, 8}]

関数の特性  (13)

Cosはすべての実数値と虚数値について定義される：

Wolfram Language code: FunctionDomain[Cos[x], x]
Wolfram Language code: FunctionDomain[Cos[z], z, Complexes]

Cosは-1から1までのすべての実数値に達する：

Wolfram Language code: FunctionRange[Cos[x], x, y]

複素値の範囲は平面全体である：

Wolfram Language code: FunctionRange[Cos[z], z, y, Complexes]

Cosは周期 の周期関数である：

Wolfram Language code: FunctionPeriod[Cos[x], x]

Cosは偶関数である：

Wolfram Language code: Cos[-x]

Cosは鏡特性cos(TemplateBox[{z}, Conjugate])=TemplateBox[{{cos, (, z, )}}, Conjugate]を有する：

Wolfram Language code: FullSimplify[Cos[Conjugate[z]] == Conjugate[Cos[z]]]

Cosは x についての解析関数である：

Wolfram Language code: FunctionAnalytic[Cos[x], x]

Cosは特定の値域で単調である：

Wolfram Language code: FunctionMonotonicity[Cos[x], x]
Wolfram Language code: FunctionMonotonicity[{Cos[x], -π / 2 < x < 0}, x]

Cosは単射ではない：

Wolfram Language code: FunctionInjective[Cos[x], x]
Wolfram Language code: Plot[{Cos[x], 1 / 2}, {x, -2π, 2π}]

Cosは全射ではない：

Wolfram Language code: FunctionSurjective[Cos[x], x]
Wolfram Language code: Plot[{Cos[x], 1.5}, {x, -2π, 2π}]

Cosは非負でも非正でもない：

Wolfram Language code: FunctionSign[Cos[x], x]

Cosは特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[Cos[x], x]
Wolfram Language code: FunctionDiscontinuities[Cos[x], x]

Cosは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Cos[x], x]

[0,π]において x について凹である：

Wolfram Language code: FunctionConvexity[{Cos[x], -π / 2 < x < π / 2}, x]
Wolfram Language code: Plot[Cos[x], {x, -π / 2, π / 2}]

TraditionalFormによる表示：

Wolfram Language code: Cos[α]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[Cos[x], x]

高次導関数：

Wolfram Language code: Table[D[Cos[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -π, π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[Cos[x], {x, n}]

積分  (3)

Cosの不定積分：

Wolfram Language code: Integrate[Cos[x], x]

周期上でのCosの定積分は0である：

Wolfram Language code: Integrate[Cos[x], {x, 0, 2 π}]

その他の積分例：

Wolfram Language code: Integrate[Sin[x]Cos[x], x]
Wolfram Language code: Integrate[Cos[x] ^ a, x]

級数展開  (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[Cos[x], {x, 0, 8}]

の周りのCosの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[Cos[x], {x, 0, m}], {m, 2, 6, 2}]; Plot[{Cos[x], terms}, {x, -2π, 2π}, PlotRange -> {-1.5, 1.5}]

Cosの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Cos[x], {x, 0, n}]

フーリエ(Fourier)級数：

Wolfram Language code: FourierSeries[Cos[z], z, 1]

Cosはベキ級数に適用できる：

Wolfram Language code: Cos[(π/2) + x + (x^2/2) + (x^3/3) + O[x]^4]

積分変換  (3)

FourierTransformを使ってフーリエ変換を計算する：

Wolfram Language code: FourierTransform[Cos[t], t, ω ]

LaplaceTransform：

Wolfram Language code: LaplaceTransform[Cos[t], t, s ]

MellinTransform：

Wolfram Language code: MellinTransform[Cos[x], x, s ]

関数の恒等式と簡約  (6)

倍角のCos：

Wolfram Language code: Expand[Cos[2x] , Trig -> True]

総和のCos：

Wolfram Language code: Expand[Cos[x + y] , Trig -> True]

マルチアングルの式を変換する：

Wolfram Language code: TrigExpand[Cos[4x]]
Wolfram Language code: TrigReduce[%]

三角関数の総和を積に変換する：

Wolfram Language code: TrigFactor[Cos[x] + Cos[y]]

実変数 および を仮定して展開する：

Wolfram Language code: ComplexExpand[Cos[x + I y]]

複素指数に変換する：

Wolfram Language code: TrigToExp[Cos[z]]

関数表現  (5)

Sinを介した表現：

Wolfram Language code: Simplify[Sin[(Pi/2) - x]]

ベッセル(Bessel)関数を介した表現：

Wolfram Language code: Simplify[Sqrt[( π x/2)]BesselJ[-(1/2), x]]
Wolfram Language code: Simplify[Sqrt[( π I x/2)]BesselI[-(1/2), I x]]

SphericalHarmonicYを介した表現：

Wolfram Language code: Simplify[Sqrt[4 π / 3]SphericalHarmonicY[1, 0, θ, 0]]

MeijerGによる表現：

Wolfram Language code: MeijerGReduce[Cos[x], x]
Wolfram Language code: Activate[%]

CosはDifferentialRootとして表現できる：

Wolfram Language code: DifferentialRootReduce[Cos[x], x]

アプリケーション  (14)

円を描く：

Wolfram Language code: ParametricPlot[{Cos[t], Sin[t]}, {t, 0, 2Pi}]

リサージュ(Lissajous)の図形：

Wolfram Language code: ParametricPlot[{Cos[2t], Cos[5t]}, {t, 0, 2Pi}]

等角（対数の）螺線：

Wolfram Language code: ParametricPlot[Exp[t / 10]{Cos[t], Sin[t]}, {t, 0, 10Pi}, PlotRange -> All]

円運動：

Wolfram Language code: Animate[Graphics[Line[{{0, 0}, {Cos[t], Sin[t]}}], PlotRange -> 1.2], {t, 0, 10Pi}]

調和運動の式を解く：

Wolfram Language code: DSolve[x''[t] + ω^2x[t] == 0, x[t], t]

回転行列：

Wolfram Language code: RotationMatrix[θ]

水平に並んだベクトルに適用する：

Wolfram Language code: %.{1, 0}

球をプロットする：

Wolfram Language code: ParametricPlot3D[{Cos[ϕ] Sin[θ], Sin[θ] Sin[ϕ], Cos[θ]}, {ϕ, -π, π}, {θ, 0, π}]

トーラスをプロットする：

Wolfram Language code: ParametricPlot3D[{Cos[ϕ] + 1 / 2 Cos[θ] Cos[ϕ], Sin[ϕ] + 1 / 2 Cos[θ] Sin[ϕ], Sin[θ] / 2}, {ϕ, -π, π}, {θ, 0, 2 π}]

二次元波：

Wolfram Language code: Plot3D[Cos[x]Cos[y], {x, 0, 10Pi}, {y, 0, 10Pi}]

3重周期曲面：

Wolfram Language code: ContourPlot3D[Cos[x] + Cos[y] + Cos[z], {x, -2Pi, 2Pi}, {y, -2Pi, 2Pi}, {z, -2Pi, 2Pi}, Contours -> {0}, Mesh -> False, BoundaryStyle -> None, ContourStyle -> {Opacity[0.8]}]

微分できるところがほとんどどこにもないRiemann–Weierstrass関数を近似する：

Wolfram Language code: Plot[Sum[N[Cos[j ^ 2 x] / j ^ 2], {j, 12}], {x, 0, 2Pi}]

2つの角が等しい三角形は二等辺三角形である：

Wolfram Language code: IsoscelesTriangle[α_, s_] := AASTriangle[α, α, s]
Wolfram Language code: t = IsoscelesTriangle[5π / 13, 1]

可視化する：

Wolfram Language code: Graphics[t]

面積を求める：

Wolfram Language code: FullSimplify[Area@IsoscelesTriangle[α, s], s > 0 && 0 < α < π]

エアリー(Airy)関数の組合せについてのゾンマーフェルト(Sommerfeld)の放射条件をチェックする：

Wolfram Language code: Series[AiryBi[z] - I AiryAi[z], {z, -∞, 2}]

外へ向かう平面波しかない：

Wolfram Language code: Simplify[Normal[%]//TrigToExp]

Cos関数とSin関数を使って円の上の点を求める：

Wolfram Language code: ContourPlot[x ^ 2 + y ^ 2 == 1, {x, -1.5, 1.5}, {y, -1.5, 1.5}, Epilog -> Style[Point[{Cos[π / 4], Sin[π / 4]}], PointSize[Large], Red], Axes -> True, Frame -> False, AxesLabel -> {x, y}]

特性と関係  (12)

余弦関数の基本的なパリティと周期性の性質は自動的に適用される：

Wolfram Language code: Cos[x + 2Pi]
Wolfram Language code: {Cos[-x], Cos[I x]}
Wolfram Language code: 1 / Cos[x]

三角関数を含む複雑な式は自動的には簡約されない：

Wolfram Language code: Cos[3z]^2 - (Cos[z]^3 - 3 Cos[z] Sin[z]^2)^2
Wolfram Language code: Simplify[%]
Wolfram Language code: Cos[(x + y/2)]Cos[(x - y/2)] + ((1/2) Cos[(x/2)]^2 + (1/2) Cos[(y/2)]^2 - (1/2) Sin[(x/2)]^2 - (1/2) Sin[(y/2)]^2)
Wolfram Language code: Simplify[%]

逆関数を用いて構築する：

Wolfram Language code: {Cos[ArcCos[z]], Cos[2ArcCos[z]], Cos[3ArcCos[z]]}
Wolfram Language code: FunctionExpand[%]

1ラジアンは度である：

Wolfram Language code: Cos[1] == CosDegrees[180 / π]//Simplify

三角方程式を解く：

Wolfram Language code: Reduce[Cos[z]^2 + 3 Cos[z + Pi / 6] == 4, z]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[Cos[z]^2 + 3 Cos[z + Pi / 6] + z == 4, {z, 4}]

三角方程式を簡約する：

Wolfram Language code: Reduce[Cos[α x + β] == 0, x]

積分：

Wolfram Language code: ∫Cos[z]^aⅆz

Cosは多くの数学関数の特殊形に見られる：

Wolfram Language code: {BesselJ[-(1/2), z], MathieuC[1, 0, z], JacobiCD[z, 0], Hypergeometric0F1[(1/2), -z], MeijerG[{{}, {}}, {{0}, {(1/2)}}, z]}

Cosは数値関数である：

Wolfram Language code: Attributes[Cos]
Wolfram Language code: NumericQ[Cos[2 + E]]

Cosの母関数：

Wolfram Language code: GeneratingFunction[Cos[n], n, x]
Wolfram Language code: Series[%, {x, 0, 5}]//FullSimplify

Cosの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[Cos[n], n, x]

考えられる問題  (5)

機械精度の入力では正解を出すのに不十分である：

Wolfram Language code: Cos[10. ^ 45]

厳密な入力を使うと，正しい答が得られる：

Wolfram Language code: N[Cos[10 ^ 45], 20]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[Cos[10 ^ 100], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Cos[10 ^ 100], 20]]

機械数の入力で高精度の結果が得られることがある：

Wolfram Language code: Cos[10. ^ 3I]
Wolfram Language code: MachineNumberQ[%]

Cos[x]を含む連続関数が不連続な不定積分を返すことがある：

Wolfram Language code: Integrate[(1/2 + Cos[x]), x]
Wolfram Language code: Plot[%, {x, 0, 2Pi}]

TraditionalFormでは，引数の周りに丸カッコが必要である：

Wolfram Language code: cos x
Wolfram Language code: cos(x)

おもしろい例題  (5)

非整合な波（準周期関数）：

Wolfram Language code: Plot[Cos[x] + Cos[Sqrt[2]x], {x, 0, 40Pi}]

引数の中にはネストした根号の有限数列として表せるものがある：

Wolfram Language code: Cos[(π/2^12)]//FunctionExpand

の有限積分：

Wolfram Language code: Table[Integrate[Cos[x ^ n], x], {n, 3}]

クラドニ(Chladni)図形：

Wolfram Language code: DensityPlot[Cos[4x]Cos[3y] + 1 / 2Cos[3x]Cos[4y], {x, 0, 2Pi}, {y, 0, 2Pi}]

整数点でCosをプロットする：

Wolfram Language code: ArrayPlot[Table[Cos[x y], {x, -20, 20}, {y, -20, 20}]]
Wolfram Research (1988), Cos, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cos.html （2021年に更新）.

テキスト

Wolfram Research (1988), Cos, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cos.html （2021年に更新）.

CMS

Wolfram Language. 1988. "Cos." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Cos.html.

APA

Wolfram Language. (1988). Cos. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Cos.html

BibTeX

@misc{reference.wolfram_2026_cos, author="Wolfram Research", title="{Cos}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Cos.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cos, organization={Wolfram Research}, title={Cos}, year={2021}, url={https://reference.wolfram.com/language/ref/Cos.html}, note=[Accessed: 16-September-2026]}