WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DifferenceRoot[lde][k]

線形差分方程式 lde[h,k]で指定されたホロノミック数列 を与える．

DifferenceRoot[lde]

純ホロノミック数列 を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
可視化  
関数の特性  
特殊数列  
微分  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

DifferenceRoot

DifferenceRoot[lde][k]

線形差分方程式 lde[h,k]で指定されたホロノミック数列 を与える．

DifferenceRoot[lde]

純ホロノミック数列 を与える．

詳細

  • 記号操作と数値操作の両方に適した数学的数列である．ホロノミック数列およびP再帰数列としても知られている．
  • DifferenceRoot関数で定義されるホロノミック数列 は，多項係数 を持ち，初期値が の，ホロノミック差分方程式 を満足する．
  • DifferenceRootは他の任意の数学関数と同じように使うことができる．
  • FunctionExpandはDifferenceRoot関数を特殊関数によって変換しようとする．
  • DifferenceRootで表される数列には，多くの特殊数列が含まれる．
  • DifferenceRootReduceは多くの特殊数列をDifferenceRoot数列に変換することができる．
  • ホロノミック数列は，以下を含む多くの操作の下で閉じている．
  • , 定数倍，整数ベキ
    , 和と積
    離散たたみ込み
    , , 離散シフト，差と和
  • DifferenceRootは，Sum，RSolve，SeriesCoefficient等の関数によって，自動的に生成される．
  • Sum，DifferenceDelta，GeneratingFunction等の関数には，DifferenceRoot入力を使うことができる．
  • DifferenceRootは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (2)

fがフィボナッチ(Fibonacci)数列であると定義する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]

20番目のフィボナッチ数を計算する：

Wolfram Language code: f[20]

結果を組込みのFibonacci関数と比較する：

Wolfram Language code: Fibonacci[20]

最初の10個のフィボナッチ数をプロットする：

Wolfram Language code: DiscretePlot[f[n], {n, 0, 10}]

関数の中にはDifferenceRoot関数を使って閉形式の答を作ることができるものもある：

Wolfram Language code: Sum[(n + 4)!2 ^ n, n]
Wolfram Language code: RSolve[y[n + 3] + n y[n + 2] + y[n] == n! && y[0] == y[1] == y[2] == 1, y[n], n]
Wolfram Language code: SeriesCoefficient[Exp[(1/x^2 + 1)], {x, 0, n}]

スコープ  (21)

数値評価  (6)

DifferenceRoot数列を定義する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == (n + 1)y[n], y[1] == 1}]]

任意の点で評価する：

Wolfram Language code: f[20]

数列を非厳密な係数で評価する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {3.5 y[n + 1] == (n + 1)y[n], y[1] == 1}]][{3, 5, 10}]

数列を複素係数で評価する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] - (n + 1)y[n], y[0] == 1 + 2I, y[1] == -3 + 2I}]][4]

数列をパラメータで評価する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == x y[n + 1] - (n + 1)y[n], y[0] == 1, y[1] == -3}]][4]

数列を負の項について評価する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] - y[n], y[0] == 1, y[1] == 1 / 3}]][-5]

DifferenceRootは要素単位でリストと行列に縫い込まれる：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] / (n + 1) - y[n] == 0, y[0] == 0, y[1] == 1}]][{1, 2, 3, 4, 5}]
Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] / (n + 1) - y[n] == 0, y[-1] == 1, y[1] == 1}]][(| | | | :- | :- | | 3 | -1 | | -2 | 6 |)]

可視化  (2)

f というDifferenceRootオブジェクトを定義する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] - 1 / 2y[n], y[0] == 0, y[1] == 1}]]

f の最初の10項をプロットする：

Wolfram Language code: DiscretePlot[f[n], {n, 0, 15}]

f の最初の25項をListLinePlotを使ってプロットする：

Wolfram Language code: ListLinePlot[Table[f[n], {n, 1, 25}], PlotRange -> All]

f というDifferenceRootオブジェクトを定義する，パラメータ a は任意でもよい：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == a y[n + 1] - 1 / 2y[n], y[0] == 0, y[1] == 1}]]

数列 f をパラメータ a のさまざまな値についてプロットする：

Wolfram Language code: DiscretePlot3D[f[n], {n, 3, 10}, {a, -1, 1, 1 / 10}, AxesLabel -> Automatic]

関数の特性  (9)

DifferenceRootは，線形再帰方程式に使うことができる：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] - n y[n] == 0, y[0] == 0, y[1] == 1}]]

DifferenceRootは，有理係数を持つ再帰方程式を多項式係数を持つ形に変換する：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] / (n + 1) - y[n] == 0, y[0] == 0, y[1] == 1}]]

非同次再帰方程式は，より高次の同次再帰方程式に変換される：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] - n y[n] == n!, y[1] == 1}]]

DifferenceRootは多項式強制関数を持つ非同次方程式に使うことができる：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] - y[n] == n ^ 2, y[0] == 0, y[1] == 1}]]

非同次数列の最初の10項を計算する：

Wolfram Language code: Table[f[n], {n, 1, 10}]

DifferenceRootは複数の初期値で使うことができる：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {-n y[n] + (1 + n)y[1 + n] == 0, y[-1] == 0, y[1] == 1}]]

記号成分を持つ数列についての差分関数：

Wolfram Language code: DifferenceRootReduce[Fibonacci[n, x], n]
Wolfram Language code: Table[%, {n, 10}]

がInfinityに近付くときのDifferenceRootオブジェクトの最高次の漸近項を求める：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] - n ^ 2 y[n] == 0, y[1] == 1}]][n]
Wolfram Language code: DiscreteAsymptotic[f, n -> ∞]

AsymptoticRSolveValueを使って同じ結果を得る：

Wolfram Language code: AsymptoticRSolveValue[{y[n + 1] - n ^ 2 * y[n] == 0, y[1] == 1}, y[n], n -> ∞]

DifferenceRootはパラメータを取ることができる：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == a y[n + 1] - 1 / 2y[n], y[0] == 0, y[1] == 1}]]

この数列の最初の5つの項を記号的な a について計算する：

Wolfram Language code: Table[f[n], {n, 1, 5}]

パラメータ a を指定する：

Wolfram Language code: % /. a -> -1 / 10

数列 f をパラメータ a のさまざまな値についてプロットする：

Wolfram Language code: DiscretePlot3D[f[n], {n, 2, 10}, {a, -1, 1, 1 / 10}, AxesLabel -> Automatic]

可能な場合は，DifferenceRootは組込み関数に縮退する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]
Wolfram Language code: FullSimplify[f[n]]

特殊数列  (3)

Fibonacciからの差分方程式：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]
Wolfram Language code: FullSimplify[f[n]]

LucasLからの差分方程式：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 2, y[1] == 1}]]
Wolfram Language code: FullSimplify[f[n]]

HarmonicNumberからの差分方程式：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {(n + 1)y[n + 1] == (n + 1) y[n] + 1, y[0] == 0}]]
Wolfram Language code: FullSimplify[f[n]]

微分  (1)

ChebyshevT多項式に対応するパラメトリック数列を生成する：

Wolfram Language code: ChebTSequence = DifferenceRootReduce[ChebyshevT[n, x], n]

この数列のパラメータについての導関数を計算する：

Wolfram Language code: dChebTSequence = D[ChebTSequence, x]

ChebyshevTの導関数が従う差分方程式を抽出する：

Wolfram Language code: %[[0, 1]][y, n]

この数列の最初の10項とChebyshevTの直接導関数の等価性をチェックする：

Wolfram Language code: Table[Expand[dChebTSequence == D[ChebyshevT[n, x], x]], {n, 0, 10}]

一般化と拡張  (2)

ホロノミックな定数項を持つ方程式は自動的に多項式係数に上げられる：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] - y[n] == n!, y[0] == 1}]]

次の関数は n>0については定義されない：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {n y[1 + n] + (-1 + n) y[n] == 0, y[-1] == -1}]];
Wolfram Language code: Table[f[n], {n, -2, 2}]

すべての n について定義されるように初期値 y[1]=2を加える：

Wolfram Language code: g = DifferenceRoot[Function[{y, n}, {n y[1 + n] + (-1 + n) y[n] == 0, y[1] == 2, y[-1] == -1}]];
Wolfram Language code: Table[g[n], {n, -2, 2}]

アプリケーション  (7)

DifferenceRootを使ってHarmonicNumberの差分方程式形式を得る：

Wolfram Language code: DifferenceRootReduce[HarmonicNumber[k], k]

特殊数列の組合せを簡約してDifferenceRoot形式にする：

Wolfram Language code: f = DifferenceRootReduce[Fibonacci[n] + 2LucasL[n] + n ^ 2, n]

