WOLFRAM

Wolfram 语言与系统参考资料中心

CramerVonMisesTest[data]

使用 Cramér–von Mises 检验对 data 是否服从正态分布进行校验.

CramerVonMisesTest[data,dist]

使用 Cramér–vonMises 检验对 data 是否服从 dist 进行校验.

CramerVonMisesTest[data,dist,"property"]

返回 "property" 的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
检验  
报告  
选项  
Method  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

CramerVonMisesTest

CramerVonMisesTest[data]

使用 Cramér–von Mises 检验对 data 是否服从正态分布进行校验.

CramerVonMisesTest[data,dist]

使用 Cramér–vonMises 检验对 data 是否服从 dist 进行校验.

CramerVonMisesTest[data,dist,"property"]

返回 "property" 的值.

更多信息和选项

  • CramerVonMisesTest 执行 Cramér–von Mises拟合优度检验，其中零假设 为 data 从服从分布 dist 的总体中抽取，而备择假设 认为并不服从.
  • 默认情况下，返回一个概率值或者 值.
  • 一个较小的 值表明 data 不可能服从 dist.
  • dist 可以是任意具有数值和符号参数或者数据集的符号分布.
  • data 可以是单变量 {x1,x2,…} 或者多变量 {{x1,y1,…},{x2,y2,…},…}.
  • Cramér–von Mises 检验假设数据来自一个连续分布.
  • Cramér–von Mises 检验实际上使用基于 的期望值的检验统计量，其中 是 data 的经验累积分布函数，而 是 dist 的累积分布函数.
  • 对于单变量数据，检验统计量由 给出.
  • 对于多变量检验，使用单变量边缘 值的和，并且在 下假设它服从 UniformSumDistribution.
  • CramerVonMisesTest[data,dist,"HypothesisTestData"] 返回一个 HypothesisTestData 对象 htd，通过使用htd["property"] 的形式，它可以用来提取额外的检验结果和属性.
  • CramerVonMisesTest[data,dist,"property"] 可以用来直接给出 "property" 的值.
  • 与检验结果的报告相关的属性包括：
  • "PValue"-值
    "PValueTable""PValue" 的格式化版本
    "ShortTestConclusion"一个检验结论的简短描述
    "TestConclusion"一个检验结论的描述
    "TestData"检验统计量和 值
    "TestDataTable""TestData" 的格式化版本
    "TestStatistic"检验统计量
    "TestStatisticTable"格式化的 "TestStatistic"
  • 下列属性与所执行的检验类型无关.
  • 与数据分布相关的属性包括：
  • "FittedDistribution"数据的拟合分布
    "FittedDistributionParameters"数据的分布参数
  • 可以给出下列选项：
  • Method Automatic计算 值所用的方法
    SignificanceLevel0.05诊断和报告的分界点
  • 对于一个拟合优度检验，选择一个临界值 ，以使得只有当 时，否定 . 用于 "TestConclusion" 和 "ShortTestConclusion" 属性的 值由 SignificanceLevel 选项控制. 默认情况下， 设为 0.05.
  • 在设置 Method->"MonteCarlo" 下，在 下使用拟合分布，生成 个与输入 si 具有相同长度的数据集. 来自CramerVonMisesTest[si,dist,"TestStatistic"] 的经验分布用于估计 值.

范例

打开所有单元 关闭所有单元

基本范例  (3)

执行 Cramér-von Mises 检验对正态性进行校验：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^4];
Wolfram Language code: CramerVonMisesTest[data]

使用 QuantilePlot 对结果进行确认：

Wolfram Language code: QuantilePlot[data]

比较一些数据对一个特定分布的拟合情况：

Wolfram Language code: data = RandomVariate[LaplaceDistribution[1, 2], 10^3];
Wolfram Language code: Show[SmoothHistogram[data, PlotStyle -> ColorData[97, 2]], Plot[PDF[LaplaceDistribution[1, 2], x], {x, -10, 10}, PlotStyle -> Dashed]]
Wolfram Language code: CramerVonMisesTest[data, LaplaceDistribution[1, 2]]

比较两个数据集合的分布：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: data2 = RandomVariate[NormalDistribution[], 150];
Wolfram Language code: SmoothHistogram[{data1, data2}]
Wolfram Language code: CramerVonMisesTest[data1, data2]

范围  (9)

检验  (6)

执行 Cramér-von Mises 检验对正态性进行校验：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 10^4]; data2 = RandomVariate[StudentTDistribution[3], 10^4];

正态数据的 值相对于非正态数据的 值来说，显得比较大：

Wolfram Language code: CramerVonMisesTest[data1]
Wolfram Language code: CramerVonMisesTest[data2]

检验一个特定分布的拟合优度：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 10^3]; data2 = RandomVariate[CauchyDistribution[0, 1], 10^3];
Wolfram Language code: CramerVonMisesTest[data1, CauchyDistribution[0, 1]]
Wolfram Language code: CramerVonMisesTest[data2, CauchyDistribution[0, 1]]

比较两个数据集的分布：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 10^3]; data2 = RandomVariate[NormalDistribution[], 10^3];
Wolfram Language code: CramerVonMisesTest[data1, data2]

这两个数据集不具有相同的分布：

Wolfram Language code: data3 = RandomVariate[NormalDistribution[0, 1.25], 10^3];
Wolfram Language code: CramerVonMisesTest[data1, data3]

检验多元正态性：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 10^3]; data2 = RandomVariate[LaplaceDistribution[1, 2], {10^3, 2}];
Wolfram Language code: CramerVonMisesTest[data1]
Wolfram Language code: CramerVonMisesTest[data2]

检验任意多变量分布的拟合优度：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 10^3]; data2 = RandomVariate[𝒹 = LaplaceDistribution[1, 2], {10^3, 2}];
Wolfram Language code: 𝒟 = ProductDistribution[𝒹, 𝒹];
Wolfram Language code: CramerVonMisesTest[data1, 𝒟]
Wolfram Language code: CramerVonMisesTest[data2, 𝒟]

创建一个 HypothesisTestData 对象以进行重复属性提取：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10];
Wolfram Language code: ℋ = CramerVonMisesTest[data, Automatic, "HypothesisTestData"]

可用于提取的属性：

Wolfram Language code: ℋ["Properties"]

报告  (3)

将 Cramér-von Mises 检验的结果制作成表格：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: ℋ = CramerVonMisesTest[data, Automatic, "HypothesisTestData"];

完全检验表：

Wolfram Language code: ℋ["TestDataTable"]

一个 值表：

Wolfram Language code: ℋ["PValueTable"]

检验统计量：

Wolfram Language code: ℋ["TestStatisticTable"]

从 Cramér-von Mises 检验表中提取项目，用于生成定制的报告：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 100]; data2 = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: ℋ1 = CramerVonMisesTest[data1, Automatic, "TestData"]
Wolfram Language code: ℋ2 = CramerVonMisesTest[data2, Automatic, "TestData"]
Wolfram Language code: BarChart[{Labeled[ℋ1, "Set 1"], Labeled[ℋ2, "Set 2"]}, ChartLabels -> {"SuperscriptBox[ω, 2]", "p‐value"}]

使用 "ShortTestConclusion" 和 "TestConclusion" 报告检验结论：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[ParetoDistribution[1.05, 2], 100]];
Wolfram Language code: ℋ = CramerVonMisesTest[data, ParetoDistribution[1, 2], "HypothesisTestData"];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

结论在不同的显著性水平上可能是不同的：

Wolfram Language code: ℋ = CramerVonMisesTest[data, ParetoDistribution[1, 2], "HypothesisTestData", SignificanceLevel -> .001];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

选项  (3)

Method  (3)

使用基于蒙特卡罗的方法或者一个可计算的公式：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: CramerVonMisesTest[data, NormalDistribution[], Method -> "MonteCarlo"]
Wolfram Language code: CramerVonMisesTest[data, NormalDistribution[], Method -> Automatic]

对于基于蒙特卡罗的方法，设置样本数：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: pts = Table[{i, CramerVonMisesTest[data, NormalDistribution[], Method -> {"MonteCarlo", "MonteCarloSamples" -> i}]}, {i, Range[5, 100, 5]}];

当样本数增加时，蒙特卡罗估计量收敛到真实的 值：

Wolfram Language code: pval = CramerVonMisesTest[data, NormalDistribution[]];
Wolfram Language code: Show[ListLinePlot[pts, PlotRange -> {0, 1}, FrameLabel -> {"Samples", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {100, pval}}]}]]

设置在蒙特卡罗方法中所使用的随机种子：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: pts = Table[{i, CramerVonMisesTest[data, NormalDistribution[], Method -> {"MonteCarlo", "RandomSeed" -> i, "MonteCarloSamples" -> 50}]}, {i, Range[1, 10]}];

种子对生成器的状态有影响，而且对所得的 值也有一定影响：

Wolfram Language code: pval = CramerVonMisesTest[data, NormalDistribution[]];
Wolfram Language code: Show[ListLinePlot[pts, PlotRange -> {Min[pts[[All, 2]]], Max[pts[[All, 2]]]}, FrameLabel -> {"Seed", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {100, pval}}]}]]

应用  (3)

Cramér-von Mises 检验的功效曲线：

Wolfram Language code: data = Table[RandomVariate[UniformDistribution[{-4, 4}], {500, i}], {i, n = {7, 10, 15, 20, 25, 30, 50}}];
Wolfram Language code: ℋ = Table[CramerVonMisesTest[data[[i, j]], NormalDistribution[]], {i, Length[data]}, {j, Length[data[[i]]]}];
Wolfram Language code: pC = Interpolation[Transpose[{n, Table[Probability[x ≤ 0.05, xi], {i, ℋ}]}], InterpolationOrder -> 1];

将近似的功效曲线可视化：

Wolfram Language code: Plot[pC[x], {x, 7, 50}, PlotRange -> {0, 1}, Ticks -> {n, Automatic}, AxesOrigin -> {0, 0}]

当内在的分布为 UniformDistribution[{-4, 4}]，检验尺度为 0.05，而样本大小为 32，估计 Cramér–von Mises 检验的功效：

Wolfram Language code: pC[32.]

由齐次泊松过程生成的观测数据应该表现出完全的空间随机性，这意味着它们从一个均匀分布中抽取. 判断从下面的图像中抽取的观测数据是否应该使用齐次泊松过程建模：

Wolfram Language code: img1 = [image];img2 = [image];
Wolfram Language code: m = MorphologicalComponents[Binarize[#, {0, .7}]]& /@ {img1, img2};

求每个点的中心，并且缩放至 的区间上：

Wolfram Language code: locs = ComponentMeasurements[#, "Centroid"][[All, 2]]& /@ m;
Wolfram Language code: s1 = MapThread[Rescale[#1, {0, #2}]&, {locs[[1]], ImageDimensions[img1]}]; s2 = MapThread[Rescale[#1, {0, #2}]&, {locs[[2]], ImageDimensions[img2]}];

第一个图像上的点应该使用齐次泊松过程建模：

Wolfram Language code: CramerVonMisesTest[s1, UniformDistribution[{{0, 1}, {0, 1}}], "TestDataTable"]

第二组数据的模型应该考虑独立性：

Wolfram Language code: CramerVonMisesTest[s2, UniformDistribution[{{0, 1}, {0, 1}}], "TestDataTable"]

求最小化 Cramér-von Mises 检验统计量的分布参数：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: f[μ_ ? NumericQ, σ_ ? NumericQ, dist_] := CramerVonMisesTest[data, dist[μ, σ], "TestStatistic"]
Wolfram Language code: par = FindMinimum[f[μ, σ, NormalDistribution], {{μ}, {σ}}]

将结果与 FindDistributionParameters 比较：

Wolfram Language code: estPar = FindDistributionParameters[data, NormalDistribution[μ, σ]]
Wolfram Language code: Show[Plot3D[f[μ, σ, NormalDistribution], {μ, -3, 3}, {σ, 0, 6}, PlotStyle -> Directive[Opacity[0.5]], PlotRange -> {{-2, 2}, {0, 3}, {-10, 35}}], Graphics3D[{Red, Tube[{{μ, σ, 40}, {μ, σ, -20}} /. par[[2]], .05]}], Graphics3D[{Green, Tube[{{μ, σ, 40}, {μ, σ, -20}} /. estPar, .05]}], AspectRatio -> 1]

属性和关系  (8)

默认情况下，单变量数据与 NormalDistribution 相比较：

Wolfram Language code: data = RandomVariate[NormalDistribution[2, 3], 10];
Wolfram Language code: ℋ = CramerVonMisesTest[data, Automatic, "HypothesisTestData"];
Wolfram Language code: ℋ["TestDataTable"]

参数已经从数据中估计得到：

Wolfram Language code: ℋ["FittedDistribution"]

默认情况下，多变量数据与 MultinormalDistribution 相比较：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{1, 2, 3}, IdentityMatrix[3]], 1000];
Wolfram Language code: ℋ = CramerVonMisesTest[data, Automatic, "HypothesisTestData"];
Wolfram Language code: ℋ["TestDataTable"]
Wolfram Language code: ℋ["FittedDistribution"]//TraditionalForm

若未指明，则检验分布的参数由数据中估计得到：

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2], 1000];
Wolfram Language code: CramerVonMisesTest[data, NormalDistribution[μ, σ], "FittedDistribution"]

不估计指定的参数：

Wolfram Language code: CramerVonMisesTest[data, NormalDistribution[μ, 2], "FittedDistribution"]
Wolfram Language code: CramerVonMisesTest[data, NormalDistribution[1, 2], "FittedDistribution"]

对检验分布的未指明的参数，使用最大似然估计法：

Wolfram Language code: data = RandomVariate[ExponentialDistribution[3], 10^3];
Wolfram Language code: ℋ = CramerVonMisesTest[data, ExponentialDistribution[λ], "FittedDistribution"]
Wolfram Language code: CramerVonMisesTest[data, ExponentialDistribution[λ]]

如果参数未知，则当可能的情况下，CramerVonMisesTest 应用一次校正：

Wolfram Language code: data = RandomVariate[NormalDistribution[3, 4], 10^4];
Wolfram Language code: est = EstimatedDistribution[data, NormalDistribution[μ, σ]]

估计参数，但不校正：

Wolfram Language code: CramerVonMisesTest[data, est]
Wolfram Language code: ℋ = CramerVonMisesTest[data, NormalDistribution[μ, σ], "HypothesisTestData"];

拟合分布与之前的相同，而且 值被校正：

Wolfram Language code: ℋ["FittedDistribution"]
Wolfram Language code: ℋ["PValue"]

在多变量拟合优度的检验中，假设边缘密度是独立的：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{0, 0}, {{0.118, 0.252}, {0.252, 0.665}}], 100];
Wolfram Language code: CramerVonMisesTest[data, MultinormalDistribution[{0, 0}, {{0.118, 0.252}, {0.252, 0.665}}], "TestStatistic"]

假设独立的情况下，检验统计量是相同的：

Wolfram Language code: CramerVonMisesTest[data, MultinormalDistribution[{0, 0}, {{0.118, 0}, {0, 0.665}}], "TestStatistic"]

可以使用 NExpectation 定义 Cramér–von Mises 统计量：

Wolfram Language code: n = 10; h0 = NormalDistribution[1, 2]; data = RandomVariate[h0, n];
Wolfram Language code: f[x_] := CDF[h0, x] Overscript[f, ^ ][x_] := CDF[EmpiricalDistribution[data], x]
Wolfram Language code: n NExpectation[(Overscript[f, ^ ][t] - f[t])^2, th0]
Wolfram Language code: CramerVonMisesTest[data, h0, "TestStatistic"]

