WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DifferentiatorFilter[data,ωc]

カットオフ周波数 ωcの微分器フィルタをデータ配列に適用する．

DifferentiatorFilter[data,ωc,n]

長さ n のフィルタカーネルを使う．

DifferentiatorFilter[data,ωc,n,wfun]

平滑化窓 wfun をフィルタカーネルに適用する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
データ  
パラメータ  
オプション  
Padding  
SampleRate  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

DifferentiatorFilter

DifferentiatorFilter[data,ωc]

カットオフ周波数 ωcの微分器フィルタをデータ配列に適用する．

DifferentiatorFilter[data,ωc,n]

長さ n のフィルタカーネルを使う．

DifferentiatorFilter[data,ωc,n,wfun]

平滑化窓 wfun をフィルタカーネルに適用する．

詳細とオプション

  • DifferentiatorFilterは，一般にサンプルとして取ったデータの微分の近似に使われる，有限インパルス応答（impulse response，FIR）離散時間フィルタである．
  • data は次のいずれでもよい．
  • list任意階数の数値配列
    tseriesTimeSeriesやTemporalDataのような時間データ
    image任意のImageオブジェクトまたはImage3Dオブジェクト
    audioAudioオブジェクトまたはSoundオブジェクト
    videoVideoオブジェクト
  • 画像や多次元配列に適用された場合，フィルタリングはレベル1から始めて各次元に連続的に適用される．DifferentiatorFilter[data,{ωc1,ωc2,…}]は i 次元で周波数 ωci を使う．
  • カットオフ周波数 ωcでフィルタをかけると，微分の信号ノイズに対する感受性が低下する．平滑化の量はカットオフ周波数 ωcに依存する．
  • カットオフ周波数 ωcは0から まででなければならない．ωcの値が小さいほど滑らかになる．
  • DifferentiatorFilter[data,ωc]はカットオフ周波数 ωcと入力 data に適したフィルタカーネル長と平滑化窓を使う．
  • よく使われる平滑化窓 wfun
  • BlackmanWindowBlackman窓で平滑化する
    DirichletWindow平滑化は行わない
    HammingWindowハミング窓で平滑化する
    {v1,v2,…}値 viの窓を使う
    fからの範囲で f をサンプリングすることで窓を作る
  • 使用可能なオプション
  • Padding "Fixed"使用する充填値
    SampleRate Automatic入力に想定されるサンプルレート
  • デフォルトで，データと同様画像にもSampleRate->1が想定される．サンプルレート r のサンプル sound オブジェクトについては，SampleRate->r が使われる．
  • SampleRate->r の場合，カットオフ周波数 ωcは 0から r× まででなければならない．

例題

すべて開く すべて閉じる

例  (2)

サンプルされた余弦信号を微分する：

Wolfram Language code: dx = 0.1; data = Table[Cos[2x], {x, 0, 2π, dx}]; ListLinePlot[{data, (1/ 2dx) DifferentiatorFilter[data, Pi, 20]}]

画像を微分する：

Wolfram Language code: DifferentiatorFilter[[image], Pi / 2]//ImageAdjust

スコープ  (10)

データ  (7)

1D三角列にフィルタをかける：

Wolfram Language code: data = BoxMatrix[5, {41}]; ListLinePlot[{data, DifferentiatorFilter[data, 1.]}, PlotRange -> All]

2Dパルス列にフィルタをかける：

Wolfram Language code: data = Table[UnitBox[(n/7), (m/7)], {n, -7, 7}, {m, -7, 7}]; ListPlot3D[data]
Wolfram Language code: ListPlot3D[DifferentiatorFilter[data, 1.], PlotRange -> All]

TimeSeriesにフィルタをかける：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1]; filtered = DifferentiatorFilter[ts, Quantity[10, "Hertz"]];
Wolfram Language code: ListLinePlot[{ts, 5filtered}, PlotLegends -> {"original", "filtered"}, PlotRange -> All]

矩形波音声信号のデジタル微分：

Wolfram Language code: a = AudioGenerator["Square"]
Wolfram Language code: DifferentiatorFilter[a, Quantity[15000, "Hertz"]]

動画のフレームにフィルタをかける：

Wolfram Language code: DifferentiatorFilter[Video["ExampleData/fish.mp4"], 3]

3D画像の微分：

Wolfram Language code: 200DifferentiatorFilter[[image], Pi]

厳密精度でフィルタをかける：

Wolfram Language code: DifferentiatorFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, Pi, 4]

パラメータ  (3)

音声信号の場合，数値カットオフ周波数はラジアン／秒として解釈される：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-iz4x8)"]\);
Wolfram Language code: DifferentiatorFilter[a, 10000 2 Pi] === DifferentiatorFilter[a, Quantity[10000*2*Pi, "Radians"/"Seconds"]] === DifferentiatorFilter[a, Quantity[10000, "Hertz"]]

長さ7のフィルタを使った単位ステップ列の微分：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi, 6]

別のカットオフ周波数を使う：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi / 2, 6]

特定の窓関数を使う：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi, 6, BlackmanWindow]

窓関数を数値リストとして指定する：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi, 6, {1, 1, 1, 1, 1, 1}]

各次元に異なるカットオフ周波数を使う：

Wolfram Language code: DifferentiatorFilter[[image], {Pi / 3, Pi}, 20]//ImageAdjust

オプション  (4)

Padding  (2)