f を任意の数列にように使う：

Wolfram Language code: Table[f, {n, 0, 5}]
Wolfram Language code: Table[Fibonacci[n] + 2LucasL[n] + n ^ 2, {n, 0, 5}]

DifferenceRootを使ってペル(Pell)数列を定義する：

Wolfram Language code: PellNumber = DifferenceRoot[Function[{y, n}, {-y[n] - 2y[1 + n] + y[2 + n] == 0, y[0] == 0, y[1] == 1}]]

これを任意の数列のように使う：

Wolfram Language code: Table[PellNumber[n], {n, 0, 5}]

ペル数の特性を証明する：

Wolfram Language code: FullSimplify[PellNumber[n + 1]PellNumber[n - 1] - PellNumber[n] ^ 2 == (-1) ^ n]

閉じた形の式：

Wolfram Language code: DifferenceRootReduce[PellNumber[n] == (-(1 - Sqrt[2]) ^ n + (1 + Sqrt[2]) ^ n) / (2Sqrt[2]), n]

総和恒等式：

Wolfram Language code: DifferenceRootReduce[Sum[PellNumber[i], {i, 0, 4n + 1}] == (PellNumber[2n] + PellNumber[2n + 1]) ^ 2, n]

特殊数列の組合せを簡約してDifferenceRootにする：

Wolfram Language code: f = DifferenceRootReduce[Fibonacci[n] ^ 2, n]

これをプロットする：

Wolfram Language code: DiscretePlot[f, {n, -5, 5}]

テイラー(Taylor)展開が与えられたDifferenceRootオブジェクトである関数を生成する：

Wolfram Language code: GeneratingFunction[DifferenceRoot[Function[{y, n}, {y[n] + y[n + 1] + (1 + n) (2 + n) y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, x]

結果を検証する：

Wolfram Language code: SeriesCoefficient[%, {x, 0, n}]

BesselJ 関数を生成するDifferenceRootオブジェクトを生成する：

Wolfram Language code: f = BesselJ[k, z];
Wolfram Language code: DifferenceRootReduce[f, k]

fをフィボナッチ数列として定義する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]

最初の30個のフィボナッチ数の和を計算する：

Wolfram Language code: Sum[f[n], {n, 30}]

フィボナッチ数列の母関数 を求める：

Wolfram Language code: F[x_] = GeneratingFunction[f[n], n, x]

の級数展開の最初の10個の係数を求める：

Wolfram Language code: Table[SeriesCoefficient[F[x], {x, 0, n}], {n, 0, 10}]

結果を最初の10個のフィボナッチ数と比較する：

Wolfram Language code: Fibonacci[Table[n, {n, 0, 10}]]

特性と関係  (14)

DifferenceRootReduceを使ってDifferenceRootオブジェクトを生成する：

Wolfram Language code: f = DifferenceRootReduce[Fibonacci[n], n]

対応する常差分方程式を得る：

Wolfram Language code: oΔe = First[Head[f]][y, n]

この方程式を使って解を証明する：

Wolfram Language code: oΔe /. y -> Fibonacci//FullSimplify

DifferenceRootオブジェクトの総和：

Wolfram Language code: Sum[DifferenceRoot[Function[{y, n}, {-y[n] - y[n + 1] + y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n]
Wolfram Language code: Table[%, {n, 1, 10}]
Wolfram Language code: Accumulate[Table[Fibonacci[n], {n, 0, 9}]]

GeneratingFunctionは，ホロノミック数列からDifferentialRootオブジェクトを生成することがある：

Wolfram Language code: GeneratingFunction[DifferenceRoot[Function[{y, n}, {y[n] + (1 + n) (2 + n) y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, x]

特別なケースについては，GeneratingFunctionが明示的な関数を与えるかもしれない：

Wolfram Language code: GeneratingFunction[DifferenceRoot[Function[{y, n}, {-y[n] - y[n + 1] + y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, z]

DifferenceRootオブジェクトの指数母関数を求める：

Wolfram Language code: ExponentialGeneratingFunction[DifferenceRoot[Function[{y, n}, {-y[n] - y[n + 1] + y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, z]

差分方程式の解はDifferenceRootオブジェクトかもしれない：

Wolfram Language code: RSolve[a[1 + n] == a[n] + n a[n - 1] + n! && a[0] == 1 && a[1] == 2, a, n]

Sumからの結果はDifferenceRootオブジェクトかもしれない：

Wolfram Language code: Sum[(n + 4)! 2^n, n]

関数を展開した際の係数はDifferenceRootオブジェクトとして与えられるかもしれない：

Wolfram Language code: SeriesCoefficient[Exp[Sqrt[x + 1]], {x, 0, n}]

FindSequenceFunctionからの結果はDifferenceRootオブジェクトかもしれない：

Wolfram Language code: FindSequenceFunction[{2, 3 / 2, 7 / 3, 13 / 4, 26 / 5, 49 / 6, 92 / 7, 169 / 8, 307 / 9, 551 / 10, 980 / 11, 1729 / 12, 3030 / 13, 5279 / 14, 9151 / 15, 15793 / 16, 27150 / 17, 46513 / 18, 79440 / 19, 135301 / 20}, n]

FunctionExpandはDifferenceRootについてより簡単な式を生成しようとする：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]
Wolfram Language code: FunctionExpand[f[n]]

FunctionExpandはパラメトリック数列についてより簡単な式を生成しようとする：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == a y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]
Wolfram Language code: FunctionExpand[f[n]]

f がホロノミック数列であると定義する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == 3y[n], y[1] == 7}]][{1, 2, 3, 4, 5}]

結果をRecurrenceTableの出力と比較する：

Wolfram Language code: RecurrenceTable[{y[n + 1] == 3y[n], y[1] == 7}, y, {n, 1, 5}]

DiscreteShiftはDifferenceRoot関数を取ってシフトされた数列を生成する：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == (n + 2) y[n], y[1] == 1}]]
Wolfram Language code: f[{1, 2, 3, 4, 5}]
Wolfram Language code: ds = DiscreteShift[f[n], n]
Wolfram Language code: ds /. n -> {1, 2, 3, 4, 5}

DifferenceDeltaはDifferenceRoot関数を入力として取る：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == n ^ 2 y[n], y[1] == 1}]]
Wolfram Language code: dd = DifferenceDelta[f[n], n]

この式を簡約する：

Wolfram Language code: dd//FunctionExpand

考えられる問題  (2)

DifferenceRootは多項式係数がある線形微分方程式しか評価しない：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {(Sqrt[n] + 1)y[n + 1] - y^2[n] == 0, y[0] == 0, y[1] == 1}]]

DifferenceRootは整数項しか評価しない：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == (n + 1)y[n], y[1] == 1}]]
Wolfram Language code: f[3 / 2]

