Wolfram 语言与系统参考资料中心

CovarianceFunction

CovarianceFunction[data,hspec]

估计数据 data 在滞后 hspec 处的协方差函数.

CovarianceFunction[proc,hspec]

表示随机过程 proc 在滞后 hspec 处的协方差函数.

CovarianceFunction[proc,s,t]

表示随机过程 proc 在时刻 s 和 t 的协方差函数.

范例

打开所有单元关闭所有单元

基本范例 (4)

估计在滞后2处的协方差函数：

Wolfram Language code: CovarianceFunction[{2, 3, 4, 3}, 2]

自回归时间序列随机样本的样本协方差函数：

Wolfram Language code: data = RandomFunction[ARProcess[{.2, .3, .4}, 1], {1, 10 ^ 4}];

Wolfram Language code: ListPlot[CovarianceFunction[data, {20}], Filling -> Axis, PlotRange -> All]

计算离散时间过程的协方差函数：

Wolfram Language code: CovarianceFunction[BinomialProcess[p], s, t]

Wolfram Language code: DiscretePlot3D[Evaluate[% /. {p -> 2 / 3}], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

计算连续时间过程的协方差函数：

Wolfram Language code: CovarianceFunction[WienerProcess[μ, σ], s, t]

Wolfram Language code: Plot3D[Evaluate[% /. {μ -> 1, σ -> 2}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

范围 (13)

经验估计 (7)

估计某些数据在滞后9处的协方差函数：

Wolfram Language code: CovarianceFunction[Range[10], 9]

获取在滞后9以内的协方差函数的经验估计：

Wolfram Language code: CovarianceFunction[Range[10], {9}]

计算步长为2、滞后从1到9的协方差函数：

Wolfram Language code: CovarianceFunction[Range[10], {1, 9, 2}]

计算时间序列的协方差函数：

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{-2.9904395734335427, -1.5547517217370468, -2.007044987914736, 
    -0.7114933373063236, -1.5920036118254968, 0.23183536513859127, 0.056774681349179124, 
    0.32394041932443046, 0.10382798659711348, -0.684046765274114, - ... 1687325555, 
    3.410933732368106, 2.5200924558212163, 2.008558601261935, 0.43151331467691206, 
    0.6249727955196763}}, {{1, 1000, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];

多个滞后时间序列的协方差函数由时间序列给出：

Wolfram Language code: cov = CovarianceFunction[ts, {100}]

Wolfram Language code: ListPlot[cov, Filling -> Axis]

估计一组路径的协方差函数：

Wolfram Language code: data = RandomFunction[ARProcess[{.8}, 1], {0, 500}, 25]

Wolfram Language code: cov = CovarianceFunction[data, {50}];

Wolfram Language code: ListPlot[cov, Filling -> 0]

比较经验和理论协方差函数：

Wolfram Language code: proc = MAProcess[{.4, .3, .5, .6, .3}, 1.];

Wolfram Language code: data = RandomFunction[proc, {0, 5000}];

Wolfram Language code:

ListPlot[CovarianceFunction[#, {10}]& /@ {proc, data}, Filling -> {1 -> {2}}, PlotStyle -> PointSize[Medium], PlotLegends -> {"process covariance", "sample covariance"}]

绘制向量数据的互协方差：

Wolfram Language code:

proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}];
data = RandomFunction[proc, {100}];
cov = CovarianceFunction[data, {-6, 6}];

Wolfram Language code: Table[ListPlot[cov["Values"][[All, i, j]], Filling -> 0, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]

随机过程 (6)

一个弱平稳离散时间过程的协方差函数：

Wolfram Language code: CovarianceFunction[ARProcess[{a}, σ^2], s, t]

Wolfram Language code:

DiscretePlot3D[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {s, 0, 10}, {t, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

协方差函数只取决于反对角线：

Wolfram Language code: CovarianceFunction[ARProcess[{a}, σ^2], h]

Wolfram Language code:

DiscretePlot[Evaluate[% /. {a -> 2 / 3, σ -> 1}], {h, 0, 10}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow", AxesLabel -> {h, None}]

一个弱平稳连续时间过程的协方差函数：

Wolfram Language code: CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], s, t]

Wolfram Language code: Plot3D[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

协方差函数只取决于反对角线：

Wolfram Language code: CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], h]

Wolfram Language code:

Plot[Evaluate[% /. {μ -> 1, σ -> 2, θ -> 1 / 3}], {h, 0, 10}, ColorFunction -> "Rainbow", Filling -> Axis, AxesLabel -> {h, None}]

一个非弱平稳离散时间过程的协方差函数：

Wolfram Language code: CovarianceFunction[BinomialProcess[p], s, t]

Wolfram Language code:

DiscretePlot3D[Evaluate[% /. p -> 1 / 3], {s, 0, 10}, {t, 0, 10}, 
	ExtentSize -> 1 / 2, ColorFunction -> "Rainbow"]

协方差函数与两个时间参数均有关：

Wolfram Language code: antidiagonals = CovarianceFunction[BinomialProcess[1 / 3], t, t + h]

Wolfram Language code:

DiscretePlot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 6}, ExtentSize -> 1 / 2, PlotLegends -> (Row[{"t = ", #}]& /@ Range[1, 4]), AxesLabel -> {h, None}]

一个非弱平稳连续时间过程的协方差函数：

Wolfram Language code: CovarianceFunction[PoissonProcess[μ], s, t]

Wolfram Language code: Plot3D[Evaluate[% /. μ -> 3], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

协方差函数与两个时间参数均有关：

Wolfram Language code: antidiagonals = CovarianceFunction[PoissonProcess[3], t, t + h]

Wolfram Language code:

Plot[Evaluate@Table[antidiagonals, {t, 1, 4}], {h, 0, 6}, AxesLabel -> {h, None}, PlotLegends -> (Row[{"t = ", #}]& /@ Range[1, 4])]

一些时间序列过程的协方差函数：

Wolfram Language code:

proc1 = ARProcess[{.8}, 1];
proc2 = MAProcess[{-.4, -.7, .6, -1}, 1];
proc3 = SARMAProcess[{}, {}, {3, {.6}, {.1}}, 1];
proc4 = FARIMAProcess[{}, 1 / 3, {}, 1];

Wolfram Language code:

DiscretePlot[CovarianceFunction[#, h], {h, 0, 15}, ExtentSize -> 1 / 2, PlotRange -> All, PlotLabel -> Head[#]]& /@ {proc1, proc2, proc3, proc4}

向量 ARProcess 的互协方差图：

Wolfram Language code:

proc = ARProcess[{{{.3, .1}, {.6, .3}}}, {{1, .3}, {.3, .6}}];
cov = CovarianceFunction[proc, h];

Wolfram Language code: Table[DiscretePlot[cov[[i, j]], {h, -6, 6}, ExtentSize -> 1 / 2, PlotLabel -> {i, j}], {i, 1, 2}, {j, 1, 2}]

应用 (1)

确定下列数据是用 MAProcess 模拟还是用 ARProcess 模拟效果最好：

Wolfram Language code:

ListLinePlot[data = TemporalData[TimeSeries, {{{-1.4735257611469446, -0.9158187257309729, -1.9060205147226934, 
    -1.6174582169404574, -2.633459084244463, -2.104839842098871, -2.8701276893108894, 
    -2.4118183939601607, -0.5125633448622677, -1.2356329399850385, 1. ... 26394036266876, -0.16380797769527589, 0.3559909972777121, 
    1.5343047104249412, 0.10763337590714506}}, {{0, 100, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.1]]

很难从样本路径确定底层过程：

Wolfram Language code: candidates = {MAProcess[{.5, .4}, 1], ARProcess[{.5, .4}, 1]};

Wolfram Language code: SeedRandom[2];ListLinePlot[RandomFunction[#, {0, 100}]]& /@ candidates

数据的协方差函数缓慢衰减：

Wolfram Language code: ListPlot[CovarianceFunction[data, {10}], Filling -> 0]

显然，ARProcess 是一个比 MAProcess 更好的候选模型：

Wolfram Language code: ListPlot[CovarianceFunction[#, {10}], PlotLabel -> Head[#], Filling -> 0]& /@ candidates

属性和关系 (14)

样本协方差函数是过程协方差函数的有偏估计量：

Wolfram Language code:

proc = ARMAProcess[1, {5 / 6, -1 / 6}, {2 / 3}, 1];
paths = RandomFunction[proc, {0, n = 10}, 10 ^ 3];

计算样本协方差函数：

Wolfram Language code: CovarianceFunction[paths, {10}]

Wolfram Language code: scov = TimeSeriesMapThread[#2(n + 1) / (n + 1 - #1)&, %]

过程的协方差函数：

Wolfram Language code: cov = CovarianceFunction[proc, {10}]

绘制两个函数：

Wolfram Language code: ListPlot[{scov, cov}, Filling -> 0, PlotLegends -> {"sample covariance", "process covariance"}]

过程的协方差函数是 Covariance 矩阵的非对角线项：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];

Wolfram Language code: Covariance[𝒫[{s, t}], 1, 2]

Wolfram Language code: CovarianceFunction[𝒫, s, t]

Wolfram Language code: Simplify[%% - %, 0 < s < t]

滞后0的样本协方差函数是一个方差估计量：

Wolfram Language code:

data = Range[10];
evar1 = CovarianceFunction[data, 0]

利用 Variance 与估计比较：

Wolfram Language code: evar2 = Variance[data]

缩放因子是不同的：

Wolfram Language code: (10 evar1) / (9evar2)

样本协方差函数与 CorrelationFunction 有关：

Wolfram Language code: data = Range[10];

Wolfram Language code: CovarianceFunction[data, {9}]

经缩放的样本相关函数：

Wolfram Language code: CorrelationFunction[data, {9}] (CovarianceFunction[data, 0])

Wolfram Language code: % - %%

样本协方差函数与 AbsoluteCorrelationFunction 有关：

Wolfram Language code:

data = Range[10];
n = Length[data];

Wolfram Language code: CovarianceFunction[data, {n - 1}]

Wolfram Language code: AbsoluteCorrelationFunction[data - Mean[data], {n - 1}]

Wolfram Language code: % - %%

使用 Expectation 计算协方差函数：

Wolfram Language code:

𝒫 = WienerProcess[μ, σ];
m[s_] := Mean[𝒫[s]]

Wolfram Language code: Expectation[(x[s] - m[s])(x[t] - m[t]), x𝒫, Assumptions -> s > 0 && t > 0]

Wolfram Language code: CovarianceFunction[𝒫, s, t]

Wolfram Language code: Simplify[% - %%, 0 < s < t]

相同时间的协方差函数减少为 Variance：

Wolfram Language code: 𝒫 = OrnsteinUhlenbeckProcess[μ, σ, θ];

Wolfram Language code: CovarianceFunction[𝒫, t, t]

Wolfram Language code: Variance[𝒫[t]]

Wolfram Language code: % - %%

协方差函数与 AbsoluteCorrelationFunction 有关：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];

Wolfram Language code: AbsoluteCorrelationFunction[𝒫, s, t]

对于，均值函数为：

Wolfram Language code: CovarianceFunction[𝒫, s, t] + Mean[𝒫[s]] Mean[𝒫[t]]

Wolfram Language code: % - %%

协方差函数与 Covariance 有关：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];

Wolfram Language code: CovarianceFunction[𝒫, s, t]

这是协方差矩阵的非对角项：

Wolfram Language code: Covariance[𝒫[{s, t}], 1, 2]

Wolfram Language code: Simplify[%% - %, 0 < s < t]

协方差函数与 CorrelationFunction 有关：

Wolfram Language code:

𝒫 = PoissonProcess[μ];
sd[s_] := StandardDeviation[𝒫[s]]

Wolfram Language code: CorrelationFunction[𝒫, s, t]

对于，标准差函数为：

Wolfram Language code: CovarianceFunction[𝒫, s, t] / (sd[s] sd[t])

Wolfram Language code: % - %%//FullSimplify[#, s > 0 && t > 0]&

协方差函数对于 ToInvertibleTimeSeries 是不变的：

Wolfram Language code: TimeSeriesInvertibility[proc = MAProcess[{2, 4}, 1]]

Wolfram Language code: iproc = ToInvertibleTimeSeries@proc

Wolfram Language code: CovarianceFunction[#, s, t]& /@ {proc, iproc}

协方差函数对于集中化是不变的：

Wolfram Language code: data = RandomFunction[ARIMAProcess[{}, 1, {}, 1], {0, 100}];

数据的均值非零：

Wolfram Language code: Mean[data]

集中化数据：

Wolfram Language code: newdata = Standardize[data, Mean, 1&];

比较协方差函数：

Wolfram Language code: ListPlot[CovarianceFunction[#, {20}], Filling -> 0]& /@ {data, newdata}

时间序列的 PowerSpectralDensity 是协方差函数的变换：

Wolfram Language code:

proc = ARProcess[c, {a}, σ^2];
cf = CovarianceFunction[proc, h]

使用 FourierSequenceTransform：

Wolfram Language code: ft = FourierSequenceTransform[cf, h, z]

与幂谱比较：

Wolfram Language code: PowerSpectralDensity[proc, z]

Wolfram Language code: FullSimplify[% - ft]

数据的 PowerSpectralDensity 是样本协方差函数的变换：

Wolfram Language code:

sample = Range[20];
n = Length[sample];
cov = CovarianceFunction[sample, {n - 1}];
cov = Join[Reverse[Rest[cov]], cov];

应用 ListFourierSequenceTransform：

Wolfram Language code: ListFourierSequenceTransform[cov, w, -n + 1]//ExpToTrig

与 SamplePowerSpectralDensity 比较：

Wolfram Language code: PowerSpectralDensity[sample, w]

Wolfram Language code: % - %%//FullSimplify

可能存在的问题 (1)

CovarianceFunction 输出可包含 DifferenceRoot：

Wolfram Language code: CovarianceFunction[ARProcess[{a, b}, σ^2], t] //Simplify[#, t > 0]&

使用 FunctionExpand 来恢复显式的幂：

Wolfram Language code: %//FunctionExpand

Top

	τ	在时刻或滞后 τ
	{τ_max}	从 0 到 τ_max 的间距单位
	{τ_min,τ_max}	从 τ_min 到 τ_max 的间距单位
	{τ_min,τ_max,d τ}	步长为 d τ，从 τ_min 到 τ_max
	{{τ₁,τ₂,…}}	使用显式 {τ₁,τ₂,…}

	Expectation[(x[s]-μ[s])(x[t]-μ[t])]	对于标量值过程
	Expectation[(x[s]-μ[s])⊗(x[t]-μ[t])]	对于向量值过程

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

CovarianceFunction

更多信息

范例

基本范例 (4)

范围 (13)

经验估计 (7)

随机过程 (6)

应用 (1)

属性和关系 (14)

可能存在的问题 (1)

文本

CMS

APA

BibTeX

BibLaTeX

	(x_i+h- )(x_i-)	对于标量值数据
		对于向量值数据

CovarianceFunction

更多信息

范例

基本范例 (4)

范围 (13)

经验估计 (7)

随机过程 (6)

应用 (1)

属性和关系 (14)

可能存在的问题 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX