WOLFRAM

Wolfram 语言与系统参考资料中心

DifferenceRoot[lde][k]

给出由线性微分方程 lde[h,k] 指定的完整序列 .

DifferenceRoot[lde]

表示纯完整序列 .

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
可视化  
函数属性  
特殊序列  
微分  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

DifferenceRoot

DifferenceRoot[lde][k]

给出由线性微分方程 lde[h,k] 指定的完整序列 .

DifferenceRoot[lde]

表示纯完整序列 .

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

将 f 定义为斐波那契数列：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]

计算第 20 个斐波那契数：

Wolfram Language code: f[20]

与内置 Fibonacci 函数对比结果：

Wolfram Language code: Fibonacci[20]

绘制前 10 个斐波那契数：

Wolfram Language code: DiscretePlot[f[n], {n, 0, 10}]

计算前 30 个斐波那契数的总和：

Wolfram Language code: Sum[f[n], {n, 30}]

求斐波那契数列的生成函数 ：

Wolfram Language code: F[x_] = GeneratingFunction[f[n], n, x]

求出 级数展开的前 10 个系数：

Wolfram Language code: Table[SeriesCoefficient[F[x], {x, 0, n}], {n, 0, 10}]

与前 10 个斐波那契数进行比较：

Wolfram Language code: Fibonacci[Table[n, {n, 0, 10}]]

通过应用 DifferenceRoot 函数，几个函数可以产生闭合形式的结果：

Wolfram Language code: Sum[(n + 4)!2 ^ n, n]
Wolfram Language code: RSolve[y[n + 3] + n y[n + 2] + y[n] == n! && y[0] == y[1] == y[2] == 1, y[n], n]
Wolfram Language code: SeriesCoefficient[Exp[(1/x^2 + 1)], {x, 0, n}]

范围  (21)

数值计算  (6)

定义一个 DifferenceRoot 数列：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == (n + 1)y[n], y[1] == 1}]]

在任意一点求值：

Wolfram Language code: f[20]

计算有非精确系数的数列：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {3.5 y[n + 1] == (n + 1)y[n], y[1] == 1}]][{3, 5, 10}]

计算带有复数参数的数列：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] - (n + 1)y[n], y[0] == 1 + 2I, y[1] == -3 + 2I}]][4]

计算有参数的数列：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == x y[n + 1] - (n + 1)y[n], y[0] == 1, y[1] == -3}]][4]

为负数项计算数列：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] - y[n], y[0] == 1, y[1] == 1 / 3}]][-5]

DifferenceRoot 以元素方式线性作用于（threads over）列表和矩阵：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] / (n + 1) - y[n] == 0, y[0] == 0, y[1] == 1}]][{1, 2, 3, 4, 5}]
Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] / (n + 1) - y[n] == 0, y[-1] == 1, y[1] == 1}]][(| | | | :- | :- | | 3 | -1 | | -2 | 6 |)]

可视化  (2)

定义一个 DifferenceRoot 对象，称作 f：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] - 1 / 2y[n], y[0] == 0, y[1] == 1}]]

绘制 f 的前 10 个项：

Wolfram Language code: DiscretePlot[f[n], {n, 0, 15}]

使用 ListLinePlot 绘制 f 的前25个项：

Wolfram Language code: ListLinePlot[Table[f[n], {n, 1, 25}], PlotRange -> All]

定义一个 DifferenceRoot 对象 f，其中参数 a 可为任意值：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == a y[n + 1] - 1 / 2y[n], y[0] == 0, y[1] == 1}]]

为不同数值的参数 a 绘制数列 f：

Wolfram Language code: DiscretePlot3D[f[n], {n, 3, 10}, {a, -1, 1, 1 / 10}, AxesLabel -> Automatic]

函数属性  (9)

DifferenceRoot 用于线性递归：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] - n y[n] == 0, y[0] == 0, y[1] == 1}]]

DifferenceRoot 将有有理系数的递归转换为有多项式系数的递归：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] / (n + 1) - y[n] == 0, y[0] == 0, y[1] == 1}]]

非齐次递归转换成更高阶的齐次递归：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] - n y[n] == n!, y[1] == 1}]]

DifferenceRoot 作用于有多项式强制函数的非齐次方程：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] - y[n] == n ^ 2, y[0] == 0, y[1] == 1}]]

计算这个数列的前 10 项：

Wolfram Language code: Table[f[n], {n, 1, 10}]

DifferenceRoot 用于多个初始值：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {-n y[n] + (1 + n)y[1 + n] == 0, y[-1] == 0, y[1] == 1}]]

有符号分量的级数的差分函数：

Wolfram Language code: DifferenceRootReduce[Fibonacci[n, x], n]
Wolfram Language code: Table[%, {n, 10}]

当 趋近于 Infinity 时，求 DifferenceRoot 对象的渐进首项：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] - n ^ 2 y[n] == 0, y[1] == 1}]][n]
Wolfram Language code: DiscreteAsymptotic[f, n -> ∞]

使用 AsymptoticRSolveValue 获取相同结果：

Wolfram Language code: AsymptoticRSolveValue[{y[n + 1] - n ^ 2 * y[n] == 0, y[1] == 1}, y[n], n -> ∞]

DifferenceRoot 可以有参数：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == a y[n + 1] - 1 / 2y[n], y[0] == 0, y[1] == 1}]]

为符号 a 计算这个数列的前 5 项：

Wolfram Language code: Table[f[n], {n, 1, 5}]

指定参数 a：

Wolfram Language code: % /. a -> -1 / 10

为不同参数 a 的值绘制数列 f：

Wolfram Language code: DiscretePlot3D[f[n], {n, 2, 10}, {a, -1, 1, 1 / 10}, AxesLabel -> Automatic]

如果可以的话，DifferenceRoot 约化到内置函数：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]
Wolfram Language code: FullSimplify[f[n]]

特殊序列  (3)

Fibonacci 的差分方程式形式：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]
Wolfram Language code: FullSimplify[f[n]]

LucasL 的差分方程式形式：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 2, y[1] == 1}]]
Wolfram Language code: FullSimplify[f[n]]

HarmonicNumber 的差分方程式形式：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {(n + 1)y[n + 1] == (n + 1) y[n] + 1, y[0] == 0}]]
Wolfram Language code: FullSimplify[f[n]]

微分  (1)

生成 ChebyshevT 多项式对应的参数数列:

Wolfram Language code: ChebTSequence = DifferenceRootReduce[ChebyshevT[n, x], n]

计算该数列关于参数的导数：

Wolfram Language code: dChebTSequence = D[ChebTSequence, x]

提取 ChebyshevT 导数遵守的差分方程：:

Wolfram Language code: %[[0, 1]][y, n]

通过对 ChebyshevT 直接求导检查是否与该数列前 10 项相等：

Wolfram Language code: Table[Expand[dChebTSequence == D[ChebyshevT[n, x], x]], {n, 0, 10}]

推广和延伸  (2)

有完整常数项的方程自动移位成多项式系数：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {y[n + 1] - y[n] == n!, y[0] == 1}]]

下面的函数在 n>0 时无定义：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {n y[1 + n] + (-1 + n) y[n] == 0, y[-1] == -1}]];
Wolfram Language code: Table[f[n], {n, -2, 2}]

加上初值 y[1]=2，使它对所有的 n 有定义：

Wolfram Language code: g = DifferenceRoot[Function[{y, n}, {n y[1 + n] + (-1 + n) y[n] == 0, y[1] == 2, y[-1] == -1}]];
Wolfram Language code: Table[g[n], {n, -2, 2}]

应用  (6)

使用 DifferenceRoot 获取 HarmonicNumber 的差分方程形式：

Wolfram Language code: DifferenceRootReduce[HarmonicNumber[k], k]

将特殊数列的组合约化为其 DifferenceRoot 格式：

Wolfram Language code: f = DifferenceRootReduce[Fibonacci[n] + 2LucasL[n] + n ^ 2, n]

像使用任何数列一样使用 f：

Wolfram Language code: Table[f, {n, 0, 5}]
Wolfram Language code: Table[Fibonacci[n] + 2LucasL[n] + n ^ 2, {n, 0, 5}]

使用 DifferenceRoot 定义佩尔数数列：

Wolfram Language code: PellNumber = DifferenceRoot[Function[{y, n}, {-y[n] - 2y[1 + n] + y[2 + n] == 0, y[0] == 0, y[1] == 1}]]

像使用任何数列一样使用它：

Wolfram Language code: Table[PellNumber[n], {n, 0, 5}]

证明佩尔数的属性：

Wolfram Language code: FullSimplify[PellNumber[n + 1]PellNumber[n - 1] - PellNumber[n] ^ 2 == (-1) ^ n]

闭合形式的公式：

Wolfram Language code: DifferenceRootReduce[PellNumber[n] == (-(1 - Sqrt[2]) ^ n + (1 + Sqrt[2]) ^ n) / (2Sqrt[2]), n]

加和恒等：

Wolfram Language code: DifferenceRootReduce[Sum[PellNumber[i], {i, 0, 4n + 1}] == (PellNumber[2n] + PellNumber[2n + 1]) ^ 2, n]

将特殊数列的组合约化成 DifferenceRoot 函数：

Wolfram Language code: f = DifferenceRootReduce[Fibonacci[n] ^ 2, n]

进行绘制：

Wolfram Language code: DiscretePlot[f, {n, -5, 5}]

生成一个函数，该函数的泰勒展开是给定的 DifferenceRoot 对象：

Wolfram Language code: GeneratingFunction[DifferenceRoot[Function[{y, n}, {y[n] + y[n + 1] + (1 + n) (2 + n) y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, x]

验证结果：

Wolfram Language code: SeriesCoefficient[%, {x, 0, n}]

生成可生成 BesselJ 函数的 DifferenceRoot 对象：

Wolfram Language code: f = BesselJ[k, z];
Wolfram Language code: DifferenceRootReduce[f, k]

属性和关系  (14)

用 DifferenceRootReduce 产生 DifferenceRoot 对象：

Wolfram Language code: f = DifferenceRootReduce[Fibonacci[n], n]

得到相应的常差分方程：

Wolfram Language code: oΔe = First[Head[f]][y, n]

用方程验证解：

Wolfram Language code: oΔe /. y -> Fibonacci//FullSimplify

一个 DifferenceRoot 对象的和：

Wolfram Language code: Sum[DifferenceRoot[Function[{y, n}, {-y[n] - y[n + 1] + y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n]
Wolfram Language code: Table[%, {n, 1, 10}]
Wolfram Language code: Accumulate[Table[Fibonacci[n], {n, 0, 9}]]

GeneratingFunction 可能会从完全数列中生成一个 DifferentialRoot：

Wolfram Language code: GeneratingFunction[DifferenceRoot[Function[{y, n}, {y[n] + (1 + n) (2 + n) y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, x]

在特定情况下，GeneratingFunction 可能会给出一个显函数：

Wolfram Language code: GeneratingFunction[DifferenceRoot[Function[{y, n}, {-y[n] - y[n + 1] + y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, z]

求 DifferenceRoot 对象的指数生成函数：

Wolfram Language code: ExponentialGeneratingFunction[DifferenceRoot[Function[{y, n}, {-y[n] - y[n + 1] + y[n + 2] == 0, y[0] == 0, y[1] == 1}]][n], n, z]

差分方程的解可能是一个 DifferenceRoot 对象：

Wolfram Language code: RSolve[a[1 + n] == a[n] + n a[n - 1] + n! && a[0] == 1 && a[1] == 2, a, n]

Sum 函数的结果可能是一个 DifferenceRoot：

Wolfram Language code: Sum[(n + 4)! 2^n, n]

函数展开式中的系数可以 DifferenceRoot 对象的形式给出：

Wolfram Language code: SeriesCoefficient[Exp[Sqrt[x + 1]], {x, 0, n}]

FindSequenceFunction 结果可能是一个 DifferenceRoot 对象：

Wolfram Language code: FindSequenceFunction[{2, 3 / 2, 7 / 3, 13 / 4, 26 / 5, 49 / 6, 92 / 7, 169 / 8, 307 / 9, 551 / 10, 980 / 11, 1729 / 12, 3030 / 13, 5279 / 14, 9151 / 15, 15793 / 16, 27150 / 17, 46513 / 18, 79440 / 19, 135301 / 20}, n]

FunctionExpand 尝试生成 DifferenceRoot 的更简单的表达式：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]
Wolfram Language code: FunctionExpand[f[n]]

FunctionExpand 尝试生成参数数列的更简单的表达式：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 2] == a y[n + 1] + y[n], y[0] == 0, y[1] == 1}]]
Wolfram Language code: FunctionExpand[f[n]]

将 f 定义成某个完全数列：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == 3y[n], y[1] == 7}]][{1, 2, 3, 4, 5}]

将结果与 RecurrenceTable 的输出进行比较：

Wolfram Language code: RecurrenceTable[{y[n + 1] == 3y[n], y[1] == 7}, y, {n, 1, 5}]

DiscreteShift 使用 DifferenceRoot 函数并生成一个平移数列：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == (n + 2) y[n], y[1] == 1}]]
Wolfram Language code: f[{1, 2, 3, 4, 5}]
Wolfram Language code: ds = DiscreteShift[f[n], n]
Wolfram Language code: ds /. n -> {1, 2, 3, 4, 5}

DifferenceDelta 将 DifferenceRoot 视作输入：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == n ^ 2 y[n], y[1] == 1}]]
Wolfram Language code: dd = DifferenceDelta[f[n], n]