おもしろい例題  (1)

DifferenceRoot関数を定義する：

Wolfram Language code: PadovanNumber = DifferenceRoot[Function[{y, n}, {y[n + 3] - y[n + 1] - y[n] == 0, y[0] == 1, y[1] == 1, y[2] == 1}]]

これをプロットする：

Wolfram Language code: DiscretePlot[PadovanNumber[n], {n, 0, 20}]

恒等式を証明する：

Wolfram Language code: DifferenceRootReduce[PadovanNumber[k] == PadovanNumber[k - 2] + PadovanNumber[k - 4] + PadovanNumber[k - 8], k]
Wolfram Language code: DifferenceRootReduce[Sum[PadovanNumber[2k + 1], {k, 0, n}] == PadovanNumber[2n + 4] - 1, n]

展開してあまり一般的ではない関数にしようとする：

Wolfram Language code: g = FunctionExpand[PadovanNumber[n]]
Wolfram Language code: DiscretePlot[g, {n, 0, 20}]
Wolfram Research (2008), DifferenceRoot, Wolfram言語関数， https://reference.wolfram.com/language/ref/DifferenceRoot.html （2020年に更新）.

テキスト

Wolfram Research (2008), DifferenceRoot, Wolfram言語関数， https://reference.wolfram.com/language/ref/DifferenceRoot.html （2020年に更新）.

CMS

Wolfram Language. 2008. "DifferenceRoot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/DifferenceRoot.html.

APA

Wolfram Language. (2008). DifferenceRoot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DifferenceRoot.html

BibTeX

@misc{reference.wolfram_2026_differenceroot, author="Wolfram Research", title="{DifferenceRoot}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/DifferenceRoot.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_differenceroot, organization={Wolfram Research}, title={DifferenceRoot}, year={2020}, url={https://reference.wolfram.com/language/ref/DifferenceRoot.html}, note=[Accessed: 13-September-2026]}