Cramér–von Mises 检验仅在输入为 TimeSeries 时适用于值：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: CramerVonMisesTest[ts]
Wolfram Language code: CramerVonMisesTest[ts["Values"]]

可能存在的问题  (3)

Cramér–von Mises 检验不用于离散分布：

Wolfram Language code: data = RandomVariate[PoissonDistribution[30], 35];
Wolfram Language code: CramerVonMisesTest[data, PoissonDistribution[30]]

连续性校正对于保持检验大小非常有效：

Wolfram Language code: sim = RandomVariate[PoissonDistribution[30], {500, 35}];
Wolfram Language code: p = Quiet[CramerVonMisesTest[#, PoissonDistribution[30]]]& /@ sim;
Wolfram Language code: Show[ListLinePlot[Table[{α, Probability[pv ≤ α, pvp]}, {α, .01, 1, .01}]], Plot[x, {x, 0, 1}, PlotStyle -> Dashed]]

在某些情况下，并非如此：

Wolfram Language code: sim = RandomVariate[DiscreteUniformDistribution[{1, 3}], {500, 35}];
Wolfram Language code: p = Quiet[CramerVonMisesTest[#, DiscreteUniformDistribution[{1, 3}]]]& /@ sim;
Wolfram Language code: Show[ListLinePlot[Table[{α, Probability[pv ≤ α, pvp]}, {α, .01, 1, .01}]], Plot[x, {x, 0, 1}, PlotStyle -> Dashed]]

在这些情况下，应该使用蒙特卡洛方法或者 PearsonChiSquareTest：

Wolfram Language code: CramerVonMisesTest[sim[[1]], DiscreteUniformDistribution[{1, 3}], Method -> "MonteCarlo"]
Wolfram Language code: PearsonChiSquareTest[sim[[1]], DiscreteUniformDistribution[{1, 3}]]

当参数已经从数据中估计得到时，对于某些分布，Cramér-von Mises 检验是无效的：

Wolfram Language code: data = RandomVariate[BetaDistribution[1, 2], 100];
Wolfram Language code: CramerVonMisesTest[data, BetaDistribution[1, b]]

提供已知的参数值：

Wolfram Language code: CramerVonMisesTest[data, BetaDistribution[1, 2]]

或者，使用蒙特卡罗方法来求近似 值：

Wolfram Language code: CramerVonMisesTest[data, BetaDistribution[1, b], Method -> "MonteCarlo"]

为了得到有效的 值，Cramér–von Mises检验要求样本数至少为 7：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 5];
Wolfram Language code: DistributionFitTest[data, Automatic, "CramerVonMises"]

使用蒙特卡罗方法得到一个有效的 值：

Wolfram Language code: DistributionFitTest[data, Automatic, "CramerVonMises", Method -> "MonteCarlo"]

巧妙范例  (1)

计算零假设 为真时的统计量：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2500, 100}];
Wolfram Language code: T1 = CramerVonMisesTest[#, NormalDistribution[], "TestStatistic"]& /@ data;

给出特定选择时的检验统计量：

Wolfram Language code: T2 = CramerVonMisesTest[#, NormalDistribution[.5, 2], "TestStatistic"]& /@ data;

比较检验统计量的分布：

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}]
Wolfram Research (2010)，CramerVonMisesTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CramerVonMisesTest.html.

文本

Wolfram Research (2010)，CramerVonMisesTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CramerVonMisesTest.html.

CMS

Wolfram 语言. 2010. "CramerVonMisesTest." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CramerVonMisesTest.html.

APA

Wolfram 语言. (2010). CramerVonMisesTest. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CramerVonMisesTest.html 年

BibTeX

@misc{reference.wolfram_2026_cramervonmisestest, author="Wolfram Research", title="{CramerVonMisesTest}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/CramerVonMisesTest.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cramervonmisestest, organization={Wolfram Research}, title={CramerVonMisesTest}, year={2010}, url={https://reference.wolfram.com/language/ref/CramerVonMisesTest.html}, note=[Accessed: 10-September-2026]}