化简该表达式：

Wolfram Language code: dd//FunctionExpand

可能存在的问题  (2)

DifferenceRoot 只计算有多项式系数的线性差分数列：

Wolfram Language code: DifferenceRoot[Function[{y, n}, {(Sqrt[n] + 1)y[n + 1] - y^2[n] == 0, y[0] == 0, y[1] == 1}]]

DifferenceRoot 只计算整数项：

Wolfram Language code: f = DifferenceRoot[Function[{y, n}, {y[n + 1] == (n + 1)y[n], y[1] == 1}]]
Wolfram Language code: f[3 / 2]

巧妙范例  (1)

定义一个 DifferenceRoot 函数：

Wolfram Language code: PadovanNumber = DifferenceRoot[Function[{y, n}, {y[n + 3] - y[n + 1] - y[n] == 0, y[0] == 1, y[1] == 1, y[2] == 1}]]

进行绘制：

Wolfram Language code: DiscretePlot[PadovanNumber[n], {n, 0, 20}]

证明恒等：

Wolfram Language code: DifferenceRootReduce[PadovanNumber[k] == PadovanNumber[k - 2] + PadovanNumber[k - 4] + PadovanNumber[k - 8], k]
Wolfram Language code: DifferenceRootReduce[Sum[PadovanNumber[2k + 1], {k, 0, n}] == PadovanNumber[2n + 4] - 1, n]

尝试展开成为非一般函数：

Wolfram Language code: g = FunctionExpand[PadovanNumber[n]]
Wolfram Language code: DiscretePlot[g, {n, 0, 20}]
Wolfram Research (2008)，DifferenceRoot，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DifferenceRoot.html （更新于 2020 年）.

文本

Wolfram Research (2008)，DifferenceRoot，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DifferenceRoot.html （更新于 2020 年）.

CMS

Wolfram 语言. 2008. "DifferenceRoot." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/DifferenceRoot.html.

APA

Wolfram 语言. (2008). DifferenceRoot. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DifferenceRoot.html 年

BibTeX

@misc{reference.wolfram_2026_differenceroot, author="Wolfram Research", title="{DifferenceRoot}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/DifferenceRoot.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_differenceroot, organization={Wolfram Research}, title={DifferenceRoot}, year={2020}, url={https://reference.wolfram.com/language/ref/DifferenceRoot.html}, note=[Accessed: 12-September-2026]}