デフォルトで，"Fixed"充填が使われる：

Wolfram Language code: DifferentiatorFilter[[image], Pi / 3, 21]//ImageAdjust

Padding->Noneを使って潜在的な画像境界のアーチファクトを排除する：

Wolfram Language code: DifferentiatorFilter[[image], Pi / 3, 21, Padding -> None]//ImageAdjust

充填法を変えるとエッジ効果も変わる：

Wolfram Language code: ramp = Range[21] / 21. + RandomReal[.1, 21]; GraphicsRow@(ListLinePlot[{ramp, DifferentiatorFilter[ramp, Pi, 6, Padding -> #]}, ...]& /@ {"Fixed", "Periodic", 0})

SampleRate  (2)

正規化されたサンプルレート1を仮定して，ハイバンド微分フィルタを使う：

Wolfram Language code: DifferentiatorFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, π / 2., 5]

サンプルレート3を仮定する：

Wolfram Language code: DifferentiatorFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, 3 π / 2., 5, SampleRate -> 3]

ハイバンド微分器フィルタをレートでサンプルされた音声に適用する：

Wolfram Language code: a = AudioGenerator[Sin[11025 2 π #^2]&]; sr = QuantityMagnitude@AudioSampleRate[a]
Wolfram Language code: DifferentiatorFilter[a, sr π / 2., 21]//Periodogram

アプリケーション  (2)

導関数フィルタを使って画像中の辺をハイライトする：

Wolfram Language code: DifferentiatorFilter[[image], Pi, 6]//ImageAdjust

三角波を矩形波に変換する：

Wolfram Language code: x = Table[TriangleWave[n / 32], {n, 0, 63}]//N; y = DifferentiatorFilter[x, Pi, 6, Padding -> "Periodic"];
Wolfram Language code: GraphicsRow[{ListPlot[x, Filling -> 0, ImageSize -> Small], ListPlot[y, Filling -> 0, ImageSize -> Small]}]

特性と関係  (7)

LeastSquaresFilterKernelおよびハミング窓を使って微分器フィルタを作る：

Wolfram Language code: n = 5; ω = 1.5; win = Array[HammingWindow, n, {-1 / 2, 1 / 2}]; ker = win LeastSquaresFilterKernel[{"Differentiator", ω}, n]
Wolfram Language code: ListConvolve[ker, {0, 0, 0, 0, 1, 1, 1, 1}, Ceiling[n / 2], 0]

DifferentiatorFilterの結果と比較する：

Wolfram Language code: DifferentiatorFilter[{0, 0, 0, 0, 1, 1, 1, 1}, ω, n, win, Padding -> 0]

奇数長，フルバンドで長さ21の導関数フィルタのインパルス応答：

Wolfram Language code: h = DifferentiatorFilter[ArrayPad[{1.}, 10], Pi, 21]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

フィルタの振幅スペクトル：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

平滑化窓がない，奇数長のフルバンド導関数フィルタの振幅スペクトル：

Wolfram Language code: Plot[Evaluate@Abs[ListFourierSequenceTransform[DifferentiatorFilter[ArrayPad[{1.}, 10], Pi, 21, None], ω]], {ω, 0, π}]

偶数長のヒルベルトフィルタのインパルス応答：

Wolfram Language code: h = DifferentiatorFilter[ArrayPad[{1.}, 10], Pi, 20]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

フィルタの振幅スペクトル：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

平滑化窓がない，偶数長のフルバンド導関数フィルタの振幅スペクトル：

Wolfram Language code: Plot[Evaluate@Abs[ListFourierSequenceTransform[DifferentiatorFilter[ArrayPad[{1.}, 10], Pi, 20, None], ω]], {ω, 0, π}]

平滑化窓がない，奇数長のフルバンドの微分器フィルタの振幅スペクトル：

Wolfram Language code: Manipulate[ ListLinePlot[Abs[Fourier[DifferentiatorFilter[ArrayPad[{1.}, 128], Pi, n], FourierParameters -> {1, -1}]][[ ;; 129]], ...], {{n, 21}, 3, 127, 2}]

ハーフバンドで奇数長の導関数フィルタのインパルス応答：

Wolfram Language code: h = DifferentiatorFilter[ArrayPad[{1.}, 10], Pi / 2, 21]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

フィルタの振幅スペクトル：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

考えられる問題  (1)

PaddingNoneとすると，出力は入力よりも短くなる：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 1., 1., 1.}, 1., Padding -> None]
Wolfram Research (2012), DifferentiatorFilter, Wolfram言語関数， https://reference.wolfram.com/language/ref/DifferentiatorFilter.html （2025年に更新）.

テキスト

Wolfram Research (2012), DifferentiatorFilter, Wolfram言語関数， https://reference.wolfram.com/language/ref/DifferentiatorFilter.html （2025年に更新）.

CMS

Wolfram Language. 2012. "DifferentiatorFilter." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/DifferentiatorFilter.html.

APA

Wolfram Language. (2012). DifferentiatorFilter. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DifferentiatorFilter.html

BibTeX

@misc{reference.wolfram_2026_differentiatorfilter, author="Wolfram Research", title="{DifferentiatorFilter}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/DifferentiatorFilter.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_differentiatorfilter, organization={Wolfram Research}, title={DifferentiatorFilter}, year={2025}, url={https://reference.wolfram.com/language/ref/DifferentiatorFilter.html}, note=[Accessed: 09-September-2026]}